contrib/benitlux/src/benitlux_daily.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Daily program to fetch and parse the Web site, update the database and email subscribers
  18 module benitlux_daily
  19
  20 import curl
  21 import sendmail
  22 import opts
  23
  24 import benitlux_model
  25 import benitlux_db
  26
  27 redef class Text
  28         # Return a `String` without any HTML tags (such as `<br />`) from `recv`
  29         fun strip_tags: String
  30         do
  31                 var str = to_s
  32                 var new_str = ""
  33
  34                 var from = 0
  35                 loop
  36                         var at = str.index_of_from('<', from)
  37                         if at == -1 then break
  38
  39                         new_str += str.substring(from, at-from)
  40
  41                         at = str.index_of_from('>', at)
  42                         assert at != -1
  43
  44                         from = at+1
  45                 end
  46
  47                 return new_str
  48         end
  49
  50         # Return an `Array` of the non-empty lines in `self`
  51         #
  52         #     assert ["a", "asdf", "", "  ", "&nbsp;", "b"].join("\n").to_clean_lines == ["a", "asdf", "b"]
  53         fun to_clean_lines: Array[String]
  54         do
  55                 var orig_lines = split_with("\n")
  56                 var new_lines = new Array[String]
  57
  58                 for line in orig_lines do
  59                         line = line.trim
  60
  61                         # remove empty lines
  62                         if line == "&nbsp;" then continue
  63                         if line.is_empty then continue
  64
  65                         new_lines.add line.to_s
  66                 end
  67
  68                 return new_lines
  69         end
  70 end
  71
  72 # Main logic of the program to be executed daily
  73 class Benitlux
  74         # The street on which is the Benelux
  75         var street: String
  76
  77         # The url of this precise Benelux
  78         var url: String
  79
  80         # Path to the database
  81         var db_path: String
  82
  83         # Where to save the sample email
  84         var sample_email_path: String
  85
  86         init(street: String)
  87         do
  88                 self.street = street
  89                 self.url = "www.brasseriebenelux.com/{street}"
  90                 self.db_path = "benitlux_{street}.db"
  91                 self.sample_email_path = "benitlux_{street}.email"
  92         end
  93
  94         # Execute the main program logic
  95         fun run(send_emails: Bool)
  96         do
  97                 # Get the web page
  98                 var body = download_html_page
  99
 100                 # Parse the Web page and get the available beers
 101                 var beers = parse_beers_from_html(body)
 102
 103                 var db = new DB.open(db_path)
 104
 105                 # Update the database with the beers of the day
 106                 db.insert_beers_of_the_day beers
 107
 108                 # Query the beer-related events of today
 109                 var beer_events = db.beer_events_today
 110
 111                 # Generate the email title and content, store them in attributes
 112                 generate_email(beer_events)
 113
 114                 # Save as sample email to file
 115                 var f = new FileWriter.open(sample_email_path)
 116                 f.write email_title + "\n"
 117                 for line in email_content do f.write line + "\n"
 118                 f.close
 119
 120                 # Set the email if desired
 121                 if send_emails then
 122                         var subs = db.subscribers
 123                         send_emails_to subs
 124                 end
 125
 126                 db.close
 127         end
 128
 129         # Fetch the Web page at `url`
 130         fun download_html_page: String
 131         do
 132                 var curl = new Curl
 133
 134                 var request = new CurlHTTPRequest(url, curl)
 135                 var response = request.execute
 136
 137                 if response isa CurlResponseSuccess then
 138                         var body = response.body_str
 139                         curl.destroy
 140                         return body
 141                 else if response isa CurlResponseFailed then
 142                         print "Failed downloading URL '{url}' with: {response.error_msg} ({response.error_code})"
 143                         exit 1
 144                 end
 145                 abort
 146         end
 147
 148         # Extract the beers of the day information from the HTML if `body`
 149         fun parse_beers_from_html(body: String): HashSet[Beer]
 150         do
 151                 # Parts of the HTML page expected to encapsulate the interesting section
 152                 var header = "<h1>Bières<br /></h1>"
 153                 var ender = "</div></div></div>"
 154
 155                 var match = body.search(header)
 156                 assert match != null else print body
 157                 var start = match.after
 158
 159                 match = body.search_from(ender, start)
 160                 assert match != null
 161                 var finish = match.from
 162
 163                 var of_interest = body.substring(start, finish-start)
 164                 var lines = of_interest.strip_tags.to_clean_lines
 165
 166                 var beers = new HashSet[Beer]
 167                 for line in lines do
 168                         var parts = line.split(" - ")
 169                         if parts.length >= 2 then
 170                                 beers.add new Beer(parts[0].trim, parts[1].trim)
 171                         end
 172                 end
 173                 return beers
 174         end
 175
 176         # Content lines of the email
 177         var email_content: Array[String]
 178
 179         # Title of the email
 180         var email_title: String
 181
 182         # Generate email and fill the attributes `email_content` and `email_title`
 183         fun generate_email(beer_events: BeerEvents)
 184         do
 185                 email_title = beer_events.to_email_title
 186                 email_content = beer_events.to_email_content
 187         end
 188
 189         # Send the email to all the addresses in `subs`
 190         fun send_emails_to(subs: Array[String])
 191         do
 192                 for email in subs do
 193                         var unsub_link = "http://benitlux.xymus.net/?unsub=&email={email}"
 194                         var content = """
 195 {{{email_content.join("<br />\n")}}}
 196 <br /><br />
 197 To unsubscribe, go to <a href="{{{unsub_link}}}">{{{unsub_link}}}</a>
 198 """
 199
 200                         var mail = new Mail("Benitlux <benitlux@xymus.net>", email_title, content)
 201                         mail.to.add email
 202                         mail.header["Content-Type"] = "text/html; charset=\"UTF-8\""
 203                         mail.encrypt_with_base64
 204
 205                         mail.send
 206                 end
 207         end
 208 end
 209
 210 redef class OptionContext
 211         # Shall we mail the mailing list?
 212         var send_emails = new OptionBool("Send emails to subscribers", "-e", "--email")
 213
 214         # Print the usage message
 215         var help = new OptionBool("Print this help message", "-h", "--help")
 216
 217         redef init do add_option(send_emails, help)
 218 end
 219
 220 # Avoid executing when running tests
 221 if "NIT_TESTING".environ == "true" then exit 0
 222
 223 var opts = new OptionContext
 224 opts.parse args
 225 if not opts.errors.is_empty or opts.help.value == true then
 226         print opts.errors.join("\n")
 227         print "Usage: benitlux_daily [Options]"
 228         opts.usage
 229         exit 1
 230 end
 231
 232 var ben = new Benitlux("sherbrooke")
 233 ben.run(opts.send_emails.value)
 234
 235 # The parsing logic for the wellington locaiton is active (to gather data)
 236 # but the web interface do not allow to subscribe to its mailing list.
 237 #
 238 # TODO revamp mailing list Web interface
 239 ben = new Benitlux("wellington")
 240 ben.run(opts.send_emails.value)