src/debugger.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2013 Lucas Bajolet <lucas.bajolet@gmail.com>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Debugging of a nit program using the NaiveInterpreter
  18 module debugger
  19
  20 import breakpoint
  21 intrude import naive_interpreter
  22 import nitx
  23 intrude import local_var_init
  24 intrude import scope
  25 intrude import toolcontext
  26
  27 redef class Model
  28         # Cleans the model to remove a module and what it defines when semantic analysis fails on injected code
  29         private fun try_remove_module(m: MModule): Bool
  30         do
  31                 var index = -1
  32                 for i in [0 .. mmodules.length[ do
  33                         if mmodules[i] == m then
  34                                 index = i
  35                                 break
  36                         end
  37                 end
  38                 if index == -1 then return false
  39                 var mmodule = mmodules[index]
  40                 mmodules.remove_at(index)
  41                 for classdef in mmodule.mclassdefs do
  42                         var mclass = classdef.mclass
  43                         for i in [0 .. mclass.mclassdefs.length[ do
  44                                 if mclass.mclassdefs[i] == classdef then
  45                                         index = i
  46                                         break
  47                                 end
  48                         end
  49                         mclass.mclassdefs.remove_at(index)
  50                         var propdefs = classdef.mpropdefs
  51                         for propdef in propdefs do
  52                                 var prop = propdef.mproperty
  53                                 for i in [0..prop.mpropdefs.length[ do
  54                                         if prop.mpropdefs[i] == propdef then
  55                                                 index = i
  56                                                 break
  57                                         end
  58                                 end
  59                                 prop.mpropdefs.remove_at(index)
  60                         end
  61                 end
  62                 return true
  63         end
  64 end
  65
  66 redef class ScopeVisitor
  67
  68         redef init(toolcontext)
  69         do
  70                 super
  71                 if toolcontext.dbg != null then
  72                         var localvars = toolcontext.dbg.frame.map
  73                         for i in localvars.keys do
  74                                 scopes.first.variables[i.to_s] = i
  75                         end
  76                 end
  77         end
  78
  79 end
  80
  81 redef class LocalVarInitVisitor
  82         redef fun mark_is_unset(node: AExpr, variable: nullable Variable)
  83         do
  84                 super
  85                 if toolcontext.dbg != null then
  86                         var varname = variable.to_s
  87                         var instmap = toolcontext.dbg.frame.map
  88                         for i in instmap.keys do
  89                                 if i.to_s == varname then
  90                                         mark_is_set(node, variable)
  91                                 end
  92                         end
  93                 end
  94         end
  95
  96 end
  97
  98 redef class ToolContext
  99         private var dbg: nullable Debugger = null
 100
 101         private var had_error: Bool = false
 102
 103         redef fun check_errors
 104         do
 105                 if dbg == null then
 106                         super
 107                 else
 108                         if messages.length > 0 then
 109                                 message_sorter.sort(messages)
 110
 111                                 for m in messages do
 112                                         if "Warning".search_in(m.text, 0) == null then had_error = true
 113                                         stderr.write("{m.to_color_string}\n")
 114                                 end
 115                         end
 116
 117                         messages.clear
 118                 end
 119         end
 120
 121         # -d
 122         var opt_debugger_mode: OptionBool = new OptionBool("Launches the target program with the debugger attached to it", "-d")
 123         # -c
 124         var opt_debugger_autorun: OptionBool = new OptionBool("Launches the target program with the interpreter, such as when the program fails, the debugging prompt is summoned", "-c")
 125
 126         redef init
 127         do
 128                 super
 129                 self.option_context.add_option(self.opt_debugger_mode)
 130                 self.option_context.add_option(self.opt_debugger_autorun)
 131         end
 132 end
 133
 134 redef class ModelBuilder
 135         # Execute the program from the entry point (Sys::main) of the `mainmodule`
 136         # `arguments` are the command-line arguments in order
 137         # REQUIRE that:
 138         #   1. the AST is fully loaded.
 139         #   2. the model is fully built.
 140         #   3. the instructions are fully analysed.
 141         fun run_debugger(mainmodule: MModule, arguments: Array[String])
 142         do
 143                 var time0 = get_time
 144                 self.toolcontext.info("*** START INTERPRETING ***", 1)
 145
 146                 var interpreter = new Debugger(self, mainmodule, arguments)
 147
 148                 init_naive_interpreter(interpreter, mainmodule)
 149
 150                 var time1 = get_time
 151                 self.toolcontext.info("*** END INTERPRETING: {time1-time0} ***", 2)
 152         end
 153
 154         fun run_debugger_autorun(mainmodule: MModule, arguments: Array[String])
 155         do
 156                 var time0 = get_time
 157                 self.toolcontext.info("*** START INTERPRETING ***", 1)
 158
 159                 var interpreter = new Debugger(self, mainmodule, arguments)
 160                 interpreter.autocontinue = true
 161
 162                 init_naive_interpreter(interpreter, mainmodule)
 163
 164                 var time1 = get_time
 165                 self.toolcontext.info("*** END INTERPRETING: {time1-time0} ***", 2)
 166         end
 167 end
 168
 169 # The class extending `NaiveInterpreter` by adding debugging methods
 170 class Debugger
 171         super NaiveInterpreter
 172
 173         # Keeps the frame count in memory to find when to stop
 174         # and launch the command prompt after a step out call
 175         var step_stack_count = 1
 176
 177         # Triggers a step over an instruction in a nit program
 178         var stop_after_step_over_trigger = true
 179
 180         # Triggers a step out of an instruction
 181         var stop_after_step_out_trigger= false
 182
 183         # Triggers a step in a instruction (enters a function
 184         # if the instruction is a function call)
 185         var step_in_trigger = false
 186
 187         # HashMap containing the breakpoints bound to a file
 188         var breakpoints = new HashMap[String, HashSet[Breakpoint]]
 189
 190         # Contains the current file
 191         var curr_file = ""
 192
 193         # Aliases hashmap (maps an alias to a variable name)
 194         var aliases = new HashMap[String, String]
 195
 196         # Set containing all the traced variables and their related frame
 197         private var traces = new HashSet[TraceObject]
 198
 199         # Map containing all the positions for the positions of the arguments traced
 200         # In a function call
 201         private var fun_call_arguments_positions = new HashMap[Int, TraceObject]
 202
 203         # Triggers the remapping of a trace object in the local context after a function call
 204         var aftermath = false
 205
 206         # Used to prevent the case when the body of the function called is empty
 207         # If it is not, then, the remapping won't be happening
 208         var frame_count_aftermath = 1
 209
 210         # Auto continues the execution until the end or until an error is encountered
 211         var autocontinue = false
 212
 213         #######################################################################
 214         ##                  Execution of statement function                  ##
 215         #######################################################################
 216
 217         # Main loop, every call to a debug command is done here
 218         redef fun stmt(n: nullable AExpr)
 219         do
 220                 if n == null then return
 221
 222                 var frame = self.frame
 223                 var old = frame.current_node
 224                 frame.current_node = n
 225
 226                 if not self.autocontinue then
 227                         if not n isa ABlockExpr then
 228                                 steps_fun_call(n)
 229
 230                                 breakpoint_check(n)
 231
 232                                 check_funcall_and_traced_args(n)
 233
 234                                 remap(n)
 235
 236                                 check_if_vars_are_traced(n)
 237                         end
 238                 end
 239
 240                 n.stmt(self)
 241                 frame.current_node = old
 242         end
 243
 244         # Does the same as an usual send, except it will modify the call chain on the first call when injecting code at Runtime using the debugger.
 245         # Instead of creating a pristine Frame, it will copy the actual values of the frame, and re-inject them after execution in the current context.
 246         fun rt_send(mproperty: MMethod, args: Array[Instance]): nullable Instance
 247         do
 248                 var recv = args.first
 249                 var mtype = recv.mtype
 250                 var ret = send_commons(mproperty, args, mtype)
 251                 if ret != null then return ret
 252                 var propdef = mproperty.lookup_first_definition(self.mainmodule, mtype)
 253                 return self.rt_call(propdef, args)
 254         end
 255
 256         # Same as a regular call but for a runtime injected module
 257         #
 258         fun rt_call(mpropdef: MMethodDef, args: Array[Instance]): nullable Instance
 259         do
 260                 args = call_commons(mpropdef, args)
 261                 return rt_call_without_varargs(mpropdef, args)
 262         end
 263
 264         # Common code to call and this function
 265         #
 266         # Call only executes the variadic part, this avoids
 267         # double encapsulation of variadic parameters into an Array
 268         fun rt_call_without_varargs(mpropdef: MMethodDef, args: Array[Instance]): nullable Instance
 269         do
 270                 if self.modelbuilder.toolcontext.opt_discover_call_trace.value and not self.discover_call_trace.has(mpropdef) then
 271                         self.discover_call_trace.add mpropdef
 272                         self.debug("Discovered {mpropdef}")
 273                 end
 274                 if args.length < mpropdef.msignature.arity + 1 or args.length > mpropdef.msignature.arity + 1 then
 275                         fatal("NOT YET IMPLEMENTED: Invalid arity for {mpropdef}. {args.length} arguments given.")
 276                 end
 277                 if args.length < mpropdef.msignature.arity + 1 then
 278                         fatal("NOT YET IMPLEMENTED: default closures")
 279                 end
 280
 281                 # Look for the AST node that implements the property
 282                 var mproperty = mpropdef.mproperty
 283                 if self.modelbuilder.mpropdef2npropdef.has_key(mpropdef) then
 284                         var npropdef = self.modelbuilder.mpropdef2npropdef[mpropdef]
 285                         self.parameter_check(npropdef, mpropdef, args)
 286                         if npropdef isa AConcreteMethPropdef then
 287                                 return npropdef.rt_call(self, mpropdef, args)
 288                         else
 289                                 print "Error, invalid propdef to call at runtime !"
 290                                 return null
 291                         end
 292                 else if mproperty.name == "init" then
 293                         var nclassdef = self.modelbuilder.mclassdef2nclassdef[mpropdef.mclassdef]
 294                         self.parameter_check(nclassdef, mpropdef, args)
 295                         return nclassdef.call(self, mpropdef, args)
 296                 else
 297                         fatal("Fatal Error: method {mpropdef} not found in the AST")
 298                         abort
 299                 end
 300         end
 301
 302         # Evaluates dynamically a snippet of Nit code
 303         # `nit_code` : Nit code to be executed
 304         fun eval(nit_code: String)
 305         do
 306                 var local_toolctx = modelbuilder.toolcontext
 307                 local_toolctx.dbg = self
 308                 var e = local_toolctx.parse_something(nit_code)
 309                 if e isa AExpr then
 310                         nit_code = "print " + nit_code
 311                         e = local_toolctx.parse_something(nit_code)
 312                 end
 313                 if e isa AModule then
 314                         local_toolctx.had_error = false
 315                         modelbuilder.load_rt_module(self.mainmodule, e, "rt_module")
 316                         local_toolctx.run_phases([e])
 317                         if local_toolctx.had_error then
 318                                 modelbuilder.model.try_remove_module(e.mmodule.as(not null))
 319                                 local_toolctx.dbg = null
 320                                 return
 321                         end
 322                         var mmod = e.mmodule
 323                         if mmod != null then
 324                                 self.mainmodule = mmod
 325                                 var local_classdefs = mmod.mclassdefs
 326                                 var sys_type = mmod.sys_type
 327                                 if sys_type == null then
 328                                         print "Fatal error, cannot find Class Sys !\nAborting"
 329                                         abort
 330                                 end
 331                                 var mobj = new MutableInstance(sys_type)
 332                                 init_instance(mobj)
 333                                 var initprop = mmod.try_get_primitive_method("init", sys_type.mclass)
 334                                 if initprop != null then
 335                                         self.send(initprop, [mobj])
 336                                 end
 337                                 var mainprop = mmod.try_get_primitive_method("main", sys_type.mclass)
 338                                 if mainprop != null then
 339                                         self.rt_send(mainprop, [mobj])
 340                                 end
 341                         else
 342                                 print "Error while loading_rt_module"
 343                         end
 344                 else
 345                         print "Error when parsing, e = {e.class_name}"
 346                 end
 347                 local_toolctx.dbg = null
 348         end
 349
 350         # Encpasulates the behaviour for step over/out
 351         private fun steps_fun_call(n: AExpr)
 352         do
 353                 if self.stop_after_step_over_trigger then
 354                         if self.frames.length <= self.step_stack_count then
 355                                 n.debug("Execute stmt {n.to_s}")
 356                                 while read_cmd do end
 357                         end
 358                 else if self.stop_after_step_out_trigger then
 359                         if frames.length < self.step_stack_count then
 360                                 n.debug("Execute stmt {n.to_s}")
 361                                 while read_cmd do end
 362                         end
 363                 else if step_in_trigger then
 364                         n.debug("Execute stmt {n.to_s}")
 365                         while read_cmd do end
 366                 end
 367         end
 368
 369         # Checks if a breakpoint is encountered, and launches the debugging prompt if true
 370         private fun breakpoint_check(n: AExpr)
 371         do
 372                 var currFileNameSplit = self.frame.current_node.location.file.filename.to_s.split_with("/")
 373
 374                 self.curr_file = currFileNameSplit[currFileNameSplit.length-1]
 375
 376                 var breakpoint = find_breakpoint(curr_file, n.location.line_start)
 377
 378                 if breakpoints.keys.has(curr_file) and breakpoint != null then
 379
 380                         breakpoint.check_in
 381
 382                         if not breakpoint.is_valid
 383                         then
 384                                 remove_breakpoint(curr_file, n.location.line_start)
 385                         end
 386
 387                         n.debug("Execute stmt {n.to_s}")
 388                         while read_cmd do end
 389                 end
 390         end
 391
 392         # Check if a variable of current expression is traced
 393         # Then prints and/or breaks for command prompt
 394         private fun check_if_vars_are_traced(n: AExpr)
 395         do
 396                 var identifiers_in_instruction = get_identifiers_in_current_instruction(n.location.text)
 397
 398                 for i in identifiers_in_instruction do
 399                         var variable = seek_variable(i, frame)
 400                         for j in self.traces do
 401                                 if j.is_variable_traced_in_frame(i, frame) then
 402                                         n.debug("Traced variable {i} used")
 403                                         if j.break_on_encounter then while read_cmd do end
 404                                         break
 405                                 end
 406                         end
 407                 end
 408         end
 409
 410         # Function remapping all the traced objects to match their name in the local context
 411         private fun remap(n: AExpr)
 412         do
 413                 if self.aftermath then
 414
 415                         # Trace every argument variable pre-specified
 416                         if self.frame_count_aftermath < frames.length and fun_call_arguments_positions.length > 0 then
 417
 418                                 var ids_in_fun_def = get_identifiers_in_current_instruction(get_function_arguments(frame.mpropdef.location.text))
 419
 420                                 for i in fun_call_arguments_positions.keys do
 421                                         self.fun_call_arguments_positions[i].add_frame_variable(frame, ids_in_fun_def[i])
 422                                 end
 423                         end
 424
 425                         self.aftermath = false
 426                 end
 427         end
 428
 429         # If the current instruction is a function call
 430         # We analyse its signature and the position of traced arguments if the call
 431         # For future remapping when inside the function
 432         private fun check_funcall_and_traced_args(n: AExpr) do
 433                 # If we have a function call, we need to see if any of the arguments is traced (including the caller)
 434                 # if it is, next time we face an instruction, we'll trace the local version on the traced variable in the next frame
 435                 if n isa ACallExpr then
 436                         self.aftermath = true
 437                         self.frame_count_aftermath = frames.length
 438                         fun_call_arguments_positions.clear
 439                         var fun_arguments = get_identifiers_in_current_instruction(get_function_arguments(n.location.text))
 440
 441                         for i in self.traces do
 442                                 for j in [0 .. fun_arguments.length - 1] do
 443                                         if i.is_variable_traced_in_frame(fun_arguments[j],frame) then
 444                                                 fun_call_arguments_positions[j] = i
 445                                         end
 446                                 end
 447                         end
 448                 end
 449         end
 450
 451         #######################################################################
 452         ##                   Processing commands functions                   ##
 453         #######################################################################
 454
 455         fun read_cmd: Bool
 456         do
 457                 printn "> "
 458                 return process_debug_command(gets)
 459         end
 460
 461         # Takes a user command as a parameter
 462         #
 463         # Returns a boolean value, representing whether or not to
 464         # continue reading commands from the console input
 465         fun process_debug_command(command:String): Bool
 466         do
 467                 # Step-out command
 468                 if command == "finish"
 469                 then
 470                         return step_out
 471                 # Step-in command
 472                 else if command == "s"
 473                 then
 474                         return step_in
 475                 # Step-over command
 476                 else if command == "n" then
 477                         return step_over
 478                 # Opens a new NitIndex prompt on current model
 479                 else if command == "nitx" then
 480                         new NitIndex.with_infos(modelbuilder, self.mainmodule).prompt
 481                         return true
 482                 # Continues execution until the end
 483                 else if command == "c" then
 484                         return continue_exec
 485                 else if command == "nit" then
 486                         printn "$~> "
 487                         command = gets
 488                         var nit_buf = new Buffer
 489                         while not command == ":q" do
 490                                 nit_buf.append(command)
 491                                 nit_buf.append("\n")
 492                                 printn "$~> "
 493                                 command = gets
 494                         end
 495                         step_in
 496                         eval(nit_buf.to_s)
 497                 else if command == "quit" then
 498                         exit(0)
 499                 else if command == "abort" then
 500                         print stack_trace
 501                         exit(0)
 502                 else
 503                         var parts_of_command = command.split_with(' ')
 504                         # Shows the value of a variable in the current frame
 505                         if parts_of_command[0] == "p" or parts_of_command[0] == "print" then
 506                                 print_command(parts_of_command)
 507                         # Places a breakpoint on line x of file y
 508                         else if parts_of_command[0] == "break" or parts_of_command[0] == "b"
 509                         then
 510                                 process_place_break_fun(parts_of_command)
 511                         # Places a temporary breakpoint on line x of file y
 512                         else if parts_of_command[0] == "tbreak" and (parts_of_command.length == 2 or parts_of_command.length == 3)
 513                         then
 514                                 process_place_tbreak_fun(parts_of_command)
 515                         # Removes a breakpoint on line x of file y
 516                         else if parts_of_command[0] == "d" or parts_of_command[0] == "delete" then
 517                                 process_remove_break_fun(parts_of_command)
 518                         # Sets an alias for a variable
 519                         else if parts_of_command.length == 3 and parts_of_command[1] == "as"
 520                         then
 521                                 add_alias(parts_of_command[0], parts_of_command[2])
 522                         # Modifies the value of a variable in the current frame
 523                         else if parts_of_command.length >= 3 and parts_of_command[1] == "=" then
 524                                 process_mod_function(parts_of_command)
 525                         # Traces the modifications on a variable
 526                         else if parts_of_command.length >= 2 and parts_of_command[0] == "trace" then
 527                                 process_trace_command(parts_of_command)
 528                         # Untraces the modifications on a variable
 529                         else if parts_of_command.length == 2 and parts_of_command[0] == "untrace" then
 530                                 process_untrace_command(parts_of_command)
 531                         else
 532                                 print "Unknown command \"{command}\""
 533                         end
 534                 end
 535                 return true
 536         end
 537
 538         #######################################################################
 539         ##               Processing specific command functions               ##
 540         #######################################################################
 541
 542         # Sets the flags to step-over an instruction in the current file
 543         fun step_over: Bool
 544         do
 545                 self.step_stack_count = frames.length
 546                 self.stop_after_step_over_trigger = true
 547                 self.stop_after_step_out_trigger = false
 548                 self.step_in_trigger = false
 549                 return false
 550         end
 551
 552         #Sets the flags to step-out of a function
 553         fun step_out: Bool
 554         do
 555                 self.stop_after_step_over_trigger = false
 556                 self.stop_after_step_out_trigger = true
 557                 self.step_in_trigger = false
 558                 self.step_stack_count = frames.length
 559                 return false
 560         end
 561
 562         # Sets the flags to step-in an instruction
 563         fun step_in: Bool
 564         do
 565                 self.step_in_trigger = true
 566                 self.stop_after_step_over_trigger = false
 567                 self.stop_after_step_out_trigger = false
 568                 return false
 569         end
 570
 571         # Sets the flags to continue execution
 572         fun continue_exec: Bool
 573         do
 574                 self.stop_after_step_over_trigger = false
 575                 self.stop_after_step_out_trigger = false
 576                 self.step_in_trigger = false
 577                 return false
 578         end
 579
 580         # Prints the demanded variable in the command
 581         #
 582         # The name of the variable in in position 1 of the array 'parts_of_command'
 583         fun print_command(parts_of_command: Array[String])
 584         do
 585                 if parts_of_command[1] == "*" then
 586                         var map_of_instances = frame.map
 587
 588                         var keys = map_of_instances.iterator
 589
 590                         print "Variables collection : \n"
 591
 592                         for instance in map_of_instances.keys do
 593                                 print "Variable {instance.to_s}, Instance {map_of_instances[instance].to_s}"
 594                         end
 595
 596                         print "\nEnd of current instruction \n"
 597                 else if parts_of_command[1] == "stack" then
 598                         print self.stack_trace
 599                 else if parts_of_command[1].has('[') and parts_of_command[1].has(']') then
 600                         process_array_command(parts_of_command)
 601                 else
 602                         var instance = seek_variable(get_real_variable_name(parts_of_command[1]), frame)
 603
 604                         if instance != null
 605                         then
 606                                 print_instance(instance)
 607                         else
 608                                 print "Cannot find variable {parts_of_command[1]}"
 609                         end
 610                 end
 611         end
 612
 613         # Processes the input string to know where to put a breakpoint
 614         fun process_place_break_fun(parts_of_command: Array[String])
 615         do
 616                 var bp = get_breakpoint_from_command(parts_of_command)
 617                 if bp != null then
 618                         place_breakpoint(bp)
 619                 end
 620         end
 621
 622         # Returns a breakpoint containing the informations stored in the command
 623         fun get_breakpoint_from_command(parts_of_command: Array[String]): nullable Breakpoint
 624         do
 625                 if parts_of_command[1].is_numeric then
 626                         return new Breakpoint(parts_of_command[1].to_i, curr_file)
 627                 else if parts_of_command.length >= 3 and parts_of_command[2].is_numeric then
 628                         return new Breakpoint(parts_of_command[2].to_i, parts_of_command[1])
 629                 else
 630                         return null
 631                 end
 632         end
 633
 634         # Processes the command of removing a breakpoint on specified line and file
 635         fun process_remove_break_fun(parts_of_command: Array[String])
 636         do
 637                 if parts_of_command[1].is_numeric then
 638                         remove_breakpoint(self.curr_file, parts_of_command[1].to_i)
 639                 else if parts_of_command.length >= 3 and parts_of_command[2].is_numeric then
 640                         remove_breakpoint(parts_of_command[1], parts_of_command[2].to_i)
 641                 end
 642         end
 643
 644         # Processes an array print command
 645         fun process_array_command(parts_of_command: Array[String])
 646         do
 647                 var index_of_first_brace = parts_of_command[1].index_of('[')
 648                 var variable_name = get_real_variable_name(parts_of_command[1].substring(0,index_of_first_brace))
 649                 var braces = parts_of_command[1].substring_from(index_of_first_brace)
 650
 651                 var indexes = remove_braces(braces)
 652
 653                 var index_array = new Array[Array[Int]]
 654
 655                 if indexes != null then
 656                         for index in indexes do
 657                                 var temp_indexes_array = process_index(index)
 658                                 if temp_indexes_array != null then
 659                                         index_array.push(temp_indexes_array)
 660                                         #print index_array.last
 661                                 end
 662                         end
 663                 end
 664
 665                 var instance = seek_variable(variable_name, frame)
 666
 667                 if instance != null then
 668                         print_nested_collection(instance, index_array, 0, variable_name, "")
 669                 else
 670                         print "Cannot find variable {variable_name}"
 671                 end
 672         end
 673
 674         # Processes the modification function to modify a variable dynamically
 675         #
 676         # Command of type variable = value
 677         fun process_mod_function(parts_of_command: Array[String])
 678         do
 679                 parts_of_command[0] = get_real_variable_name(parts_of_command[0])
 680                 var parts_of_variable = parts_of_command[0].split_with(".")
 681
 682                 if parts_of_variable.length > 1 then
 683                         var last_part = parts_of_variable.pop
 684                         var first_part = parts_of_command[0].substring(0,parts_of_command[0].length - last_part.length - 1)
 685                         var papa = seek_variable(first_part, frame)
 686
 687                         if papa != null and papa isa MutableInstance then
 688                                 var attribute = get_attribute_in_mutable_instance(papa, last_part)
 689
 690                                 if attribute != null then
 691                                         modify_argument_of_complex_type(papa, attribute, parts_of_command[2])
 692                                 end
 693                         end
 694                 else
 695                         var target = seek_variable(parts_of_variable[0], frame)
 696                         if target != null then
 697                                 modify_in_frame(target, parts_of_command[2])
 698                         end
 699                 end
 700         end
 701
 702         # Processes the untrace variable command
 703         #
 704         # Command pattern : "untrace variable"
 705         fun process_untrace_command(parts_of_command: Array[String])
 706         do
 707                 var variable_name = get_real_variable_name(parts_of_command[1])
 708                 if untrace_variable(variable_name) then
 709                         print "Untraced variable {parts_of_command[1]}"
 710                 else
 711                         print "{parts_of_command[1]} is not traced"
 712                 end
 713         end
 714
 715         # Processes the trace variable command
 716         #
 717         # Command pattern : "trace variable [break/print]"
 718         fun process_trace_command(parts_of_command: Array[String])
 719         do
 720                 var variable_name = get_real_variable_name(parts_of_command[1])
 721                 var breaker:Bool
 722
 723                 if seek_variable(variable_name, frame) == null then
 724                         print "Cannot find a variable called {parts_of_command[1]}"
 725                         return
 726                 end
 727
 728                 if parts_of_command.length == 3 then
 729                         if parts_of_command[2] == "break" then
 730                                 breaker = true
 731                         else
 732                                 breaker = false
 733                         end
 734                 else
 735                         breaker = false
 736                 end
 737
 738                 trace_variable(variable_name, breaker)
 739
 740                 print "Successfully tracing {parts_of_command[1]}"
 741         end
 742
 743         #######################################################################
 744         ##                    Trace Management functions                     ##
 745         #######################################################################
 746
 747         # Effectively untraces the variable called *variable_name*
 748         #
 749         # Returns true if the variable exists, false otherwise
 750         private fun untrace_variable(variable_name: String): Bool
 751         do
 752                 var to_remove: nullable TraceObject = null
 753                 for i in self.traces do
 754                         if i.is_variable_traced_in_frame(variable_name, frame) then
 755                                 to_remove = i
 756                         end
 757                 end
 758
 759                 if to_remove != null then
 760                         self.traces.remove(to_remove)
 761                         return true
 762                 else
 763                         return false
 764                 end
 765         end
 766
 767         # Effectively traces the variable *variable_name* either in print or break mode depending on the value of breaker (break if true, print if false)
 768         #
 769         private fun trace_variable(variable_name: String, breaker: Bool)
 770         do
 771                 for i in self.traces do
 772                         if i.is_variable_traced_in_frame(variable_name, frame) then
 773                                 print "This variable is already traced"
 774                                 return
 775                         end
 776                 end
 777
 778                 var trace_object: TraceObject
 779
 780                 if breaker then
 781                         trace_object = new TraceObject(true)
 782                 else
 783                         trace_object = new TraceObject(false)
 784                 end
 785
 786                 # We trace the current variable found for the current frame
 787                 trace_object.add_frame_variable(self.frame, variable_name)
 788
 789                 var position_of_variable_in_arguments = get_position_of_variable_in_arguments(frame, variable_name)
 790
 791                 # Start parsing the frames starting with the parent of the current one, until the highest
 792                 # When the variable traced is declared locally, the loop stops
 793                 for i in [1 .. frames.length-1] do
 794
 795                         # If the variable was reported to be an argument of the previous frame
 796                         if position_of_variable_in_arguments != -1 then
 797
 798                                 var local_name = get_identifiers_in_current_instruction(get_function_arguments(frames[i].current_node.location.text))[position_of_variable_in_arguments]
 799
 800                                 position_of_variable_in_arguments = get_position_of_variable_in_arguments(frames[i], local_name)
 801
 802                                 trace_object.add_frame_variable(frames[i], local_name)
 803                         else
 804                                 break
 805                         end
 806                 end
 807
 808                 self.traces.add(trace_object)
 809         end
 810
 811         # If the variable *variable_name* is an argument of the function being executed in the frame *frame*
 812         # The function returns its position in the arguments
 813         # Else, it returns -1
 814         private fun get_position_of_variable_in_arguments(frame: Frame, variable_name: String): Int
 815         do
 816                 var identifiers = get_identifiers_in_current_instruction(get_function_arguments(frame.mpropdef.location.text))
 817                 for i in [0 .. identifiers.length-1] do
 818                         # If the current traced variable is an argument of the current function, we trace its parent (at least)
 819                         if identifiers[i] == variable_name then return i
 820                 end
 821                 return -1
 822         end
 823
 824         # Gets all the identifiers of an instruction (uses the rules of Nit as of Mar 05 2013)
 825         #
 826         fun get_identifiers_in_current_instruction(instruction: AbstractString): Array[String]
 827         do
 828                 var result_array = new Array[String]
 829                 var instruction_buffer = new Buffer
 830
 831                 var trigger_char_escape = false
 832                 var trigger_string_escape = false
 833                 var trigger_concat_in_string = false
 834
 835                 for i in instruction do
 836                         if trigger_char_escape then
 837                                 if i == '\'' then trigger_char_escape = false
 838                         else if trigger_string_escape then
 839                                 if i == '{' then
 840                                         trigger_concat_in_string = true
 841                                         trigger_string_escape = false
 842                                 else if i == '\"' then trigger_string_escape = false
 843                         else
 844                                 if i.is_alphanumeric or i == '_' then
 845                                         instruction_buffer.add(i)
 846                                 else if i == '.' then
 847                                         if instruction_buffer.is_numeric or (instruction_buffer[0] >= 'A' and instruction_buffer[0] <= 'Z') then
 848                                                 instruction_buffer.clear
 849                                         else
 850                                                 result_array.push(instruction_buffer.to_s)
 851                                                 instruction_buffer.add(i)
 852                                         end
 853                                 else if i == '\'' then
 854                                         trigger_char_escape = true
 855                                 else if i == '\"' then
 856                                         trigger_string_escape = true
 857                                 else if i == '}' then
 858                                         trigger_concat_in_string = false
 859                                         trigger_string_escape = true
 860                                 else
 861                                         if instruction_buffer.length > 0 and not instruction_buffer.is_numeric and not (instruction_buffer[0] >= 'A' and instruction_buffer[0] <= 'Z') then result_array.push(instruction_buffer.to_s)
 862                                         instruction_buffer.clear
 863                                 end
 864                         end
 865                 end
 866
 867                 if instruction_buffer.length > 0 and not instruction_buffer.is_numeric and not (instruction_buffer[0] >= 'A' and instruction_buffer[0] <= 'Z') then result_array.push(instruction_buffer.to_s)
 868
 869                 return result_array
 870         end
 871
 872         # Takes a function call or declaration and strips all but the arguments
 873         #
 874         fun get_function_arguments(function: AbstractString): String
 875         do
 876                 var buf = new Buffer
 877                 var trigger_copy = false
 878
 879                 for i in function do
 880                         if i == ')' then break
 881                         if trigger_copy then buf.add(i)
 882                         if i == '(' then trigger_copy = true
 883                 end
 884
 885                 return buf.to_s
 886         end
 887
 888         #######################################################################
 889         ##                    Alias management functions                     ##
 890         #######################################################################
 891
 892         # Adds a new alias to the tables
 893         fun add_alias(var_represented: String, alias: String)
 894         do
 895                 self.aliases[alias] = var_represented
 896         end
 897
 898         # Gets the real name of a variable hidden by an alias
 899         fun get_variable_name_by_alias(alias: String): nullable String
 900         do
 901                 if self.aliases.keys.has(alias) then
 902                         return self.aliases[alias]
 903                 end
 904
 905                 return null
 906         end
 907
 908         # Gets the variable named by name, whether it is an alias or not
 909         fun get_real_variable_name(name: String): String
 910         do
 911                 var explode_string = name.split_with(".")
 912                 var final_string = new Buffer
 913                 for i in explode_string do
 914                         var alias_resolved = get_variable_name_by_alias(i)
 915                         if alias_resolved != null then
 916                                 final_string.append(get_real_variable_name(alias_resolved))
 917                         else
 918                                 final_string.append(i)
 919                         end
 920                         final_string.append(".")
 921                 end
 922
 923                 return final_string.substring(0,final_string.length-1).to_s
 924         end
 925
 926         #######################################################################
 927         ##                         Print functions                           ##
 928         #######################################################################
 929
 930         # Prints an object instance and its attributes if it has some
 931         #
 932         # If it is a primitive type, its value is directly printed
 933         fun print_instance(instance: Instance)
 934         do
 935                 print "Printing innards of a variable"
 936
 937                 if instance isa MutableInstance then
 938                         var attributes = instance.attributes
 939                         print "Object : {instance}"
 940
 941                         for current_attribute in attributes.keys do
 942                                 print "Attribute : {current_attribute.to_s} \nValeur : {attributes[current_attribute].to_s}"
 943                         end
 944                 else
 945                         print "Found variable {instance}"
 946                 end
 947
 948                 print "Stopping printing innards of a variable"
 949         end
 950
 951         # Prints the attributes demanded in a SequenceRead
 952         # Used recursively to print nested collections
 953         fun print_nested_collection(instance: Instance, indexes: Array[Array[Int]], depth: Int, variable_name: String, depth_string: String)
 954         do
 955                 var collection: nullable SequenceRead[Object] = null
 956                 var real_collection_length: nullable Int = null
 957
 958                 if instance isa MutableInstance then
 959                         real_collection_length = get_collection_instance_real_length(instance)
 960                         collection = get_primary_collection(instance)
 961                 end
 962
 963                 if collection != null and real_collection_length != null then
 964                         for i in indexes[depth] do
 965                                 if i >= 0 and i < real_collection_length then
 966                                         if depth == indexes.length-1 then
 967                                                 print "{variable_name}{depth_string}[{i}] = {collection[i]}"
 968                                         else
 969                                                 var item_i = collection[i]
 970
 971                                                 if item_i isa MutableInstance then
 972                                                         print_nested_collection(item_i, indexes, depth+1, variable_name, depth_string+"[{i}]")
 973                                                 else
 974                                                         print "The item at {variable_name}{depth_string}[{i}] is not a collection"
 975                                                         print item_i
 976                                                 end
 977                                         end
 978                                 else
 979                                         print "Out of bounds exception : i = {i} and collection_length = {real_collection_length.to_s}"
 980
 981                                         if i < 0 then
 982                                                 continue
 983                                         else if i >= real_collection_length then
 984                                                 break
 985                                         end
 986                                 end
 987                         end
 988                 else
 989                         if collection == null then
 990                                 print "Cannot find {variable_name}{depth_string}"
 991                         else if real_collection_length != null then
 992                                 print "Cannot find attribute length in {instance}"
 993                         else
 994                                 print "Unknown error."
 995                                 abort
 996                         end
 997                 end
 998         end
 999
1000         #######################################################################
1001         ##                  Variable Exploration functions                   ##
1002         #######################################################################
1003
1004         # Seeks a variable from the current frame called 'variable_path', can introspect complex objects using function get_variable_in_mutable_instance
1005         private fun seek_variable(variable_path: String, frame: Frame): nullable Instance
1006         do
1007                 var full_variable = variable_path.split_with(".")
1008
1009                 var full_variable_iterator = full_variable.iterator
1010
1011                 var first_instance = get_variable_in_frame(full_variable_iterator.item, frame)
1012
1013                 if first_instance == null then  return null
1014
1015                 if full_variable.length <= 1 then return first_instance
1016
1017                 full_variable_iterator.next
1018
1019                 if not (first_instance isa MutableInstance and full_variable_iterator.is_ok) then return null
1020
1021                 return get_variable_in_mutable_instance(first_instance, full_variable_iterator)
1022         end
1023
1024         # Gets a variable 'variable_name' contained in the frame 'frame'
1025         private fun get_variable_in_frame(variable_name: String, frame: Frame): nullable Instance
1026         do
1027                 if variable_name == "self" then
1028                         if frame.arguments.length >= 1 then return frame.arguments.first
1029                 end
1030
1031                 var map_of_instances = frame.map
1032
1033                 for key in map_of_instances.keys do
1034                         if key.to_s == variable_name then
1035                                 return map_of_instances[key]
1036                         end
1037                 end
1038
1039                 return null
1040         end
1041
1042         # Gets an attribute 'attribute_name' contained in variable 'variable'
1043         fun get_attribute_in_mutable_instance(variable: MutableInstance, attribute_name: String): nullable MAttribute
1044         do
1045                 var map_of_attributes = variable.attributes
1046
1047                 for key in map_of_attributes.keys do
1048                         if key.to_s.substring_from(1) == attribute_name then
1049                                 return key
1050                         end
1051                 end
1052
1053                 return null
1054         end
1055
1056         # Recursive function, returns the variable described by 'total_chain'
1057         fun get_variable_in_mutable_instance(variable: MutableInstance, iterator: Iterator[String]): nullable Instance
1058         do
1059                 var attribute = get_attribute_in_mutable_instance(variable, iterator.item)
1060
1061                 if attribute == null then return null
1062
1063                 iterator.next
1064
1065                 if iterator.is_ok then
1066                         var new_variable = variable.attributes[attribute]
1067                         if new_variable isa MutableInstance then
1068                                 return get_variable_in_mutable_instance(new_variable, iterator)
1069                         else
1070                                 return null
1071                         end
1072                 else
1073                         return variable.attributes[attribute]
1074                 end
1075         end
1076
1077         #######################################################################
1078         ##                     Array exploring functions                     ##
1079         #######################################################################
1080
1081         # Gets the length of a collection
1082         # Used by the debugger, else if we call Collection.length, it returns the capacity instead
1083         fun get_collection_instance_real_length(collection: MutableInstance): nullable Int
1084         do
1085                 var collection_length_attribute = get_attribute_in_mutable_instance(collection, "length")
1086
1087                 var real_collection_length: nullable Int = null
1088
1089                 if collection_length_attribute != null then
1090                         var primitive_length_instance = collection.attributes[collection_length_attribute]
1091                         if primitive_length_instance isa PrimitiveInstance[Int] then
1092                                 return primitive_length_instance.val
1093                         end
1094                 end
1095
1096                 return null
1097         end
1098
1099         # Processes the indexes of a print array call
1100         # Returns an array containing all the indexes demanded
1101         fun process_index(index_string: String): nullable Array[Int]
1102         do
1103                 var from_end_index = index_string.index_of('.')
1104                 var to_start_index = index_string.last_index_of('.')
1105
1106                 if from_end_index != -1 and to_start_index != -1 then
1107                         var index_from_string = index_string.substring(0,from_end_index)
1108                         var index_to_string = index_string.substring_from(to_start_index+1)
1109
1110                         if index_from_string.is_numeric and index_to_string.is_numeric then
1111                                 var result_array = new Array[Int]
1112
1113                                 var index_from = index_from_string.to_i
1114                                 var index_to = index_to_string.to_i
1115
1116                                 for i in [index_from..index_to] do
1117                                         result_array.push(i)
1118                                 end
1119
1120                                 return result_array
1121                         end
1122                 else
1123                         if index_string.is_numeric
1124                         then
1125                                 var result_array = new Array[Int]
1126
1127                                 result_array.push(index_string.to_i)
1128
1129                                 return result_array
1130                         else
1131                                 return null
1132                         end
1133                 end
1134
1135                 return null
1136         end
1137
1138         # Gets a collection in a MutableInstance
1139         fun get_primary_collection(container: MutableInstance): nullable SequenceRead[Object]
1140         do
1141                 var items_of_array = get_attribute_in_mutable_instance(container, "items")
1142                 if items_of_array != null then
1143                         var array = container.attributes[items_of_array]
1144
1145                         if array isa PrimitiveInstance[Object] then
1146                                 var sequenceRead_final = array.val
1147                                 if sequenceRead_final isa SequenceRead[Object] then
1148                                         return sequenceRead_final
1149                                 end
1150                         end
1151                 end
1152
1153                 return null
1154         end
1155
1156         # Removes the braces '[' ']' in a print array command
1157         # Returns an array containing their content
1158         fun remove_braces(braces: String): nullable Array[String]
1159         do
1160                 var buffer = new Buffer
1161
1162                 var result_array = new Array[String]
1163
1164                 var number_of_opening_brackets = 0
1165                 var number_of_closing_brackets = 0
1166
1167                 var last_was_opening_bracket = false
1168
1169                 for i in braces do
1170                         if i == '[' then
1171                                 if last_was_opening_bracket then
1172                                         return null
1173                                 end
1174
1175                                 number_of_opening_brackets += 1
1176                                 last_was_opening_bracket = true
1177                         else if i == ']' then
1178                                 if not last_was_opening_bracket then
1179                                         return null
1180                                 end
1181
1182                                 result_array.push(buffer.to_s)
1183                                 buffer.clear
1184                                 number_of_closing_brackets += 1
1185                                 last_was_opening_bracket = false
1186                         else if i.is_numeric or i == '.' then
1187                                 buffer.append(i.to_s)
1188                         else if not i == ' ' then
1189                                 return null
1190                         end
1191                 end
1192
1193                 if number_of_opening_brackets != number_of_closing_brackets then
1194                         return null
1195                 end
1196
1197                 return result_array
1198         end
1199
1200         #######################################################################
1201         ##                   Breakpoint placing functions                    ##
1202         #######################################################################
1203
1204         # Places a breakpoint on line 'line_to_break' for file 'file_to_break'
1205         fun place_breakpoint(breakpoint: Breakpoint)
1206         do
1207                 if not self.breakpoints.keys.has(breakpoint.file) then
1208                         self.breakpoints[breakpoint.file] = new HashSet[Breakpoint]
1209                 end
1210                 if find_breakpoint(breakpoint.file, breakpoint.line) == null then
1211                         self.breakpoints[breakpoint.file].add(breakpoint)
1212                         print "Breakpoint added on line {breakpoint.line} for file {breakpoint.file}"
1213                 else
1214                         print "Breakpoint already present on line {breakpoint.line} for file {breakpoint.file}"
1215                 end
1216         end
1217
1218         #Places a breakpoint that will trigger once and be destroyed afterwards
1219         fun process_place_tbreak_fun(parts_of_command: Array[String])
1220         do
1221                 var bp = get_breakpoint_from_command(parts_of_command)
1222                 if bp != null
1223                 then
1224                         bp.set_max_breaks(1)
1225                         place_breakpoint(bp)
1226                 end
1227         end
1228
1229         #######################################################################
1230         ##                  Breakpoint removing functions                    ##
1231         #######################################################################
1232
1233         # Removes a breakpoint on line 'line_to_break' for file 'file_to_break'
1234         fun remove_breakpoint(file_to_break: String, line_to_break: Int)
1235         do
1236                 if self.breakpoints.keys.has(file_to_break) then
1237                         var bp = find_breakpoint(file_to_break, line_to_break)
1238
1239                         if bp != null then
1240                                 self.breakpoints[file_to_break].remove(bp)
1241                                 print "Breakpoint removed on line {line_to_break} for file {file_to_break}"
1242                                 return
1243                         end
1244                 end
1245
1246                 print "No breakpoint existing on line {line_to_break} for file {file_to_break}"
1247         end
1248
1249         #######################################################################
1250         ##                  Breakpoint searching functions                   ##
1251         #######################################################################
1252
1253         # Finds a breakpoint for 'file' and 'line' in the class HashMap
1254         fun find_breakpoint(file: String, line: Int): nullable Breakpoint
1255         do
1256                 if self.breakpoints.keys.has(file)
1257                 then
1258                         for i in self.breakpoints[file]
1259                         do
1260                                 if i.line == line
1261                                 then
1262                                         return i
1263                                 end
1264                         end
1265                 end
1266
1267                 return null
1268         end
1269
1270         #######################################################################
1271         ##                  Runtime modification functions                   ##
1272         #######################################################################
1273
1274         # Modifies the value of a variable contained in a frame
1275         fun modify_in_frame(variable: Instance, value: String)
1276         do
1277                 var new_variable = get_variable_of_type_with_value(variable.mtype.to_s, value)
1278                 if new_variable != null
1279                 then
1280                         var keys = frame.map.keys
1281                         for key in keys
1282                         do
1283                                 if frame.map[key] == variable
1284                                 then
1285                                         frame.map[key] = new_variable
1286                                 end
1287                         end
1288                 end
1289         end
1290
1291         # Modifies the value of a variable contained in a MutableInstance
1292         fun modify_argument_of_complex_type(papa: MutableInstance, attribute: MAttribute, value: String)
1293         do
1294                 var final_variable = papa.attributes[attribute]
1295                 var type_of_variable = final_variable.mtype.to_s
1296                 var new_variable = get_variable_of_type_with_value(type_of_variable, value)
1297                 if new_variable != null
1298                 then
1299                         papa.attributes[attribute] = new_variable
1300                 end
1301         end
1302
1303         #######################################################################
1304         ##                   Variable generator functions                    ##
1305         #######################################################################
1306
1307         # Returns a new variable of the type 'type_of_variable' with a value of 'value'
1308         fun get_variable_of_type_with_value(type_of_variable: String, value: String): nullable Instance
1309         do
1310                 if type_of_variable == "Int" then
1311                         return get_int(value)
1312                 else if type_of_variable == "Float" then
1313                         return get_float(value)
1314                 else if type_of_variable == "Bool" then
1315                         return get_bool(value)
1316                 else if type_of_variable == "Char" then
1317                         return get_char(value)
1318                 end
1319
1320                 return null
1321         end
1322
1323         # Returns a new int instance with value 'value'
1324         fun get_int(value: String): nullable Instance
1325         do
1326                 if value.is_numeric then
1327                         return int_instance(value.to_i)
1328                 else
1329                         return null
1330                 end
1331         end
1332
1333         # Returns a new float instance with value 'value'
1334         fun get_float(value:String): nullable Instance
1335         do
1336                 if value.is_numeric then
1337                         return float_instance(value.to_f)
1338                 else
1339                         return null
1340                 end
1341         end
1342
1343         # Returns a new char instance with value 'value'
1344         fun get_char(value: String): nullable Instance
1345         do
1346                 if value.length >= 1 then
1347                         return char_instance(value[0])
1348                 else
1349                         return null
1350                 end
1351         end
1352
1353         # Returns a new bool instance with value 'value'
1354         fun get_bool(value: String): nullable Instance
1355         do
1356                 if value.to_lower == "true" then
1357                         return self.true_instance
1358                 else if value.to_lower == "false" then
1359                         return self.false_instance
1360                 else
1361                         print "Invalid value, a boolean must be set at \"true\" or \"false\""
1362                         return null
1363                 end
1364         end
1365
1366 end
1367
1368 redef class AConcreteMethPropdef
1369
1370         # Same as call except it will copy local variables of the parent frame to the frame defined in this call.
1371         # Not supposed to be used by anyone else than the Debugger.
1372         private fun rt_call(v: Debugger, mpropdef: MMethodDef, args: Array[Instance]): nullable Instance
1373         do
1374                 var f = new Frame(self, self.mpropdef.as(not null), args)
1375                 var curr_instances = v.frame.map
1376                 for i in curr_instances.keys do
1377                         f.map[i] = curr_instances[i]
1378                 end
1379                 call_commons(v,mpropdef,args,f)
1380                 var currFra = v.frames.shift
1381                 for i in curr_instances.keys do
1382                         if currFra.map.keys.has(i) then
1383                                 curr_instances[i] = currFra.map[i]
1384                         end
1385                 end
1386                 if v.returnmark == f then
1387                         v.returnmark = null
1388                         var res = v.escapevalue
1389                         v.escapevalue = null
1390                         return res
1391                 end
1392                 return null
1393
1394         end
1395 end
1396
1397 # Traces the modifications of an object linked to a certain frame
1398 private class TraceObject
1399
1400         # Map of the local names bound to a frame
1401         var trace_map: HashMap[Frame, String]
1402         # Decides if breaking or printing statement when the variable is encountered
1403         var break_on_encounter: Bool
1404
1405         init(break_on_encounter: Bool)
1406         do
1407                 trace_map = new HashMap[Frame, String]
1408                 self.break_on_encounter = break_on_encounter
1409         end
1410
1411         # Adds the local alias for a variable and the frame bound to it
1412         fun add_frame_variable(frame: Frame, variable_name: String)
1413         do
1414                 self.trace_map[frame] = variable_name
1415         end
1416
1417         # Checks if the prompted variable is traced in the specified frame
1418         fun is_variable_traced_in_frame(variable_name: String, frame: Frame): Bool
1419         do
1420                 if self.trace_map.has_key(frame) then
1421                         if self.trace_map[frame] == variable_name then
1422                                 return true
1423                         end
1424                 end
1425
1426                 return false
1427         end
1428
1429 end
1430
1431 redef class ANode
1432
1433         # Breaks automatically when encountering an error
1434         # Permits the injunction of commands before crashing
1435         redef private fun fatal(v: NaiveInterpreter, message: String)
1436         do
1437                 if v isa Debugger then
1438                         print "An error was encountered, the program will stop now."
1439                         self.debug(message)
1440                         while v.process_debug_command(gets) do end
1441                 end
1442
1443                 super
1444         end
1445 end