lib/nitcc_runtime.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Runtime library required by parsers and lexers generated by nitcc
  16 module nitcc_runtime
  17
  18 # A abstract parser engine generated by nitcc
  19 abstract class Parser
  20         # The list of tokens
  21         # FIXME: provide something better, like a lexer?
  22         var tokens = new List[NToken]
  23
  24         # Look at the next token
  25         # Used by generated parsers
  26         fun peek_token: NToken do return tokens.first
  27
  28         # Consume the next token
  29         # Used by generated parsers
  30         fun get_token: NToken do return tokens.shift
  31
  32         # Consume the next token and shift to the state `dest`.
  33         # Used by generated parsers
  34         fun shift(dest: LRState)
  35         do
  36                 var t = get_token
  37                 #print "shift {t} -> {dest}"
  38                 node_stack.push t
  39                 state_stack.push state
  40                 state = dest
  41         end
  42
  43         # After a reduction on `goto` go to the next state
  44         # Used by generated parsers
  45         fun goto(goto: LRGoto)
  46         do
  47                 #print "reduce from {state} -> {prod}"
  48                 state.goto(self, goto)
  49         end
  50
  51         # push a new state on the stack of states (
  52         # Used by generated parsers
  53         fun push(dest: LRState)
  54         do
  55                 #print "push prod {prod} -> {dest}"
  56                 state_stack.push state
  57                 state = dest
  58         end
  59
  60         # Pop and return the last node
  61         # Also pop (and discard) the associated state
  62         # Used by generated parsers
  63         fun pop: Node
  64         do
  65                 var res = node_stack.pop
  66                 state = state_stack.pop
  67                 return res
  68         end
  69
  70         # Produce a parse error and stop the parsing
  71         # Used by generated parsers
  72         fun parse_error
  73         do
  74                 var token = peek_token
  75                 #print "* parse error in state {state} on token {token}"
  76                 #print "  expected: {state.error_msg}"
  77                 #print "  node_stack={node_stack.join(", ")}"
  78                 #print "  state_stack={state_stack.join(", ")}"
  79                 node_stack.add(token)
  80                 var error: NError
  81                 if token isa NLexerError then
  82                         error = token
  83                 else
  84                         error = new NParserError
  85                         error.position = token.position
  86                         error.text = token.text
  87                         error.token = token
  88                 end
  89                 error.error_tree.children.add_all(node_stack)
  90                 error.expected = state.error_msg
  91                 node_stack.clear
  92                 node_stack.add error
  93                 stop = true
  94         end
  95
  96         # The stating state for parsing
  97         # Used by generated parsers
  98         protected fun start_state: LRState is abstract
  99
 100         # The current state
 101         # Used by generated parsers
 102         var state: LRState is noinit
 103
 104         init
 105         do
 106                 state = start_state
 107         end
 108
 109         # The stack of nodes
 110         # Used by generated parsers
 111         var node_stack = new Array[Node]
 112
 113         # The stack of states
 114         # Used by generated parsers
 115         var state_stack = new Array[LRState]
 116
 117         # Should the parser stop
 118         # Used by generated parsers
 119         var stop = true is writable
 120
 121         # Parse a full sequence of tokens and return a complete syntactic tree
 122         fun parse: Node
 123         do
 124                 state = start_state
 125                 state_stack.clear
 126                 node_stack.clear
 127                 stop = false
 128                 while not stop do
 129                         #print "* current state {state}"
 130                         #print "  tokens={tokens.join(" ")}"
 131                         #print "  node_stack={node_stack.join(" ")}"
 132                         #print "  state_stack={state_stack.join(" ")}"
 133                         state.action(self)
 134                 end
 135                 #print "* over"
 136                 return node_stack.first
 137         end
 138 end
 139
 140 # A state in a parser LR automaton generated by nitcc
 141 # Used by generated parsers
 142 abstract class LRState
 143         fun action(parser: Parser) is abstract
 144         fun goto(parser: Parser, goto: LRGoto) is abstract
 145         fun error_msg: String do return "FIXME"
 146 end
 147
 148 # A concrete production in a parser LR automation generated by nitcc
 149 # Used by generated parsers
 150 abstract class LRGoto
 151 end
 152
 153 ###
 154
 155 # A abstract lexer engine generated by nitcc
 156 abstract class Lexer
 157         # The input stream of characters
 158         var stream: String
 159
 160         # The stating state for lexing
 161         # Used by generated parsers
 162         protected fun start_state: DFAState is abstract
 163
 164         # Lexize a stream of characters and return a sequence of tokens
 165         fun lex: List[NToken]
 166         do
 167                 var res = new List[NToken]
 168                 var state = start_state
 169                 var pos = 0
 170                 var pos_start = 0
 171                 var pos_end = 0
 172                 var line = 1
 173                 var line_start = 1
 174                 var line_end = 0
 175                 var col = 1
 176                 var col_start = 1
 177                 var col_end = 0
 178                 var last_state: nullable DFAState = null
 179                 var text = stream
 180                 var length = text.length
 181                 loop
 182                         if state.is_accept then
 183                                 pos_end = pos - 1
 184                                 line_end = line
 185                                 col_end = col
 186                                 last_state = state
 187                         end
 188                         var c
 189                         var next
 190                         if pos >= length then
 191                                 c = '\0'
 192                                 next = null
 193                         else
 194                                 c = text.chars[pos]
 195                                 next = state.trans(c)
 196                         end
 197                         if next == null then
 198                                 if pos_start < length then
 199                                         if last_state == null then
 200                                                 var token = new NLexerError
 201                                                 var position = new Position(pos_start, pos, line_start, line, col_start, col)
 202                                                 token.position = position
 203                                                 token.text = text.substring(pos_start, pos-pos_start+1)
 204                                                 res.add token
 205                                                 break
 206                                         end
 207                                         var position = new Position(pos_start, pos_end, line_start, line_end, col_start, col_end)
 208                                         var token = last_state.make_token(position, text.substring(pos_start, pos_end-pos_start+1))
 209                                         if token != null then res.add(token)
 210                                 end
 211                                 if pos >= length then
 212                                         var token = new NEof
 213                                         var position = new Position(pos, pos, line, line, col, col)
 214                                         token.position = position
 215                                         token.text = ""
 216                                         res.add token
 217                                         break
 218                                 end
 219                                 state = start_state
 220                                 pos_start = pos_end + 1
 221                                 pos = pos_start
 222                                 line_start = line_end
 223                                 line = line_start
 224                                 col_start = col_end
 225                                 col = col_start
 226
 227                                 last_state = null
 228                                 continue
 229                         end
 230                         state = next
 231                         pos += 1
 232                         col += 1
 233                         if c == '\n' then
 234                                 line += 1
 235                                 col = 1
 236                         end
 237                 end
 238                 return res
 239         end
 240 end
 241
 242 # A state in a lexer automaton generated by nitcc
 243 # Used by generated lexers
 244 interface DFAState
 245         fun is_accept: Bool do return false
 246         fun trans(c: Char): nullable DFAState do return null
 247         fun make_token(position: Position, text: String): nullable NToken is abstract
 248 end
 249
 250 ###
 251
 252 # A abstract visitor on syntactic trees generated by nitcc
 253 abstract class Visitor
 254         # The main entry point to visit a node `n`
 255         # Should not be redefined
 256         fun enter_visit(n: Node)
 257         do
 258                 visit(n)
 259         end
 260
 261         # The specific implementation of a visit
 262         #
 263         # Should be redefined by concrete visitors
 264         #
 265         # Should not be called directly (use `enter_visit` instead)
 266         #
 267         # By default, the visitor just rescursively visit the children of `n`
 268         protected fun visit(n: Node)
 269         do
 270                 n.visit_children(self)
 271         end
 272 end
 273
 274 # Print a node (using to_s) on a line and recustively each children indented (with two spaces)
 275 class TreePrinterVisitor
 276         super Visitor
 277         var writer: Writer
 278         private var indent = 0
 279         redef fun visit(n)
 280         do
 281                 for i in [0..indent[ do writer.write("  ")
 282                 writer.write(n.to_s)
 283                 writer.write("\n")
 284                 indent += 1
 285                 super
 286                 indent -= 1
 287         end
 288 end
 289
 290 # A position into a input stream
 291 # Used to give position to tokens
 292 class Position
 293         var pos_start: Int
 294         var pos_end: Int
 295         var line_start: Int
 296         var line_end: Int
 297         var col_start: Int
 298         var col_end: Int
 299         redef fun to_s do return "{line_start}:{col_start}-{line_end}:{col_end}"
 300 end
 301
 302 # A node of a syntactic tree
 303 abstract class Node
 304         # The name of the node (as used in the grammar file)
 305         fun node_name: String do return class_name
 306
 307         # A point of view on the direct children of the node
 308         fun children: SequenceRead[nullable Node] is abstract
 309
 310         # A point of view of a depth-first visit of all non-null children
 311         var depth: Collection[Node] = new DephCollection(self)
 312
 313         # Visit all the children of the node with the visitor `v`
 314         protected fun visit_children(v: Visitor)
 315         do
 316                 for c in children do if c != null then v.enter_visit(c)
 317         end
 318
 319         # The position of the node in the input stream
 320         var position: nullable Position = null is writable
 321
 322         # Produce a graphiz file for the syntaxtic tree rooted at `self`.
 323         fun to_dot(filepath: String)
 324         do
 325                 var f = new FileWriter.open(filepath)
 326                 f.write("digraph g \{\n")
 327                 f.write("rankdir=BT;\n")
 328
 329                 var a = new Array[NToken]
 330                 to_dot_visitor(f, a)
 331
 332                 f.write("\{ rank=same\n")
 333                 var first = true
 334                 for n in a do
 335                         if first then
 336                                 first = false
 337                         else
 338                                 f.write("->")
 339                         end
 340                         f.write("n{n.object_id}")
 341                 end
 342                 f.write("[style=invis];\n")
 343                 f.write("\}\n")
 344
 345                 f.write("\}\n")
 346                 f.close
 347         end
 348
 349         private fun to_dot_visitor(f: Writer, a: Array[NToken])
 350         do
 351                 f.write("n{object_id} [label=\"{node_name}\"];\n")
 352                 for x in children do
 353                         if x == null then continue
 354                         f.write("n{x.object_id} -> n{object_id};\n")
 355                         x.to_dot_visitor(f,a )
 356                 end
 357         end
 358
 359         redef fun to_s do
 360                 var pos = position
 361                 if pos == null then
 362                         return "{node_name}"
 363                 else
 364                         return "{node_name}@({pos})"
 365                 end
 366         end
 367 end
 368
 369 private class DephCollection
 370         super Collection[Node]
 371         var node: Node
 372         redef fun iterator do return new DephIterator([node].iterator)
 373 end
 374
 375 private class DephIterator
 376         super Iterator[Node]
 377
 378         var stack = new List[Iterator[nullable Node]]
 379
 380         init(i: Iterator[nullable Node]) is old_style_init do
 381                 stack.add i
 382         end
 383
 384         redef fun is_ok do return not stack.is_empty
 385         redef fun item do return stack.last.item.as(not null)
 386         redef fun next
 387         do
 388                 var i = stack.last
 389                 stack.push i.item.children.iterator
 390                 i.next
 391                 while is_ok do
 392                         if not stack.last.is_ok then
 393                                 stack.pop
 394                                 continue
 395                         end
 396                         if stack.last.item == null then
 397                                 stack.last.next
 398                                 continue
 399                         end
 400                         return
 401                 end
 402         end
 403 end
 404
 405 # A token produced by the lexer and used in a syntactic tree
 406 abstract class NToken
 407         super Node
 408
 409         redef fun children do return once new Array[Node]
 410
 411         redef fun to_dot_visitor(f, a)
 412         do
 413                 var labe = "{node_name}"
 414                 var pos = position
 415                 if pos != null then labe += "\\n{pos}"
 416                 var text = self.text
 417                 if node_name != "'{text}'" then
 418                         labe += "\\n'{text.escape_to_c}'"
 419                 end
 420                 f.write("n{object_id} [label=\"{labe}\",shape=box];\n")
 421                 a.add(self)
 422         end
 423
 424         # The text associated with the token
 425         var text: String = "" is writable
 426
 427         redef fun to_s do
 428                 var res = super
 429                 var text = self.text
 430                 if node_name != "'{text}'" then
 431                         res += "='{text.escape_to_c}'"
 432                 end
 433                 return res
 434         end
 435 end
 436
 437 # The special token for the end of stream
 438 class NEof
 439         super NToken
 440 end
 441
 442 # A special token used to represent a parser or lexer error
 443 abstract class NError
 444         super NToken
 445
 446         # All the partially built tree during parsing (aka the node_stack)
 447         var error_tree = new Nodes[Node]
 448
 449         # The things unexpected
 450         fun unexpected: String is abstract
 451
 452         # The things expected (if any)
 453         var expected: nullable String = null
 454
 455         # The error message,using `expected` and `unexpected`
 456         fun message: String
 457         do
 458                 var exp = expected
 459                 var res = "Unexpected {unexpected}"
 460                 if exp != null then res += "; is acceptable instead: {exp}"
 461                 return res
 462         end
 463 end
 464
 465 # A lexer error as a token for the unexpected characted
 466 class NLexerError
 467         super NError
 468
 469         redef fun unexpected do return "character '{text.chars.first}'"
 470 end
 471
 472 # A parser error linked to a unexpected token
 473 class NParserError
 474         super NError
 475
 476         # The unexpected token
 477         var token: nullable NToken = null
 478
 479         redef fun unexpected
 480         do
 481                 var res = token.node_name
 482                 var text = token.text
 483                 if not text.is_empty and res != "'{text}'" then
 484                         res += " '{text.escape_to_c}'"
 485                 end
 486                 return res
 487         end
 488 end
 489
 490 # A hogeneous sequence of node, used to represent unbounded lists (and + modifier)
 491 class Nodes[T: Node]
 492         super Node
 493         redef var children: Array[T] = new Array[T]
 494 end
 495
 496 # A production with a specific, named and statically typed children
 497 class NProd
 498         super Node
 499         redef var children: SequenceRead[nullable Node] = new NProdChildren(self)
 500
 501         # The exact number of direct children
 502         # Used to implement `children` by generated parsers
 503         fun number_of_children: Int is abstract
 504
 505         # The specific children got by its index
 506         # Used to implement `children` by generated parsers
 507         fun child(x: Int): nullable Node is abstract
 508 end
 509
 510
 511 private class NProdChildren
 512         super SequenceRead[nullable Node]
 513         var prod: NProd
 514         redef fun iterator do return new NProdIterator(prod)
 515         redef fun length do return prod.number_of_children
 516         redef fun is_empty do return prod.number_of_children == 0
 517         redef fun [](i) do return prod.child(i)
 518 end
 519
 520 private class NProdIterator
 521         super IndexedIterator[nullable Node]
 522         var prod: NProd
 523         redef var index = 0
 524         redef fun is_ok do return index < prod.number_of_children
 525         redef fun next do index += 1
 526         redef fun item do return prod.child(index)
 527 end
 528
 529 # All-in-one abstract class to test generated parsers on a given
 530 abstract class TestParser
 531         # How to get a new lexer on a given stream of character
 532         fun new_lexer(text: String): Lexer is abstract
 533
 534         # How to get a new parser
 535         fun new_parser: Parser is abstract
 536
 537         # The name of the language (used for generated files)
 538         fun name: String is abstract
 539
 540         # Use the class as the main enrty point of the program
 541         # - parse arguments and options of the command
 542         # - test the parser (see `work`)
 543         fun main: Node
 544         do
 545                 if args.is_empty then
 546                         print "usage {name}_test <filepath> | - | -e <text>"
 547                         exit 0
 548                 end
 549
 550                 var filepath = args.shift
 551                 var text
 552                 if filepath == "-" then
 553                         text = sys.stdin.read_all
 554                 else if filepath == "-e" then
 555                         if args.is_empty then
 556                                 print "Error: -e need a text"
 557                                 exit 1
 558                         end
 559                         text = args.shift
 560                 else
 561                         var f = new FileReader.open(filepath)
 562                         text = f.read_all
 563                         f.close
 564                 end
 565
 566                 if not args.is_empty then
 567                         print "Error: superfluous arguments."
 568                         exit 1
 569                 end
 570
 571                 return work(text)
 572         end
 573
 574         # Produce a full syntactic tree for a given stream of character
 575         # Produce also statistics and output files
 576         fun work(text: String): Node
 577         do
 578                 print "INPUT: {text.length} chars"
 579                 var l = new_lexer(text)
 580                 var tokens = l.lex
 581
 582                 var tokout = "{name}.tokens.out"
 583                 print "TOKEN: {tokens.length} tokens (see {tokout})"
 584
 585                 var f = new FileWriter.open(tokout)
 586                 for t in tokens do
 587                         f.write "{t.to_s}\n"
 588                 end
 589                 f.close
 590
 591                 var p = new_parser
 592                 p.tokens.add_all(tokens)
 593
 594                 var n = p.parse
 595
 596                 var astout = "{name}.ast.out"
 597                 f = new FileWriter.open(astout)
 598                 var tpv = new TreePrinterVisitor(f)
 599                 var astdotout = "{name}.ast.dot"
 600                 if n isa NError then
 601                         print "Syntax error: {n.message}"
 602                         print "ERROR: {n} (see {astout} and {astdotout})"
 603                         tpv.enter_visit(n)
 604                         n = n.error_tree
 605                 else
 606                         print "ROOT: {n}; {n.depth.length} nodes (see {astout} and {astdotout})"
 607                 end
 608                 tpv.enter_visit(n)
 609                 n.to_dot(astdotout)
 610                 f.close
 611
 612                 return n
 613         end
 614 end