lib/nitcorn/reactor.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2013 Jean-Philippe Caissy <jpcaissy@piji.ca>
   4 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   5 # Copyright 2014 Alexandre Terrasa <alexandre@moz-code.org>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18
  19 # Core of the `nitcorn` project, provides `HttpFactory` and `Action`
  20 module reactor
  21
  22 import more_collections
  23 import http_request_parser
  24
  25 import vararg_routes
  26 import http_request
  27 import http_response
  28
  29 # A server handling a single connection
  30 class HttpServer
  31         super Connection
  32
  33         # The associated `HttpFactory`
  34         var factory: HttpFactory
  35
  36         # Init the server using `HttpFactory`.
  37         init(buf_ev: NativeBufferEvent, factory: HttpFactory) is old_style_init do
  38                 self.factory = factory
  39         end
  40
  41         private var parser = new HttpRequestParser is lazy
  42
  43         redef fun read_callback(str)
  44         do
  45                 var request_object = parser.parse_http_request(str.to_s)
  46                 if request_object != null then delegate_answer request_object
  47         end
  48
  49         # Answer to a request
  50         fun delegate_answer(request: HttpRequest)
  51         do
  52                 # Find target virtual host
  53                 var virtual_host = null
  54                 if request.header.keys.has("Host") then
  55                         var host = request.header["Host"]
  56                         if host.index_of(':') == -1 then host += ":80"
  57                         for vh in factory.config.virtual_hosts do
  58                                 for i in vh.interfaces do if i.to_s == host then
  59                                         virtual_host = vh
  60                                         break label
  61                                 end
  62                         end label
  63                 end
  64
  65                 # Use default virtual host if none already responded
  66                 if virtual_host == null then virtual_host = factory.config.default_virtual_host
  67
  68                 # Get a response from the virtual host
  69                 var response
  70                 if virtual_host != null then
  71                         var route = virtual_host.routes[request.uri]
  72                         if route != null then
  73                                 # include uri parameters in request
  74                                 request.uri_params = route.parse_params(request.uri)
  75
  76                                 var handler = route.handler
  77                                 var root = route.path
  78                                 var turi
  79                                 if root != null then
  80                                         turi = ("/" + request.uri.substring_from(root.length)).simplify_path
  81                                 else turi = request.uri
  82                                 response = handler.answer(request, turi)
  83                         else response = new HttpResponse(405)
  84                 else response = new HttpResponse(405)
  85
  86                 # Send back a response
  87                 write response.to_s
  88                 close
  89         end
  90 end
  91
  92 redef abstract class Action
  93         # Handle a request with the relative URI `truncated_uri`
  94         #
  95         # `request` is fully formed request object and has a reference to the session
  96         # if one preexists.
  97         #
  98         # `truncated_uri` is the ending of the full request URI, truncated from the route
  99         # leading to this `Action`.
 100         fun answer(request: HttpRequest, truncated_uri: String): HttpResponse is abstract
 101 end
 102
 103 # Factory to create `HttpServer` instances, and hold the libevent base handler
 104 class HttpFactory
 105         super ConnectionFactory
 106
 107         # Configuration of this server
 108         #
 109         # It should be populated after this object has instanciated
 110         var config = new ServerConfig.with_factory(self)
 111
 112         # Instanciate a server and libvent
 113         #
 114         # You can use this to create the first `HttpFactory`, which is the most common.
 115         init and_libevent do init(new NativeEventBase)
 116
 117         redef fun spawn_connection(buf_ev) do return new HttpServer(buf_ev, self)
 118
 119         # Launch the main loop of this server
 120         fun run
 121         do
 122                 event_base.dispatch
 123                 event_base.destroy
 124         end
 125 end
 126
 127 redef class ServerConfig
 128         # Handle to retreive the `HttpFactory` on config change
 129         private var factory: HttpFactory
 130
 131         private init with_factory(factory: HttpFactory) do self.factory = factory
 132 end
 133
 134 redef class Sys
 135         # Active listeners
 136         private var listeners = new HashMap2[String, Int, ConnectionListener]
 137
 138         # Hosts needong each listener
 139         private var listeners_count = new HashMap2[String, Int, Int]
 140
 141         # Activate a listener on `interfac` if there's not already one
 142         private fun listen_on(interfac: Interface, factory: HttpFactory)
 143         do
 144                 if interfac.registered then return
 145
 146                 var name = interfac.name
 147                 var port = interfac.port
 148
 149                 var listener = listeners[name, port]
 150                 if listener == null then
 151                         listener = factory.bind_to(name, port)
 152                         if listener != null then
 153                                 sys.listeners[name, port] = listener
 154                                 listeners_count[name, port] = 1
 155                         end
 156                 else
 157                         listeners_count[name, port] += 1
 158                 end
 159
 160                 interfac.registered = true
 161         end
 162
 163         # TODO close listener
 164 end
 165
 166 redef class Interface
 167         # Has `self` been registered by `listen_on`?
 168         private var registered = false
 169 end
 170
 171 redef class Interfaces
 172         redef fun add(e)
 173         do
 174                 super
 175                 if vh.server_config != null then sys.listen_on(e, vh.server_config.factory)
 176         end
 177
 178         # TODO remove
 179 end
 180
 181 redef class VirtualHosts
 182         redef fun add(e)
 183         do
 184                 super
 185                 for i in e.interfaces do sys.listen_on(i, config.factory)
 186         end
 187
 188         # TODO remove
 189 end