src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwpackage = 'package';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwuniversal = 'universal';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'fun';
  69 kwtype = 'type';
  70 kwinit = 'init';
  71 kwredef = 'redef';
  72 kwis = 'is';
  73 kwdo = 'do';
  74 kwreadable = 'readable';
  75 kwwritable = 'writable';
  76 kwvar = 'var';
  77 kwintern = 'intern';
  78 kwextern = 'extern';
  79 kwprotected = 'protected';
  80 kwprivate = 'private';
  81 kwintrude = 'intrude';
  82 kwif = 'if';
  83 kwthen = 'then';
  84 kwelse = 'else';
  85 kwwhile = 'while';
  86 kwfor = 'for';
  87 kwin = 'in';
  88 kwand = 'and';
  89 kwor = 'or';
  90 kwnot = 'not';
  91 kwreturn = 'return';
  92 kwcontinue = 'continue';
  93 kwbreak = 'break';
  94 kwabort = 'abort';
  95 kwassert = 'assert';
  96 kwnew = 'new';
  97 kwisa = 'isa';
  98 kwonce = 'once';
  99 kwsuper = 'super';
 100 kwself = 'self';
 101 kwtrue = 'true';
 102 kwfalse = 'false';
 103 kwnull = 'null';
 104 kwas = 'as';
 105 kwnullable = 'nullable';
 106 kwisset = 'isset';
 107 kwlabel = 'label';
 108
 109 opar = '(';
 110 cpar = ')';
 111 obra = '[';
 112 cbra = ']';
 113 comma = ',';
 114 column = ':';
 115 quad = '::';
 116 assign = '=';
 117 pluseq = '+=';
 118 minuseq = '-=';
 119 dotdotdot = '...';
 120 dotdot = '..';
 121 dot = '.';
 122 plus = '+';
 123 minus = '-';
 124 star = '*';
 125 slash = '/';
 126 percent = '%';
 127 eq = '==';
 128 ne = '!=';
 129 lt = '<';
 130 le = '<=';
 131 gt = '>';
 132 ge = '>=';
 133 starship = '<=>';
 134 bang='!';
 135
 136 classid = uppercase letter*;
 137 id = lowercase letter*;
 138 attrid = '_' lowercase letter*;
 139
 140 number = digit+;
 141 float = digit* '.' digit+;
 142 char = ''' [any - ''']* ''';
 143 string = '"' str_body '"';
 144 start_string = '"' str_body '{';
 145 mid_string = '}' str_body '{';
 146 end_string = '}' str_body '"';
 147
 148
 149 /*****************************************************************************/
 150 Ignored Tokens
 151 /*****************************************************************************/
 152
 153 blank;
 154
 155 /*****************************************************************************/
 156 Productions
 157 /*****************************************************************************/
 158
 159 /* MODULES *******************************************************************/
 160 module
 161         = packagedecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(packagedecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 162
 163 packagedecl
 164         = [doc]:no kwpackage no id [n2]:n1 {-> New packagedecl(doc.doc, kwpackage, id)};
 165
 166 import
 167         = {std} [doc]:no visibility kwimport no id [n2]:n1              {-> New import.std(visibility, kwimport, id)}
 168         | {no} [doc]:no visibility kwimport no kwend [n2]:n1    {-> New import.no(visibility, kwimport, kwend)}
 169         ;
 170
 171 implicit_top_class {-> classdef}
 172         = propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])};
 173
 174 implicit_main_class {-> classdef?}
 175         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 176         | {null} n {-> Null}
 177         ;
 178 implicit_main_meth {-> propdef}
 179         = [doc]:no stmts no {-> New propdef.main_meth(Null, stmts.expr)};
 180
 181 /* CLASSES *******************************************************************/
 182 classdef
 183         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs? [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef])};
 184 redef {-> kwredef?}
 185         = kwredef? {-> kwredef};
 186 classkind
 187         = {concrete} kwclass
 188         | {abstract} kwabstract kwclass
 189         | {interface} kwinterface
 190         | {universal} kwuniversal
 191         ;
 192
 193 formaldefs {-> formaldef*}
 194         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 195 formaldefs_tail {-> formaldef}
 196         = comma no formaldef {-> formaldef};
 197 formaldef
 198         = classid typing? {-> New formaldef(classid, typing.type)};
 199
 200 special {-> superclass}
 201         = no kwspecial [n2]:no type {-> New superclass(kwspecial, type)};
 202
 203 propdefs~toplevel {-> propdef*}
 204         = propdef~toplevel n1 propdefs_tail~toplevel* {-> [propdef~toplevel.propdef, propdefs_tail~toplevel.propdef]}
 205         ;
 206 propdefs_tail~toplevel {-> propdef}
 207         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 208         ;
 209 propdef~toplevel {-> propdef}
 210         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 211         | {assign_return} [doc]:no redef visibility kwmeth methid_noassign signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid_noassign.methid, signature_withret.signature, assign_return.expr)}
 212 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 213 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 214         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string)}
 215 !toplevel| {var} [doc]:no readable writable redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, typing.type, Null)}
 216 !toplevel| {var2} [doc]:no readable writable redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, typing.type, expr)}
 217 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 218 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 219         ;
 220 readable {-> able?}
 221         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 222         | {empty} {-> Null}
 223         ;
 224 writable {-> able?}
 225         = redef kwwritable {-> New able.write(redef.kwredef, kwwritable)}
 226         | {empty} {-> Null}
 227         ;
 228
 229 visibility
 230         = {public} {-> New visibility.public()}
 231         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 232         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 233         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 234         ;
 235
 236 methid~noassign {-> methid}
 237         = {id} id {-> New methid.id(id)}
 238         | {plus} plus {-> New methid.plus(plus)}
 239         | {minus} minus {-> New methid.minus(minus)}
 240         | {star} star {-> New methid.star(star)}
 241         | {slash} slash {-> New methid.slash(slash)}
 242         | {percent} percent {-> New methid.percent(percent)}
 243         | {eq} eq {-> New methid.eq(eq)}
 244         | {ne} ne {-> New methid.ne(ne)}
 245         | {le} le {-> New methid.le(le)}
 246         | {ge} ge {-> New methid.ge(ge)}
 247         | {lt} lt {-> New methid.lt(lt)}
 248         | {gt} gt {-> New methid.gt(gt)}
 249         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 250         | {starship} starship {-> New methid.starship(starship)}
 251 !noassign       | {assign} id assign {-> New methid.assign(id, assign)}
 252 !noassign       | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 253         ;
 254
 255 signature~withret {-> signature}
 256         = params? typing closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 257         | {noclosures} params? typing no {-> New signature([params.param], typing.type, [])}
 258 !withret| {noret} params? closure_decls {-> New signature([params.param], Null, [closure_decls.closure_decl])}
 259 !withret| {noretnoclosures} params? no {-> New signature([params.param], Null, [])}
 260         ;
 261
 262 signature_noclosures {-> signature}
 263         = params? typing? {-> New signature([params.param], typing.type, [])};
 264
 265 params {-> param*}
 266         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 267         | {empty} opar no cpar {-> []}
 268         ;
 269 params_tail {-> param}
 270         = comma no param {-> param};
 271 param
 272         = {untyped} id {-> New param(id, Null, Null)}
 273         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 274         ;
 275
 276 closure_decls {->closure_decl*}
 277         = no closure_decl+ {-> [closure_decl]};
 278 closure_decl
 279         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 280         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 281         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 282         ;
 283
 284 assign_return{-> expr}
 285         = expr_final {-> New expr.return(Null, expr_final.expr)}
 286         ;
 287
 288
 289 /* TYPES *********************************************************************/
 290 type~nobra {-> type}
 291         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 292 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 293         ;
 294 types {-> type*}
 295         = type types_tail* {-> [type, types_tail.type]};
 296 types_tail {-> type}
 297         = comma no type {-> type};
 298 typing {-> type}
 299         = column no type {-> type};
 300
 301 /* STATMENTS *****************************************************************/
 302 stmtso~withelse~withend {-> expr?}
 303         = {block} n stmts [n2]:n kwend {-> stmts.expr}
 304         | {emptyblock} n kwend {-> New expr.block([])}
 305         | {emptyoneline} kwend {-> New expr.block([])}
 306 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 307         ;
 308 stmts {-> expr}
 309         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr])};
 310 stmts_tail {-> expr}
 311         = n stmt {-> stmt.expr};
 312 stmt~withelse {-> expr}
 313         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 314         | {assign} assignment~withelse {-> assignment~withelse.expr}
 315         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 316         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 317         | {abort} kwabort {-> New expr.abort(kwabort)}
 318         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 319         | {do} do~withelse {-> do~withelse.expr}
 320         | {if} if~withelse {-> if~withelse.expr}
 321         | {while} while~withelse {-> while~withelse.expr}
 322         | {for} for~withelse {-> for~withelse.expr}
 323         | {assert} assert~withelse {-> assert~withelse.expr}
 324         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 325         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 326         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 327         ;
 328
 329 label= kwlabel id;
 330
 331 closure_defs~withelse {-> closure_def*}
 332         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 333         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 334         ;
 335
 336 closure_def_last~withelse {-> closure_def}
 337         = bang [id]:closure_id idlist? kwdo stmtso~withelse_withend label? {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse_withend.expr, label)}
 338         | {noend} bang [id]:closure_id idlist? kwdo stmt~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmt~withelse.expr, Null)}
 339         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 340         ;
 341
 342 closure_def {-> closure_def}
 343         = bang [id]:closure_id idlist? kwdo n stmts [n2]:n {-> New closure_def(bang, id, [idlist.id], kwdo, stmts.expr, Null)}
 344         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 345         ;
 346 closure_id
 347         = {simple} id
 348         | {break} kwbreak
 349         ;
 350
 351 assign_continue~withelse{-> expr}
 352         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 353         ;
 354
 355 vardecl~withelse{-> expr}
 356         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 357         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 358         ;
 359
 360 assignment~withelse {-> expr}
 361         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 362         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 363         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 364         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 365         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 366         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 367         ;
 368 assign_op
 369         = {plus} pluseq
 370         | {minus} minuseq
 371         ;
 372
 373 do~withelse {-> expr}
 374         = kwdo stmtso~withelse_withend label? {-> New expr.do(kwdo, stmtso~withelse_withend.expr, label)}
 375         | {noend} kwdo stmt~withelse {-> New expr.do(kwdo, stmt~withelse.expr, Null)}
 376         ;
 377
 378 if~withelse {-> expr}
 379         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 380 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 381 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmts [n4]:n elsepartblock {-> New expr.if(kwif, expr, stmts.expr, elsepartblock.expr)}
 382 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 383         ;
 384 elsepartblock {-> expr?}
 385         = {else} kwelse stmtso {-> stmtso.expr}
 386         | {empty} kwend {-> Null}
 387         ;
 388
 389 while~withelse {-> expr}
 390         = kwwhile no expr [n2]:no kwdo stmtso~withelse_withend label? {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse_withend.expr, label)}
 391         | {noend} kwwhile no expr [n2]:no kwdo stmt~withelse {-> New expr.while(kwwhile, expr, kwdo, stmt~withelse.expr, Null)}
 392         ;
 393
 394 for~withelse {-> expr}
 395         = kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse_withend label? {-> New expr.for(kwfor, id, expr, kwdo, stmtso~withelse_withend.expr, label)}
 396         | {noend} kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmt~withelse {-> New expr.for(kwfor, id, expr, kwdo, stmt~withelse.expr, Null)}
 397         ;
 398
 399 assert~withelse {-> expr}
 400         = kwassert assertid? expr_final~withelse {-> New expr.assert(kwassert, assertid.id, expr_final~withelse.expr)};
 401 assertid {-> id}
 402         = id column {-> id};
 403
 404 /* EXPRESSIONS ***************************************************************/
 405 expr_final~nopar~withelse~nobra {-> expr}
 406         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 407         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 408 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 409         ;
 410
 411 expr~nopar~nobra {-> expr}
 412         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 413         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 414         ;
 415
 416 expr_and~nopar~nobra {-> expr}
 417         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 418         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 419         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 420         ;
 421
 422 expr_not~nopar~nobra {-> expr}
 423         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 424         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 425         ;
 426
 427 expr_eq~nopar~nobra {-> expr}
 428         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 429         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 430         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 431         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 432         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 433         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 434         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 435         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 436         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 437         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 438         ;
 439
 440 expr_add~nopar~nobra {-> expr}
 441         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 442         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 443         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 444         ;
 445
 446 expr_mul~nopar~nobra {-> expr}
 447         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 448         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 449         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 450         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 451         ;
 452
 453 expr_minus~nopar~nobra {-> expr}
 454         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 455         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 456         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 457         ;
 458
 459 expr_new~nopar~nobra {-> expr}
 460         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 461         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, [args.expr])}
 462         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 463         ;
 464
 465 expr_atom~nopar~nobra {-> expr}
 466         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 467         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 468         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 469         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 470 !nobra!nopar    | {bra} expr_atom braargs {-> New expr.bra(expr_atom.expr, [braargs.expr], [])}
 471         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, [args.expr])}
 472 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 473 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 474 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 475         | {self} kwself {-> New expr.self(kwself)}
 476         | {true} kwtrue {-> New expr.true(kwtrue)}
 477         | {false} kwfalse {-> New expr.false(kwfalse)}
 478         | {null} kwnull {-> New expr.null(kwnull)}
 479         | {int} number  {-> New expr.int(number)}
 480         | {float} float  {-> New expr.float(float)}
 481         | {char} char  {-> New expr.char(char)}
 482         | {string} string  {-> New expr.string(string)}
 483         | {superstring} superstring  {-> superstring.expr}
 484 !nopar  | {par} opar expr cpar {-> expr}
 485         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, type)}
 486         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, kwnot, kwnull)}
 487         ;
 488
 489 superstring {-> expr}
 490         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 491 superstring_start {-> expr*}
 492         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 493 start_string_p {-> expr}
 494         = start_string {-> New expr.start_string(start_string)};
 495 superstring_middle {-> expr*}
 496         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 497 mid_string_p {-> expr}
 498         = mid_string {-> New expr.mid_string(mid_string)};
 499 superstring_end {-> expr}
 500         = end_string {-> New expr.end_string(end_string)};
 501
 502 /* MISC **********************************************************************/
 503
 504 recv~nopar~nobra {-> expr}
 505         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 506         | {implicit} {-> New expr.implicit_self()}
 507         ;
 508
 509 args {-> expr*}
 510         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 511         | {emptypar} opar no cpar {-> []}
 512         | {empty} {-> []}
 513         ;
 514 args_nopar {-> expr*}
 515         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 516         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 517         | {emptypar} opar no cpar {-> []}
 518         | {empty} {-> []}
 519         ;
 520 braargs {-> expr*}
 521         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 522 args_tail {-> expr}
 523         = comma no expr [n2]:no {-> expr};
 524 idlist {-> id*}
 525         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 526         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 527         ;
 528 idlist_nopar {-> id*}
 529         = {single} id {-> [id]}
 530         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 531         ;
 532
 533 qualified
 534         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 535         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 536         ;
 537 modquad {-> id}
 538         = id quad no {-> id};
 539 classquad {-> classid}
 540         = classid quad no {-> classid};
 541
 542 n1      = {a} comment | {b} eol;
 543 n {-> doc?}
 544         = {a} n2? comment+ {-> New doc([comment])}
 545         | {b} n2 {-> Null}
 546         ;
 547 no {-> doc?}
 548         = {empty} {-> Null}
 549         | n {-> n.doc}
 550         ;
 551
 552 n2
 553         = {a} n2? comment+ eol+
 554         | {b} eol+
 555         ;
 556
 557 /*****************************************************************************/
 558 Abstract Syntax Tree
 559 /*****************************************************************************/
 560
 561 module  = packagedecl? [imports]:import* [classdefs]:classdef*;
 562
 563 packagedecl
 564         = doc? kwpackage id;
 565
 566 import  = {std} visibility kwimport id
 567         | {no} visibility kwimport kwend
 568         ;
 569
 570 visibility
 571         = {public}
 572         | {private} kwprivate
 573         | {protected} kwprotected
 574         | {intrude} kwintrude
 575         ;
 576
 577 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef*
 578         | {top} [propdefs]:propdef*
 579         | {main} [propdefs]:propdef*
 580         ;
 581 classkind
 582         = {concrete} kwclass
 583         | {abstract} kwabstract kwclass
 584         | {interface} kwinterface
 585         | {universal} kwuniversal
 586         ;
 587 formaldef = [id]:classid type?;
 588 superclass = kwspecial type;
 589
 590
 591 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid type? expr?
 592         | {meth} doc? kwredef? visibility methid signature
 593         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 594         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 595         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string?
 596         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 597         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 598         | {main_meth} kwredef? [block]:expr?
 599         | {type} doc? kwredef? visibility kwtype [id]:classid type
 600         ;
 601
 602 able    = {read} kwredef? kwreadable
 603         | {write} kwredef? kwwritable
 604         ;
 605
 606 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 607
 608 signature = [params]:param* type? [closure_decls]:closure_decl*;
 609
 610 param   = id type? dotdotdot?
 611         ;
 612
 613 closure_decl = kwbreak? bang id signature expr?
 614         ;
 615
 616 type    = kwnullable? [id]:classid [types]:type*;
 617
 618 label = kwlabel id;
 619
 620 expr    = {block} expr*
 621         | {vardecl} kwvar id type? assign? expr?
 622         | {return} kwreturn? expr?
 623         | {break} kwbreak label? expr?
 624         | {abort} kwabort
 625         | {continue} kwcontinue? label? expr?
 626         | {do} kwdo [block]:expr? label?
 627         | {if} kwif expr [then]:expr? [else]:expr?
 628         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 629         | {while} kwwhile expr kwdo [block]:expr? label?
 630         | {for} kwfor id expr kwdo [block]:expr? label?
 631         | {assert} kwassert id? expr
 632         | {once} kwonce expr
 633         | {send} expr
 634         | {binop} expr [expr2]:expr
 635         | {or} expr [expr2]:expr
 636         | {and} expr [expr2]:expr
 637         | {not} kwnot expr
 638         | {eq} expr [expr2]:expr
 639         | {ee} expr [expr2]:expr
 640         | {ne} expr [expr2]:expr
 641         | {lt} expr [expr2]:expr
 642         | {le} expr [expr2]:expr
 643         | {gt} expr [expr2]:expr
 644         | {ge} expr [expr2]:expr
 645         | {isa} expr type
 646         | {plus} expr [expr2]:expr
 647         | {minus} expr [expr2]:expr
 648         | {starship} expr [expr2]:expr
 649         | {star} expr [expr2]:expr
 650         | {slash} expr [expr2]:expr
 651         | {percent} expr [expr2]:expr
 652         | {uminus} minus expr
 653         | {new} kwnew type id? [args]:expr*
 654         | {attr} expr [id]:attrid
 655         | {attr_assign} expr [id]:attrid assign [value]:expr
 656         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 657         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 658         | {call_assign} expr id [args]:expr* assign [value]:expr
 659         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 660         | {super} qualified? kwsuper [args]:expr*
 661         | {init} expr kwinit [args]:expr*
 662         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 663         | {bra_assign} expr [args]:expr* assign [value]:expr
 664         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 665         | {closure_call} id [args]:expr* [closure_defs]:closure_def*
 666         | {var} id
 667         | {var_assign} id assign [value]:expr
 668         | {var_reassign} id assign_op [value]:expr
 669         | {range} expr [expr2]:expr
 670         | {crange} expr [expr2]:expr
 671         | {orange} expr [expr2]:expr
 672         | {array} [exprs]:expr*
 673         | {self} kwself
 674         | {implicit_self}
 675         | {true} kwtrue
 676         | {false} kwfalse
 677         | {null} kwnull
 678         | {int} number
 679         | {float} float
 680         | {char} char
 681         | {string} string
 682         | {start_string} [string]:start_string
 683         | {mid_string} [string]:mid_string
 684         | {end_string} [string]:end_string
 685         | {superstring} [exprs]:expr*
 686         | {par} expr
 687         | {as_cast} expr kwas type
 688         | {as_notnull} expr kwas kwnot kwnull
 689         | {isset_attr} kwisset expr [id]:attrid
 690         ;
 691 assign_op
 692         = {plus} pluseq
 693         | {minus} minuseq
 694         ;
 695
 696 closure_def
 697         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 698         ;
 699 closure_id
 700         = {simple} id
 701         | {break} kwbreak
 702         ;
 703
 704 qualified = id* classid? ;
 705
 706 doc = comment+;
 707
 708 /*****************************************************************************/
 709