src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 letter = lowercase | uppercase | digit | '_';
  31
  32 tab = 9;
  33 cr = 13;
  34 lf = 10;
  35 any = [all - [cr + lf]];
  36 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  37
  38 // characers inside strings and super-strings (atomaton powaa)
  39 str_char
  40         = [any - [['"' + '{'] + '\']]
  41         | '\' any
  42         ;
  43 str_body = str_char*;
  44
  45 sstr_char
  46         = [any - [''' + '\']]
  47         | '\' any
  48         ;
  49
  50 sstr_body = sstr_char*;
  51
  52 long_str_char = str_char | cr | lf;
  53
  54 long_str_part
  55         = long_str_char
  56         | '"' long_str_char
  57         | '"' '"' long_str_char
  58         | '{' long_str_char
  59         | '{' '{' long_str_char
  60         ;
  61
  62 long_str_body = long_str_part*;
  63
  64 long_sstr_char = sstr_char | cr | lf;
  65 long_sstr_part
  66         = long_sstr_char
  67         | ''' long_sstr_char
  68         | ''' ''' long_sstr_char
  69         ;
  70
  71 long_sstr_body = long_sstr_part*;
  72
  73
  74 extern_code_char
  75         = [all - ['`' + '\']]
  76         | '\' all
  77         ;
  78 extern_code_body = extern_code_char*;
  79
  80 /*****************************************************************************/
  81 States
  82 /*****************************************************************************/
  83 initial;
  84
  85
  86 /*****************************************************************************/
  87 Tokens
  88 /*****************************************************************************/
  89
  90 blank = (' ' | tab)+;
  91
  92 eol = eol_helper;
  93 comment = '#' any* eol_helper?;
  94
  95 kwpackage = 'package';
  96 kwmodule = 'module';
  97 kwimport = 'import';
  98 kwclass = 'class';
  99 kwabstract = 'abstract';
 100 kwinterface = 'interface';
 101 kwenum = 'universal'|'enum';
 102 kwend = 'end';
 103 kwmeth = 'fun';
 104 kwtype = 'type';
 105 kwinit = 'init';
 106 kwredef = 'redef';
 107 kwis = 'is';
 108 kwdo = 'do';
 109 kwreadable = 'readable';
 110 kwwritable = 'writable';
 111 kwvar = 'var';
 112 kwintern = 'intern';
 113 kwextern = 'extern';
 114 kwprotected = 'protected';
 115 kwprivate = 'private';
 116 kwintrude = 'intrude';
 117 kwif = 'if';
 118 kwthen = 'then';
 119 kwelse = 'else';
 120 kwwhile = 'while';
 121 kwloop = 'loop';
 122 kwfor = 'for';
 123 kwin = 'in';
 124 kwand = 'and';
 125 kwor = 'or';
 126 kwnot = 'not';
 127 kwimplies = 'implies';
 128 kwreturn = 'return';
 129 kwcontinue = 'continue';
 130 kwbreak = 'break';
 131 kwabort = 'abort';
 132 kwassert = 'assert';
 133 kwnew = 'new';
 134 kwisa = 'isa';
 135 kwonce = 'once';
 136 kwsuper = 'super';
 137 kwself = 'self';
 138 kwtrue = 'true';
 139 kwfalse = 'false';
 140 kwnull = 'null';
 141 kwas = 'as';
 142 kwnullable = 'nullable';
 143 kwisset = 'isset';
 144 kwlabel = 'label';
 145 kwdebug = '__debug__';
 146
 147 opar = '(';
 148 cpar = ')';
 149 obra = '[';
 150 cbra = ']';
 151 comma = ',';
 152 column = ':';
 153 quad = '::';
 154 assign = '=';
 155 pluseq = '+=';
 156 minuseq = '-=';
 157 dotdotdot = '...';
 158 dotdot = '..';
 159 dot = '.';
 160 plus = '+';
 161 minus = '-';
 162 star = '*';
 163 slash = '/';
 164 percent = '%';
 165 eq = '==';
 166 ne = '!=';
 167 lt = '<';
 168 le = '<=';
 169 ll = '<<';
 170 gt = '>';
 171 ge = '>=';
 172 gg = '>>';
 173 starship = '<=>';
 174 bang='!';
 175 at='@';
 176
 177 classid = uppercase letter*;
 178 id = lowercase letter*;
 179 attrid = '_' lowercase letter*;
 180
 181 number = digit+;
 182 float = digit* '.' digit+;
 183 string = '"' str_body '"' | '"' '"' '"' long_str_body '"' '"' '"' | ''' ''' ''' long_sstr_body ''' ''' ''';
 184 start_string = '"' str_body '{' | '"' '"' '"' long_str_body '{' '{' '{';
 185 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body '{' '{' '{';
 186 end_string = '}' str_body '"' | '}' '}' '}' long_str_body '"' '"' '"';
 187 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 188 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 189 bad_char = ''' '\'? any;
 190
 191 extern_code_segment = '`' '{' extern_code_body '`' '}';
 192
 193 /*****************************************************************************/
 194 Ignored Tokens
 195 /*****************************************************************************/
 196
 197 blank;
 198
 199 /*****************************************************************************/
 200 Productions
 201 /*****************************************************************************/
 202
 203 /* MODULES *******************************************************************/
 204 module
 205         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 206
 207 moduledecl
 208         = [doc]:no kwmodule no module_name annotation_withend? [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, module_name, annotation_withend.annotations)};
 209
 210 import
 211         = {std} [doc]:no visibility kwimport no module_name annotation_withend? [n2]:n1 {-> New import.std(visibility, kwimport, module_name, annotation_withend.annotations)}
 212         | {no} [doc]:no visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 213         ;
 214
 215 implicit_top_class {-> classdef}
 216         = propdefs_toplevel+ {-> New classdef.top([propdefs_toplevel.propdef])};
 217
 218 implicit_main_class {-> classdef?}
 219         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 220         | {null} n {-> Null}
 221         ;
 222 implicit_main_meth {-> propdef}
 223         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 224         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 225         ;
 226
 227 /* CLASSES *******************************************************************/
 228 classdef
 229         = [doc]:no redef visibility classkind no qualified? classid formaldefs? line_annotations_forclass? extern_code_block? [superclasses]:superclass* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], line_annotations_forclass.annotations, extern_code_block, [superclasses.superclass], [propdefs.propdef], kwend)};
 230 redef {-> kwredef?}
 231         = kwredef? {-> kwredef};
 232 classkind
 233         = {concrete} kwclass
 234         | {abstract} kwabstract kwclass
 235         | {interface} kwinterface
 236         | {enum} kwenum
 237         | {extern} kwextern kwclass?
 238         ;
 239
 240 formaldefs {-> formaldef*}
 241         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 242 formaldefs_tail {-> formaldef}
 243         = comma no formaldef {-> formaldef};
 244 formaldef
 245         = classid annotations? typing? {-> New formaldef(classid, typing.type, annotations)};
 246
 247 superclass {-> superclass}
 248         = {super} no kwsuper [n2]:no type annotation_withend? {-> New superclass(kwsuper, type, annotation_withend.annotations)}
 249         ;
 250
 251 propdefs~toplevel {-> propdef}
 252         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 253         ;
 254 propdef~toplevel {-> propdef}
 255         = {meth} [doc]:no redef visibility kwmeth methid signature annotation_noend? kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, annotation_noend.annotations, stmtso.expr)}
 256         | {assign_return} [doc]:no redef visibility kwmeth methid signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature_withret.signature, Null, assign_return.expr)}
 257         | {nobody} [doc]:no redef visibility kwmeth methid signature annotation_withend {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, annotation_withend.annotations)}
 258 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, Null)}
 259 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 260         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? extern_calls? extern_code_block? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string, extern_calls, extern_code_block)}
 261         | {extern_implicit} [doc]:no redef visibility kwmeth methid signature extern_calls? extern_code_block {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, Null, extern_calls, extern_code_block)}
 262 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null, Null)}
 263 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null, expr)}
 264 !toplevel| {var3} [doc]:no redef visibility kwvar id typing? writable2? annotation_withend? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, annotation_withend.annotations, Null)}
 265 !toplevel| {var4} [doc]:no redef visibility kwvar id typing? writable2? assign [n2]:no expr_nois annotation_withend? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, annotation_withend.annotations, expr_nois.expr)}
 266 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature annotation_noend? kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, annotation_noend.annotations, stmtso.expr)}
 267 !toplevel| {type} [doc]:no redef visibility kwtype classid typing annotation_withend? {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type, annotation_withend.annotations)}
 268 !toplevel| {extern_init} [doc]:no redef visibility kwnew methid? signature kwis kwextern string? extern_calls? extern_code_block? {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls, extern_code_block)}
 269 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew methid? signature string? extern_calls? extern_code_block {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls, extern_code_block)}
 270         ;
 271 annotation_withend {-> annotations}
 272         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 273         | {more} kwis n1 line_annotations kwend {-> line_annotations.annotations}
 274         ;
 275 annotation_noend {-> annotations}
 276         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 277         | {more} kwis n1 line_annotations {-> line_annotations.annotations}
 278         ;
 279 readable {-> able}
 280         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 281         ;
 282 writable {-> able}
 283         = redef kwwritable {-> New able.write(redef.kwredef, Null, kwwritable)}
 284         ;
 285 writable2 {-> able}
 286         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 287         ;
 288
 289 visibility
 290         = {public} {-> New visibility.public()}
 291         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 292         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 293         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 294         ;
 295
 296 methid {-> methid}
 297         = {id} id {-> New methid.id(id)}
 298         | {plus} plus {-> New methid.plus(plus)}
 299         | {minus} minus {-> New methid.minus(minus)}
 300         | {star} star {-> New methid.star(star)}
 301         | {slash} slash {-> New methid.slash(slash)}
 302         | {percent} percent {-> New methid.percent(percent)}
 303         | {eq} eq {-> New methid.eq(eq)}
 304         | {ne} ne {-> New methid.ne(ne)}
 305         | {le} le {-> New methid.le(le)}
 306         | {ge} ge {-> New methid.ge(ge)}
 307         | {lt} lt {-> New methid.lt(lt)}
 308         | {gt} gt {-> New methid.gt(gt)}
 309         | {ll} ll {-> New methid.ll(ll)}
 310         | {gg} gg {-> New methid.gg(gg)}
 311         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 312         | {starship} starship {-> New methid.starship(starship)}
 313         | {assign} id assign {-> New methid.assign(id, assign)}
 314         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 315         ;
 316
 317 signature~withret {-> signature}
 318         = opar no params? cpar typing [no2]:no closure_decls? {-> New signature(opar, [params.param], cpar, typing.type, [closure_decls.closure_decl])}
 319 !withret| {noret} opar no params? cpar [no2]:no closure_decls? {-> New signature(opar, [params.param], cpar, Null, [closure_decls.closure_decl])}
 320         | {nopar} typing no closure_decls? {-> New signature(Null, [], Null, typing.type, [closure_decls.closure_decl])}
 321 !withret| {noparnoret} no closure_decls? {-> New signature(Null, [], Null, Null, [closure_decls.closure_decl])}
 322         ;
 323
 324 signature_noclosures {-> signature}
 325         = opar no params? cpar typing? {-> New signature(opar, [params.param], cpar, typing.type, [])}
 326         | {nopar} typing? {-> New signature(Null, [], Null, typing.type, [])}
 327         ;
 328
 329 params {-> param*}
 330         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 331         ;
 332 params_tail {-> param}
 333         = comma no param {-> param};
 334 param
 335         = {untyped} id annotations? {-> New param(id, Null, Null, annotations)}
 336         | id annotations? typing dotdotdot? {-> New param(id, typing.type, dotdotdot, annotations)}
 337         ;
 338
 339 closure_decls {->closure_decl*}
 340         = closure_decl+ {-> [closure_decl]};
 341 closure_decl
 342         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 343         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 344         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 345         ;
 346
 347 assign_return{-> expr}
 348         = expr_final {-> New expr.return(Null, expr_final.expr)}
 349         ;
 350
 351 extern_calls {-> extern_calls}
 352         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 353         ;
 354 extern_call_tail {-> extern_call}
 355         = comma no extern_call {-> extern_call};
 356 extern_call {-> extern_call}
 357     = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 358     | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 359         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 360     ;
 361 extern_call_prop {-> extern_call}
 362     = {local} methid {-> New extern_call.local_prop( methid )}
 363         | {full} classid quad methid {-> New extern_call.full_prop( classid, quad, methid )}
 364         | {init} classid {-> New extern_call.init_prop( classid )}
 365         ;
 366 extern_call_cast {-> extern_call}
 367     = {as_cast} [from_type]:type kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, kwas, to_type)}
 368         | {as_nullable} type kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 369         | {as_not_nullable} type kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 370         ;
 371
 372 in_language = kwin string;
 373 extern_code_block = in_language? extern_code_segment;
 374 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 375
 376 /* TYPES *********************************************************************/
 377 type~nobra~nopar {-> type}
 378         = {simple} kwnullable? classid annotations~nopar? {-> New type(kwnullable, classid, [], annotations~nopar.annotations)}
 379 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra annotations~nopar? {-> New type(kwnullable, classid, [types.type], annotations~nopar.annotations)}
 380         ;
 381 types {-> type*}
 382         = type types_tail* {-> [type, types_tail.type]};
 383 types_tail {-> type}
 384         = comma no type {-> type};
 385 typing {-> type}
 386         = column no type {-> type};
 387
 388 /* STATMENTS *****************************************************************/
 389 stmtso~withelse~withend {-> expr?}
 390         = {block} n stmtsnend {-> stmtsnend.expr}
 391         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 392         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 393 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 394         ;
 395 stmts {-> expr}
 396         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 397 stmtsn {-> expr}
 398         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 399 stmtsnend {-> expr}
 400         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 401 stmts_tail {-> expr}
 402         = n stmt {-> stmt.expr};
 403 stmt~withelse~noexpr~nopar {-> expr}
 404         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 405         | {assign} assignment~withelse~nopar {-> assignment~withelse~nopar.expr}
 406         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 407         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 408         | {abort} kwabort {-> New expr.abort(kwabort)}
 409         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 410         | {do} do~withelse {-> do~withelse.expr}
 411 !noexpr | {if} if~withelse {-> if~withelse.expr}
 412         | {while} while~withelse {-> while~withelse.expr}
 413         | {loop} loop~withelse {-> loop~withelse.expr}
 414         | {for} for~withelse {-> for~withelse.expr}
 415         | {assert} assert~withelse {-> assert~withelse.expr}
 416 !noexpr | {call} recv qualified? id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, args_nopar.exprs, [closure_defs~withelse.closure_def])}
 417 !noexpr | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, args_nopar.exprs)}
 418 !noexpr | {init} recv qualified? kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 419         | {debug_type_is} kwdebug kwtype type column expr_final~withelse {-> New expr.debug_type(kwdebug, kwtype, expr_final~withelse.expr, type) }
 420         ;
 421
 422 label= kwlabel id;
 423
 424 closure_defs~withelse {-> closure_def*}
 425         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 426         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 427         ;
 428
 429 closure_def_last~withelse {-> closure_def}
 430         = bang [id]:closure_id idlist? kwdo stmtso_withend label {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso_withend.expr, label)}
 431         | {nolabel} bang [id]:closure_id idlist? kwdo stmtso~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse.expr, Null)}
 432         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 433         ;
 434
 435 closure_def {-> closure_def}
 436         = bang [id]:closure_id idlist? kwdo n stmtsn {-> New closure_def(bang, id, [idlist.id], kwdo, stmtsn.expr, Null)}
 437         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 438         ;
 439 closure_id
 440         = {simple} id
 441         | {break} kwbreak
 442         ;
 443
 444 assign_continue~withelse{-> expr}
 445         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 446         ;
 447
 448 vardecl~withelse{-> expr}
 449         = kwvar id annotations? typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null, annotations)}
 450         | {assign} kwvar id annotations? typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr, annotations)}
 451         ;
 452
 453 assignment~withelse~nopar {-> expr}
 454         = {attr} recv~nopar qualified? attrid assign expr_final~withelse {-> New expr.attr_assign(recv~nopar.expr, attrid, assign, expr_final~withelse.expr)}
 455         | {call} recv~nopar qualified? id args assign expr_final~withelse {-> New expr.call_assign(recv~nopar.expr, id, args.exprs, assign,  expr_final~withelse.expr)}
 456         | {bra} expr_atom~nopar braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom~nopar.expr, braargs.exprs, assign,  expr_final~withelse.expr)}
 457         | {attr_re} recv~nopar qualified? attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv~nopar.expr, attrid, assign_op,  expr_final~withelse.expr)}
 458         | {call_re} recv~nopar qualified? id args assign_op expr_final~withelse {-> New expr.call_reassign(recv~nopar.expr, id, args.exprs, assign_op,  expr_final~withelse.expr)}
 459         | {bra_re} expr_atom~nopar braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom~nopar.expr, braargs.exprs, assign_op,  expr_final~withelse.expr)}
 460         ;
 461 assign_op
 462         = {plus} pluseq
 463         | {minus} minuseq
 464         ;
 465
 466 do~withelse {-> expr}
 467         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 468         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 469         ;
 470
 471 if~withelse {-> expr}
 472         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 473 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 474 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 475 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 476         ;
 477 elsepartblock {-> expr?}
 478         = {else} kwelse stmtso {-> stmtso.expr}
 479         | {empty} kwend {-> New expr.block([], kwend)}
 480         ;
 481
 482 loop~withelse {-> expr}
 483         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 484         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 485         ;
 486
 487 while~withelse {-> expr}
 488         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 489         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 490         ;
 491
 492 for~withelse {-> expr}
 493         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 494         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 495         ;
 496
 497 assert~withelse {-> expr}
 498         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 499 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 500         ;
 501 assertid {-> id}
 502         = id column {-> id};
 503
 504 /* EXPRESSIONS ***************************************************************/
 505 expr_final~nopar~withelse~nobra {-> expr}
 506         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 507         | {closure_call} recv~nobra qualified? id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, args.exprs, [closure_defs~withelse.closure_def])}
 508 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, braargs.exprs, [closure_defs~withelse.closure_def])}
 509         ;
 510
 511 expr~nopar~nobra~nois {-> expr}
 512         = expr_and~nopar~nobra~nois {-> expr_and~nopar~nobra~nois.expr}
 513         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra~nois {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 514         ;
 515
 516 expr_and~nopar~nobra~nois {-> expr}
 517         = expr_not~nopar~nobra~nois {-> expr_not~nopar~nobra~nois.expr}
 518         | {:or} expr_and~nopar~nobra~nois :kwor :no expr_not~nopar~nobra~nois
 519         | {:and} expr_and~nopar~nobra~nois :kwand :no expr_not~nopar~nobra~nois
 520         | {:or_else} expr_and~nopar~nobra~nois :kwor :kwelse :no expr_not~nopar~nobra~nois
 521         | {:implies} expr_and~nopar~nobra~nois :kwimplies :no expr_not~nopar~nobra~nois
 522         ;
 523
 524 expr_not~nopar~nobra~nois {-> expr}
 525         = expr_eq~nopar~nobra~nois {-> expr_eq~nopar~nobra~nois.expr}
 526         | {not} kwnot no expr_not~nopar~nobra~nois {-> New expr.not(kwnot, expr_not~nopar~nobra~nois.expr)}
 527         ;
 528
 529 expr_eq~nopar~nobra~nois {-> expr}
 530         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 531         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 532 !nois   | {ee} [expr]:expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr.expr, expr2.expr)}
 533         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 534         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 535         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 536         | {:ll} expr_eq~nopar~nobra~nois :ll :no [expr2]:expr_add~nopar~nobra
 537         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 538         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 539         | {:gg} expr_eq~nopar~nobra~nois :gg :no [expr2]:expr_add~nopar~nobra
 540         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 541         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 542         ;
 543
 544 expr_add~nopar~nobra {-> expr}
 545         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 546         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 547         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 548         ;
 549
 550 expr_mul~nopar~nobra {-> expr}
 551         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 552         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_minus~nopar~nobra
 553         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_minus~nopar~nobra
 554         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_minus~nopar~nobra
 555         ;
 556
 557 expr_minus~nopar~nobra {-> expr}
 558         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 559         | {:uminus} minus :no expr_minus~nopar~nobra
 560         | {:once} kwonce :no expr_minus~nopar~nobra
 561         ;
 562
 563 expr_new~nopar~nobra {-> expr}
 564         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 565         | {new} kwnew no type~nobra_nopar args {-> New expr.new(kwnew, type~nobra_nopar.type, Null, args.exprs)}
 566         | {isset_attr} kwisset recv~nopar~nobra qualified? attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 567         ;
 568
 569 expr_atom~nopar~nobra {-> expr}
 570         = {attr} recv~nopar~nobra qualified? attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 571         | {call} recv~nopar~nobra qualified? id args {-> New expr.call(recv~nopar~nobra.expr, id, args.exprs, [])}
 572         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, args.exprs)}
 573         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 574 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs, [])}
 575         | {new} kwnew no type~nobra_nopar dot [n2]:no qualified? id args {-> New expr.new(kwnew, type~nobra_nopar.type, id, args.exprs)}
 576 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 577 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra annotations? {-> New expr.crange(obra, expr, expr2.expr, cbra, annotations)}
 578 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra annotations? {-> New expr.orange(obra, expr, expr2.expr, cbra, annotations)}
 579 !nobra!nopar    | {array} braargs annotations? {-> New expr.array(braargs.exprs, annotations)}
 580         | {self} kwself annotations? {-> New expr.self(kwself, annotations)}
 581         | {true} kwtrue annotations? {-> New expr.true(kwtrue, annotations)}
 582         | {false} kwfalse annotations? {-> New expr.false(kwfalse, annotations)}
 583         | {null} kwnull annotations? {-> New expr.null(kwnull, annotations)}
 584         | {int} number annotations? {-> New expr.int(number, annotations)}
 585         | {float} float annotations? {-> New expr.float(float, annotations)}
 586         | {char} char annotations? {-> New expr.char(char, annotations)}
 587         | {string} string annotations? {-> New expr.string(string, annotations)}
 588         | {superstring} superstring  {-> superstring.expr}
 589 !nopar  | {par} opar no expr [n2]:no cpar annotations? {-> New expr.par(opar, expr, cpar, annotations)}
 590         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 591         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 592         ;
 593
 594 superstring {-> expr}
 595         = superstring_start superstring_middle* superstring_end annotations? {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr], annotations)};
 596 superstring_start {-> expr*}
 597         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 598 start_string_p {-> expr}
 599         = start_string {-> New expr.start_string(start_string)};
 600 superstring_middle {-> expr*}
 601         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 602 mid_string_p {-> expr}
 603         = mid_string {-> New expr.mid_string(mid_string)};
 604 superstring_end {-> expr}
 605         = end_string {-> New expr.end_string(end_string)};
 606
 607 /* ANNOTATIONS *******************************************************************/
 608
 609 annotations~nopar {-> annotations}
 610         = {one} at one_annotation~nopar {-> New annotations(at, Null, [one_annotation~nopar.annotation], Null)}
 611         | {many} at opar no annotation_list [n2]:no cpar {-> New annotations(at, opar, [annotation_list.annotation], cpar)}
 612         ;
 613
 614 one_annotation~nopar {-> annotation}
 615         = {alone} atid annotations~nopar? {-> New annotation(atid, Null, [], Null, annotations~nopar.annotations)}
 616 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 617 !nopar  | {args} atid opar no at_args [n2]:no cpar annotations~nopar? {-> New annotation(atid, opar, [at_args.at_arg], cpar, annotations~nopar.annotations)}
 618         ;
 619
 620 many_annotations {-> annotations}
 621         = {many} annotation_list {-> New annotations(Null, Null, [annotation_list.annotation], Null)}
 622         ;
 623
 624 annotation_list {-> annotation*}
 625         = {many} one_annotation annotations_tail* {-> [one_annotation.annotation, annotations_tail.annotation] }
 626         ;
 627
 628 line_annotations~forclass {-> annotations}
 629         = line_annotation~forclass+ {-> New annotations(Null, Null, [line_annotation~forclass.annotation], Null) }
 630         ;
 631 line_annotation~forclass {-> annotation}
 632         = [doc]:no atid~forclass annotations? n1 {-> New annotation(atid~forclass.atid, Null, [], Null, annotations)}
 633         | {args} [doc]:no atid~forclass opar no at_args cpar annotations? n1 {-> New annotation(atid~forclass.atid, opar, [at_args.at_arg], cpar, annotations)}
 634         | {nopar} [doc]:no atid~forclass at_args_nopar n1 {-> New annotation(atid~forclass.atid, Null, [at_args_nopar.at_arg], Null, Null)}
 635         ;
 636
 637 annotations_tail {-> annotation}
 638         = comma no one_annotation {-> one_annotation.annotation}
 639         ;
 640
 641 at_args~nopar {-> at_arg* }
 642         = {many} at_arg~nopar at_args_tail* {-> [at_arg~nopar.at_arg, at_args_tail.at_arg]}
 643         ;
 644
 645 at_args_tail {-> at_arg}
 646         = comma no at_arg {-> at_arg}
 647         ;
 648
 649 at_arg~nopar {-> at_arg}
 650         = {type} type {-> New at_arg.type(type)}
 651         | {expr} expr~nopar {-> New at_arg.expr(expr~nopar.expr)}
 652         | {stmt} stmt_noexpr~nopar {-> New at_arg.expr(stmt_noexpr~nopar.expr)}
 653 !nopar  | {at} annotations {-> New at_arg.at(annotations.annotations)}
 654         ;
 655
 656 atid~forclass {-> atid}
 657         = {id} qualified? id {-> New atid.id(id)}
 658 //!forclass     | {kwextern} qualified? kwextern {-> New atid.kwextern(kwextern)}
 659 //!forclass     | {kwintern} qualified? kwintern {-> New atid.kwintern(kwintern)}
 660 !forclass       | {kwreadable} qualified? kwreadable {-> New atid.kwreadable(kwreadable)}
 661 !forclass       | {kwwritable} qualified? kwwritable {-> New atid.kwwritable(kwwritable)}
 662         | {kwimport} qualified? kwimport {-> New atid.kwimport(kwimport)}
 663         ;
 664
 665 /* MISC **********************************************************************/
 666
 667 recv~nopar~nobra {-> expr}
 668         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 669         | {implicit} {-> New expr.implicit_self()}
 670         ;
 671
 672 args {-> exprs}
 673         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 674         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 675         | {empty} {-> New exprs.list([])}
 676         ;
 677 args_nopar {-> exprs}
 678         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 679         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 680         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 681         | {empty} {-> New exprs.list([])}
 682         ;
 683 braargs {-> exprs}
 684         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 685 expr_list {-> expr*}
 686         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 687 expr_tail {-> expr}
 688         = comma no expr [n2]:no {-> expr};
 689 idlist {-> id*}
 690         = opar no idlist_nopar [n2]:no cpar {-> [idlist_nopar.id]}
 691         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 692         ;
 693 idlist_nopar {-> id*}
 694         = {single} id {-> [id]}
 695         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 696         ;
 697
 698 module_name {-> module_name}
 699         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 700         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 701         ;
 702
 703 qualified
 704         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 705         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 706         ;
 707 modquad {-> id}
 708         = id quad no {-> id};
 709 classquad {-> classid}
 710         = classid quad no {-> classid};
 711
 712 n1      = {a} comment | {b} eol;
 713 n {-> doc?}
 714         = {a} n2? comment+ {-> New doc([comment])}
 715         | {b} n2 {-> Null}
 716         ;
 717 no {-> doc?}
 718         = {empty} {-> Null}
 719         | n {-> n.doc}
 720         ;
 721
 722 n2
 723         = {a} n2? comment+ eol+
 724         | {b} eol+
 725         ;
 726
 727 /*****************************************************************************/
 728 Abstract Syntax Tree
 729 /*****************************************************************************/
 730
 731 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 732
 733 moduledecl
 734         = doc? kwmodule [name]:module_name annotations?;
 735
 736 import  = {std} visibility kwimport [name]:module_name annotations?
 737         | {no} visibility kwimport kwend
 738         ;
 739
 740 visibility
 741         = {public}
 742         | {private} kwprivate
 743         | {protected} kwprotected
 744         | {intrude} kwintrude
 745         ;
 746
 747 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* annotations? extern_code_block? [superclasses]:superclass* [propdefs]:propdef* kwend
 748         | {top} [propdefs]:propdef*
 749         | {main} [propdefs]:propdef*
 750         ;
 751 classkind
 752         = {concrete} kwclass
 753         | {abstract} kwabstract kwclass
 754         | {interface} kwinterface
 755         | {enum} kwenum
 756         | {extern} kwextern kwclass?
 757         ;
 758 formaldef = [id]:classid type? annotations?;
 759 superclass = kwsuper type annotations?;
 760
 761
 762 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? annotations? expr?
 763         | {meth} doc? kwredef? visibility methid signature
 764         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature annotations?
 765         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 766         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string? extern_calls? extern_code_block?
 767         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature annotations? [block]:expr?
 768         | {concrete_init} doc? kwredef? visibility kwinit methid? signature annotations? [block]:expr?
 769         //| {concrete_new} doc? kwredef? visibility kwnew methid? signature [block]:expr?
 770         | {extern_init} doc? kwredef? visibility kwnew methid? signature [extern]:string? extern_calls? extern_code_block?
 771         | {main_meth} kwredef? [block]:expr?
 772         | {type} doc? kwredef? visibility kwtype [id]:classid type annotations?
 773         ;
 774
 775 able    = {read} kwredef? kwreadable
 776         | {write} kwredef? visibility? kwwritable
 777         ;
 778
 779 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 780
 781 signature = opar? [params]:param* cpar? type? [closure_decls]:closure_decl*;
 782
 783 param   = id type? dotdotdot? annotations?
 784         ;
 785
 786 closure_decl = kwbreak? bang id signature expr?
 787         ;
 788
 789 type    = kwnullable? [id]:classid [types]:type* annotations?;
 790
 791 label = kwlabel id;
 792
 793 expr    = {block} expr* kwend?
 794         | {vardecl} kwvar id type? assign? expr? annotations?
 795         | {return} kwreturn? expr?
 796         | {break} kwbreak label? expr?
 797         | {abort} kwabort
 798         | {continue} kwcontinue? label? expr?
 799         | {do} kwdo [block]:expr? label?
 800         | {if} kwif expr [then]:expr? [else]:expr?
 801         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 802         | {while} kwwhile expr kwdo [block]:expr? label?
 803         | {loop} kwloop [block]:expr? label?
 804         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 805         | {assert} kwassert id? expr [else]:expr?
 806         | {once} kwonce expr
 807         | {send} expr
 808         | {binop} expr [expr2]:expr
 809         | {or} expr [expr2]:expr
 810         | {and} expr [expr2]:expr
 811         | {or_else} expr [expr2]:expr
 812         | {implies} expr [expr2]:expr
 813         | {not} kwnot expr
 814         | {eq} expr [expr2]:expr
 815         | {ee} expr [expr2]:expr
 816         | {ne} expr [expr2]:expr
 817         | {lt} expr [expr2]:expr
 818         | {le} expr [expr2]:expr
 819         | {ll} expr [expr2]:expr
 820         | {gt} expr [expr2]:expr
 821         | {ge} expr [expr2]:expr
 822         | {gg} expr [expr2]:expr
 823         | {isa} expr type
 824         | {plus} expr [expr2]:expr
 825         | {minus} expr [expr2]:expr
 826         | {starship} expr [expr2]:expr
 827         | {star} expr [expr2]:expr
 828         | {slash} expr [expr2]:expr
 829         | {percent} expr [expr2]:expr
 830         | {uminus} minus expr
 831         | {new} kwnew type id? [args]:exprs
 832         | {attr} expr [id]:attrid
 833         | {attr_assign} expr [id]:attrid assign [value]:expr
 834         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 835         | {call} expr id [args]:exprs [closure_defs]:closure_def*
 836         | {call_assign} expr id [args]:exprs assign [value]:expr
 837         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 838         | {super} qualified? kwsuper [args]:exprs
 839         | {init} expr kwinit [args]:exprs
 840         | {bra} expr [args]:exprs [closure_defs]:closure_def*
 841         | {bra_assign} expr [args]:exprs assign [value]:expr
 842         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 843         | {closure_call} id [args]:exprs [closure_defs]:closure_def*
 844         | {var} id
 845         | {var_assign} id assign [value]:expr
 846         | {var_reassign} id assign_op [value]:expr
 847         | {range} expr [expr2]:expr annotations?
 848         | {crange} obra expr [expr2]:expr cbra annotations?
 849         | {orange} obra expr [expr2]:expr [cbra]:obra annotations?
 850         | {array} [exprs]:exprs annotations?
 851         | {self} kwself annotations?
 852         | {implicit_self}
 853         | {true} kwtrue annotations?
 854         | {false} kwfalse annotations?
 855         | {null} kwnull annotations?
 856         | {int} number annotations?
 857         | {float} float annotations?
 858         | {char} char annotations?
 859         | {string} string annotations?
 860         | {start_string} [string]:start_string
 861         | {mid_string} [string]:mid_string
 862         | {end_string} [string]:end_string
 863         | {superstring} [exprs]:expr* annotations?
 864         | {par} opar expr cpar annotations?
 865         | {as_cast} expr kwas opar type cpar
 866         | {as_notnull} expr kwas opar kwnot kwnull cpar
 867         | {isset_attr} kwisset expr [id]:attrid
 868         | {debug_type} kwdebug kwtype expr type
 869         ;
 870 exprs
 871         = {list} [exprs]:expr*
 872         | {par} opar [exprs]:expr* cpar
 873         | {bra} obra [exprs]:expr* cbra
 874         ;
 875 assign_op
 876         = {plus} pluseq
 877         | {minus} minuseq
 878         ;
 879
 880 closure_def
 881         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 882         ;
 883 closure_id
 884         = {simple} id
 885         | {break} kwbreak
 886         ;
 887
 888 module_name = quad? [path]:id* id;
 889 extern_calls = kwimport [extern_calls]:extern_call*
 890         ;
 891 extern_call =
 892         | {super} kwsuper
 893         | {local_prop} methid
 894         | {full_prop} classid quad? methid
 895         | {init_prop} classid
 896         | {cast_as} [from_type]:type kwas [to_type]:type
 897         | {as_nullable} type kwas kwnullable
 898         | {as_not_nullable} type kwas kwnot kwnullable
 899         ;
 900 in_language = kwin string;
 901 extern_code_block = in_language? extern_code_segment;
 902
 903 qualified = id* classid? ;
 904
 905 doc = comment+;
 906
 907 annotations = at? opar? [items]:annotation* cpar?;
 908
 909 annotation = atid opar? [args]:at_arg* cpar? annotations?;
 910
 911 at_arg
 912         = {type} type
 913         | {expr} expr
 914         | {at} annotations
 915         ;
 916 atid = {id} id | {kwextern} [id]:kwextern | {kwintern} [id]:kwintern | {kwreadable} [id]:kwreadable | {kwwritable} [id]:kwwritable | {kwimport} [id]:kwimport;
 917
 918 /*****************************************************************************/
 919