lib/android/input_events.nit

   1 # This file is part of NIT (http://www.nitlanguage.org).
   2 #
   3 # Copyright 2012-2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Pointer and hardware key events
  18 module input_events
  19
  20 import mnit_input
  21 import android
  22
  23 in "C header" `{
  24         #include <android/log.h>
  25         #include <android_native_app_glue.h>
  26
  27         #define LOGW(...) ((void)__android_log_print(ANDROID_LOG_WARN, "mnit", __VA_ARGS__))
  28         #ifdef DEBUG
  29                 #define LOGI(...) ((void)__android_log_print(ANDROID_LOG_INFO, "mnit", __VA_ARGS__))
  30         #else
  31                 #define LOGI(...) (void)0
  32         #endif
  33 `}
  34
  35 in "C" `{
  36         /* Handle inputs from the Android platform and sort them before
  37            sending them in the Nit App */
  38         static int32_t mnit_handle_input(struct android_app* app, AInputEvent* event) {
  39                 App nit_app = app->userData;
  40                 LOGI("handle input %i", (int)pthread_self());
  41                 if (AInputEvent_getType(event) == AINPUT_EVENT_TYPE_KEY) {
  42                         LOGI("key");
  43                         return App_native_input_key(nit_app, event);
  44                 }
  45                 else if (AInputEvent_getType(event) == AINPUT_EVENT_TYPE_MOTION) {
  46                         LOGI("motion");
  47                         return App_native_input_motion(nit_app, event);
  48                 }
  49
  50                 return 0;
  51         }
  52 `}
  53
  54 private extern class NativeAndroidMotionEvent `{AInputEvent *`}
  55
  56         fun pointers_count: Int `{
  57                 return AMotionEvent_getPointerCount(recv);
  58         `}
  59
  60         # Did this motion event just started?
  61         fun just_went_down: Bool `{
  62                 return (AMotionEvent_getAction(recv) & AMOTION_EVENT_ACTION_MASK) == AMOTION_EVENT_ACTION_DOWN;
  63         `}
  64
  65         fun edge: Int `{
  66                 return AMotionEvent_getEdgeFlags(recv);
  67         `}
  68
  69         # Get the non-primary pointer id that just went down (returns -1 or > 0)
  70         fun index_down_pointer: Int `{
  71                 int a = AMotionEvent_getAction(recv);
  72                 if ((a & AMOTION_EVENT_ACTION_MASK) == AMOTION_EVENT_ACTION_POINTER_DOWN)
  73                         return (a & AMOTION_EVENT_ACTION_POINTER_INDEX_MASK) >> AMOTION_EVENT_ACTION_POINTER_INDEX_SHIFT;
  74                 else return -1;
  75         `}
  76
  77         fun action: AMotionEventAction `{ return AMotionEvent_getAction(recv); `}
  78 end
  79
  80 private extern class AMotionEventAction `{ int32_t `}
  81         fun action: Int `{ return recv & AMOTION_EVENT_ACTION_MASK; `}
  82
  83         fun is_down: Bool do return action == 0
  84         fun is_up: Bool do return action == 1
  85         fun is_move: Bool do return action == 2
  86         fun is_cancel: Bool do return action == 3
  87         fun is_outside: Bool do return action == 4
  88         fun is_pointer_down: Bool do return action == 5
  89         fun is_pointer_up: Bool do return action == 6
  90 end
  91
  92 # An input event on Android
  93 interface AndroidInputEvent
  94         super InputEvent
  95 end
  96
  97 # A motion event concerning a single or more `pointers`
  98 class AndroidMotionEvent
  99         super AndroidInputEvent
 100         super MotionEvent
 101
 102         private var native: NativeAndroidMotionEvent
 103
 104         private var pointers_cache: nullable Array[AndroidPointerEvent] = null
 105
 106         # Pointers (or fingers) composing this motion event
 107         fun pointers: Array[AndroidPointerEvent]
 108         do
 109                 if pointers_cache != null then
 110                         return pointers_cache.as(not null)
 111                 else
 112                         var pointers = new Array[AndroidPointerEvent]
 113                         var pointers_count = native.pointers_count
 114                         for i in [0 .. pointers_count [do
 115                                 var pointer_event = new AndroidPointerEvent(self, i)
 116                                 pointers.add(pointer_event)
 117                         end
 118                         pointers_cache = pointers
 119                         return pointers
 120                 end
 121         end
 122
 123         redef fun just_went_down: Bool do return native.just_went_down
 124
 125         # Was the top edge of the screen intersected by this event?
 126         fun touch_to_edge: Bool do return native.edge == 1
 127
 128         # Was the bottom edge of the screen intersected by this event?
 129         fun touch_bottom_edge: Bool do return native.edge == 2
 130
 131         # Was the left edge of the screen intersected by this event?
 132         fun touch_left_edge: Bool do return native.edge == 4
 133
 134         # Was the right edge of the screen intersected by this event?
 135         fun touch_right_edge: Bool do return native.edge == 8
 136
 137         redef fun down_pointer: nullable AndroidPointerEvent
 138         do
 139                 if just_went_down then
 140                         # The primary pointer went down
 141                         return pointers[0]
 142                 end
 143
 144                 var i = native.index_down_pointer
 145                 if i > 0 then
 146                         # A secondary pointer went down
 147                         return pointers[i]
 148                 else
 149                         return null
 150                 end
 151         end
 152 end
 153
 154 # A pointer event
 155 class AndroidPointerEvent
 156         super PointerEvent
 157         super AndroidInputEvent
 158
 159         private var motion_event: AndroidMotionEvent
 160
 161         private var pointer_id: Int
 162
 163         redef fun x: Float do return native_x(motion_event.native, pointer_id)
 164
 165         private fun native_x(motion_event: NativeAndroidMotionEvent, pointer_id: Int): Float `{
 166                 return AMotionEvent_getX(motion_event, pointer_id);
 167         `}
 168
 169         redef fun y: Float do return native_y(motion_event.native, pointer_id)
 170
 171         private fun native_y(motion_event: NativeAndroidMotionEvent, pointer_id: Int): Float `{
 172                 return AMotionEvent_getY(motion_event, pointer_id);
 173         `}
 174
 175         # Pressure applied by this pointer
 176         fun pressure: Float do return native_pressure(motion_event.native, pointer_id)
 177
 178         private fun native_pressure(motion_event: NativeAndroidMotionEvent, pointer_id: Int): Float `{
 179                 return AMotionEvent_getPressure(motion_event, pointer_id);
 180         `}
 181
 182         redef fun pressed
 183         do
 184                 var action = motion_event.native.action
 185                 return action.is_down or action.is_move
 186         end
 187
 188         redef fun depressed do return not pressed
 189
 190         # Does this pointer just began touching the screen?
 191         fun just_went_down: Bool
 192         do
 193                 return motion_event.down_pointer == self
 194         end
 195 end
 196
 197 # An hardware key event
 198 extern class AndroidKeyEvent `{AInputEvent *`}
 199         super KeyEvent
 200         super AndroidInputEvent
 201
 202         private fun action: Int `{ return AKeyEvent_getAction(recv); `}
 203
 204         redef fun is_down: Bool do return action == 0
 205         redef fun is_up: Bool do return action == 1
 206
 207         # Hardware code of the key raising this event
 208         fun key_code: Int `{ return AKeyEvent_getKeyCode(recv); `}
 209
 210         redef fun to_c `{
 211                 int code = AKeyEvent_getKeyCode(recv);
 212                 if (code >= AKEYCODE_0 && code <= AKEYCODE_9)
 213                         return '0'+code-AKEYCODE_0;
 214                 if (code >= AKEYCODE_A && code <= AKEYCODE_Z)
 215                         return 'a'+code-AKEYCODE_A;
 216                 return 0;
 217         `}
 218
 219         redef fun name do return key_code.to_s
 220
 221         # Was this event raised by the back key?
 222         fun is_back_key: Bool do return key_code == 4
 223
 224         # Was this event raised by the menu key?
 225         fun is_menu_key: Bool do return key_code == 82
 226
 227         # Was this event raised by the search key?
 228         fun is_search_key: Bool do return key_code == 84
 229
 230         # Was this event raised by the volume up key?
 231         fun is_volume_up: Bool do return key_code == 24
 232
 233         # Was this event raised by the volume down key?
 234         fun is_volume_down: Bool do return key_code == 25
 235 end
 236
 237 redef class App
 238
 239         redef fun init_window
 240         do
 241                 set_as_input_handler native_app_glue
 242                 super
 243         end
 244
 245         private fun set_as_input_handler(app_glue: NativeAppGlue)
 246         import native_input_key, native_input_motion `{
 247                 app_glue->onInputEvent = mnit_handle_input;
 248         `}
 249
 250         # these are used as a callback from native to type incoming events
 251         private fun native_input_key(event: AndroidKeyEvent): Bool is abstract
 252
 253         private fun native_input_motion(event: NativeAndroidMotionEvent): Bool is abstract
 254 end