src/web/web_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Base classes used by `nitweb`.
  16 module web_base
  17
  18 import model::model_views
  19 import model::model_json
  20 import doc_down
  21 import popcorn
  22
  23 # Specific nitcorn Action that uses a Model
  24 class ModelHandler
  25         super Handler
  26
  27         # Model to use.
  28         var model: Model
  29
  30         # MModule used to flatten model.
  31         var mainmodule: MModule
  32
  33         # Find the MEntity ` with `full_name`.
  34         fun find_mentity(model: ModelView, full_name: nullable String): nullable MEntity do
  35                 if full_name == null then return null
  36                 return model.mentity_by_full_name(full_name.from_percent_encoding)
  37         end
  38
  39         # Init the model view from the `req` uri parameters.
  40         fun init_model_view(req: HttpRequest): ModelView do
  41                 var view = new ModelView(model)
  42                 var show_private = req.bool_arg("private") or else false
  43                 if not show_private then view.min_visibility = protected_visibility
  44
  45                 view.include_fictive = req.bool_arg("fictive") or else false
  46                 view.include_empty_doc = req.bool_arg("empty-doc") or else true
  47                 view.include_test_suite = req.bool_arg("test-suite") or else false
  48                 view.include_attribute = req.bool_arg("attributes") or else true
  49
  50                 return view
  51         end
  52 end
  53
  54 # Specific handler for nitweb API.
  55 abstract class APIHandler
  56         super ModelHandler
  57
  58         # The JSON API does not filter anything by default.
  59         #
  60         # So we can cache the model view.
  61         var view: ModelView is lazy do
  62                 var view = new ModelView(model)
  63                 view.min_visibility = private_visibility
  64                 view.include_fictive = true
  65                 view.include_empty_doc = true
  66                 view.include_attribute = true
  67                 view.include_test_suite = true
  68                 return view
  69         end
  70
  71         # Try to load the mentity from uri with `/:id`.
  72         #
  73         # Send 400 if `:id` is null.
  74         # Send 404 if no entity is found.
  75         # Return null in both cases.
  76         fun mentity_from_uri(req: HttpRequest, res: HttpResponse): nullable MEntity do
  77                 var id = req.param("id")
  78                 if id == null then
  79                         res.error 400
  80                         return null
  81                 end
  82                 var mentity = find_mentity(view, id)
  83                 if mentity == null then
  84                         res.error 404
  85                 end
  86                 return mentity
  87         end
  88 end
  89
  90 # A NitView is rendered by an action.
  91 interface NitView
  92         # Renders this view and returns something that can be written to a HTTP response.
  93         fun render: Writable is abstract
  94 end
  95
  96 redef class HttpResponse
  97         # Render a NitView as response.
  98         fun send_view(view: NitView, status: nullable Int) do send(view.render, status)
  99 end
 100
 101 redef class MEntity
 102
 103         # URL to `self` within the web interface.
 104         fun web_url: String is abstract
 105
 106         # URL to `self` within the JSON api.
 107         fun api_url: String do return "/api/entity/" / full_name
 108
 109         redef fun json do
 110                 var obj = super
 111                 obj["web_url"] = web_url
 112                 obj["api_url"] = api_url
 113                 return obj
 114         end
 115
 116         # Get the full json repesentation of `self` with MEntityRefs resolved.
 117         fun api_json(handler: ModelHandler): JsonObject do return json
 118 end
 119
 120 redef class MEntityRef
 121         redef fun json do
 122                 var obj = super
 123                 obj["web_url"] = mentity.web_url
 124                 obj["api_url"] = mentity.api_url
 125                 obj["name"] = mentity.name
 126                 obj["mdoc"] = mentity.mdoc_or_fallback
 127                 obj["visibility"] = mentity.visibility
 128                 obj["location"] = mentity.location
 129                 var modifiers = new JsonArray
 130                 for modifier in mentity.collect_modifiers do
 131                         modifiers.add modifier
 132                 end
 133                 obj["modifiers"] = modifiers
 134                 return obj
 135         end
 136 end
 137
 138 redef class MDoc
 139
 140         # Add doc down processing
 141         redef fun json do
 142                 var obj = super
 143                 obj["synopsis"] = synopsis
 144                 obj["documentation"] = documentation
 145                 obj["comment"] = comment
 146                 obj["html_synopsis"] = html_synopsis.write_to_string
 147                 obj["html_documentation"] = html_documentation.write_to_string
 148                 obj["html_comment"] = html_comment.write_to_string
 149                 return obj
 150         end
 151 end
 152
 153 redef class MPackage
 154         redef var web_url = "/package/{full_name}" is lazy
 155 end
 156
 157 redef class MGroup
 158         redef var web_url = "/group/{full_name}" is lazy
 159 end
 160
 161 redef class MModule
 162         redef var web_url = "/module/{full_name}" is lazy
 163
 164         redef fun api_json(handler) do
 165                 var obj = super
 166                 obj["intro_mclassdefs"] = to_mentity_refs(collect_intro_mclassdefs(private_view))
 167                 obj["redef_mclassdefs"] = to_mentity_refs(collect_redef_mclassdefs(private_view))
 168                 obj["imports"] = to_mentity_refs(in_importation.direct_greaters)
 169                 return obj
 170         end
 171 end
 172
 173 redef class MClass
 174         redef var web_url = "/class/{full_name}" is lazy
 175
 176         redef fun api_json(handler) do
 177                 var obj = super
 178                 obj["all_mproperties"] = to_mentity_refs(collect_accessible_mproperties(private_view))
 179                 obj["intro_mproperties"] = to_mentity_refs(collect_intro_mproperties(private_view))
 180                 obj["redef_mproperties"] = to_mentity_refs(collect_redef_mproperties(private_view))
 181                 var poset = hierarchy_poset(handler.mainmodule, private_view)
 182                 obj["parents"] = to_mentity_refs(poset[self].direct_greaters)
 183                 return obj
 184         end
 185 end
 186
 187 redef class MClassDef
 188         redef var web_url = "/classdef/{full_name}" is lazy
 189
 190         redef fun json do
 191                 var obj = super
 192                 obj["intro"] = to_mentity_ref(mclass.intro)
 193                 obj["mpackage"] = to_mentity_ref(mmodule.mpackage)
 194                 return obj
 195         end
 196
 197         redef fun api_json(handler) do
 198                 var obj = super
 199                 obj["intro_mpropdefs"] = to_mentity_refs(collect_intro_mpropdefs(private_view))
 200                 obj["redef_mpropdefs"] = to_mentity_refs(collect_redef_mpropdefs(private_view))
 201                 return obj
 202         end
 203 end
 204
 205 redef class MProperty
 206         redef var web_url = "/property/{full_name}" is lazy
 207
 208         redef fun json do
 209                 var obj = super
 210                 obj["intro_mclass"] = to_mentity_ref(intro_mclassdef.mclass)
 211                 obj["mpackage"] = to_mentity_ref(intro_mclassdef.mmodule.mpackage)
 212                 return obj
 213         end
 214 end
 215
 216 redef class MPropDef
 217         redef var web_url = "/propdef/{full_name}" is lazy
 218
 219         redef fun json do
 220                 var obj = super
 221                 obj["intro"] = to_mentity_ref(mproperty.intro)
 222                 obj["intro_mclassdef"] = to_mentity_ref(mproperty.intro.mclassdef)
 223                 obj["mmodule"] = to_mentity_ref(mclassdef.mmodule)
 224                 obj["mgroup"] = to_mentity_ref(mclassdef.mmodule.mgroup)
 225                 obj["mpackage"] = to_mentity_ref(mclassdef.mmodule.mpackage)
 226                 return obj
 227         end
 228 end
 229
 230 redef class MClassType
 231         redef var web_url = mclass.web_url is lazy
 232 end
 233
 234 redef class MNullableType
 235         redef var web_url = mtype.web_url is lazy
 236 end
 237
 238 redef class MParameterType
 239         redef var web_url = mclass.web_url is lazy
 240 end
 241
 242 redef class MVirtualType
 243         redef var web_url = mproperty.web_url is lazy
 244 end