src/ni_nitdoc.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Documentation generator for the nit language.
  16 # Generate API documentation in HTML format from nit source code.
  17 module ni_nitdoc
  18
  19 import model_utils
  20 import abstract_compiler
  21
  22 # The NitdocContext contains all the knowledge used for doc generation
  23 class NitdocContext
  24         super ToolContext
  25
  26         private var model: Model
  27         private var mbuilder: ModelBuilder
  28         private var mainmodule: MModule
  29         private var class_hierarchy: POSet[MClass]
  30         private var arguments: Array[String]
  31         private var output_dir: nullable String
  32         private var dot_dir: nullable String
  33         private var share_dir: nullable String
  34         private var source: nullable String
  35         private var min_visibility: MVisibility
  36
  37         private var opt_dir = new OptionString("Directory where doc is generated", "-d", "--dir")
  38         private var opt_source = new OptionString("What link for source (%f for filename, %l for first line, %L for last line)", "--source")
  39         private var opt_sharedir = new OptionString("Directory containing the nitdoc files", "--sharedir")
  40         private var opt_nodot = new OptionBool("Do not generate graphes with graphiviz", "--no-dot")
  41         private var opt_private: OptionBool = new OptionBool("Generate the private API", "--private")
  42
  43         private var opt_custom_title: OptionString = new OptionString("Title displayed in the top of the Overview page and as suffix of all page names", "--custom-title")
  44         private var opt_custom_menu_items: OptionString = new OptionString("Items displayed in menu before the 'Overview' item (Each item must be enclosed in 'li' tags)", "--custom-menu-items")
  45         private var opt_custom_overview_text: OptionString = new OptionString("Text displayed as introduction of Overview page before the modules list", "--custom-overview-text")
  46         private var opt_custom_footer_text: OptionString = new OptionString("Text displayed as footer of all pages", "--custom-footer-text")
  47
  48         init do
  49                 super
  50                 self.arguments = option_context.rest
  51                 option_context.options.clear
  52                 option_context.add_option(opt_dir)
  53                 option_context.add_option(opt_source)
  54                 option_context.add_option(opt_sharedir)
  55                 option_context.add_option(opt_nodot)
  56                 option_context.add_option(opt_private)
  57                 option_context.add_option(opt_custom_title)
  58                 option_context.add_option(opt_custom_footer_text)
  59                 option_context.add_option(opt_custom_overview_text)
  60                 option_context.add_option(opt_custom_menu_items)
  61                 process_options
  62
  63                 if arguments.length < 1 then
  64                         option_context.usage
  65                         exit(1)
  66                 end
  67
  68                 model = new Model
  69                 mbuilder = new ModelBuilder(model, self)
  70                 # Here we load an process all modules passed on the command line
  71                 var mmodules = mbuilder.parse_and_build(arguments)
  72                 if mmodules.is_empty then return
  73
  74                 if mmodules.length == 1 then
  75                         mainmodule = mmodules.first
  76                 else
  77                         # We need a main module, so we build it by importing all modules
  78                         mainmodule = new MModule(model, null, "<main>", new Location(null, 0, 0, 0, 0))
  79                         mainmodule.set_imported_mmodules(mmodules)
  80                 end
  81                 self.class_hierarchy = mainmodule.flatten_mclass_hierarchy
  82         end
  83
  84         redef fun process_options do
  85                 super
  86                 if not opt_dir.value is null then
  87                         output_dir = opt_dir.value
  88                 else
  89                         output_dir = "doc"
  90                 end
  91                 if not opt_sharedir.value is null then
  92                         share_dir = opt_sharedir.value
  93                 else
  94                         var dir = "NIT_DIR".environ
  95                         if dir.is_empty then
  96                                 dir = "{sys.program_name.dirname}/../share/nitdoc"
  97                         else
  98                                 dir = "{dir}/share/nitdoc"
  99                         end
 100                         share_dir = dir
 101                         if share_dir is null then
 102                                 print "Error: Cannot locate nitdoc share files. Uses --sharedir or envvar NIT_DIR"
 103                                 abort
 104                         end
 105                         dir = "{share_dir.to_s}/scripts/js-facilities.js"
 106                         if share_dir is null then
 107                                 print "Error: Invalid nitdoc share files. Check --sharedir or envvar NIT_DIR"
 108                                 abort
 109                         end
 110
 111                         if opt_private.value then
 112                                 min_visibility = none_visibility
 113                         else
 114                                 min_visibility = protected_visibility
 115                         end
 116                 end
 117                 source = opt_source.value
 118         end
 119
 120         fun generate_nitdoc do
 121                 # Create destination dir if it's necessary
 122                 if not output_dir.file_exists then output_dir.mkdir
 123                 sys.system("cp -r {share_dir.to_s}/* {output_dir.to_s}/")
 124                 self.dot_dir = null
 125                 if not opt_nodot.value then self.dot_dir = output_dir.to_s
 126                 overview
 127                 fullindex
 128                 modules
 129                 classes
 130                 quicksearch_list
 131         end
 132
 133         private fun overview do
 134                 var overviewpage = new NitdocOverview(self, dot_dir)
 135                 overviewpage.save("{output_dir.to_s}/index.html")
 136         end
 137
 138         private fun fullindex do
 139                 var fullindex = new NitdocFullindex(self)
 140                 fullindex.save("{output_dir.to_s}/full-index.html")
 141         end
 142
 143         private fun modules do
 144                 for mmodule in model.mmodules do
 145                         if mmodule.name == "<main>" then continue
 146                         var modulepage = new NitdocModule(mmodule, self, dot_dir)
 147                         modulepage.save("{output_dir.to_s}/{mmodule.url}")
 148                 end
 149         end
 150
 151         private fun classes do
 152                 for mclass in mbuilder.model.mclasses do
 153                         var classpage = new NitdocClass(mclass, self, dot_dir, source)
 154                         classpage.save("{output_dir.to_s}/{mclass.url}")
 155                 end
 156         end
 157
 158         private fun quicksearch_list do
 159                 var file = new OFStream.open("{output_dir.to_s}/quicksearch-list.js")
 160                 var content = new Buffer
 161                 content.append("var entries = \{ ")
 162
 163                 for mmodule in model.mmodules do
 164                         content.append("\"{mmodule.name}\": [")
 165                         content.append("\{txt: \"{mmodule.name}\", url:\"{mmodule.url}\" \},")
 166                         content.append("],")
 167                 end
 168                 for mclass in model.mclasses do
 169                         if mclass.visibility < min_visibility then continue
 170                         content.append("\"{mclass.name}\": [")
 171                         content.append("\{txt: \"{mclass.name}\", url:\"{mclass.url}\" \},")
 172                         content.append("],")
 173                 end
 174                 var name2mprops = new HashMap[String, Set[MPropDef]]
 175                 for mproperty in model.mproperties do
 176                         if mproperty.visibility < min_visibility then continue
 177                         if mproperty isa MAttribute then continue
 178                         if not name2mprops.has_key(mproperty.name) then name2mprops[mproperty.name] = new HashSet[MPropDef]
 179                         name2mprops[mproperty.name].add_all(mproperty.mpropdefs)
 180                 end
 181                 for mproperty, mpropdefs in name2mprops do
 182                         content.append("\"{mproperty}\": [")
 183                         for mpropdef in mpropdefs do
 184                                 content.append("\{txt: \"{mpropdef.full_name}\", url:\"{mpropdef.url}\" \},")
 185                         end
 186                         content.append("],")
 187                 end
 188
 189                 content.append(" \};")
 190                 file.write(content.to_s)
 191                 file.close
 192         end
 193
 194 end
 195
 196 # Nitdoc base page
 197 abstract class NitdocPage
 198         super Buffer
 199
 200         var dot_dir: nullable String
 201         var source: nullable String
 202         var ctx: NitdocContext
 203
 204         init(ctx: NitdocContext) do
 205                 super
 206                 self.ctx = ctx
 207         end
 208
 209         protected fun head do
 210                 append("<meta charset='utf-8'/>")
 211                 append("<script type='text/javascript' src='scripts/jquery-1.7.1.min.js'></script>")
 212                 append("<script type='text/javascript' src='quicksearch-list.js'></script>")
 213                 append("<script type='text/javascript' src='scripts/js-facilities.js'></script>")
 214                 append("<link rel='stylesheet' href='styles/main.css' type='text/css' media='screen'/>")
 215                 var title = ""
 216                 if ctx.opt_custom_title.value != null then
 217                         title = " | {ctx.opt_custom_title.value.to_s}"
 218                 end
 219                 append("<title>{self.title}{title}</title>")
 220         end
 221
 222         protected fun menu do
 223                 if ctx.opt_custom_menu_items.value != null then
 224                         append(ctx.opt_custom_menu_items.value.to_s)
 225                 end
 226         end
 227
 228         protected fun title: String is abstract
 229
 230         protected fun header do
 231                 append("<header>")
 232                 append("<nav class='main'>")
 233                 append("<ul>")
 234                 menu
 235                 append("<li id='liGitHub'>")
 236                 append("<a class='btn' id='logGitHub'>")
 237                 append("<img id='imgGitHub' src='resources/icons/github-icon.png' alt='GitHub'/>")
 238                 append("</a>")
 239                 append("<div class='popover bottom'>")
 240                 append("<div class='arrow'>&nbsp;</div>")
 241                 append("<div class='githubTitle'>")
 242                 append("<h3>Github Sign In</h3>")
 243                 append("</div>")
 244                 append("<div>")
 245                 append("<label id='lbloginGit'>Username</label>")
 246                 append("<input id='loginGit' name='login' type='text'/>")
 247                 append("<label id='logginMessage'>Hello ")
 248                 append("<a id='githubAccount'><strong id='nickName'></strong></a>")
 249                 append("</label>")
 250                 append("</div>")
 251                 append("<div>")
 252                 append("<label id='lbpasswordGit'>Password</label>")
 253                 append("<input id='passwordGit' name='password' type='password'/>")
 254                 append("<div id='listBranches'>")
 255                 append("<label id='lbBranches'>Branch</label>")
 256                 append("<select class='dropdown' id='dropBranches' name='dropBranches' tabindex='1'></select>")
 257                 append("</div>")
 258                 append("</div>")
 259                 append("<div>")
 260                 append("<label id='lbrepositoryGit'>Repository</label>")
 261                 append("<input id='repositoryGit' name='repository' type='text'/>")
 262                 append("</div>")
 263                 append("<div>")
 264                 append("<label id='lbbranchGit'>Branch</label>")
 265                 append("<input id='branchGit' name='branch' type='text'/>")
 266                 append("</div>")
 267                 append("<div>")
 268                 append("<a id='signIn'>Sign In</a>")
 269                 append("</div>")
 270                 append("</div>")
 271                 append("</li>")
 272                 append("</ul>")
 273                 append("</nav>")
 274                 append("</header>")
 275         end
 276
 277         protected fun content is abstract
 278
 279         protected fun footer do
 280                 if ctx.opt_custom_footer_text.value != null then
 281                         append("<footer>{ctx.opt_custom_footer_text.value.to_s}</footer>")
 282                 end
 283         end
 284
 285         # Generate a clickable graphviz image using a dot content
 286         protected fun generate_dot(dot: String, name: String, alt: String) do
 287                 var output_dir = dot_dir
 288                 if output_dir == null then return
 289                 var file = new OFStream.open("{output_dir}/{name}.dot")
 290                 file.write(dot)
 291                 file.close
 292                 sys.system("\{ test -f {output_dir}/{name}.png && test -f {output_dir}/{name}.s.dot && diff {output_dir}/{name}.dot {output_dir}/{name}.s.dot >/dev/null 2>&1 ; \} || \{ cp {output_dir}/{name}.dot {output_dir}/{name}.s.dot && dot -Tpng -o{output_dir}/{name}.png -Tcmapx -o{output_dir}/{name}.map {output_dir}/{name}.s.dot ; \}")
 293                 append("<article class='graph'>")
 294                 append("<img src='{name}.png' usemap='#{name}' style='margin:auto' alt='{alt}'/>")
 295                 append("</article>")
 296                 var fmap = new IFStream.open("{output_dir}/{name}.map")
 297                 append(fmap.read_all)
 298                 fmap.close
 299         end
 300
 301         # Add a (source) link for a given location
 302         protected fun show_source(l: Location): String
 303         do
 304                 if source == null then
 305                         return "({l.file.filename.simplify_path})"
 306                 else
 307                         # THIS IS JUST UGLY ! (but there is no replace yet)
 308                         var x = source.split_with("%f")
 309                         source = x.join(l.file.filename.simplify_path)
 310                         x = source.split_with("%l")
 311                         source = x.join(l.line_start.to_s)
 312                         x = source.split_with("%L")
 313                         source = x.join(l.line_end.to_s)
 314                         return " (<a href=\"{source.to_s}\">source</a>)"
 315                 end
 316         end
 317
 318         # Render the page as a html string
 319         fun render: String do
 320                 append("<!DOCTYPE html>")
 321                 append("<head>")
 322                 head
 323                 append("</head>")
 324                 append("<body>")
 325                 header
 326                 append("<div class='page'>")
 327                 content
 328                 append("</div>")
 329                 footer
 330                 append("</body>")
 331                 return to_s
 332         end
 333
 334         # Save html page in the specified file
 335         fun save(file: String) do
 336                 var out = new OFStream.open(file)
 337                 out.write(render)
 338                 out.close
 339         end
 340 end
 341
 342 # The overview page
 343 class NitdocOverview
 344         super NitdocPage
 345         private var mbuilder: ModelBuilder
 346         private var mmodules = new Array[MModule]
 347
 348         init(ctx: NitdocContext, dot_dir: nullable String) do
 349                 super(ctx)
 350                 self.mbuilder = ctx.mbuilder
 351                 self.dot_dir = dot_dir
 352                 # get modules
 353                 var mmodules = new HashSet[MModule]
 354                 for mmodule in mbuilder.model.mmodules do
 355                         if mmodule.name == "<main>" then continue
 356                         var owner = mmodule.public_owner
 357                         if owner != null then
 358                                 mmodules.add(owner)
 359                         else
 360                                 mmodules.add(mmodule)
 361                         end
 362                 end
 363                 # sort modules
 364                 var sorter = new MModuleNameSorter
 365                 self.mmodules.add_all(mmodules)
 366                 sorter.sort(self.mmodules)
 367         end
 368
 369         redef fun title do return "Overview"
 370
 371         redef fun menu do
 372                 super
 373                 append("<li class='current'>Overview</li>")
 374                 append("<li><a href='full-index.html'>Full Index</a></li>")
 375         end
 376
 377         redef fun content do
 378                 append("<div class='content fullpage'>")
 379                 var title = "Overview"
 380                 if ctx.opt_custom_title.value != null then
 381                         title = ctx.opt_custom_title.value.to_s
 382                 end
 383                 append("<h1>{title}</h1>")
 384                 var text = ""
 385                 if ctx.opt_custom_overview_text.value != null then
 386                         text = ctx.opt_custom_overview_text.value.to_s
 387                 end
 388                 append("<article class='overview'>{text}</article>")
 389                 append("<article class='overview'>")
 390                 # module list
 391                 append("<h2>Modules</h2>")
 392                 append("<ul>")
 393                 for mmodule in mmodules do
 394                         if mbuilder.mmodule2nmodule.has_key(mmodule) then
 395                                 var amodule = mbuilder.mmodule2nmodule[mmodule]
 396                                 append("<li>")
 397                                 mmodule.html_link(self)
 398                                 append("&nbsp;{amodule.short_comment}</li>")
 399                         end
 400                 end
 401                 append("</ul>")
 402                 # module graph
 403                 process_generate_dot
 404                 append("</article>")
 405                 append("</div>")
 406         end
 407
 408         private fun process_generate_dot do
 409                 # build poset with public owners
 410                 var poset = new POSet[MModule]
 411                 for mmodule in mmodules do
 412                         poset.add_node(mmodule)
 413                         for omodule in mmodules do
 414                                 if mmodule == omodule then continue
 415                                 if mmodule.in_importation < omodule then
 416                                         poset.add_node(omodule)
 417                                         poset.add_edge(mmodule, omodule)
 418                                 end
 419                         end
 420                 end
 421                 # build graph
 422                 var op = new Buffer
 423                 op.append("digraph dep \{ rankdir=BT; node[shape=none,margin=0,width=0,height=0,fontsize=10]; edge[dir=none,color=gray]; ranksep=0.2; nodesep=0.1;\n")
 424                 for mmodule in poset do
 425                         op.append("\"{mmodule.name}\"[URL=\"{mmodule.url}\"];\n")
 426                         for omodule in poset[mmodule].direct_greaters do
 427                                 op.append("\"{mmodule.name}\"->\"{omodule.name}\";\n")
 428                         end
 429                 end
 430                 op.append("\}\n")
 431                 generate_dot(op.to_s, "dep", "Modules hierarchy")
 432         end
 433 end
 434
 435 # The full index page
 436 class NitdocFullindex
 437         super NitdocPage
 438
 439         init(ctx: NitdocContext) do
 440                 super(ctx)
 441                 self.dot_dir = null
 442         end
 443
 444         redef fun title do return "Full Index"
 445
 446         redef fun menu do
 447                 super
 448                 append("<li><a href='index.html'>Overview</a></li>")
 449                 append("<li class='current'>Full Index</li>")
 450         end
 451
 452         redef fun content do
 453                 append("<div class='content fullpage'>")
 454                 append("<h1>Full Index</h1>")
 455                 module_column
 456                 classes_column
 457                 properties_column
 458                 append("</div>")
 459         end
 460
 461         # Add to content modules column
 462         private fun module_column do
 463                 var sorted = ctx.mbuilder.model.mmodule_importation_hierarchy.to_a
 464                 var sorter = new MModuleNameSorter
 465                 sorter.sort(sorted)
 466                 append("<article class='modules filterable'>")
 467                 append("<h2>Modules</h2>")
 468                 append("<ul>")
 469                 for mmodule in sorted do
 470                         append("<li>")
 471                         mmodule.html_link(self)
 472                         append("</li>")
 473                 end
 474                 append("</ul>")
 475                 append("</article>")
 476         end
 477
 478         # Add to content classes modules
 479         private fun classes_column do
 480                 var sorted = ctx.mbuilder.model.mclasses
 481                 var sorter = new MClassNameSorter
 482                 sorter.sort(sorted)
 483                 append("<article class='modules filterable'>")
 484                 append("<h2>Classes</h2>")
 485                 append("<ul>")
 486                 for mclass in sorted do
 487                         if mclass.visibility < ctx.min_visibility then continue
 488                         append("<li>")
 489                         mclass.html_link(self)
 490                         append("</li>")
 491                 end
 492                 append("</ul>")
 493                 append("</article>")
 494         end
 495
 496         # Insert the properties column of fullindex page
 497         private fun properties_column do
 498                 var sorted = ctx.mbuilder.model.mproperties
 499                 var sorter = new MPropertyNameSorter
 500                 sorter.sort(sorted)
 501                 append("<article class='modules filterable'>")
 502                 append("<h2>Properties</h2>")
 503                 append("<ul>")
 504                 for mproperty in sorted do
 505                         if mproperty.visibility < ctx.min_visibility then continue
 506                         if mproperty isa MAttribute then continue
 507                         append("<li>")
 508                         mproperty.intro.html_link(self)
 509                         append(" (")
 510                         mproperty.intro.mclassdef.mclass.html_link(self)
 511                         append(")</li>")
 512                 end
 513                 append("</ul>")
 514                 append("</article>")
 515         end
 516
 517 end
 518
 519 # A module page
 520 class NitdocModule
 521         super NitdocPage
 522
 523         private var mmodule: MModule
 524         private var mbuilder: ModelBuilder
 525
 526         init(mmodule: MModule, ctx: NitdocContext, dot_dir: nullable String) do
 527                 super(ctx)
 528                 self.mmodule = mmodule
 529                 self.mbuilder = ctx.mbuilder
 530                 self.dot_dir = dot_dir
 531         end
 532
 533         redef fun title do
 534                 if mbuilder.mmodule2nmodule.has_key(mmodule) then
 535                         var nmodule = mbuilder.mmodule2nmodule[mmodule]
 536                         return "{mmodule.name} module | {nmodule.short_comment}"
 537                 else
 538                         return "{mmodule.name} module"
 539                 end
 540         end
 541
 542         redef fun menu do
 543                 super
 544                 append("<li><a href='index.html'>Overview</a></li>")
 545                 append("<li class='current'>{mmodule.name}</li>")
 546                 append("<li><a href='full-index.html'>Full Index</a></li>")
 547         end
 548
 549         redef fun content do
 550                 sidebar
 551                 append("<div class='content'>")
 552                 append("<h1>{mmodule.name}</h1>")
 553                 append("<div class='subtitle info'>")
 554                 mmodule.html_signature(self)
 555                 append("</div>")
 556                 mmodule.html_full_comment(self)
 557                 process_generate_dot
 558                 classes
 559                 properties
 560                 append("</div>")
 561         end
 562
 563         private fun process_generate_dot do
 564                 # build poset with public owners
 565                 var poset = new POSet[MModule]
 566                 for mmodule in self.mmodule.in_importation.poset do
 567                         if mmodule.name == "<main>" then continue
 568                         if mmodule.public_owner != null then continue
 569                         if not mmodule.in_importation < self.mmodule and not self.mmodule.in_importation < mmodule and mmodule != self.mmodule then continue
 570                         poset.add_node(mmodule)
 571                         for omodule in mmodule.in_importation.poset do
 572                                 if mmodule == omodule then continue
 573                                 if omodule.name == "<main>" then continue
 574                                 if omodule.public_owner != null then continue
 575                                 if mmodule.in_importation < omodule then
 576                                         poset.add_node(omodule)
 577                                         poset.add_edge(mmodule, omodule)
 578                                 end
 579                         end
 580                 end
 581                 # build graph
 582                 var op = new Buffer
 583                 var name = "dep_{mmodule.name}"
 584                 op.append("digraph {name} \{ rankdir=BT; node[shape=none,margin=0,width=0,height=0,fontsize=10]; edge[dir=none,color=gray]; ranksep=0.2; nodesep=0.1;\n")
 585                 for mmodule in poset do
 586                         if mmodule == self.mmodule then
 587                                 op.append("\"{mmodule.name}\"[shape=box,margin=0.03];\n")
 588                         else
 589                                 op.append("\"{mmodule.name}\"[URL=\"{mmodule.url}\"];\n")
 590                         end
 591                         for omodule in poset[mmodule].direct_greaters do
 592                                 op.append("\"{mmodule.name}\"->\"{omodule.name}\";\n")
 593                         end
 594                 end
 595                 op.append("\}\n")
 596                 generate_dot(op.to_s, name, "Dependency graph for module {mmodule.name}")
 597         end
 598
 599         private fun sidebar do
 600                 append("<div class='menu'>")
 601                 append("<nav>")
 602                 append("<h3>Module Hierarchy</h3>")
 603                 var dependencies = new Array[MModule]
 604                 for dep in mmodule.in_importation.greaters do
 605                         if dep == mmodule or dep.public_owner != null then continue
 606                         dependencies.add(dep)
 607                 end
 608                 if dependencies.length > 0 then
 609                         append("<h4>All dependencies</h4>")
 610                         display_module_list(dependencies)
 611                 end
 612                 var clients = new Array[MModule]
 613                 for dep in mmodule.in_importation.smallers do
 614                         if dep.name == "<main>" then continue
 615                         if dep == mmodule or dep.public_owner != null then continue
 616                         clients.add(dep)
 617                 end
 618                 if clients.length > 0 then
 619                         append("<h4>All clients</h4>")
 620                         display_module_list(clients)
 621                 end
 622                 append("</nav>")
 623                 if ctx.min_visibility < protected_visibility then
 624                         if mmodule.in_nesting.direct_greaters.length > 0 then
 625                                 append("<nav>")
 626                                 append("<h3>Nested Modules</h3>")
 627                                 display_module_list(mmodule.in_nesting.direct_greaters.to_a)
 628                                 append("</nav>")
 629                         end
 630                 end
 631                 append("</div>")
 632         end
 633
 634         private fun display_module_list(list: Array[MModule]) do
 635                 append("<ul>")
 636                 var sorter = new MModuleNameSorter
 637                 sorter.sort(list)
 638                 for m in list do
 639                         append("<li>")
 640                         m.html_link(self)
 641                         append("</li>")
 642                 end
 643                 append("</ul>")
 644         end
 645
 646         # display the class column
 647         private fun classes do
 648                 var intro_mclasses = mmodule.intro_mclasses
 649                 var redef_mclasses = mmodule.redef_mclasses
 650                 var all_mclasses = new HashSet[MClass]
 651                 for m in mmodule.in_nesting.greaters do
 652                         all_mclasses.add_all(m.intro_mclasses)
 653                         all_mclasses.add_all(m.redef_mclasses)
 654                 end
 655                 all_mclasses.add_all(intro_mclasses)
 656                 all_mclasses.add_all(redef_mclasses)
 657
 658                 var sorted = new Array[MClass]
 659                 sorted.add_all(all_mclasses)
 660                 var sorter = new MClassNameSorter
 661                 sorter.sort(sorted)
 662                 append("<div class='module'>")
 663                 append("<article class='classes filterable'>")
 664                 append("<h2>Classes</h2>")
 665                 append("<ul>")
 666                 for c in sorted do
 667                         if c.visibility < ctx.min_visibility then continue
 668                         if redef_mclasses.has(c) and c.intro_mmodule.public_owner != mmodule then
 669                                 append("<li class='redef'>")
 670                                 append("<span title='refined in this module'>R </span>")
 671                         else
 672                                 append("<li class='intro'>")
 673                                 append("<span title='introduced in this module'>I </span>")
 674                         end
 675                         c.html_link(self)
 676                         append("</li>")
 677                 end
 678                 append("</ul>")
 679                 append("</article>")
 680                 append("</div>")
 681         end
 682
 683         # display the property column
 684         private fun properties do
 685                 # get properties
 686                 var mpropdefs = new HashSet[MPropDef]
 687                 for m in mmodule.in_nesting.greaters do
 688                         for c in m.mclassdefs do mpropdefs.add_all(c.mpropdefs)
 689                 end
 690                 for c in mmodule.mclassdefs do mpropdefs.add_all(c.mpropdefs)
 691                 var sorted = mpropdefs.to_a
 692                 var sorter = new MPropDefNameSorter
 693                 sorter.sort(sorted)
 694                 # display properties in one column
 695                 append("<article class='properties filterable'>")
 696                 append("<h2>Properties</h2>")
 697                 append("<ul>")
 698                 for mprop in sorted do
 699                         if mprop isa MAttributeDef then continue
 700                         if mprop.mproperty.visibility < ctx.min_visibility then continue
 701                         mprop.html_list_item(self)
 702                 end
 703                 append("</ul>")
 704                 append("</article>")
 705         end
 706 end
 707
 708 # A class page
 709 class NitdocClass
 710         super NitdocPage
 711
 712         private var mclass: MClass
 713         private var vtypes = new HashSet[MVirtualTypeDef]
 714         private var consts = new HashSet[MMethodDef]
 715         private var meths = new HashSet[MMethodDef]
 716         private var inherited = new HashSet[MPropDef]
 717
 718         init(mclass: MClass, ctx: NitdocContext, dot_dir: nullable String, source: nullable String) do
 719                 super(ctx)
 720                 self.mclass = mclass
 721                 self.dot_dir = dot_dir
 722                 self.source = source
 723                 # load properties
 724                 for mclassdef in mclass.mclassdefs do
 725                         for mpropdef in mclassdef.mpropdefs do
 726                                 if mpropdef.mproperty.visibility < ctx.min_visibility then continue
 727                                 if mpropdef isa MVirtualTypeDef then vtypes.add(mpropdef)
 728                                 if mpropdef isa MMethodDef then
 729                                         if mpropdef.mproperty.is_init then
 730                                                 consts.add(mpropdef)
 731                                         else
 732                                                 meths.add(mpropdef)
 733                                         end
 734                                 end
 735                         end
 736                 end
 737                 # get inherited properties
 738                 for mprop in mclass.inherited_mproperties do
 739                         var mpropdef = mprop.intro
 740                         if mprop.visibility < ctx.min_visibility then continue
 741                         if mpropdef isa MVirtualTypeDef then vtypes.add(mpropdef)
 742                         if mpropdef isa MMethodDef then
 743                                 if mpropdef.mproperty.is_init then
 744                                         consts.add(mpropdef)
 745                                 else
 746                                         meths.add(mpropdef)
 747                                 end
 748                         end
 749                         inherited.add(mpropdef)
 750                 end
 751         end
 752
 753         redef fun title do
 754                 var nclass = ctx.mbuilder.mclassdef2nclassdef[mclass.intro]
 755                 if nclass isa AStdClassdef then
 756                         return "{mclass.name} class | {nclass.short_comment}"
 757                 else
 758                         return "{mclass.name} class"
 759                 end
 760         end
 761
 762         redef fun menu do
 763                 super
 764                 append("<li><a href='index.html'>Overview</a></li>")
 765                 var public_owner = mclass.public_owner
 766                 if public_owner is null then
 767                         append("<li>")
 768                         mclass.intro_mmodule.html_link(self)
 769                         append("</li>")
 770                 else
 771                         append("<li>")
 772                         public_owner.html_link(self)
 773                         append("</li>")
 774                 end
 775                 append("<li class='current'>{mclass.name}</li>")
 776                 append("<li><a href='full-index.html'>Full Index</a></li>")
 777         end
 778
 779         redef fun content do
 780                 append("<div class='menu'>")
 781                 properties_column
 782                 inheritance_column
 783                 append("</div>")
 784                 append("<div class='content'>")
 785                 class_doc
 786                 append("</div>")
 787         end
 788
 789         private fun properties_column do
 790                 var sorter = new MPropDefNameSorter
 791                 append("<nav class='properties filterable'>")
 792                 append("<h3>Properties</h3>")
 793                 # virtual types
 794                 if vtypes.length > 0 then
 795                         var vts = new Array[MVirtualTypeDef]
 796                         vts.add_all(vtypes)
 797                         sorter.sort(vts)
 798                         append("<h4>Virtual Types</h4>")
 799                         append("<ul>")
 800                         for mprop in vts do
 801                                 mprop.html_sidebar_item(self)
 802                         end
 803                         append("</ul>")
 804                 end
 805                 # constructors
 806                 if consts.length > 0 then
 807                         var cts = new Array[MMethodDef]
 808                         cts.add_all(consts)
 809                         sorter.sort(cts)
 810                         append("<h4>Constructors</h4>")
 811                         append("<ul>")
 812                         for mprop in cts do
 813                                 if mprop.mproperty.name == "init" and mprop.mclassdef.mclass != mclass then continue
 814                                 mprop.html_sidebar_item(self)
 815                         end
 816                         append("</ul>")
 817                 end
 818                 # methods
 819                 if meths.length > 0 then
 820                         var mts = new Array[MMethodDef]
 821                         mts.add_all(meths)
 822                         sorter.sort(mts)
 823                         append("<h4>Methods</h4>")
 824                         append("<ul>")
 825                         for mprop in mts do
 826                                 if mclass.name != "Object" and mprop.mproperty.intro_mclassdef.mclass.name == "Object" and mprop.mproperty.visibility <= protected_visibility then continue
 827                                 mprop.html_sidebar_item(self)
 828                         end
 829                         append("</ul>")
 830                 end
 831                 append("</nav>")
 832         end
 833
 834         private fun inheritance_column do
 835                 var sorted = new Array[MClass]
 836                 var sorterp = new MClassNameSorter
 837                 append("<nav>")
 838                 append("<h3>Inheritance</h3>")
 839                 var greaters = mclass.in_hierarchy(ctx.mainmodule).greaters.to_a
 840                 if greaters.length > 1 then
 841                         ctx.mainmodule.linearize_mclasses(greaters)
 842                         append("<h4>Superclasses</h4>")
 843                         append("<ul>")
 844                         for sup in greaters do
 845                                 if sup == mclass then continue
 846                                 append("<li>")
 847                                 sup.html_link(self)
 848                                 append("</li>")
 849                         end
 850                         append("</ul>")
 851                 end
 852                 var smallers = mclass.in_hierarchy(ctx.mainmodule).smallers.to_a
 853                 var direct_smallers = mclass.in_hierarchy(ctx.mainmodule).direct_smallers.to_a
 854                 if smallers.length <= 1 then
 855                         append("<h4>No Known Subclasses</h4>")
 856                 else if smallers.length <= 100 then
 857                         ctx.mainmodule.linearize_mclasses(smallers)
 858                         append("<h4>Subclasses</h4>")
 859                         append("<ul>")
 860                         for sub in smallers do
 861                                 if sub == mclass then continue
 862                                 append("<li>")
 863                                 sub.html_link(self)
 864                                 append("</li>")
 865                         end
 866                         append("</ul>")
 867                 else if direct_smallers.length <= 100 then
 868                         ctx.mainmodule.linearize_mclasses(direct_smallers)
 869                         append("<h4>Direct Subclasses Only</h4>")
 870                         append("<ul>")
 871                         for sub in direct_smallers do
 872                                 if sub == mclass then continue
 873                                 append("<li>")
 874                                 sub.html_link(self)
 875                                 append("</li>")
 876                         end
 877                         append("</ul>")
 878                 else
 879                         append("<h4>Too much Subclasses to list</h4>")
 880                 end
 881                 append("</nav>")
 882         end
 883
 884         private fun class_doc do
 885                 # title
 886                 append("<h1>{mclass.signature}</h1>")
 887                 append("<div class='subtitle info'>")
 888                 mclass.html_full_signature(self)
 889                 append("</div>")
 890                 # comment
 891                 var nclass = ctx.mbuilder.mclassdef2nclassdef[mclass.intro]
 892                 append("<div style=\"float: right;\"><a id=\"lblDiffCommit\"></a></div>")
 893                 append("<section class='description'>")
 894                 if nclass isa AStdClassdef and not nclass.full_comment.is_empty then append("<pre class=\"text_label\" title=\"122\" name=\"\" tag=\"{mclass.mclassdefs.first.location.to_s}\" type=\"2\">{nclass.full_comment}</pre><textarea id=\"fileContent\" class=\"edit\" cols=\"76\" rows=\"1\" style=\"display: none;\"></textarea><a id=\"cancelBtn\" style=\"display: none;\">Cancel</a><a id=\"commitBtn\" style=\"display: none;\">Commit</a><pre id=\"preSave\" class=\"text_label\" type=\"2\"></pre>")
 895                 process_generate_dot
 896                 append("</section>")
 897                 # concerns
 898                 var concern2meths = new ArrayMap[MModule, Array[MMethodDef]]
 899                 var sorted_meths = new Array[MMethodDef]
 900                 var sorted = new Array[MModule]
 901                 sorted_meths.add_all(meths)
 902                 ctx.mainmodule.linearize_mpropdefs(sorted_meths)
 903                 for meth in meths do
 904                         if inherited.has(meth) then continue
 905                         var mmodule = meth.mclassdef.mmodule
 906                         if not concern2meths.has_key(mmodule) then
 907                                 sorted.add(mmodule)
 908                                 concern2meths[mmodule] = new Array[MMethodDef]
 909                         end
 910                         concern2meths[mmodule].add(meth)
 911                 end
 912                 var sections = new ArrayMap[MModule, Array[MModule]]
 913                 for mmodule in concern2meths.keys do
 914                         var owner = mmodule.public_owner
 915                         if owner == null then owner = mmodule
 916                         if not sections.has_key(owner) then sections[owner] = new Array[MModule]
 917                         if owner != mmodule then sections[owner].add(mmodule)
 918                 end
 919                 append("<section class='concerns'>")
 920                 append("<h2 class='section-header'>Concerns</h2>")
 921                 append("<ul>")
 922                 for owner, mmodules in sections do
 923                         var nowner = ctx.mbuilder.mmodule2nmodule[owner]
 924                         append("<li>")
 925                         if nowner.short_comment.is_empty then
 926                                 append("<a href=\"#{owner.anchor}\">{owner.name}</a>")
 927                         else
 928                                 append("<a href=\"#{owner.anchor}\">{owner.name}</a>: {nowner.short_comment}")
 929                         end
 930                         if not mmodules.is_empty then
 931                                 append("<ul>")
 932                                 for mmodule in mmodules do
 933                                         var nmodule = ctx.mbuilder.mmodule2nmodule[mmodule]
 934                                         if nmodule.short_comment.is_empty then
 935                                                 append("<li><a href=\"#{mmodule.anchor}\">{mmodule.name}</a></li>")
 936                                         else
 937                                                 append("<li><a href=\"#{mmodule.anchor}\">{mmodule.name}</a>: {nmodule.short_comment}</li>")
 938                                         end
 939                                 end
 940                                 append("</ul>")
 941                         end
 942                         append("</li>")
 943                 end
 944                 append("</ul>")
 945                 append("</section>")
 946                 # properties
 947                 var prop_sorter = new MPropDefNameSorter
 948                 var lmmodule = new List[MModule]
 949                 # virtual and formal types
 950                 var local_vtypes = new Array[MVirtualTypeDef]
 951                 for vt in vtypes do if not inherited.has(vt) then local_vtypes.add(vt)
 952                 if local_vtypes.length > 0 or mclass.arity > 0 then
 953                         append("<section class='types'>")
 954                         append("<h2>Formal and Virtual Types</h2>")
 955                         # formal types
 956                         if mclass.arity > 0 and nclass isa AStdClassdef then
 957                                 for ft, bound in mclass.parameter_types do
 958                                         append("<article id='FT_{ft}'>")
 959                                         append("<h3 class='signature'>{ft}: ")
 960                                         bound.html_link(self)
 961                                         append("</h3>")
 962                                         append("<div class=\"info\">formal generic type</div>")
 963                                         append("</article>")
 964                                 end
 965                         end
 966                         # virtual types
 967                         prop_sorter.sort(local_vtypes)
 968                         for prop in local_vtypes do prop.html_full_desc(self)
 969                         append("</section>")
 970                 end
 971                 # constructors
 972                 var local_consts = new Array[MMethodDef]
 973                 for const in consts do if not inherited.has(const) then local_consts.add(const)
 974                 prop_sorter.sort(local_consts)
 975                 if local_consts.length > 0 then
 976                         append("<section class='constructors'>")
 977                         append("<h2 class='section-header'>Constructors</h2>")
 978                         for prop in local_consts do prop.html_full_desc(self)
 979                         append("</section>")
 980                 end
 981                 # methods
 982                 if not concern2meths.is_empty then
 983                         append("<section class='methods'>")
 984                         append("<h2 class='section-header'>Methods</h2>")
 985                         for owner, mmodules in sections do
 986                                 append("<a id=\"{owner.anchor}\"></a>")
 987                                 if owner != mclass.intro_mmodule and owner != mclass.public_owner then
 988                                         var nowner = ctx.mbuilder.mmodule2nmodule[owner]
 989                                         append("<h3 class=\"concern-toplevel\">Methods refined in ")
 990                                         owner.html_link(self)
 991                                         append("</h3>")
 992                                         append("<p class=\"concern-doc\">")
 993                                         owner.html_link(self)
 994                                         if not nowner.short_comment.is_empty then
 995                                                 append(": {nowner.short_comment}")
 996                                         end
 997                                         append("</p>")
 998                                 end
 999                                 if concern2meths.has_key(owner) then
1000                                         var mmethods = concern2meths[owner]
1001                                         prop_sorter.sort(mmethods)
1002                                         for prop in mmethods do prop.html_full_desc(self)
1003                                 end
1004                                 for mmodule in mmodules do
1005                                         append("<a id=\"{mmodule.anchor}\"></a>")
1006                                         var nmodule = ctx.mbuilder.mmodule2nmodule[mmodule]
1007                                         if mmodule != mclass.intro_mmodule and mmodule != mclass.public_owner then
1008                                                 append("<p class=\"concern-doc\">")
1009                                                 mmodule.html_link(self)
1010                                                 if not nmodule.short_comment.is_empty then
1011                                                         append(": {nmodule.short_comment}")
1012                                                 end
1013                                                 append("</p>")
1014                                         end
1015                                         var mmethods = concern2meths[mmodule]
1016                                         prop_sorter.sort(mmethods)
1017                                         for prop in mmethods do prop.html_full_desc(self)
1018                                 end
1019                         end
1020                 end
1021                 # inherited properties
1022                 if inherited.length > 0 then
1023                         var sorted_inherited = new Array[MPropDef]
1024                         sorted_inherited.add_all(inherited)
1025                         ctx.mainmodule.linearize_mpropdefs(sorted_inherited)
1026                         var classes = new ArrayMap[MClass, Array[MPropDef]]
1027                         for mmethod in sorted_inherited.reversed do
1028                                 var mclass = mmethod.mclassdef.mclass
1029                                 if not classes.has_key(mclass) then classes[mclass] = new Array[MPropDef]
1030                                 classes[mclass].add(mmethod)
1031                         end
1032                         append("<h3>Inherited Properties</h3>")
1033                         for c, mmethods in classes do
1034                                 prop_sorter.sort(mmethods)
1035                                 append("<p>Defined in ")
1036                                 c.html_link(self)
1037                                 append(": ")
1038                                 for i in [0..mmethods.length[ do
1039                                         var mmethod = mmethods[i]
1040                                         mmethod.html_link(self)
1041                                         if i <= mmethods.length - 1 then append(", ")
1042                                 end
1043                                 append("</p>")
1044                         end
1045                 end
1046                 append("</section>")
1047         end
1048
1049         private fun process_generate_dot do
1050                 var pe = ctx.class_hierarchy[mclass]
1051                 var cla = new HashSet[MClass]
1052                 var sm = new HashSet[MClass]
1053                 var sm2 = new HashSet[MClass]
1054                 sm.add(mclass)
1055                 while cla.length + sm.length < 10 and sm.length > 0 do
1056                         cla.add_all(sm)
1057                         sm2.clear
1058                         for x in sm do
1059                                 sm2.add_all(pe.poset[x].direct_smallers)
1060                         end
1061                         var t = sm
1062                         sm = sm2
1063                         sm2 = t
1064                 end
1065                 cla.add_all(pe.greaters)
1066
1067                 var op = new Buffer
1068                 var name = "dep_{mclass.name}"
1069                 op.append("digraph {name} \{ rankdir=BT; node[shape=none,margin=0,width=0,height=0,fontsize=10]; edge[dir=none,color=gray]; ranksep=0.2; nodesep=0.1;\n")
1070                 for c in cla do
1071                         if c == mclass then
1072                                 op.append("\"{c.name}\"[shape=box,margin=0.03];\n")
1073                         else
1074                                 op.append("\"{c.name}\"[URL=\"{c.url}\"];\n")
1075                         end
1076                         for c2 in pe.poset[c].direct_greaters do
1077                                 if not cla.has(c2) then continue
1078                                 op.append("\"{c.name}\"->\"{c2.name}\";\n")
1079                         end
1080                         if not pe.poset[c].direct_smallers.is_empty then
1081                                 var others = true
1082                                 for c2 in pe.poset[c].direct_smallers do
1083                                         if cla.has(c2) then others = false
1084                                 end
1085                                 if others then
1086                                         op.append("\"{c.name}...\"[label=\"\"];\n")
1087                                         op.append("\"{c.name}...\"->\"{c.name}\"[style=dotted];\n")
1088                                 end
1089                         end
1090                 end
1091                 op.append("\}\n")
1092                 generate_dot(op.to_s, name, "Dependency graph for class {mclass.name}")
1093         end
1094 end
1095
1096 #
1097 # Model redefs
1098 #
1099
1100 redef class MModule
1101         # URL to nitdoc page
1102         fun url: String do
1103                 var res = new Buffer
1104                 res.append("module_")
1105                 var mowner = public_owner
1106                 if mowner != null then
1107                         res.append("{public_owner.name}_")
1108                 end
1109                 res.append("{self.name}.html")
1110                 return res.to_s
1111         end
1112
1113         # html anchor id to the module in a nitdoc page
1114         fun anchor: String do
1115                 var res = new Buffer
1116                 res.append("MOD_")
1117                 var mowner = public_owner
1118                 if mowner != null then
1119                         res.append("{public_owner.name}_")
1120                 end
1121                 res.append(self.name)
1122                 return res.to_s
1123         end
1124
1125         # Return a link (html a tag) to the nitdoc module page
1126         fun html_link(page: NitdocPage) do
1127                 if page.ctx.mbuilder.mmodule2nmodule.has_key(self) then
1128                         page.append("<a href='{url}' title='{page.ctx.mbuilder.mmodule2nmodule[self].short_comment}'>{name}</a>")
1129                 else
1130                         page.append("<a href='{url}'>{name}</a>")
1131                 end
1132         end
1133
1134         # Return the module signature decorated with html
1135         fun html_signature(page: NitdocPage) do
1136                 page.append("<span>module ")
1137                 html_full_namespace(page)
1138                 page.append("</span>")
1139         end
1140
1141         # Return the module full namespace decorated with html
1142         fun html_full_namespace(page: NitdocPage) do
1143                 page.append("<span>")
1144                 var mowner = public_owner
1145                 if mowner != null then
1146                         public_owner.html_namespace(page)
1147                         page.append("::")
1148                 end
1149                 html_link(page)
1150                 page.append("</span>")
1151         end
1152
1153         # Return the module full namespace decorated with html
1154         fun html_namespace(page: NitdocPage) do
1155                 page.append("<span>")
1156                 var mowner = public_owner
1157                 if mowner != null then
1158                         public_owner.html_namespace(page)
1159                 else
1160                         html_link(page)
1161                 end
1162                 page.append("</span>")
1163         end
1164
1165         # Return the full comment of the module decorated with html
1166         fun html_full_comment(page: NitdocPage) do
1167                 if page.ctx.mbuilder.mmodule2nmodule.has_key(self) then
1168                         page.append("<div id='description'>")
1169                         page.append("<pre class='text_label'>{page.ctx.mbuilder.mmodule2nmodule[self].full_comment}</pre>")
1170                         page.append("<textarea class='edit' rows='1' cols='76' id='fileContent'></textarea>")
1171                         page.append("<a id='cancelBtn'>Cancel</a>")
1172                         page.append("<a id='commitBtn'>Commit</a>")
1173                         page.append("<pre class='text_label' id='preSave' type='2'></pre>")
1174                         page.append("</div>")
1175                 end
1176         end
1177 end
1178
1179 redef class MClass
1180         # Return the module signature decorated with html
1181         fun html_full_signature(page: NitdocPage) do
1182                 if visibility < public_visibility then page.append("{visibility.to_s} ")
1183                 page.append("{kind} ")
1184                 html_namespace(page)
1185         end
1186
1187         # name with formal parameter
1188         # Foo[A, B]
1189         private fun signature: String do
1190                 if arity > 0 then
1191                         return "{name}[{intro.parameter_names.join(", ")}]"
1192                 else
1193                         return name
1194                 end
1195         end
1196
1197         # Return a link (html a tag) to the nitdoc class page
1198         fun html_link(page: NitdocPage) do
1199                 page.append("<a href='{url}'")
1200                 if page.ctx.mbuilder.mclassdef2nclassdef.has_key(intro) then
1201                         var nclass = page.ctx.mbuilder.mclassdef2nclassdef[intro]
1202                         if nclass isa AStdClassdef then
1203                                 page.append(" title=\"{nclass.short_comment}\"")
1204                         end
1205                 end
1206                 page.append(">{signature}</a>")
1207         end
1208
1209         # Return the class namespace decorated with html
1210         fun html_namespace(page: NitdocPage) do
1211                 intro_mmodule.html_namespace(page)
1212                 page.append("::<span>")
1213                 html_link(page)
1214                 page.append("</span>")
1215         end
1216
1217         fun url: String do
1218                 return "class_{public_owner}_{c_name}.html"
1219         end
1220
1221         # Escape name for html output
1222         redef fun name do return super.html_escape
1223 end
1224
1225 redef class MProperty
1226         # Return the property namespace decorated with html
1227         fun html_namespace(page: NitdocPage) do
1228                 intro_mclassdef.mclass.html_namespace(page)
1229                 page.append("::<span>")
1230                 intro.html_link(page)
1231                 page.append("</span>")
1232         end
1233
1234         # Escape name for html output
1235         redef fun name do return super.html_escape
1236 end
1237
1238 redef class MType
1239         fun html_link(page: NitdocPage) is abstract
1240 end
1241
1242 redef class MClassType
1243         redef fun html_link(page) do mclass.html_link(page)
1244 end
1245
1246 redef class MNullableType
1247         redef fun html_link(page) do
1248                 page.append("nullable ")
1249                 mtype.html_link(page)
1250         end
1251 end
1252
1253 redef class MGenericType
1254         redef fun html_link(page) do
1255                 page.append("<a href='{mclass.url}'>{mclass.name}</a>[")
1256                 for i in [0..arguments.length[ do
1257                         arguments[i].html_link(page)
1258                         if i < arguments.length - 1 then page.append(", ")
1259                 end
1260                 page.append("]")
1261         end
1262 end
1263
1264 redef class MParameterType
1265         redef fun html_link(page) do
1266                 var name = mclass.intro.parameter_names[rank]
1267                 page.append("<a href='{mclass.url}#FT_{name}' title='formal type'>{name}</a>")
1268         end
1269 end
1270
1271 redef class MVirtualType
1272         redef fun html_link(page) do mproperty.intro.html_link(page)
1273 end
1274
1275 redef class MClassDef
1276         # Return the classdef namespace decorated with html
1277         fun html_namespace(page: NitdocPage) do
1278                 mmodule.html_full_namespace(page)
1279                 page.append("::<span>")
1280                 mclass.html_link(page)
1281                 page.append("</span>")
1282         end
1283 end
1284
1285 redef class MPropDef
1286         fun url: String do return "{mclassdef.mclass.url}#{anchor}"
1287         fun anchor: String do return "PROP_{mclassdef.mclass.public_owner.name}_{c_name}"
1288
1289         # Return a link (html a tag) to the nitdoc class page
1290         fun html_link(page: NitdocPage) do
1291                 if page.ctx.mbuilder.mpropdef2npropdef.has_key(self) then
1292                         var nprop = page.ctx.mbuilder.mpropdef2npropdef[self]
1293                         page.append("<a href=\"{url}\" title=\"{nprop.short_comment}\">{mproperty.name}</a>")
1294                 else
1295                         page.append("<a href=\"{url}\">{mproperty.name}</a>")
1296                 end
1297         end
1298
1299         # Return a list item for the mpropdef
1300         private fun html_list_item(page: NitdocPage) do
1301                 if is_intro then
1302                         page.append("<li class='intro'>")
1303                         page.append("<span title='introduction'>I</span>&nbsp;")
1304                 else
1305                         page.append("<li class='redef'>")
1306                         page.append("<span title='redefinition'>R</span>&nbsp;")
1307                 end
1308                 html_link(page)
1309                 page.append("(")
1310                 mclassdef.mclass.html_link(page)
1311                 page.append(")")
1312                 page.append("</li>")
1313         end
1314
1315         # Return a list item for the mpropdef
1316         private fun html_sidebar_item(page: NitdocClass) do
1317                 if is_intro and mclassdef.mclass == page.mclass then
1318                         page.append("<li class='intro'>")
1319                         page.append("<span title='Introduced'>I</span>")
1320                 else if is_intro and mclassdef.mclass != page.mclass then
1321                         page.append("<li class='inherit'>")
1322                         page.append("<span title='Inherited'>H</span>")
1323                 else
1324                         page.append("<li class='redef'>")
1325                         page.append("<span title='Redefined'>R</span>")
1326                 end
1327                 html_link(page)
1328                 page.append("</li>")
1329         end
1330
1331         private fun html_full_desc(page: NitdocClass) is abstract
1332         private fun html_info(page: NitdocClass) is abstract
1333
1334         fun full_name: String do
1335                 return "{mclassdef.mclass.public_owner.name}::{mclassdef.mclass.name}::{mproperty.name}"
1336         end
1337
1338         private fun html_inheritance(page: NitdocClass) do
1339                 # definitions block
1340                 page.append("<p class='info'>")
1341                 page.ctx.mainmodule.linearize_mpropdefs(mproperty.mpropdefs)
1342                 var previous_defs = new Array[MPropDef]
1343                 var next_defs = new Array[MPropDef]
1344                 var self_passed = false
1345                 for def in mproperty.mpropdefs do
1346                         if def == self then
1347                                 self_passed = true
1348                                 continue
1349                         end
1350                         if not self_passed then
1351                                 if def.mclassdef.mclass.in_hierarchy(page.ctx.mainmodule) < page.mclass then continue
1352                                 if def.is_intro then continue
1353                                 previous_defs.add(def)
1354                         else
1355                                 if page.mclass.in_hierarchy(page.ctx.mainmodule) < def.mclassdef.mclass then continue
1356                                 next_defs.add(def)
1357                         end
1358                 end
1359                 page.append("defined by ")
1360                 mclassdef.mmodule.html_full_namespace(page)
1361                 if page.ctx.mbuilder.mpropdef2npropdef.has_key(self) then
1362                         page.append(" {page.show_source(page.ctx.mbuilder.mpropdef2npropdef[self].location)}")
1363                 end
1364                 if not is_intro then
1365                         page.append(", introduced by ")
1366                         mproperty.intro.mclassdef.mclass.html_link(page)
1367                         if page.ctx.mbuilder.mpropdef2npropdef.has_key(self) then
1368                                 page.append(" {page.show_source(page.ctx.mbuilder.mpropdef2npropdef[self].location)}")
1369                         end
1370                 end
1371                 if not previous_defs.is_empty then
1372                         page.append(", inherited from ")
1373                         for i in [0..previous_defs.length[ do
1374                                 var def = previous_defs[i]
1375                                 def.mclassdef.mclass.html_link(page)
1376                                 if page.ctx.mbuilder.mpropdef2npropdef.has_key(def) then
1377                                         page.append(" {page.show_source(page.ctx.mbuilder.mpropdef2npropdef[def].location)}")
1378                                 end
1379
1380                                 if i < previous_defs.length - 1 then page.append(", ")
1381                         end
1382                 end
1383                 if not next_defs.is_empty then
1384                         page.append(", redefined by ")
1385                         for i in [0..next_defs.length[ do
1386                                 var def = next_defs[i]
1387                                 def.mclassdef.mclass.html_link(page)
1388                                 if page.ctx.mbuilder.mpropdef2npropdef.has_key(def) then
1389                                         page.append(" {page.show_source(page.ctx.mbuilder.mpropdef2npropdef[def].location)}")
1390                                 end
1391                                 if i < next_defs.length - 1 then page.append(", ")
1392                         end
1393                 end
1394                 page.append(".</p>")
1395         end
1396
1397         private fun html_comment(page: NitdocClass) do
1398                 if not page.ctx.mbuilder.mpropdef2npropdef.has_key(self) then return
1399                 var nprop = page.ctx.mbuilder.mpropdef2npropdef[self]
1400                 page.append("<div class='description'>")
1401                 if not is_intro then
1402                         var intro_nprop = page.ctx.mbuilder.mpropdef2npropdef[mproperty.intro]
1403                         page.append("<p>from ")
1404                         mproperty.html_namespace(page)
1405                         page.append("</p>")
1406                         if intro_nprop.full_comment == "" then
1407                                 page.append("<a class=\"newComment\" title=\"32\" tag=\"\">New Comment</a>")
1408                         else
1409                                 page.append("<pre class=\"text_label\" title=\"\" name=\"\" tag=\"\" type=\"1\">{intro_nprop.full_comment}</pre>")
1410                         end
1411                         page.append("<p>from ")
1412                         mclassdef.html_namespace(page)
1413                         page.append("</p>")
1414                 end
1415                 if nprop.full_comment == "" then
1416                         page.append("<a class=\"newComment\" title=\"32\" tag=\"\">New Comment</a>")
1417                 else
1418                         page.append("<pre class=\"text_label\" title=\"\" name=\"\" tag=\"\" type=\"1\">{nprop.full_comment}</pre>")
1419                 end
1420                 page.append("<textarea id=\"fileContent\" class=\"edit\" cols=\"76\" rows=\"1\" style=\"display: none;\"></textarea><a id=\"cancelBtn\" style=\"display: none;\">Cancel</a><a id=\"commitBtn\" style=\"display: none;\">Commit</a><pre id=\"preSave\" class=\"text_label\" type=\"2\"></pre>")
1421                 html_inheritance(page)
1422                 page.append("</div>")
1423         end
1424 end
1425
1426 redef class MMethodDef
1427         redef fun html_full_desc(page) do
1428                 var classes = new Array[String]
1429                 var is_redef = mproperty.intro_mclassdef.mclass != page.mclass
1430                 if mproperty.is_init then
1431                         classes.add("init")
1432                 else
1433                         classes.add("fun")
1434                 end
1435                 if is_redef then classes.add("redef")
1436                 classes.add(mproperty.visibility.to_s)
1437                 page.append("<article class='{classes.join(" ")}' id='{anchor}'>")
1438                 if page.ctx.mbuilder.mpropdef2npropdef.has_key(self) then
1439                         page.append("<h3 class='signature'>{mproperty.name}")
1440                         msignature.html_signature(page)
1441                         page.append("</h3>")
1442                 else
1443                         page.append("<h3 class='signature'>init")
1444                         msignature.html_signature(page)
1445                         page.append("</h3>")
1446                 end
1447                 html_info(page)
1448                 html_comment(page)
1449                 page.append("</article>")
1450         end
1451
1452         redef fun html_info(page) do
1453                 page.append("<div class='info'>")
1454                 if mproperty.visibility < public_visibility then page.append("{mproperty.visibility.to_s} ")
1455                 if mproperty.intro_mclassdef.mclass != page.mclass then page.append("redef ")
1456                 if mproperty.is_init then
1457                         page.append("init ")
1458                 else
1459                         page.append("fun ")
1460                 end
1461                 mproperty.html_namespace(page)
1462                 page.append("</div>")
1463                 page.append("<div style=\"float: right;\"><a id=\"lblDiffCommit\"></a></div>")
1464         end
1465 end
1466
1467 redef class MVirtualTypeDef
1468         redef fun html_full_desc(page) do
1469                 var is_redef = mproperty.intro_mclassdef.mclass != page.mclass
1470                 var classes = new Array[String]
1471                 classes.add("type")
1472                 if is_redef then classes.add("redef")
1473                 classes.add(mproperty.visibility.to_s)
1474                 page.append("<article class='{classes.join(" ")}' id='{anchor}'>")
1475                 page.append("<h3 class='signature'>{mproperty.name}: ")
1476                 bound.html_link(page)
1477                 page.append("</h3>")
1478                 html_info(page)
1479                 html_comment(page)
1480                 page.append("</article>")
1481         end
1482
1483         redef fun html_info(page) do
1484                 page.append("<div class='info'>")
1485                 if mproperty.intro_mclassdef.mclass != page.mclass then page.append("redef ")
1486                 page.append("type ")
1487                 mproperty.html_namespace(page)
1488                 page.append("</div>")
1489                 page.append("<div style=\"float: right;\"><a id=\"lblDiffCommit\"></a></div>")
1490         end
1491 end
1492
1493 redef class MSignature
1494         private fun html_signature(page: NitdocPage) do
1495                 if not mparameters.is_empty then
1496                         page.append("(")
1497                         for i in [0..mparameters.length[ do
1498                                 mparameters[i].html_link(page)
1499                                 if i < mparameters.length - 1 then page.append(", ")
1500                         end
1501                         page.append(")")
1502                 end
1503                 if return_mtype != null then
1504                         page.append(": ")
1505                         return_mtype.html_link(page)
1506                 end
1507         end
1508 end
1509
1510 redef class MParameter
1511         private fun html_link(page: NitdocPage) do
1512                 page.append("{name}: ")
1513                 mtype.html_link(page)
1514                 if is_vararg then page.append("...")
1515         end
1516 end
1517
1518 #
1519 # Nodes redefs
1520 #
1521
1522 redef class AModule
1523         private fun short_comment: String do
1524                 if n_moduledecl != null and n_moduledecl.n_doc != null then
1525                         return n_moduledecl.n_doc.n_comment.first.text.substring_from(2).replace("\n", "").html_escape
1526                 end
1527                 return ""
1528         end
1529
1530         private fun full_comment: String do
1531                 var res = new Buffer
1532                 if n_moduledecl != null and n_moduledecl.n_doc != null then
1533                         for t in n_moduledecl.n_doc.n_comment do
1534                                 res.append(t.text.substring_from(1).html_escape)
1535                         end
1536                 end
1537                 return res.to_s
1538         end
1539 end
1540
1541 redef class AStdClassdef
1542         private fun short_comment: String do
1543                 if n_doc != null then return n_doc.n_comment.first.text.substring_from(2).replace("\n", "").html_escape
1544                 return ""
1545         end
1546
1547         private fun full_comment: String do
1548                 var res = new Buffer
1549                 if n_doc != null then
1550                         for t in n_doc.n_comment do res.append(t.text.substring_from(1).html_escape)
1551                 end
1552                 return res.to_s
1553         end
1554 end
1555
1556 redef class APropdef
1557         private fun short_comment: String do
1558                 if n_doc != null then return n_doc.n_comment.first.text.substring_from(2).replace("\n", "").html_escape
1559                 return ""
1560         end
1561
1562         private fun full_comment: String do
1563                 var res = new Buffer
1564                 if n_doc != null then
1565                         for t in n_doc.n_comment do res.append(t.text.substring_from(1).html_escape)
1566                 end
1567                 return res.to_s
1568         end
1569 end
1570
1571 var nitdoc = new NitdocContext
1572 nitdoc.generate_nitdoc