src/model/mpackage.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Modelisation of a Nit package
  16 module mpackage
  17
  18 import model_base
  19 private import more_collections
  20 import poset
  21 import mdoc
  22
  23 # A Nit package, that encompass a product
  24 class MPackage
  25         super MConcern
  26
  27         # The name of the package
  28         redef var name
  29
  30         redef fun full_name do return name
  31
  32         redef var c_name = name.to_cmangle is lazy
  33
  34         # The model of the package
  35         redef var model
  36
  37         redef var location
  38
  39         # The root of the group tree
  40         var root: nullable MGroup = null is writable
  41
  42         # The group tree, as a POSet
  43         var mgroups = new POSet[MGroup]
  44
  45         redef fun to_s do return name
  46
  47         init
  48         do
  49                 model.mpackages.add(self)
  50                 model.mpackage_by_name.add_one(name, self)
  51         end
  52
  53         # MPackage are always roots of the concerns hierarchy
  54         redef fun parent_concern do return null
  55
  56         redef fun mdoc_or_fallback
  57         do
  58                 var mdoc = self.mdoc
  59                 if mdoc != null then return mdoc
  60                 var root = self.root
  61                 if root != null then return root.mdoc_or_fallback
  62                 return null
  63         end
  64 end
  65
  66 # A group of modules in a package
  67 class MGroup
  68         super MConcern
  69
  70         # The name of the group
  71         # empty name for a default group in a single-module package
  72         redef var name
  73
  74         redef var location
  75
  76         # The enclosing package
  77         var mpackage: MPackage
  78
  79         # The parent group if any
  80         # see `in_nesting` for more
  81         var parent: nullable MGroup
  82
  83         # Fully qualified name.
  84         # It includes each parent group separated by `>`.
  85         # The full_name is terminated by `>` to avoid collision with other entities.
  86         #
  87         # E.g. `core>` and `core>collection>`
  88         redef fun full_name
  89         do
  90                 var p = parent
  91                 if p == null then return "{name}>"
  92                 return "{p.full_name}{name}>"
  93         end
  94
  95         # The group is the group tree on the package (`mpackage.mgroups`)
  96         # nested groups (children) are smaller
  97         # nesting group (see `parent`) is bigger
  98         var in_nesting: POSetElement[MGroup] is noinit
  99
 100         # Is `self` the root of its package?
 101         fun is_root: Bool do return mpackage.root == self
 102
 103         # The filepath (usually a directory) of the group, if any
 104         #
 105         # safe alias to `location.file.filename`
 106         fun filepath: nullable String do
 107                 var res
 108                 res = self.location.file
 109                 if res == null then return null
 110                 return res.filename
 111         end
 112
 113         init
 114         do
 115                 var tree = mpackage.mgroups
 116                 self.in_nesting = tree.add_node(self)
 117                 var parent = self.parent
 118                 if parent != null then
 119                         tree.add_edge(self, parent)
 120                 end
 121         end
 122
 123         redef fun model do return mpackage.model
 124
 125         redef fun parent_concern do
 126                 if not is_root then return parent
 127                 return mpackage
 128         end
 129
 130         redef fun to_s do return name
 131 end
 132
 133 redef class Model
 134         # packages of the model
 135         var mpackages = new Array[MPackage]
 136
 137         # Collections of package grouped by their names
 138         private var mpackage_by_name = new MultiHashMap[String, MPackage]
 139
 140         # Return all package named `name`
 141         # If such a package is not yet loaded, null is returned (instead of an empty array)
 142         fun get_mpackages_by_name(name: String): nullable Array[MPackage]
 143         do
 144                 if mpackage_by_name.has_key(name) then
 145                         return mpackage_by_name[name]
 146                 else
 147                         return null
 148                 end
 149         end
 150 end