src/doc/doc_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Base entities shared by all the nitdoc code.
  16 module doc_base
  17
  18 import toolcontext
  19 import model_utils
  20 import model_ext
  21
  22 # The model of a Nitdoc documentation.
  23 #
  24 # `DocModel` contains the list of the `DocPage` to be generated.
  25 #
  26 # The model is populated through `DocPhase` to be constructed.
  27 # It is a placeholder to share data between each phase.
  28 class DocModel
  29
  30         # `DocPage` composing the documentation.
  31         #
  32         # This is where `DocPhase` store and access pages to produce documentation.
  33         var pages = new Array[DocPage]
  34
  35         # Nit `Model` from which we extract the documentation.
  36         var model: Model is writable
  37
  38         # The entry point of the `model`.
  39         var mainmodule: MModule is writable
  40 end
  41
  42 # A documentation page abstraction.
  43 #
  44 # The page contains a link to the `root` of the `DocComposite` that compose the
  45 # the page.
  46 class DocPage
  47
  48         # Title of this page.
  49         var title: String is writable
  50
  51         # Root element of the page.
  52         #
  53         # `DocPhase` access the structure of the page from the `DocRoot`.
  54         var root = new DocRoot
  55
  56         redef fun to_s do return title
  57 end
  58
  59 # `DocPage` elements that can be nested in another.
  60 #
  61 # `DocComposite` is an abstraction for everything that go in a `DocPage` like
  62 # sections, articles, images, lists, graphs...
  63 #
  64 # It provides base services for nesting mechanisms following the
  65 # *Composite pattern*.
  66 # The composed structure is a tree from a `DocRoot` that can be manipulated
  67 # recursively.
  68 abstract class DocComposite
  69
  70         # Parent element.
  71         var parent: nullable DocComposite = null
  72
  73         # Does `self` have a `parent`?
  74         fun is_root: Bool do return parent == null
  75
  76         # Children elements contained in `self`.
  77         #
  78         # Children are ordered, this order can be changed by the `DocPhase`.
  79         var children = new Array[DocComposite]
  80
  81         # Does `self` have `children`?
  82         fun is_empty: Bool do return children.is_empty
  83
  84         # Add a `child` to `self`.
  85         #
  86         # Shortcut for `children.add`.
  87         fun add_child(child: DocComposite) do
  88                 children.add child
  89         end
  90 end
  91
  92 # The `DocComposite` element that contains all the other.
  93 #
  94 # The root uses a specific subclass to provide different a different behavior
  95 # than other `DocComposite` elements.
  96 class DocRoot
  97         super DocComposite
  98
  99         # No op for `RootSection`.
 100         redef fun parent=(p) do end
 101 end
 102
 103 # Base page elements.
 104
 105 # `DocSection` are used to break the documentation page into meaningfull parts.
 106 #
 107 # The content of the documentation summary is based on the section structure
 108 # contained in the DocComposite tree.
 109 class DocSection
 110         super DocComposite
 111 end
 112
 113 # `DocArticle` are pieces of documentation.
 114 #
 115 # They maintains the content (text, list, image...) of a documentation page.
 116 class DocArticle
 117         super DocComposite
 118 end
 119
 120 # A DocPhase is a step in the production of a Nitdoc documentation.
 121 #
 122 # Phases work from a `DocModel`.
 123 # Specific phases are used to populate, organize, enhance and render the content
 124 # of the documentation pages.
 125 #
 126 # See `doc_phases` for available DocPhase.
 127 class DocPhase
 128
 129         # Link to the ToolContext to access Nitdoc tool options.
 130         var ctx: ToolContext
 131
 132         # `DocModel` used by this phase to work.
 133         var doc: DocModel
 134
 135         # Starting point of a `DocPhase`.
 136         #
 137         # This is where the behavior of the phase is implemented.
 138         # Phases can populate, edit or render the `doc` from here.
 139         fun apply is abstract
 140 end
 141
 142 redef class ToolContext
 143
 144         # Directory where the Nitdoc is rendered.
 145         var opt_dir = new OptionString("output directory", "-d", "--dir")
 146
 147         # Shortcut for `opt_dir.value` with default "doc".
 148         var output_dir: String is lazy do return opt_dir.value or else "doc"
 149
 150         redef init do
 151                 super
 152                 option_context.add_option(opt_dir)
 153         end
 154 end
 155
 156 # Catalog properties by kind.
 157 class PropertiesByKind
 158         # The virtual types.
 159         var virtual_types = new PropertyGroup[MVirtualTypeProp]("Virtual types")
 160
 161         # The constructors.
 162         var constructors = new PropertyGroup[MMethod]("Contructors")
 163
 164         # The attributes.
 165         var attributes = new PropertyGroup[MAttribute]("Attributes")
 166
 167         # The methods.
 168         var methods = new PropertyGroup[MMethod]("Methods")
 169
 170         # The inner classes.
 171         var inner_classes = new PropertyGroup[MInnerClass]("Inner classes")
 172
 173         # All the groups.
 174         #
 175         # Sorted in the order they are displayed to the user.
 176         var groups: SequenceRead[PropertyGroup[MProperty]] = [
 177                         virtual_types,
 178                         constructors,
 179                         attributes,
 180                         methods,
 181                         inner_classes: PropertyGroup[MProperty]]
 182
 183         # Add each the specified property to the appropriate list.
 184         init with_elements(properties: Collection[MProperty]) do add_all(properties)
 185
 186         # Add the specified property to the appropriate list.
 187         fun add(property: MProperty) do
 188                 if property isa MMethod then
 189                         if property.is_init then
 190                                 constructors.add property
 191                         else
 192                                 methods.add property
 193                         end
 194                 else if property isa MVirtualTypeProp then
 195                         virtual_types.add property
 196                 else if property isa MAttribute then
 197                         attributes.add property
 198                 else if property isa MInnerClass then
 199                         inner_classes.add property
 200                 else
 201                         abort
 202                 end
 203         end
 204
 205         # Add each the specified property to the appropriate list.
 206         fun add_all(properties: Collection[MProperty]) do
 207                 for p in properties do add(p)
 208         end
 209
 210         # Sort each group with the specified comparator.
 211         fun sort_groups(comparator: Comparator) do
 212                 for g in groups do comparator.sort(g)
 213         end
 214 end
 215
 216 # An ordered list of properties of the same kind.
 217 class PropertyGroup[E: MProperty]
 218         super Array[E]
 219
 220         # The title of the group, as displayed to the user.
 221         var title: String
 222 end
 223
 224 redef class MEntity
 225         # Name displayed in console for debug and tests.
 226         fun nitdoc_name: String do return name.html_escape
 227 end
 228
 229 redef class MClassDef
 230         redef fun nitdoc_name do return mclass.nitdoc_name
 231 end
 232
 233 redef class MPropDef
 234         redef fun nitdoc_name do return mproperty.nitdoc_name
 235 end