lib/ios/data_store.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Implements `app::data_store` using `NSUserDefaults`
  16 module data_store
  17
  18 import app::data_store
  19 import cocoa::foundation
  20 private import json
  21
  22 redef class DataStore
  23
  24         # The `NSUserDefaults` used to implement `DataStore`
  25         var user_defaults = new NSUserDefaults.standard_user_defaults is lazy
  26
  27         redef fun [](key)
  28         do
  29                 var nsstr = user_defaults.string_for_key(key.to_nsstring)
  30
  31                 if nsstr.address_is_null then return null
  32
  33                 # TODO report errors
  34                 var deserializer = new JsonDeserializer(nsstr.to_s)
  35                 var deserialized = deserializer.deserialize
  36
  37                 var errors = deserializer.errors
  38                 if errors.not_empty then
  39                         # An update may have broken the versioning compatibility
  40                         print_error "{class_name} error at deserialization: {errors.join(", ")}"
  41                         return null # Let's be safe
  42                 end
  43
  44                 return deserialized
  45         end
  46
  47         redef fun []=(key, value)
  48         do
  49                 var nsobject: NSString
  50
  51                 if value == null then
  52                         nsobject = new NSString.nil
  53                 else
  54                         var serialized_string = new StringWriter
  55                         var serializer = new JsonSerializer(serialized_string)
  56                         serializer.serialize(value)
  57
  58                         # TODO report errors
  59                         nsobject = serialized_string.to_s.to_nsstring
  60                 end
  61
  62                 user_defaults.set_object(nsobject, key.to_nsstring)
  63         end
  64 end