src/nitls.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Simple tool to list Nit source files
  18 module nitls
  19
  20 intrude import modelbuilder
  21 import ordered_tree
  22
  23 class ProjTree
  24         super OrderedTree[Object]
  25
  26         var opt_paths = false
  27
  28         redef fun display(o)
  29         do
  30                 if o isa MGroup then
  31                         if opt_paths then
  32                                 return o.filepath.as(not null)
  33                         else
  34                                 return "{o.name} ({o.filepath})"
  35                         end
  36                 else if o isa ModulePath then
  37                         if opt_paths then
  38                                 return o.filepath
  39                         else
  40                                 return "{o.name} ({o.filepath})"
  41                         end
  42                 else
  43                         abort
  44                 end
  45         end
  46 end
  47
  48 var tc = new ToolContext
  49 var model = new Model
  50 var mb = new ModelBuilder(model, tc)
  51
  52 var opt_keep = new OptionBool("Ignore errors and files that are not a Nit source file", "-k", "--keep")
  53 var opt_recursive = new OptionBool("Process directories recussively", "-r", "--recursive")
  54 var opt_tree = new OptionBool("List source files in their groups and projects", "-t", "--tree")
  55 var opt_source = new OptionBool("List source files", "-s", "--source")
  56 var opt_project = new OptionBool("List projects paths (default)", "-P", "--project")
  57 var opt_depends = new OptionBool("List dependencies of given modules", "-d", "--depends")
  58 var opt_make = new OptionBool("List dependencies suitable for a rule in a Makefile. Alias for -d, -p and -s", "-M")
  59 var opt_paths = new OptionBool("List only path (instead of name + path)", "-p", "--path")
  60
  61 tc.option_context.add_option(opt_keep, opt_recursive, opt_tree, opt_source, opt_project, opt_depends, opt_paths, opt_make)
  62 tc.tooldescription = "Usage: nitls [OPTION]... <file.nit|directory>...\nLists the projects and/or paths of Nit sources files."
  63 tc.process_options(args)
  64
  65 if opt_make.value then
  66         opt_depends.value = true
  67         opt_paths.value = true
  68         opt_source.value = true
  69 end
  70
  71 var sum = opt_tree.value.to_i + opt_source.value.to_i + opt_project.value.to_i
  72 if sum > 1 then
  73         print "Error: options --tree, --source, and --project are exclusives."
  74         print tc.tooldescription
  75         exit 1
  76 end
  77
  78 if opt_depends.value then
  79         if opt_recursive.value then
  80                 print "-M incompatible with -r"
  81                 exit 1
  82         end
  83
  84         mb.parse(tc.option_context.rest)
  85 else
  86         var files
  87         if opt_recursive.value then
  88                 files = new Array[String]
  89                 for d in tc.option_context.rest do
  90                         var pipe = new IProcess("find", d, "-name", "*.nit")
  91                         while not pipe.eof do
  92                                 var l = pipe.read_line
  93                                 if l == "" then break # last line
  94                                 l = l.substring(0,l.length-1) # strip last oef
  95                                 files.add l
  96                         end
  97                         pipe.close
  98                         pipe.wait
  99                         if pipe.status != 0 and not opt_keep.value then exit 1
 100                 end
 101         else
 102                 files = tc.option_context.rest
 103         end
 104
 105         for a in files do
 106                 var mp = mb.identify_file(a)
 107                 if mp == null then
 108                         if not opt_keep.value then tc.check_errors
 109                 end
 110         end
 111 end
 112
 113 if sum == 0 then opt_project.value = true
 114
 115 if opt_tree.value then
 116         var ot = new ProjTree
 117         ot.opt_paths = opt_paths.value
 118         for p in model.mprojects do
 119                 for g in p.mgroups do
 120                         ot.add(g.parent, g)
 121                         for mp in g.module_paths do
 122                                 ot.add(g, mp)
 123                         end
 124                 end
 125         end
 126         ot.sort_with(new CachedAlphaComparator)
 127         ot.write_to(stdout)
 128 end
 129
 130 if opt_source.value then
 131         var list = new Array[String]
 132         for p in model.mprojects do
 133                 for g in p.mgroups do
 134                         for mp in g.module_paths do
 135                                 if opt_paths.value then
 136                                         list.add(mp.filepath)
 137                                 else
 138                                         list.add("{g.full_name}/{mp.name} ({mp.filepath})")
 139                                 end
 140                         end
 141                 end
 142         end
 143         alpha_comparator.sort(list)
 144         for l in list do print l
 145 end
 146
 147 if opt_project.value then
 148         var list = new Array[String]
 149         for p in model.mprojects do
 150                 var path = p.root.filepath.as(not null)
 151                 if opt_paths.value then
 152                         list.add(path)
 153                 else
 154                         list.add("{p.name} ({path})")
 155                 end
 156         end
 157         alpha_comparator.sort(list)
 158         for l in list do print l
 159 end