src/common_ffi/common_ffi.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2013 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # FFI concers common between the compilers and the interpreter.
  18 # Offers services to compile modules using foreign code. Mainly allows
  19 # to wrap foreign code in Nit methods.
  20 module common_ffi
  21
  22 import parser
  23 import modelbuilder
  24
  25 import nitni
  26
  27 import ffi_base
  28 import extern_classes
  29 import header_dependency
  30 import pkgconfig
  31 import c_compiler_options
  32 import c
  33 import cpp
  34 import java
  35
  36 redef class MModule
  37         # Does this module uses the FFI?
  38         var uses_ffi: Bool = false
  39
  40         # C compilation unit for the FFI files
  41         private var ffi_ccu: nullable CCompilationUnit = null
  42
  43         # Foreign language used in this AModule
  44         private var present_languages = new HashSet[FFILanguage]
  45
  46         # Complete the compilation of the FFI code
  47         fun finalize_ffi_wrapper(compdir: String, mainmodule: MModule)
  48         do
  49                 for language in present_languages do if ffi_callbacks.keys.has(language) then
  50                         for callback in ffi_callbacks[language] do
  51                                 language.compile_callback(callback, self, mainmodule, ffi_ccu.as(not null))
  52                         end
  53
  54                         language.compile_to_files(self, compdir)
  55                 end
  56
  57                 # include dependancies FFI
  58                 for mod in header_dependencies do
  59                         if mod.uses_ffi then ffi_ccu.header_custom.add("#include \"{mod.name}._ffi.h\"\n")
  60                 end
  61
  62                 ffi_ccu.write_as_impl(self, compdir)
  63                 for filename in ffi_ccu.files do ffi_files.add(new ExternCFile(filename, c_compiler_options))
  64         end
  65 end
  66
  67 redef class AModule
  68
  69         # Ensures all of the general foreign code of the module has been analyzed.
  70         # Manages header blocks, extern class types and foreign dependancies between modules
  71         fun ensure_compile_ffi_wrapper
  72         do
  73                 var mmodule = mmodule
  74                 if mmodule == null or mmodule.ffi_ccu != null then return
  75
  76                 # ready extern code compiler
  77                 var ffi_ccu = new CCompilationUnit
  78                 mmodule.ffi_ccu = ffi_ccu
  79
  80                 # generate code
  81                 for block in n_extern_code_blocks do
  82                         var language = block.language
  83                         assert language != null
  84                         mmodule.present_languages.add(language)
  85                         language.compile_module_block(block, ffi_ccu, mmodule)
  86                 end
  87
  88                 ffi_ccu.header_c_base.add( "#include \"{mmodule.name}._nitni.h\"\n" )
  89
  90                 for nclassdef in n_classdefs do
  91                         # Does it declares an extern type?
  92                         if nclassdef isa AStdClassdef and nclassdef.n_extern_code_block != null then
  93                                 mmodule.uses_ffi = true
  94                                 var language = nclassdef.n_extern_code_block.language
  95                                 assert language != null
  96                                 mmodule.present_languages.add(language)
  97                                 nclassdef.n_extern_code_block.language.compile_extern_class(
  98                                         nclassdef.n_extern_code_block.as(not null), nclassdef, ffi_ccu, mmodule)
  99                         end
 100                 end
 101         end
 102 end
 103
 104 redef class AExternPropdef
 105         private var ffi_has_been_compiled = false
 106
 107         # Compile the necessary wrapper around this extern method or constructor
 108         fun compile_ffi_method(mmodule: MModule)
 109         do
 110                 assert n_extern_code_block != null
 111
 112                 if ffi_has_been_compiled then return
 113                 ffi_has_been_compiled = true
 114
 115                 var language = n_extern_code_block.language
 116                 assert language != null
 117                 mmodule.present_languages.add(language)
 118                 n_extern_code_block.language.compile_extern_method(
 119                         n_extern_code_block.as(not null), self, mmodule.ffi_ccu.as(not null), mmodule)
 120         end
 121 end
 122
 123 redef class VerifyNitniCallbacksPhase
 124         redef fun process_npropdef(npropdef)
 125         do
 126                 super
 127
 128                 if not npropdef isa AExternPropdef then return
 129
 130                 var code_block = npropdef.n_extern_code_block
 131                 if code_block == null then return
 132
 133                 var lang = code_block.language
 134                 assert lang != null
 135
 136                 # Associate callbacks used by an extern method to its foreign language
 137                 for callback in npropdef.foreign_callbacks.all do
 138                         var map = npropdef.mpropdef.mclassdef.mmodule.ffi_callbacks
 139                         if not map.keys.has(lang) then map[lang] = new HashSet[NitniCallback]
 140                         map[lang].add(callback)
 141                 end
 142         end
 143 end