src/compiling/compiling_methods.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2008 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Compile method bodies, statments and expressions to C.
  18 package compiling_methods
  19
  20 import compiling_base
  21 private import syntax
  22
  23 redef class CompilerVisitor
  24         # Compile a statment node
  25         meth compile_stmt(n: PExpr)
  26         do
  27                 n.prepare_compile_stmt(self)
  28                 var i = cfc._variable_index
  29                 n.compile_stmt(self)
  30                 cfc._variable_index = i
  31         end
  32
  33         # Compile is expression node
  34         meth compile_expr(n: PExpr): String
  35         do
  36                 var i = cfc._variable_index
  37                 var s = n.compile_expr(self)
  38                 cfc._variable_index = i
  39                 if s[0] == ' ' then
  40                         return s
  41                 end
  42                 var v = cfc.get_var
  43                 add_assignment(v, s)
  44                 return v
  45         end
  46
  47         # Ensure that a c expression is a var
  48         meth ensure_var(s: String): String
  49         do
  50                 if s.substring(0,3) == "variable" then
  51                         return s
  52                 end
  53                 var v = cfc.get_var
  54                 add_assignment(v, s)
  55                 return v
  56         end
  57
  58         # Add a assignment between a variable and an expression
  59         meth add_assignment(v: String, s: String)
  60         do
  61                 if v != s then
  62                         add_instr("{v} = {s};")
  63                 end
  64         end
  65
  66         readable writable attr _cfc: CFunctionContext
  67
  68         readable writable attr _nmc: NitMethodContext
  69
  70         # C outputs written outside the current C function.
  71         readable writable attr _out_contexts: Array[CContext] = new Array[CContext]
  72
  73         # Generate an fprintf to display an error location
  74         meth printf_locate_error(node: PNode): String
  75         do
  76                 var s = new Buffer.from("fprintf(stderr, \"")
  77                 if nmc != null then s.append(" in %s")
  78                 s.append(" (%s:%d)\\n\", ")
  79                 if nmc != null then s.append("LOCATE_{nmc.method.cname}, ")
  80                 s.append("LOCATE_{module.name}, {node.line_number});")
  81                 return s.to_s
  82         end
  83
  84         redef init(module: MMSrcModule)
  85         do
  86                 super
  87         end
  88
  89         meth invoke_super_init_calls_after(start_prop: MMMethod)
  90         do
  91                 var n = nmc.method.node
  92                 assert n isa AConcreteInitPropdef
  93
  94                 if n.super_init_calls.is_empty then return
  95                 var i = 0
  96                 var j = 0
  97                 #var s = ""
  98                 if start_prop != null then
  99                         while n.super_init_calls[i] != start_prop do
 100                                 #s.append(" {n.super_init_calls[i]}")
 101                                 i += 1
 102                         end
 103                         i += 1
 104                         #s.append(" {start_prop}")
 105
 106                         while n.explicit_super_init_calls[j] != start_prop do
 107                                 j += 1
 108                         end
 109                         j += 1
 110                 end
 111                 var stop_prop: MMMethod = null
 112                 if j < n.explicit_super_init_calls.length then
 113                         stop_prop = n.explicit_super_init_calls[j]
 114                 end
 115                 var l = n.super_init_calls.length
 116                 #s.append(" [")
 117                 while i < l do
 118                         var p = n.super_init_calls[i]
 119                         if p == stop_prop then break
 120                         var cargs = new Array[String]
 121                         if p.signature.arity == 0 then
 122                                 cargs.add(cfc.varname(nmc.method_params[0]))
 123                         else
 124                                 for va in nmc.method_params do
 125                                         cargs.add(cfc.varname(va))
 126                                 end
 127                         end
 128                         #s.append(" {p}")
 129                         p.compile_call(self, cargs)
 130                         i += 1
 131                 end
 132                 #s.append(" ]")
 133                 #while i < l do
 134                 #       s.append(" {n.super_init_calls[i]}")
 135                 #       i += 1
 136                 #end
 137                 #if stop_prop != null then s.append(" (stop at {stop_prop})")
 138                 #n.printl("implicit calls in {n.method}: {s}")
 139         end
 140 end
 141
 142 # A C function currently written
 143 class CFunctionContext
 144         readable attr _visitor: CompilerVisitor
 145
 146         # Next available variable number
 147         attr _variable_index: Int = 0
 148
 149         # Total number of variable
 150         attr _variable_index_max: Int = 0
 151
 152         # Association between nit variable and the corrsponding c variable
 153         attr _varnames: Map[Variable, String] = new HashMap[Variable, String]
 154
 155         # Are we currenlty in a closure definition?
 156         readable writable attr _in_closure: Bool = false
 157
 158         meth varname(v: Variable): String
 159         do
 160                 if _in_closure then
 161                         return "closctx->{_varnames[v]}"
 162                 else
 163                         return _varnames[v]
 164                 end
 165         end
 166
 167         # Return the next available variable
 168         meth get_var: String
 169         do
 170                 var v = variable(_variable_index)
 171                 _variable_index = _variable_index + 1
 172                 if _variable_index > _variable_index_max then
 173                         #visitor.add_decl("val_t {v};")
 174                         _variable_index_max = _variable_index
 175                 end
 176                 return v
 177         end
 178
 179         meth register_variable(v: Variable): String
 180         do
 181                 var s = get_var
 182                 _varnames[v] = "variable[{_variable_index-1}]"
 183                 return s
 184         end
 185
 186         # Next available closure variable number
 187         attr _closurevariable_index: Int = 0
 188
 189         meth register_closurevariable(v: ClosureVariable): String
 190         do
 191                 var s = "closurevariable[{_closurevariable_index}]"
 192                 _closurevariable_index += 1
 193                 _varnames[v] = s
 194                 if _in_closure then
 195                         return "(closctx->{s})"
 196                 else
 197                         return s
 198                 end
 199         end
 200
 201         # Return the ith variable
 202         protected meth variable(i: Int): String
 203         do
 204                 if _in_closure then
 205                         return "(closctx->variable[{i}])"
 206                 else
 207                         return "variable[{i}]"
 208                 end
 209         end
 210
 211         # Mark the variable available
 212         meth free_var(v: String)
 213         do
 214                 # FIXME: So ugly..
 215                 if v == variable(_variable_index-1) then
 216                         _variable_index = _variable_index - 1
 217                 end
 218         end
 219
 220         # Generate the local variable declarations
 221         # To use at the end of the C function once all variables are known
 222         meth generate_var_decls
 223         do
 224                 if _variable_index_max > 0 then
 225                         visitor.add_decl("val_t variable[{_variable_index_max}];")
 226                 else
 227                         visitor.add_decl("val_t *variable = NULL;")
 228                 end
 229                 if _closurevariable_index > 0 then
 230                         visitor.add_decl("void *closurevariable[{_closurevariable_index}];")
 231                 else
 232                         visitor.add_decl("void **closurevariable = NULL;")
 233                 end
 234         end
 235
 236         init(v: CompilerVisitor) do _visitor = v
 237 end
 238
 239 # A Nit method currenlty compiled
 240 class NitMethodContext
 241         # Current method compiled
 242         readable attr _method: MMSrcMethod
 243
 244         # Association between parameters and the corresponding variables
 245         readable writable attr _method_params: Array[ParamVariable]
 246
 247         # Where a nit return must branch
 248         readable writable attr _return_label: String
 249
 250         # Where a nit break must branch
 251         readable writable attr _break_label: String
 252
 253         # Where a nit continue must branch
 254         readable writable attr _continue_label: String
 255
 256         # Variable where a functionnal nit return must store its value
 257         readable writable attr _return_value: String
 258
 259         # Variable where a functionnal nit break must store its value
 260         readable writable attr _break_value: String
 261
 262         # Variable where a functionnal nit continue must store its value
 263         readable writable attr _continue_value: String
 264
 265         init(method: MMSrcMethod)
 266         do
 267                 _method = method
 268         end
 269 end
 270
 271 ###############################################################################
 272
 273 redef class ClosureVariable
 274         readable writable attr _ctypename: String
 275 end
 276
 277 redef class MMMethod
 278         # Compile a call on self for given arguments
 279         # Most calls are compiled with a table access,
 280         # primitive calles are inlined
 281         # == and != are guarded and possibly inlined
 282         meth compile_call(v: CompilerVisitor, cargs: Array[String]): String
 283         do
 284                 var i = self
 285                 if i isa MMSrcMethod then
 286                         if i isa MMMethSrcMethod and i.node isa AInternMethPropdef or
 287                                 (i.local_class.name == (once "Array".to_symbol) and name == (once "[]".to_symbol))
 288                         then
 289                                 var e = i.do_compile_inside(v, cargs)
 290                                 return e
 291                         end
 292                 end
 293                 var ee = once "==".to_symbol
 294                 var ne = once "!=".to_symbol
 295                 if name == ne then
 296                         var eqp = signature.recv.local_class.select_method(ee)
 297                         var eqcall = eqp.compile_call(v, cargs)
 298                         return "TAG_Bool(!UNTAG_Bool({eqcall}))"
 299                 end
 300                 if global.is_init then
 301                         cargs = cargs.to_a
 302                         cargs.add("init_table /*YYY*/")
 303                 end
 304
 305                 var m = "{global.meth_call}({cargs[0]})"
 306                 var vcall = "{m}({cargs.join(", ")}) /*{local_class}::{name}*/"
 307                 if name == ee then
 308                         vcall = "UNTAG_Bool({vcall})"
 309                         var obj = once "Object".to_symbol
 310                         if i.local_class.name == obj then
 311                                 vcall = "(({m}=={i.cname})?(IS_EQUAL_NN({cargs[0]},{cargs[1]})):({vcall}))"
 312                         end
 313                         vcall = "TAG_Bool(({cargs.first} == {cargs[1]}) || (({cargs.first} != NIT_NULL) && {vcall}))"
 314                 end
 315                 if signature.return_type != null then
 316                         return vcall
 317                 else
 318                         v.add_instr(vcall + ";")
 319                         return null
 320                 end
 321         end
 322
 323         # Compile a call on self for given arguments and given closures
 324         meth compile_call_and_closures(v: CompilerVisitor, cargs: Array[String], clos_defs: Array[PClosureDef]): String
 325         do
 326                 var ve: String = null
 327                 var arity = 0
 328                 if clos_defs != null then arity = clos_defs.length
 329
 330                 # Prepare result value.
 331                 # In case of procedure, the return value is still used to intercept breaks
 332                 var old_bv = v.nmc.break_value
 333                 ve = v.cfc.get_var
 334                 v.nmc.break_value = ve
 335
 336                 # Compile closure to c function
 337                 var realcargs = new Array[String] # Args to pass to the C function call
 338                 var closcns = new Array[String] # Closure C structure names
 339                 realcargs.add_all(cargs)
 340                 for i in [0..arity[ do
 341                         var cn = clos_defs[i].compile_closure(v, closure_cname(i))
 342                         closcns.add(cn)
 343                         realcargs.add(cn)
 344                 end
 345                 for i in [arity..signature.closures.length[ do
 346                         realcargs.add("NULL")
 347                 end
 348
 349                 v.nmc.break_value = old_bv
 350
 351                 # Call
 352                 var e = compile_call(v, realcargs)
 353                 if e != null then
 354                         v.add_assignment(ve, e)
 355                         e = ve
 356                 end
 357
 358                 # Intercept returns and breaks
 359                 for i in [0..arity[ do
 360                         # A break or a return is intercepted
 361                         v.add_instr("if ({closcns[i]}->has_broke != NULL) \{")
 362                         v.indent
 363                         # A passtrought break or a return is intercepted: go the the next closure
 364                         v.add_instr("if ({closcns[i]}->has_broke != &({ve})) \{")
 365                         v.indent
 366                         if v.cfc.in_closure then v.add_instr("closctx->has_broke = {closcns[i]}->has_broke; closctx->broke_value = {closcns[i]}->broke_value;")
 367                         v.add_instr("goto {v.nmc.return_label};")
 368                         v.unindent
 369                         # A direct break is interpected
 370                         if e != null then
 371                                 # overwrite the returned value in a function
 372                                 v.add_instr("\} else {ve} = {closcns[i]}->broke_value;")
 373                         else
 374                                 # Do nothing in a procedure
 375                                 v.add_instr("\}")
 376                         end
 377                         v.unindent
 378                         v.add_instr("\}")
 379                 end
 380                 return e
 381         end
 382
 383         # Compile a call as constructor with given args
 384         meth compile_constructor_call(v: CompilerVisitor, recvtype: MMType, cargs: Array[String]): String
 385         do
 386                 var recv = v.cfc.get_var
 387                 v.add_instr("{recv} = NEW_{recvtype.local_class}_{global.intro.cname}({cargs.join(", ")}); /*new {recvtype}*/")
 388                 return recv
 389         end
 390
 391         # Compile a call as call-next-method on self with given args
 392         meth compile_super_call(v: CompilerVisitor, cargs: Array[String]): String
 393         do
 394                 var m = "{super_meth_call}({cargs[0]})"
 395                 var vcall = "{m}({cargs.join(", ")}) /*super {local_class}::{name}*/"
 396                 return vcall
 397         end
 398
 399         # Cname of the i-th closure C struct type
 400         protected meth closure_cname(i: Int): String
 401         do
 402                 return "WBT_{cname}_{i}"
 403         end
 404 end
 405
 406 redef class MMAttribute
 407         # Compile an acces on selffor a given reciever.
 408         # Result is a valid C left-value for assigment
 409         meth compile_access(v: CompilerVisitor, recv: String): String
 410         do
 411                 return "{global.attr_access}({recv}) /*{local_class}::{name}*/"
 412         end
 413 end
 414
 415 redef class MMLocalProperty
 416         # Compile the property as a C property
 417         meth compile_property_to_c(v: CompilerVisitor) do end
 418 end
 419
 420 redef class MMSrcMethod
 421
 422         # Compile and declare the signature to C
 423         protected meth decl_csignature(v: CompilerVisitor, args: Array[String]): String
 424         do
 425                 var params = new Array[String]
 426                 params.add("val_t {args[0]}")
 427                 for i in [0..signature.arity[ do
 428                         var p = "val_t {args[i+1]}"
 429                         params.add(p)
 430                 end
 431
 432                 var first_closure_index = signature.arity + 1 # Wich parameter is the first closure
 433                 for i in [0..signature.closures.length[ do
 434                         var closcn = closure_cname(i)
 435                         var cs = signature.closures[i].signature # Closure signature
 436                         var subparams = new Array[String] # Parameters of the closure
 437                         subparams.add("struct {closcn}*")
 438                         for j in [0..cs.arity[ do
 439                                 var p = "val_t"
 440                                 subparams.add(p)
 441                         end
 442                         var r = "void"
 443                         if cs.return_type != null then r = "val_t"
 444                         params.add("struct {closcn} *{args[first_closure_index+i]}")
 445                         v.add_decl("struct {closcn};")
 446                         v.add_decl("typedef {r} (*F{closcn})({subparams.join(", ")});")
 447                         v.add_decl("struct {closcn} \{F{closcn} fun; val_t *has_broke; val_t broke_value; val_t *variable; void **closurevariable;\};")
 448                 end
 449
 450                 if global.is_init then
 451                         params.add("int* init_table")
 452                 end
 453
 454                 var ret: String
 455                 if signature.return_type != null then
 456                         ret = "val_t"
 457                 else
 458                         ret = "void"
 459                 end
 460
 461                 var p = params.join(", ")
 462                 var s = "{ret} {cname}({p})"
 463                 v.add_decl("typedef {ret} (* {cname}_t)({p});")
 464                 v.add_decl(s + ";")
 465                 return s
 466         end
 467
 468         redef meth compile_property_to_c(v)
 469         do
 470                 v.cfc = new CFunctionContext(v)
 471
 472                 var args = new Array[String]
 473                 args.add(" self")
 474                 for i in [0..signature.arity[ do
 475                         args.add(" param{i}")
 476                 end
 477                 for i in [0..signature.closures.length[ do
 478                         args.add(" wd{i}")
 479                 end
 480                 var cs = decl_csignature(v, args)
 481                 v.add_decl("#define LOCATE_{cname} \"{full_name}\"")
 482
 483                 v.add_instr("{cs} \{")
 484                 v.indent
 485                 var ctx_old = v.ctx
 486                 v.ctx = new CContext
 487
 488                 v.out_contexts.clear
 489
 490                 var ln = 0
 491                 var s = self
 492                 if s.node != null then ln = s.node.line_number
 493                 v.add_decl("struct trace_t trace = \{NULL, NULL, {ln}, LOCATE_{cname}};")
 494                 v.add_instr("trace.prev = tracehead; tracehead = &trace;")
 495                 v.add_instr("trace.file = LOCATE_{module.name};")
 496                 var s = do_compile_inside(v, args)
 497                 v.add_instr("tracehead = trace.prev;")
 498                 if s == null then
 499                         v.add_instr("return;")
 500                 else
 501                         v.add_instr("return {s};")
 502                 end
 503
 504                 v.cfc.generate_var_decls
 505
 506                 ctx_old.append(v.ctx)
 507                 v.ctx = ctx_old
 508                 v.unindent
 509                 v.add_instr("}")
 510
 511                 for ctx in v.out_contexts do v.ctx.merge(ctx)
 512         end
 513
 514         # Compile the method body inline
 515         meth do_compile_inside(v: CompilerVisitor, params: Array[String]): String is abstract
 516 end
 517
 518 redef class MMReadImplementationMethod
 519         redef meth do_compile_inside(v, params)
 520         do
 521                 return node.prop.compile_access(v, params[0])
 522         end
 523 end
 524
 525 redef class MMWriteImplementationMethod
 526         redef meth do_compile_inside(v, params)
 527         do
 528                 v.add_assignment(node.prop.compile_access(v, params[0]), params[1])
 529                 return null
 530         end
 531 end
 532
 533 redef class MMMethSrcMethod
 534         redef meth do_compile_inside(v, params)
 535         do
 536                 return node.do_compile_inside(v, self, params)
 537         end
 538 end
 539
 540 redef class MMImplicitInit
 541         redef meth do_compile_inside(v, params)
 542         do
 543                 var f = params.length - unassigned_attributes.length
 544                 var recv = params.first
 545                 for sp in super_inits do
 546                         assert sp isa MMMethod
 547                         var args_recv = [recv]
 548                         if sp == super_init then
 549                                 var args = new Array[String].with_capacity(f)
 550                                 args.add(recv)
 551                                 for i in [1..f[ do
 552                                         args.add(params[i])
 553                                 end
 554                                 sp.compile_call(v, args)
 555                         else
 556                                 sp.compile_call(v, args_recv)
 557                         end
 558                 end
 559                 for i in [f..params.length[ do
 560                         var attribute = unassigned_attributes[i-f]
 561                         v.add_assignment(attribute.compile_access(v, recv), params[i])
 562                 end
 563                 return null
 564         end
 565 end
 566
 567 redef class MMType
 568         # Compile a subtype check to self
 569         # Return a NIT Bool
 570         meth compile_cast(v: CompilerVisitor, recv: String): String
 571         do
 572                 # Fixme: handle formaltypes
 573                 var g = local_class.global
 574                 return "TAG_Bool(({recv}==NIT_NULL) || VAL_ISA({recv}, {g.color_id}, {g.id_id})) /*cast {self}*/"
 575         end
 576
 577         # Compile a cast assertion
 578         meth compile_type_check(v: CompilerVisitor, recv: String, n: PNode)
 579         do
 580                 # Fixme: handle formaltypes
 581                 var g = local_class.global
 582                 v.add_instr("if (({recv}!=NIT_NULL) && !VAL_ISA({recv}, {g.color_id}, {g.id_id})) \{ fprintf(stderr, \"Cast failled\"); {v.printf_locate_error(n)} nit_exit(1); } /*cast {self}*/;")
 583         end
 584 end
 585
 586 ###############################################################################
 587
 588 redef class AMethPropdef
 589         # Compile the method body
 590         meth do_compile_inside(v: CompilerVisitor, method: MMSrcMethod, params: Array[String]): String is abstract
 591 end
 592
 593 redef class PSignature
 594         meth compile_parameters(v: CompilerVisitor, orig_sig: MMSignature, params: Array[String]) is abstract
 595 end
 596
 597 redef class ASignature
 598         redef meth compile_parameters(v: CompilerVisitor, orig_sig: MMSignature, params: Array[String])
 599         do
 600                 for ap in n_params do
 601                         var cname = v.cfc.register_variable(ap.variable)
 602                         v.nmc.method_params.add(ap.variable)
 603                         var orig_type = orig_sig[ap.position]
 604                         if not orig_type < ap.variable.stype then
 605                                 # FIXME: do not test always
 606                                 # FIXME: handle formal types
 607                                 v.add_instr("/* check if p<{ap.variable.stype} with p:{orig_type} */")
 608                                 ap.variable.stype.compile_type_check(v, params[ap.position], ap)
 609                         end
 610                         v.add_assignment(cname, params[ap.position])
 611                 end
 612                 for i in [0..n_closure_decls.length[ do
 613                         var wd = n_closure_decls[i]
 614                         var cname = v.cfc.register_closurevariable(wd.variable)
 615                         wd.variable.ctypename = "struct {v.nmc.method.closure_cname(i)} *"
 616                         v.add_assignment(cname, "{params[orig_sig.arity + i]}")
 617                 end
 618         end
 619 end
 620
 621 redef class AConcreteMethPropdef
 622         redef meth do_compile_inside(v, method, params)
 623         do
 624                 var old_nmc = v.nmc
 625                 v.nmc = new NitMethodContext(method)
 626
 627                 var selfcname = v.cfc.register_variable(self_var)
 628                 v.add_assignment(selfcname, params[0])
 629                 params.shift
 630                 v.nmc.method_params = [self_var]
 631
 632                 if n_signature != null then
 633                         var orig_meth: MMLocalProperty = method.global.intro
 634                         var orig_sig = orig_meth.signature_for(method.signature.recv)
 635                         n_signature.compile_parameters(v, orig_sig, params)
 636                 end
 637
 638                 var itpos: String = null
 639                 if self isa AConcreteInitPropdef then
 640                         itpos = "VAL2OBJ({selfcname})->vft[{method.local_class.global.init_table_pos_id}].i"
 641                         # v.add_instr("printf(\"{method.full_name}: inittable[%d] = %d\\n\", {itpos}, init_table[{itpos}]);")
 642                         v.add_instr("if (init_table[{itpos}]) return;")
 643                 end
 644
 645                 v.nmc.return_label = "return_label{v.new_number}"
 646                 v.nmc.return_value = v.cfc.get_var
 647                 if self isa AConcreteInitPropdef then
 648                         v.invoke_super_init_calls_after(null)
 649                 end
 650                 if n_block != null then
 651                         v.compile_stmt(n_block)
 652                 end
 653                 v.add_instr("{v.nmc.return_label}: while(false);")
 654                 if self isa AConcreteInitPropdef then
 655                         v.add_instr("init_table[{itpos}] = 1;")
 656                 end
 657
 658                 var ret: String = null
 659                 if method.signature.return_type != null then
 660                         ret = v.nmc.return_value
 661                 end
 662
 663                 v.nmc = old_nmc
 664                 return ret
 665         end
 666 end
 667
 668 redef class ADeferredMethPropdef
 669         redef meth do_compile_inside(v, method, params)
 670         do
 671                 v.add_instr("fprintf(stderr, \"Deferred method called\");")
 672                 v.add_instr(v.printf_locate_error(self))
 673                 v.add_instr("nit_exit(1);")
 674                 if method.signature.return_type != null then
 675                         return("NIT_NULL")
 676                 else
 677                         return null
 678                 end
 679         end
 680 end
 681
 682 redef class AExternMethPropdef
 683         redef meth do_compile_inside(v, method, params)
 684         do
 685                 var ename = "{method.module.name}_{method.local_class.name}_{method.local_class.name}_{method.name}_{method.signature.arity}"
 686                 if n_extern != null then
 687                         ename = n_extern.text
 688                         ename = ename.substring(1, ename.length-2)
 689                 end
 690                 var sig = method.signature
 691                 if params.length != sig.arity + 1 then
 692                         printl("par:{params.length} sig:{sig.arity}")
 693                 end
 694                 var args = new Array[String]
 695                 args.add(sig.recv.unboxtype(params[0]))
 696                 for i in [0..sig.arity[ do
 697                         args.add(sig[i].unboxtype(params[i+1]))
 698                 end
 699                 var s = "{ename}({args.join(", ")})"
 700                 if sig.return_type != null then
 701                         return sig.return_type.boxtype(s)
 702                 else
 703                         v.add_instr("{s};")
 704                         return null
 705                 end
 706         end
 707 end
 708
 709 redef class AInternMethPropdef
 710         redef meth do_compile_inside(v, method, p)
 711         do
 712                 var c = method.local_class.name
 713                 var n = method.name
 714                 var s: String = null
 715                 if c == once "Int".to_symbol then
 716                         if n == once "object_id".to_symbol then
 717                                 s = "{p[0]}"
 718                         else if n == once "unary -".to_symbol then
 719                                 s = "TAG_Int(-UNTAG_Int({p[0]}))"
 720                         else if n == once "output".to_symbol then
 721                                 v.add_instr("printf(\"%ld\\n\", UNTAG_Int({p[0]}));")
 722                         else if n == once "ascii".to_symbol then
 723                                 s = "TAG_Char(UNTAG_Int({p[0]}))"
 724                         else if n == once "succ".to_symbol then
 725                                 s = "TAG_Int(UNTAG_Int({p[0]})+1)"
 726                         else if n == once "prec".to_symbol then
 727                                 s = "TAG_Int(UNTAG_Int({p[0]})-1)"
 728                         else if n == once "to_f".to_symbol then
 729                                 s = "BOX_Float((float)UNTAG_Int({p[0]}))"
 730                         else if n == once "+".to_symbol then
 731                                 s = "TAG_Int(UNTAG_Int({p[0]})+UNTAG_Int({p[1]}))"
 732                         else if n == once "-".to_symbol then
 733                                 s = "TAG_Int(UNTAG_Int({p[0]})-UNTAG_Int({p[1]}))"
 734                         else if n == once "*".to_symbol then
 735                                 s = "TAG_Int(UNTAG_Int({p[0]})*UNTAG_Int({p[1]}))"
 736                         else if n == once "/".to_symbol then
 737                                 s = "TAG_Int(UNTAG_Int({p[0]})/UNTAG_Int({p[1]}))"
 738                         else if n == once "%".to_symbol then
 739                                 s = "TAG_Int(UNTAG_Int({p[0]})%UNTAG_Int({p[1]}))"
 740                         else if n == once "<".to_symbol then
 741                                 s = "TAG_Bool(UNTAG_Int({p[0]})<UNTAG_Int({p[1]}))"
 742                         else if n == once ">".to_symbol then
 743                                 s = "TAG_Bool(UNTAG_Int({p[0]})>UNTAG_Int({p[1]}))"
 744                         else if n == once "<=".to_symbol then
 745                                 s = "TAG_Bool(UNTAG_Int({p[0]})<=UNTAG_Int({p[1]}))"
 746                         else if n == once ">=".to_symbol then
 747                                 s = "TAG_Bool(UNTAG_Int({p[0]})>=UNTAG_Int({p[1]}))"
 748                         else if n == once "lshift".to_symbol then
 749                                 s = "TAG_Int(UNTAG_Int({p[0]})<<UNTAG_Int({p[1]}))"
 750                         else if n == once "rshift".to_symbol then
 751                                 s = "TAG_Int(UNTAG_Int({p[0]})>>UNTAG_Int({p[1]}))"
 752                         else if n == once "==".to_symbol then
 753                                 s = "TAG_Bool(({p[0]})==({p[1]}))"
 754                         else if n == once "!=".to_symbol then
 755                                 s = "TAG_Bool(({p[0]})!=({p[1]}))"
 756                         end
 757                 else if c == once "Float".to_symbol then
 758                         if n == once "object_id".to_symbol then
 759                                 s = "TAG_Int((bigint)UNBOX_Float({p[0]}))"
 760                         else if n == once "unary -".to_symbol then
 761                                 s = "BOX_Float(-UNBOX_Float({p[0]}))"
 762                         else if n == once "output".to_symbol then
 763                                 v.add_instr("printf(\"%f\\n\", UNBOX_Float({p[0]}));")
 764                         else if n == once "to_i".to_symbol then
 765                                 s = "TAG_Int((bigint)UNBOX_Float({p[0]}))"
 766                         else if n == once "+".to_symbol then
 767                                 s = "BOX_Float(UNBOX_Float({p[0]})+UNBOX_Float({p[1]}))"
 768                         else if n == once "-".to_symbol then
 769                                 s = "BOX_Float(UNBOX_Float({p[0]})-UNBOX_Float({p[1]}))"
 770                         else if n == once "*".to_symbol then
 771                                 s = "BOX_Float(UNBOX_Float({p[0]})*UNBOX_Float({p[1]}))"
 772                         else if n == once "/".to_symbol then
 773                                 s = "BOX_Float(UNBOX_Float({p[0]})/UNBOX_Float({p[1]}))"
 774                         else if n == once "<".to_symbol then
 775                                 s = "TAG_Bool(UNBOX_Float({p[0]})<UNBOX_Float({p[1]}))"
 776                         else if n == once ">".to_symbol then
 777                                 s = "TAG_Bool(UNBOX_Float({p[0]})>UNBOX_Float({p[1]}))"
 778                         else if n == once "<=".to_symbol then
 779                                 s = "TAG_Bool(UNBOX_Float({p[0]})<=UNBOX_Float({p[1]}))"
 780                         else if n == once ">=".to_symbol then
 781                                 s = "TAG_Bool(UNBOX_Float({p[0]})>=UNBOX_Float({p[1]}))"
 782                         end
 783                 else if c == once "Char".to_symbol then
 784                         if n == once "object_id".to_symbol then
 785                                 s = "TAG_Int(UNTAG_Char({p[0]}))"
 786                         else if n == once "unary -".to_symbol then
 787                                 s = "TAG_Char(-UNTAG_Char({p[0]}))"
 788                         else if n == once "output".to_symbol then
 789                                 v.add_instr("printf(\"%c\", (unsigned char)UNTAG_Char({p[0]}));")
 790                         else if n == once "ascii".to_symbol then
 791                                 s = "TAG_Int((unsigned char)UNTAG_Char({p[0]}))"
 792                         else if n == once "succ".to_symbol then
 793                                 s = "TAG_Char(UNTAG_Char({p[0]})+1)"
 794                         else if n == once "prec".to_symbol then
 795                                 s = "TAG_Char(UNTAG_Char({p[0]})-1)"
 796                         else if n == once "to_i".to_symbol then
 797                                 s = "TAG_Int(UNTAG_Char({p[0]})-'0')"
 798                         else if n == once "+".to_symbol then
 799                                 s = "TAG_Char(UNTAG_Char({p[0]})+UNTAG_Char({p[1]}))"
 800                         else if n == once "-".to_symbol then
 801                                 s = "TAG_Char(UNTAG_Char({p[0]})-UNTAG_Char({p[1]}))"
 802                         else if n == once "*".to_symbol then
 803                                 s = "TAG_Char(UNTAG_Char({p[0]})*UNTAG_Char({p[1]}))"
 804                         else if n == once "/".to_symbol then
 805                                 s = "TAG_Char(UNTAG_Char({p[0]})/UNTAG_Char({p[1]}))"
 806                         else if n == once "%".to_symbol then
 807                                 s = "TAG_Char(UNTAG_Char({p[0]})%UNTAG_Char({p[1]}))"
 808                         else if n == once "<".to_symbol then
 809                                 s = "TAG_Bool(UNTAG_Char({p[0]})<UNTAG_Char({p[1]}))"
 810                         else if n == once ">".to_symbol then
 811                                 s = "TAG_Bool(UNTAG_Char({p[0]})>UNTAG_Char({p[1]}))"
 812                         else if n == once "<=".to_symbol then
 813                                 s = "TAG_Bool(UNTAG_Char({p[0]})<=UNTAG_Char({p[1]}))"
 814                         else if n == once ">=".to_symbol then
 815                                 s = "TAG_Bool(UNTAG_Char({p[0]})>=UNTAG_Char({p[1]}))"
 816                         else if n == once "==".to_symbol then
 817                                 s = "TAG_Bool(({p[0]})==({p[1]}))"
 818                         else if n == once "!=".to_symbol then
 819                                 s = "TAG_Bool(({p[0]})!=({p[1]}))"
 820                         end
 821                 else if c == once "Bool".to_symbol then
 822                         if n == once "object_id".to_symbol then
 823                                 s = "TAG_Int(UNTAG_Bool({p[0]}))"
 824                         else if n == once "unary -".to_symbol then
 825                                 s = "TAG_Bool(-UNTAG_Bool({p[0]}))"
 826                         else if n == once "output".to_symbol then
 827                                 v.add_instr("(void)printf(UNTAG_Bool({p[0]})?\"true\\n\":\"false\\n\");")
 828                         else if n == once "ascii".to_symbol then
 829                                 s = "TAG_Bool(UNTAG_Bool({p[0]}))"
 830                         else if n == once "to_i".to_symbol then
 831                                 s = "TAG_Int(UNTAG_Bool({p[0]}))"
 832                         else if n == once "==".to_symbol then
 833                                 s = "TAG_Bool(({p[0]})==({p[1]}))"
 834                         else if n == once "!=".to_symbol then
 835                                 s = "TAG_Bool(({p[0]})!=({p[1]}))"
 836                         end
 837                 else if c == once "NativeArray".to_symbol then
 838                         if n == once "object_id".to_symbol then
 839                                 s = "TAG_Int(UNBOX_NativeArray({p[0]}))"
 840                         else if n == once "[]".to_symbol then
 841                                 s = "UNBOX_NativeArray({p[0]})[UNTAG_Int({p[1]})]"
 842                         else if n == once "[]=".to_symbol then
 843                                 v.add_instr("UNBOX_NativeArray({p[0]})[UNTAG_Int({p[1]})]={p[2]};")
 844                         else if n == once "copy_to".to_symbol then
 845                                 v.add_instr("(void)memcpy(UNBOX_NativeArray({p[1]}), UNBOX_NativeArray({p[0]}), UNTAG_Int({p[2]})*sizeof(val_t));")
 846                         end
 847                 else if c == once "NativeString".to_symbol then
 848                         if n == once "object_id".to_symbol then
 849                                 s = "TAG_Int(UNBOX_NativeString({p[0]}))"
 850                         else if n == once "atoi".to_symbol then
 851                                 s = "TAG_Int(atoi(UNBOX_NativeString({p[0]})))"
 852                         else if n == once "[]".to_symbol then
 853                                 s = "TAG_Char(UNBOX_NativeString({p[0]})[UNTAG_Int({p[1]})])"
 854                         else if n == once "[]=".to_symbol then
 855                                 v.add_instr("UNBOX_NativeString({p[0]})[UNTAG_Int({p[1]})]=UNTAG_Char({p[2]});")
 856                         else if n == once "copy_to".to_symbol then
 857                                 v.add_instr("(void)memcpy(UNBOX_NativeString({p[1]})+UNTAG_Int({p[4]}), UNBOX_NativeString({p[0]})+UNTAG_Int({p[3]}), UNTAG_Int({p[2]}));")
 858                         end
 859                 else if n == once "object_id".to_symbol then
 860                         s = "TAG_Int((bigint){p[0]})"
 861                 else if n == once "sys".to_symbol then
 862                         s = "(G_sys)"
 863                 else if n == once "is_same_type".to_symbol then
 864                         s = "TAG_Bool((VAL2VFT({p[0]})==VAL2VFT({p[1]})))"
 865                 else if n == once "exit".to_symbol then
 866                         v.add_instr("exit(UNTAG_Int({p[1]}));")
 867                 else if n == once "calloc_array".to_symbol then
 868                         s = "BOX_NativeArray((val_t*)malloc((UNTAG_Int({p[1]}) * sizeof(val_t))))"
 869                 else if n == once "calloc_string".to_symbol then
 870                         s = "BOX_NativeString((char*)malloc((UNTAG_Int({p[1]}) * sizeof(char))))"
 871
 872                 else
 873                         v.add_instr("fprintf(stderr, \"Intern {n}\\n\"); nit_exit(1);")
 874                 end
 875                 if method.signature.return_type != null and s == null then
 876                         s = "NIT_NULL /*stub*/"
 877                 end
 878                 return s
 879         end
 880 end
 881
 882 ###############################################################################
 883
 884 redef class PExpr
 885         # Compile the node as an expression
 886         # Only the visitor should call it
 887         meth compile_expr(v: CompilerVisitor): String is abstract
 888
 889         # Prepare a call of node as a statement
 890         # Only the visitor should call it
 891         # It's used for local variable managment
 892         meth prepare_compile_stmt(v: CompilerVisitor) do end
 893
 894         # Compile the node as a statement
 895         # Only the visitor should call it
 896         meth compile_stmt(v: CompilerVisitor) do printl("Error!")
 897 end
 898
 899 redef class ABlockExpr
 900         redef meth compile_stmt(v)
 901         do
 902                 for n in n_expr do
 903                         v.compile_stmt(n)
 904                 end
 905         end
 906 end
 907
 908 redef class AVardeclExpr
 909         redef meth prepare_compile_stmt(v)
 910         do
 911                 v.cfc.register_variable(variable)
 912         end
 913
 914         redef meth compile_stmt(v)
 915         do
 916                 var cname = v.cfc.varname(variable)
 917                 if n_expr == null then
 918                         v.add_instr("/*{cname} is variable {variable.name}*/")
 919                 else
 920                         var e = v.compile_expr(n_expr)
 921                         v.add_assignment(cname, e)
 922                 end
 923         end
 924 end
 925
 926 redef class AReturnExpr
 927         redef meth compile_stmt(v)
 928         do
 929                 if n_expr != null then
 930                         var e = v.compile_expr(n_expr)
 931                         v.add_assignment(v.nmc.return_value, e)
 932                 end
 933                 if v.cfc.in_closure then v.add_instr("closctx->has_broke = &({v.nmc.return_value});")
 934                 v.add_instr("goto {v.nmc.return_label};")
 935         end
 936 end
 937
 938 redef class ABreakExpr
 939         redef meth compile_stmt(v)
 940         do
 941                 if n_expr != null then
 942                         var e = v.compile_expr(n_expr)
 943                         v.add_assignment(v.nmc.break_value, e)
 944                 end
 945                 if v.cfc.in_closure then v.add_instr("closctx->has_broke = &({v.nmc.break_value}); closctx->broke_value = *closctx->has_broke;")
 946                 v.add_instr("goto {v.nmc.break_label};")
 947         end
 948 end
 949
 950 redef class AContinueExpr
 951         redef meth compile_stmt(v)
 952         do
 953                 if n_expr != null then
 954                         var e = v.compile_expr(n_expr)
 955                         v.add_assignment(v.nmc.continue_value, e)
 956                 end
 957                 v.add_instr("goto {v.nmc.continue_label};")
 958         end
 959 end
 960
 961 redef class AAbortExpr
 962         redef meth compile_stmt(v)
 963         do
 964                 v.add_instr("fprintf(stderr, \"Aborted\"); {v.printf_locate_error(self)} nit_exit(1);")
 965         end
 966 end
 967
 968 redef class ADoExpr
 969         redef meth compile_stmt(v)
 970         do
 971                  if n_block != null then
 972                          v.compile_stmt(n_block)
 973                  end
 974         end
 975 end
 976
 977 redef class AIfExpr
 978         redef meth compile_stmt(v)
 979         do
 980                 var e = v.compile_expr(n_expr)
 981                 v.add_instr("if (UNTAG_Bool({e})) \{ /*if*/")
 982                 v.cfc.free_var(e)
 983                 if n_then != null then
 984                         v.indent
 985                         v.compile_stmt(n_then)
 986                         v.unindent
 987                 end
 988                 if n_else != null then
 989                         v.add_instr("} else \{ /*if*/")
 990                         v.indent
 991                         v.compile_stmt(n_else)
 992                         v.unindent
 993                 end
 994                 v.add_instr("}")
 995         end
 996 end
 997
 998 redef class AIfexprExpr
 999         redef meth compile_expr(v)
1000         do
1001                 var e = v.compile_expr(n_expr)
1002                 v.add_instr("if (UNTAG_Bool({e})) \{ /*if*/")
1003                 v.cfc.free_var(e)
1004                 v.indent
1005                 var e = v.ensure_var(v.compile_expr(n_then))
1006                 v.unindent
1007                 v.add_instr("} else \{ /*if*/")
1008                 v.cfc.free_var(e)
1009                 v.indent
1010                 var e2 = v.ensure_var(v.compile_expr(n_else))
1011                 v.add_assignment(e, e2)
1012                 v.unindent
1013                 v.add_instr("}")
1014                 return e
1015         end
1016 end
1017
1018 redef class AControlableBlock
1019         meth compile_inside_block(v: CompilerVisitor) is abstract
1020         redef meth compile_stmt(v)
1021         do
1022                 var old_break_label = v.nmc.break_label
1023                 var old_continue_label = v.nmc.continue_label
1024                 var id = v.new_number
1025                 v.nmc.break_label = "break_{id}"
1026                 v.nmc.continue_label = "continue_{id}"
1027
1028                 compile_inside_block(v)
1029
1030
1031                 v.nmc.break_label = old_break_label
1032                 v.nmc.continue_label = old_continue_label
1033         end
1034 end
1035
1036 redef class AWhileExpr
1037         redef meth compile_inside_block(v)
1038         do
1039                 v.add_instr("while (true) \{ /*while*/")
1040                 v.indent
1041                 var e = v.compile_expr(n_expr)
1042                 v.add_instr("if (!UNTAG_Bool({e})) break; /* while*/")
1043                 v.cfc.free_var(e)
1044                 if n_block != null then
1045                         v.compile_stmt(n_block)
1046                 end
1047                 v.add_instr("{v.nmc.continue_label}: while(0);")
1048                 v.unindent
1049                 v.add_instr("}")
1050                 v.add_instr("{v.nmc.break_label}: while(0);")
1051         end
1052 end
1053
1054 redef class AForExpr
1055         redef meth compile_inside_block(v)
1056         do
1057                 var e = v.compile_expr(n_expr)
1058                 var ittype = meth_iterator.signature.return_type
1059                 v.cfc.free_var(e)
1060                 var iter = v.cfc.get_var
1061                 v.add_assignment(iter, meth_iterator.compile_call(v, [e]))
1062                 v.add_instr("while (true) \{ /*for*/")
1063                 v.indent
1064                 var ok = v.cfc.get_var
1065                 v.add_assignment(ok, meth_is_ok.compile_call(v, [iter]))
1066                 v.add_instr("if (!UNTAG_Bool({ok})) break; /*for*/")
1067                 v.cfc.free_var(ok)
1068                 var e = meth_item.compile_call(v, [iter])
1069                 e = v.ensure_var(e)
1070                 var cname = v.cfc.register_variable(variable)
1071                 v.add_assignment(cname, e)
1072                 var n_block = n_block
1073                 if n_block != null then
1074                         v.compile_stmt(n_block)
1075                 end
1076                 v.add_instr("{v.nmc.continue_label}: while(0);")
1077                 e = meth_next.compile_call(v, [iter])
1078                 assert e == null
1079                 v.unindent
1080                 v.add_instr("}")
1081                 v.add_instr("{v.nmc.break_label}: while(0);")
1082         end
1083 end
1084
1085 redef class AAssertExpr
1086         redef meth compile_stmt(v)
1087         do
1088                 var e = v.compile_expr(n_expr)
1089                 var s = ""
1090                 if n_id != null then
1091                         s = " '{n_id.text}' "
1092                 end
1093                 v.add_instr("if (!UNTAG_Bool({e})) \{ fprintf(stderr, \"Assert%s failed\", \"{s}\"); {v.printf_locate_error(self)} nit_exit(1);}")
1094         end
1095 end
1096
1097 redef class AVarExpr
1098         redef meth compile_expr(v)
1099         do
1100                 return " {v.cfc.varname(variable)} /*{variable.name}*/"
1101         end
1102 end
1103
1104 redef class AVarAssignExpr
1105         redef meth compile_stmt(v)
1106         do
1107                 var e = v.compile_expr(n_value)
1108                 v.add_assignment(v.cfc.varname(variable), "{e} /*{variable.name}=*/")
1109         end
1110 end
1111
1112 redef class AVarReassignExpr
1113         redef meth compile_stmt(v)
1114         do
1115                 var e1 = v.cfc.varname(variable)
1116                 var e2 = v.compile_expr(n_value)
1117                 var e3 = assign_method.compile_call(v, [e1, e2])
1118                 v.add_assignment(v.cfc.varname(variable), "{e3} /*{variable.name}*/")
1119         end
1120 end
1121
1122 redef class ASelfExpr
1123         redef meth compile_expr(v)
1124         do
1125                 return v.cfc.varname(v.nmc.method_params[0])
1126         end
1127 end
1128
1129 redef class AOrExpr
1130         redef meth compile_expr(v)
1131         do
1132                 var e = v.ensure_var(v.compile_expr(n_expr))
1133                 v.add_instr("if (!UNTAG_Bool({e})) \{ /* or */")
1134                 v.cfc.free_var(e)
1135                 v.indent
1136                 var e2 = v.compile_expr(n_expr2)
1137                 v.add_assignment(e, e2)
1138                 v.unindent
1139                 v.add_instr("}")
1140                 return e
1141         end
1142 end
1143
1144 redef class AAndExpr
1145         redef meth compile_expr(v)
1146         do
1147                 var e = v.ensure_var(v.compile_expr(n_expr))
1148                 v.add_instr("if (UNTAG_Bool({e})) \{ /* and */")
1149                 v.cfc.free_var(e)
1150                 v.indent
1151                 var e2 = v.compile_expr(n_expr2)
1152                 v.add_assignment(e, e2)
1153                 v.unindent
1154                 v.add_instr("}")
1155                 return e
1156         end
1157 end
1158
1159 redef class ANotExpr
1160         redef meth compile_expr(v)
1161         do
1162                 return " TAG_Bool(!UNTAG_Bool({v.compile_expr(n_expr)}))"
1163         end
1164 end
1165
1166 redef class AEeExpr
1167         redef meth compile_expr(v)
1168         do
1169                 var e = v.compile_expr(n_expr)
1170                 var e2 = v.compile_expr(n_expr2)
1171                 return "TAG_Bool(IS_EQUAL_NN({e},{e2}))"
1172         end
1173 end
1174
1175 redef class AIsaExpr
1176         redef meth compile_expr(v)
1177         do
1178                 var e = v.compile_expr(n_expr)
1179                 return n_type.stype.compile_cast(v, e)
1180         end
1181 end
1182
1183 redef class AAsCastExpr
1184         redef meth compile_expr(v)
1185         do
1186                 var e = v.compile_expr(n_expr)
1187                 n_type.stype.compile_type_check(v, e, self)
1188                 return e
1189         end
1190 end
1191
1192 redef class ATrueExpr
1193         redef meth compile_expr(v)
1194         do
1195                 return " TAG_Bool(true)"
1196         end
1197 end
1198
1199 redef class AFalseExpr
1200         redef meth compile_expr(v)
1201         do
1202                 return " TAG_Bool(false)"
1203         end
1204 end
1205
1206 redef class AIntExpr
1207         redef meth compile_expr(v)
1208         do
1209                 return " TAG_Int({n_number.text})"
1210         end
1211 end
1212
1213 redef class AFloatExpr
1214         redef meth compile_expr(v)
1215         do
1216                 return "BOX_Float({n_float.text})"
1217         end
1218 end
1219
1220 redef class ACharExpr
1221         redef meth compile_expr(v)
1222         do
1223                 return " TAG_Char({n_char.text})"
1224         end
1225 end
1226
1227 redef class AStringFormExpr
1228         redef meth compile_expr(v)
1229         do
1230                 compute_string_info
1231                 var i = v.new_number
1232                 var cvar = v.cfc.get_var
1233                 v.add_decl("static val_t once_value_{i} = NIT_NULL; /* Once value for string {cvar}*/")
1234                 v.add_instr("if (once_value_{i} != NIT_NULL) {cvar} = once_value_{i};")
1235                 v.add_instr("else \{")
1236                 v.indent
1237                 v.cfc.free_var(cvar)
1238                 var e = meth_with_native.compile_constructor_call(v, stype , ["BOX_NativeString(\"{_cstring}\")", "TAG_Int({_cstring_length})"])
1239                 v.add_assignment(cvar, e)
1240                 v.add_instr("once_value_{i} = {cvar};")
1241                 v.unindent
1242                 v.add_instr("}")
1243                 return cvar
1244         end
1245
1246         # The raw string value
1247         protected meth string_text: String is abstract
1248
1249         # The string in a C native format
1250         protected attr _cstring: String
1251
1252         # The string length in bytes
1253         protected attr _cstring_length: Int
1254
1255         # Compute _cstring and _cstring_length using string_text
1256         protected meth compute_string_info
1257         do
1258                 var len = 0
1259                 var str = string_text
1260                 var res = new Buffer
1261                 var i = 0
1262                 while i < str.length do
1263                         var c = str[i]
1264                         if c == '\\' then
1265                                 i = i + 1
1266                                 var c2 = str[i]
1267                                 if c2 != '{' and c2 != '}' then
1268                                         res.add(c)
1269                                 end
1270                                 c = c2
1271                         end
1272                         len = len + 1
1273                         res.add(c)
1274                         i = i + 1
1275                 end
1276                 _cstring = res.to_s
1277                 _cstring_length = len
1278         end
1279 end
1280
1281 redef class AStringExpr
1282         redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1283 end
1284 redef class AStartStringExpr
1285         redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1286 end
1287 redef class AMidStringExpr
1288         redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1289 end
1290 redef class AEndStringExpr
1291         redef meth string_text do return n_string.text.substring(1, n_string.text.length - 2)
1292 end
1293
1294 redef class ASuperstringExpr
1295         redef meth compile_expr(v)
1296         do
1297                 var array = meth_with_capacity.compile_constructor_call(v, atype, ["TAG_Int({n_exprs.length})"])
1298
1299                 for ne in n_exprs do
1300                         var e = v.ensure_var(v.compile_expr(ne))
1301                         if ne.stype != stype then
1302                                 v.add_assignment(e, meth_to_s.compile_call(v, [e]))
1303                         end
1304                         meth_add.compile_call(v, [array, e])
1305                 end
1306
1307                 return meth_to_s.compile_call(v, [array])
1308         end
1309 end
1310
1311 redef class ANullExpr
1312         redef meth compile_expr(v)
1313         do
1314                 return " NIT_NULL /*null*/"
1315         end
1316 end
1317
1318 redef class AArrayExpr
1319         redef meth compile_expr(v)
1320         do
1321                 var recv = meth_with_capacity.compile_constructor_call(v, stype, ["TAG_Int({n_exprs.length})"])
1322
1323                 for ne in n_exprs do
1324                         var e = v.compile_expr(ne)
1325                         meth_add.compile_call(v, [recv, e])
1326                 end
1327                 return recv
1328         end
1329 end
1330
1331 redef class ARangeExpr
1332         redef meth compile_expr(v)
1333         do
1334                 var e = v.compile_expr(n_expr)
1335                 var e2 = v.compile_expr(n_expr2)
1336                 return meth_init.compile_constructor_call(v, stype, [e, e2])
1337         end
1338 end
1339
1340 redef class ASuperExpr
1341         redef meth compile_stmt(v)
1342         do
1343                 var e = compile_expr(v)
1344                 if e != null then v.add_instr("{e};")
1345         end
1346
1347         redef meth compile_expr(v)
1348         do
1349                 var arity = v.nmc.method_params.length - 1
1350                 if init_in_superclass != null then
1351                         arity = init_in_superclass.signature.arity
1352                 end
1353                 var args = new Array[String].with_capacity(arity + 1)
1354                 args.add(v.cfc.varname(v.nmc.method_params[0]))
1355                 if n_args.length != arity then
1356                         for i in [0..arity[ do
1357                                 args.add(v.cfc.varname(v.nmc.method_params[i + 1]))
1358                         end
1359                 else
1360                         for na in n_args do
1361                                 args.add(v.compile_expr(na))
1362                         end
1363                 end
1364                 #return "{prop.cname}({args.join(", ")}) /*super {prop.local_class}::{prop.name}*/"
1365                 if init_in_superclass != null then
1366                         return init_in_superclass.compile_call(v, args)
1367                 else
1368                         if prop.global.is_init then args.add("init_table")
1369                         return prop.compile_super_call(v, args)
1370                 end
1371         end
1372 end
1373
1374 redef class AAttrExpr
1375         redef meth compile_expr(v)
1376         do
1377                 var e = v.compile_expr(n_expr)
1378                 return prop.compile_access(v, e)
1379         end
1380 end
1381
1382 redef class AAttrAssignExpr
1383         redef meth compile_stmt(v)
1384         do
1385                 var e = v.compile_expr(n_expr)
1386                 var e2 = v.compile_expr(n_value)
1387                 v.add_assignment(prop.compile_access(v, e), e2)
1388         end
1389 end
1390 redef class AAttrReassignExpr
1391         redef meth compile_stmt(v)
1392         do
1393                 var e1 = v.compile_expr(n_expr)
1394                 var e2 = prop.compile_access(v, e1)
1395                 var e3 = v.compile_expr(n_value)
1396                 var e4 = assign_method.compile_call(v, [e2, e3])
1397                 v.add_assignment(e2, e4)
1398         end
1399 end
1400
1401 redef class ASendExpr
1402         redef meth compile_expr(v)
1403         do
1404                 var recv = v.compile_expr(n_expr)
1405                 var cargs = new Array[String]
1406                 cargs.add(recv)
1407                 for a in arguments do
1408                         cargs.add(v.compile_expr(a))
1409                 end
1410
1411                 var e: String
1412                 if prop_signature.closures.is_empty then
1413                         e = prop.compile_call(v, cargs)
1414                 else
1415                         e = prop.compile_call_and_closures(v, cargs, closure_defs)
1416                 end
1417
1418                 if prop.global.is_init then
1419                         v.invoke_super_init_calls_after(prop)
1420                 end
1421                 return e
1422         end
1423
1424         redef meth compile_stmt(v)
1425         do
1426                 var e = compile_expr(v)
1427                 if e != null then
1428                         v.add_instr(e + ";")
1429                 end
1430         end
1431 end
1432
1433 redef class ASendReassignExpr
1434         redef meth compile_expr(v)
1435         do
1436                 var recv = v.compile_expr(n_expr)
1437                 var cargs = new Array[String]
1438                 cargs.add(recv)
1439                 for a in arguments do
1440                         cargs.add(v.compile_expr(a))
1441                 end
1442
1443                 var e2 = read_prop.compile_call(v, cargs)
1444                 var e3 = v.compile_expr(n_value)
1445                 var e4 = assign_method.compile_call(v, [e2, e3])
1446                 cargs.add(e4)
1447                 return prop.compile_call(v, cargs)
1448         end
1449 end
1450
1451 redef class ANewExpr
1452         redef meth compile_expr(v)
1453         do
1454                 var cargs = new Array[String]
1455                 for a in arguments do
1456                         cargs.add(v.compile_expr(a))
1457                 end
1458                 return prop.compile_constructor_call(v, stype, cargs)
1459         end
1460 end
1461
1462 redef class PClosureDef
1463         # Compile the closure definition as a function in v.out_contexts
1464         # Return the cname of the function
1465         meth compile_closure(v: CompilerVisitor, closcn: String): String is abstract
1466
1467         # Compile the closure definition inside the current C function.
1468         meth do_compile_inside(v: CompilerVisitor, params: Array[String]): String is abstract
1469 end
1470
1471 redef class AClosureDef
1472         # The cname of the function
1473         readable attr _cname: String
1474
1475         redef meth compile_closure(v, closcn)
1476         do
1477                 var ctx_old = v.ctx
1478                 v.ctx = new CContext
1479                 v.out_contexts.add(v.ctx)
1480
1481                 var cfc_old = v.cfc.in_closure
1482                 v.cfc.in_closure = true
1483
1484                 var old_rv = v.nmc.return_value
1485                 var old_bv = v.nmc.break_value
1486                 if not cfc_old then
1487                         v.nmc.return_value = "closctx->{old_rv}"
1488                         v.nmc.break_value = "closctx->{old_bv}"
1489                 end
1490
1491                 var cname = "OC_{v.nmc.method.cname}_{v.out_contexts.length}"
1492                 _cname = cname
1493                 var args = new Array[String]
1494                 for i in [0..closure.signature.arity[ do
1495                         args.add(" param{i}")
1496                 end
1497
1498                 var cs = decl_csignature(v, args, closcn)
1499
1500                 v.add_instr("{cs} \{")
1501                 v.indent
1502                 var ctx_old2 = v.ctx
1503                 v.ctx = new CContext
1504
1505                 v.add_decl("struct trace_t trace = \{NULL, NULL, {line_number}, LOCATE_{v.nmc.method.cname}};")
1506                 v.add_instr("trace.prev = tracehead; tracehead = &trace;")
1507
1508                 v.add_instr("trace.file = LOCATE_{v.module.name};")
1509                 var s = do_compile_inside(v, args)
1510
1511                 v.add_instr("{v.nmc.return_label}:")
1512                 v.add_instr("tracehead = trace.prev;")
1513                 if s == null then
1514                         v.add_instr("return;")
1515                 else
1516                         v.add_instr("return {s};")
1517                 end
1518
1519                 ctx_old2.append(v.ctx)
1520                 v.ctx = ctx_old2
1521                 v.unindent
1522                 v.add_instr("}")
1523                 v.ctx = ctx_old
1524
1525                 v.cfc.in_closure = cfc_old
1526                 v.nmc.return_value = old_rv
1527                 v.nmc.break_value = old_bv
1528
1529                 # Build closure
1530                 var closcnv = "wbclos{v.new_number}"
1531                 v.add_decl("struct {closcn} {closcnv};")
1532                 v.add_instr("{closcnv}.fun = {cname};")
1533                 v.add_instr("{closcnv}.has_broke = NULL;")
1534                 if cfc_old then
1535                         v.add_instr("{closcnv}.variable = closctx->variable;")
1536                         v.add_instr("{closcnv}.closurevariable = closctx->closurevariable;")
1537                 else
1538                         v.add_instr("{closcnv}.variable = variable;")
1539                         v.add_instr("{closcnv}.closurevariable = closurevariable;")
1540                 end
1541
1542                 return "(&{closcnv})"
1543         end
1544
1545         protected meth decl_csignature(v: CompilerVisitor, args: Array[String], closcn: String): String
1546         do
1547                 var params = new Array[String]
1548                 params.add("struct {closcn}* closctx")
1549                 for i in [0..closure.signature.arity[ do
1550                         var p = "val_t {args[i]}"
1551                         params.add(p)
1552                 end
1553                 var ret: String
1554                 if closure.signature.return_type != null then
1555                         ret = "val_t"
1556                 else
1557                         ret = "void"
1558                 end
1559                 var p = params.join(", ")
1560                 var s = "{ret} {cname}({p})"
1561                 v.add_decl("struct {closcn};")
1562                 v.add_decl("typedef {ret} (* {cname}_t)({p});")
1563                 v.add_decl(s + ";")
1564                 return s
1565         end
1566
1567         redef meth do_compile_inside(v, params)
1568         do
1569                 for i in [0..variables.length[ do
1570                         var vacname = v.cfc.register_variable(variables[i])
1571                         v.add_assignment(vacname, params[i])
1572                 end
1573
1574                 var old_cv = v.nmc.continue_value
1575                 var old_cl = v.nmc.continue_label
1576                 var old_bl = v.nmc.break_label
1577
1578                 v.nmc.continue_value = v.cfc.get_var
1579                 v.nmc.continue_label = "continue_label{v.new_number}"
1580                 v.nmc.break_label = v.nmc.return_label
1581
1582                 if n_expr != null then v.compile_stmt(n_expr)
1583
1584                 v.add_instr("{v.nmc.continue_label}: while(false);")
1585
1586                 var ret: String = null
1587                 if closure.signature.return_type != null then ret = v.nmc.continue_value
1588
1589                 v.nmc.continue_value = old_cv
1590                 v.nmc.continue_label = old_cl
1591                 v.nmc.break_label = old_bl
1592
1593                 return ret
1594         end
1595 end
1596
1597 redef class PClosureDecl
1598         meth do_compile_inside(v: CompilerVisitor, params: Array[String]): String is abstract
1599 end
1600 redef class AClosureDecl
1601         redef meth do_compile_inside(v, params)
1602         do
1603                 if n_signature != null then n_signature.compile_parameters(v, variable.closure.signature, params)
1604
1605                 var old_cv = v.nmc.continue_value
1606                 var old_cl = v.nmc.continue_label
1607                 var old_bl = v.nmc.break_label
1608
1609                 v.nmc.continue_value = v.cfc.get_var
1610                 v.nmc.continue_label = "continue_label{v.new_number}"
1611                 v.nmc.break_label = v.nmc.return_label
1612
1613                 if n_expr != null then v.compile_stmt(n_expr)
1614
1615                 v.add_instr("{v.nmc.continue_label}: while(false);")
1616
1617                 var ret: String = null
1618                 if variable.closure.signature.return_type != null then ret = v.nmc.continue_value
1619
1620                 v.nmc.continue_value = old_cv
1621                 v.nmc.continue_label = old_cl
1622                 v.nmc.break_label = old_bl
1623
1624                 return ret
1625         end
1626 end
1627
1628 redef class AClosureCallExpr
1629         redef meth compile_expr(v)
1630         do
1631                 var cargs = new Array[String]
1632                 for a in arguments do cargs.add(v.compile_expr(a))
1633                 var va: String = null
1634                 if variable.closure.signature.return_type != null then va = v.cfc.get_var
1635
1636                 if variable.closure.is_optional then
1637                         v.add_instr("if({v.cfc.varname(variable)}==NULL) \{")
1638                         v.indent
1639                         var n = variable.decl
1640                         assert n isa AClosureDecl
1641                         var s = n.do_compile_inside(v, cargs)
1642                         if s != null then v.add_assignment(va, s)
1643                         v.unindent
1644                         v.add_instr("} else \{")
1645                         v.indent
1646                 end
1647
1648                 var ivar = "(({variable.ctypename})({v.cfc.varname(variable)}))"
1649                 var cargs2 = [ivar]
1650                 cargs2.append(cargs)
1651                 var s = "({ivar}->fun({cargs2.join(", ")})) /* Invoke closure {variable} */"
1652                 if va != null then
1653                         v.add_assignment(va, s)
1654                 else
1655                         v.add_instr("{s};")
1656                 end
1657                 v.add_instr("if ({ivar}->has_broke) \{")
1658                 v.indent
1659                 if n_closure_defs != null and n_closure_defs.length == 1 then do
1660                         n_closure_defs.first.do_compile_inside(v, null)
1661                 end
1662                 if v.cfc.in_closure then v.add_instr("if ({ivar}->has_broke) \{ closctx->has_broke = {ivar}->has_broke; closctx->broke_value = {ivar}->broke_value;\}")
1663                 v.add_instr("goto {v.nmc.return_label};")
1664                 v.unindent
1665                 v.add_instr("\}")
1666
1667                 if variable.closure.is_optional then
1668                         v.unindent
1669                         v.add_instr("\}")
1670                 end
1671                 return va
1672         end
1673 end
1674
1675 redef class AProxyExpr
1676         redef meth compile_expr(v)
1677         do
1678                 return v.compile_expr(n_expr)
1679         end
1680 end
1681
1682 redef class AOnceExpr
1683         redef meth compile_expr(v)
1684         do
1685                 var i = v.new_number
1686                 var cvar = v.cfc.get_var
1687                 v.add_decl("static val_t once_value_{i}; static int once_bool_{i}; /* Once value for {cvar}*/")
1688                 v.add_instr("if (once_bool_{i}) {cvar} = once_value_{i};")
1689                 v.add_instr("else \{")
1690                 v.indent
1691                 v.cfc.free_var(cvar)
1692                 var e = v.compile_expr(n_expr)
1693                 v.add_assignment(cvar, e)
1694                 v.add_instr("once_value_{i} = {cvar};")
1695                 v.add_instr("once_bool_{i} = true;")
1696                 v.unindent
1697                 v.add_instr("}")
1698                 return cvar
1699         end
1700 end