src/testing/testing_suite.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Testing from external files.
  16 module testing_suite
  17
  18 import testing_base
  19 import html
  20 private import annotation
  21
  22 redef class ToolContext
  23         # -- target-file
  24         var opt_file = new OptionString("Specify test suite location", "-t", "--target-file")
  25         # --pattern
  26         var opt_pattern = new OptionString("Only run test case with name that match pattern", "-p", "--pattern")
  27 end
  28
  29 # Used to test nitunit test files.
  30 class NitUnitTester
  31
  32         # `ModelBuilder` used to parse test files.
  33         var mbuilder: ModelBuilder
  34
  35         # Parse a file and return the contained `MModule`.
  36         private fun parse_module_unit(file: String): nullable MModule do
  37                 var mmodule = mbuilder.parse([file]).first
  38                 if mbuilder.get_mmodule_annotation("test_suite", mmodule) == null then return null
  39                 mbuilder.run_phases
  40                 return mmodule
  41         end
  42
  43         # Compile and execute the test suite for a NitUnit `file`.
  44         fun test_module_unit(file: String): nullable TestSuite do
  45                 var toolcontext = mbuilder.toolcontext
  46                 var mmodule = parse_module_unit(file)
  47                 # is the module a test_suite?
  48                 if mmodule == null then return null
  49                 var suite = new TestSuite(mmodule, toolcontext)
  50                 # method to execute before all tests in the module
  51                 var before_module = mmodule.before_test
  52                 if before_module != null then
  53                         toolcontext.modelbuilder.total_tests += 1
  54                         suite.before_module = new TestCase(suite, before_module, toolcontext)
  55                 end
  56                 # generate all test cases
  57                 for mclassdef in mmodule.mclassdefs do
  58                         if not mclassdef.is_test then continue
  59                         if not suite_match_pattern(mclassdef) then continue
  60                         toolcontext.modelbuilder.total_classes += 1
  61                         for mpropdef in mclassdef.mpropdefs do
  62                                 if not mpropdef isa MMethodDef or not mpropdef.is_test then continue
  63                                 if not case_match_pattern(mpropdef) then continue
  64                                 toolcontext.modelbuilder.total_tests += 1
  65                                 var test = new TestCase(suite, mpropdef, toolcontext)
  66                                 suite.add_test test
  67                         end
  68                 end
  69                 # method to execute after all tests in the module
  70                 var after_module = mmodule.after_test
  71                 if after_module != null then
  72                         toolcontext.modelbuilder.total_tests += 1
  73                         suite.after_module = new TestCase(suite, after_module, toolcontext)
  74                 end
  75                 suite.run
  76                 return suite
  77         end
  78
  79         # Is the test suite name match the pattern option?
  80         private fun suite_match_pattern(suite: MClassDef): Bool do
  81                 var pattern = mbuilder.toolcontext.opt_pattern.value
  82                 if pattern == null then return true
  83                 var ps = pattern.split_with("::")
  84                 var p = ps.first
  85                 if ps.length == 1 and p.first.is_lower then return true
  86                 if ps.length == 2 and p.first.is_lower then return false
  87                 if p.has_suffix("*") then
  88                         p = p.substring(0, p.length - 1)
  89                         if suite.name.has_prefix(p) then return true
  90                 else
  91                         if suite.name == p then return true
  92                 end
  93                 return false
  94         end
  95
  96         # Is the test case name match the pattern option?
  97         private fun case_match_pattern(case: MPropDef): Bool do
  98                 var pattern = mbuilder.toolcontext.opt_pattern.value
  99                 if pattern == null then return true
 100                 var ps = pattern.split_with("::")
 101                 var p = ps.last
 102                 if ps.length == 1 and p.first.is_upper then return true
 103                 if ps.length == 2 and p.first.is_upper then return false
 104                 if p.has_suffix("*") then
 105                         p = p.substring(0, p.length - 1)
 106                         if case.name.has_prefix(p) then return true
 107                 else
 108                         if case.name == p then return true
 109                 end
 110                 return false
 111         end
 112 end
 113
 114 # A test suite contains all the test cases for a `MModule`.
 115 class TestSuite
 116
 117         # `MModule` under test
 118         var mmodule: MModule
 119
 120         # `ToolContext` to use to display messages.
 121         var toolcontext: ToolContext
 122
 123         # List of `TestCase` to be executed in this suite.
 124         var test_cases = new Array[TestCase]
 125
 126         # Add a `TestCase` to the suite.
 127         fun add_test(case: TestCase) do test_cases.add case
 128
 129         # Test to be executed before the whole test suite.
 130         var before_module: nullable TestCase = null
 131
 132         # Test to be executed after the whole test suite.
 133         var after_module: nullable TestCase = null
 134
 135         # Execute the test suite
 136         fun run do
 137                 if not toolcontext.test_dir.file_exists then
 138                         toolcontext.test_dir.mkdir
 139                 end
 140                 write_to_nit
 141                 compile
 142                 toolcontext.info("Execute test-suite {mmodule.name}", 1)
 143                 var before_module = self.before_module
 144                 if not before_module == null then before_module.run
 145                 for case in test_cases do case.run
 146                 var after_module = self.after_module
 147                 if not after_module == null then after_module.run
 148         end
 149
 150         # Write the test unit for `self` in a nit compilable file.
 151         fun write_to_nit do
 152                 var file = new Template
 153                 file.addn "intrude import test_suite"
 154                 file.addn "import {mmodule.name}\n"
 155                 file.addn "var name = args.first"
 156                 for case in test_cases do
 157                         case.write_to_nit(file)
 158                 end
 159                 file.write_to_file("{test_file}.nit")
 160         end
 161
 162         # Return the test suite in XML format compatible with Jenkins.
 163         # Contents depends on the `run` execution.
 164         fun to_xml: HTMLTag do
 165                 var n = new HTMLTag("testsuite")
 166                 n.attr("package", mmodule.name)
 167                 var failure = self.failure
 168                 if failure != null then
 169                         var f = new HTMLTag("failure")
 170                         f.attr("message", failure.to_s)
 171                         n.add f
 172                 else
 173                         for test in test_cases do n.add test.to_xml
 174                 end
 175                 return n
 176         end
 177
 178         # Generated test file name.
 179         fun test_file: String do
 180                 return toolcontext.test_dir / "gen_{mmodule.name.escape_to_c}"
 181         end
 182
 183         # Compile all `test_cases` cases in one file.
 184         fun compile do
 185                 # find nitc
 186                 var nitc = toolcontext.find_nitc
 187                 # compile test suite
 188                 var file = test_file
 189                 var module_file = mmodule.location.file
 190                 if module_file == null then
 191                         toolcontext.error(null, "Error: cannot find module file for {mmodule.name}.")
 192                         toolcontext.check_errors
 193                         return
 194                 end
 195                 var include_dir = module_file.filename.dirname
 196                 var cmd = "{nitc} --no-color '{file}.nit' -I {include_dir} -o '{file}.bin' > '{file}.out' 2>&1 </dev/null"
 197                 var res = toolcontext.safe_exec(cmd)
 198                 var f = new FileReader.open("{file}.out")
 199                 var msg = f.read_all
 200                 f.close
 201                 # set test case result
 202                 var loc = mmodule.location
 203                 if res != 0 then
 204                         failure = msg
 205                         toolcontext.warning(loc, "failure", "FAILURE: {mmodule.name} (in file {file}.nit): {msg}")
 206                         toolcontext.modelbuilder.failed_tests += 1
 207                 end
 208                 toolcontext.check_errors
 209         end
 210
 211         # Error occured during test-suite compilation.
 212         var failure: nullable String = null
 213 end
 214
 215 # A test case is a unit test considering only a `MMethodDef`.
 216 class TestCase
 217
 218         # Test suite wich `self` belongs to.
 219         var test_suite: TestSuite
 220
 221         # Test method to be compiled and tested.
 222         var test_method: MMethodDef
 223
 224         # `ToolContext` to use to display messages and find `nitc` bin.
 225         var toolcontext: ToolContext
 226
 227         # Generate the test unit for `self` in `file`.
 228         fun write_to_nit(file: Template) do
 229                 var name = test_method.name
 230                 file.addn "if name == \"{name}\" then"
 231                 if test_method.mproperty.is_toplevel then
 232                         file.addn "\t{name}"
 233                 else
 234                         file.addn "\tvar subject = new {test_method.mclassdef.name}.nitunit"
 235                         file.addn "\tsubject.before_test"
 236                         file.addn "\tsubject.{name}"
 237                         file.addn "\tsubject.after_test"
 238                 end
 239                 file.addn "end"
 240         end
 241
 242         # Execute the test case.
 243         fun run do
 244                 toolcontext.info("Execute test-case {test_method.name}", 1)
 245                 was_exec = true
 246                 if toolcontext.opt_noact.value then return
 247                 # execute
 248                 var method_name = test_method.name
 249                 var test_file = test_suite.test_file
 250                 var res_name = "{test_file}_{method_name.escape_to_c}"
 251                 var res = toolcontext.safe_exec("{test_file}.bin {method_name} > '{res_name}.out1' 2>&1 </dev/null")
 252                 var f = new FileReader.open("{res_name}.out1")
 253                 var msg = f.read_all
 254                 f.close
 255                 # set test case result
 256                 var loc = test_method.location
 257                 if res != 0 then
 258                         error = msg
 259                         toolcontext.warning(loc, "failure",
 260                            "ERROR: {method_name} (in file {test_file}.nit): {msg}")
 261                         toolcontext.modelbuilder.failed_tests += 1
 262                 end
 263                 toolcontext.check_errors
 264         end
 265
 266         # Error occured during test-case execution.
 267         var error: nullable String = null
 268
 269         # Was the test case executed at least one?
 270         var was_exec = false
 271
 272         # Return the `TestCase` in XML format compatible with Jenkins.
 273         fun to_xml: HTMLTag do
 274                 var mclassdef = test_method.mclassdef
 275                 var tc = new HTMLTag("testcase")
 276                 # NOTE: jenkins expects a '.' in the classname attr
 277                 tc.attr("classname", "nitunit." + mclassdef.mmodule.full_name + "." + mclassdef.mclass.full_name)
 278                 tc.attr("name", test_method.mproperty.full_name)
 279                 if was_exec then
 280                         tc.add  new HTMLTag("system-out")
 281                         var n = new HTMLTag("system-err")
 282                         tc.add n
 283                         var error = self.error
 284                         if error != null then
 285                                 n.append error.trunc(8192).filter_nonprintable
 286                                 n = new HTMLTag("error")
 287                                 n.attr("message", "Runtime Error")
 288                                 tc.add n
 289                         end
 290                 end
 291                 return tc
 292         end
 293 end
 294
 295 redef class MMethodDef
 296         # TODO use annotations?
 297
 298         # Is the method a test_method?
 299         # i.e. begins with "test_"
 300         private fun is_test: Bool do return name.has_prefix("test_")
 301
 302         # Is the method a "before_module"?
 303         private fun is_before_module: Bool do return mproperty.is_toplevel and name == "before_module"
 304
 305         # Is the method a "after_module"?
 306         private fun is_after_module: Bool do return mproperty.is_toplevel and name == "after_module"
 307 end
 308
 309 redef class MClassDef
 310         # Is the class a TestClass?
 311         # i.e. begins with "Test"
 312         private fun is_test: Bool do
 313                 var in_hierarchy = self.in_hierarchy
 314                 if in_hierarchy == null then return false
 315                 for sup in in_hierarchy.greaters do
 316                         if sup.name == "TestSuite" then return true
 317                 end
 318                 return false
 319         end
 320 end
 321
 322 redef class MModule
 323         # "before_module" method for this module.
 324         private fun before_test: nullable MMethodDef do
 325                 for mclassdef in mclassdefs do
 326                         if not mclassdef.name == "Object" then continue
 327                         for mpropdef in mclassdef.mpropdefs do
 328                                 if mpropdef isa MMethodDef and mpropdef.is_before_module then return mpropdef
 329                         end
 330                 end
 331                 return null
 332         end
 333
 334         # "after_module" method for this module.
 335         private fun after_test: nullable MMethodDef do
 336                 for mclassdef in mclassdefs do
 337                         if not mclassdef.name == "Object" then continue
 338                         for mpropdef in mclassdef.mpropdefs do
 339                                 if mpropdef isa MMethodDef and mpropdef.is_after_module then return mpropdef
 340                         end
 341                 end
 342                 return null
 343         end
 344 end
 345
 346 redef class ModelBuilder
 347         # Number of test classes generated.
 348         var total_classes = 0
 349
 350         # Number of tests generated.
 351         var total_tests = 0
 352
 353         # Number of failed tests.
 354         var failed_tests = 0
 355
 356         # Run NitUnit test file for mmodule (if exists).
 357         fun test_unit(mmodule: MModule): HTMLTag do
 358                 var ts = new HTMLTag("testsuite")
 359                 toolcontext.info("nitunit: test-suite test_{mmodule}", 2)
 360                 var f = toolcontext.opt_file.value
 361                 var test_file = "test_{mmodule.name}.nit"
 362                 if f != null then
 363                         test_file = f
 364                 else if not test_file.file_exists then
 365                         var module_file = mmodule.location.file
 366                         if module_file == null then
 367                                 toolcontext.info("Skip test for {mmodule}, no file found", 2)
 368                                 return ts
 369                         end
 370                         var include_dir = module_file.filename.dirname
 371                         test_file = "{include_dir}/{test_file}"
 372                 end
 373                 if not test_file.file_exists then
 374                         toolcontext.info("Skip test for {mmodule}, no file {test_file} found", 2)
 375                         return ts
 376                 end
 377                 var tester = new NitUnitTester(self)
 378                 var res = tester.test_module_unit(test_file)
 379                 if res == null then
 380                         toolcontext.info("Skip test for {mmodule}, no test suite found", 2)
 381                         return ts
 382                 end
 383                 return res.to_xml
 384         end
 385 end