src/literal.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Parsing of literal values in the abstract syntax tree.
  18 module literal
  19
  20 import phase
  21
  22 redef class ToolContext
  23         var literal_phase: Phase = new LiteralPhase(self, null)
  24 end
  25
  26 private class LiteralPhase
  27         super Phase
  28
  29         redef fun process_nmodule(nmodule) do nmodule.do_literal(toolcontext)
  30 end
  31
  32 redef class AModule
  33         # Visit the module to compute the real value of the literal-related node of the AST.
  34         # Warnings and errors are displayed on the toolcontext.
  35         fun do_literal(toolcontext: ToolContext)
  36         do
  37                 var v = new LiteralVisitor(toolcontext)
  38                 v.enter_visit(self)
  39         end
  40 end
  41
  42 private class LiteralVisitor
  43         super Visitor
  44
  45         var toolcontext: ToolContext
  46
  47         redef fun visit(n)
  48         do
  49                 n.accept_literal(self)
  50                 n.visit_all(self)
  51         end
  52 end
  53
  54 redef class ANode
  55         private fun accept_literal(v: LiteralVisitor) do end
  56 end
  57
  58 redef class AIntExpr
  59         # The value of the literal int once computed.
  60         var value: nullable Int
  61 end
  62
  63 redef class ADecIntExpr
  64         redef fun accept_literal(v)
  65         do
  66                 self.value = self.n_number.text.to_i
  67         end
  68 end
  69
  70 redef class AHexIntExpr
  71         redef fun accept_literal(v)
  72         do
  73                 self.value = self.n_hex_number.text.substring_from(2).to_hex
  74         end
  75 end
  76
  77 redef class AFloatExpr
  78         # The value of the literal float once computed.
  79         var value: nullable Float
  80         redef fun accept_literal(v)
  81         do
  82                 self.value = self.n_float.text.to_f
  83         end
  84 end
  85
  86 redef class ACharExpr
  87         # The value of the literal char once computed.
  88         var value: nullable Char
  89         redef fun accept_literal(v)
  90         do
  91                 var txt = self.n_char.text.unescape_nit
  92                 if txt.length != 3 then
  93                         v.toolcontext.error(self.hot_location, "Invalid character literal {txt}")
  94                         return
  95                 end
  96                 self.value = txt.chars[1]
  97         end
  98 end
  99
 100 redef class AStringFormExpr
 101         # The value of the literal string once computed.
 102         var value: nullable String
 103         redef fun accept_literal(v)
 104         do
 105                 var txt = self.n_string.text
 106                 var behead = 1
 107                 var betail = 1
 108                 if txt.chars[0] == txt.chars[1] and txt.length >= 6 then
 109                         behead = 3
 110                         betail = 3
 111                         if txt.chars[0] == '"' and txt.chars[3] == '\n' then behead = 4 # ignore first \n in """
 112                 end
 113                 self.value = txt.substring(behead, txt.length - behead - betail).unescape_nit
 114         end
 115 end