src/nitcatalog.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Basic catalog generator for Nit packages
  16 #
  17 # See: <http://nitlanguage.org/catalog/>
  18 #
  19 # The tool scans packages and generates the HTML files of a catalog.
  20 #
  21 # ## Features
  22 #
  23 # * [X] scan packages and their `.ini`
  24 # * [X] generate lists of packages
  25 # * [X] generate a page per package with the readme and most metadata
  26 # * [ ] link/include/be included in the documentation
  27 # * [ ] propose `related packages`
  28 # * [X] show directory content (a la nitls)
  29 # * [X] gather git information from the working directory
  30 # * [ ] gather git information from the repository
  31 # * [ ] gather package information from github
  32 # * [ ] gather people information from github
  33 # * [ ] reify people
  34 # * [ ] separate information gathering from rendering
  35 # * [ ] move up information gathering in (existing or new) service modules
  36 # * [X] add command line options
  37 # * [ ] harden HTML (escaping, path injection, etc)
  38 # * [ ] nitcorn server with RESTful API
  39 #
  40 # ## Issues and limitations
  41 #
  42 # The tool works likee the other tools and expects to find valid Nit source code in the directories
  43 #
  44 # * cruft and temporary files will be collected
  45 # * missing source file (e.g. not yet generated by nitcc) will make information
  46 #   incomplete (e.g. invalid module thus partial dependency and metrics)
  47 #
  48 # How to use the tool as the basis of a Nit code archive on the web usable with a package manager is not clear.
  49 module nitcatalog
  50
  51 import loader # Scan&load packages, groups and modules
  52 import doc::doc_down # Display mdoc
  53 import md5 # To get gravatar images
  54 import counter # For statistics
  55 import modelize # To process and count classes and methods
  56
  57 redef class MPackage
  58         # Return the associated metadata from the `ini`, if any
  59         fun metadata(key: String): nullable String
  60         do
  61                 var ini = self.ini
  62                 if ini == null then return null
  63                 return ini[key]
  64         end
  65
  66         # The list of maintainers
  67         var maintainers = new Array[String]
  68
  69         # The list of contributors
  70         var contributors = new Array[String]
  71
  72         # The date of the most recent commit
  73         var last_date: nullable String = null
  74
  75         # The date of the oldest commit
  76         var first_date: nullable String = null
  77 end
  78
  79 # A HTML page in a catalog
  80 #
  81 # This is just a template with the header pre-filled and the footer injected at rendering.
  82 # Therefore, once instantiated, the content can just be added to it.
  83 class CatalogPage
  84         super Template
  85
  86         # Placeholder to include additional things before the `</head>`.
  87         var more_head = new Template
  88
  89         # Relative path to the root directory (with the index file).
  90         #
  91         # Use "" for pages in the root directory
  92         # Use ".." for pages in a subdirectory
  93         var rootpath: String
  94
  95         redef init
  96         do
  97                 add """
  98 <!DOCTYPE html>
  99 <html>
 100 <head>
 101         <meta charset="utf-8">
 102         <link rel="stylesheet" media="all" href="https://maxcdn.bootstrapcdn.com/bootstrap/3.3.1/css/bootstrap.min.css">
 103         <link rel="stylesheet" media="all" href="{{{rootpath / "style.css"}}}">
 104 """
 105                 add more_head
 106
 107                 add """
 108 </head>
 109 <body>
 110 <div class='container-fluid'>
 111  <div class='row'>
 112   <nav id='topmenu' class='navbar navbar-default navbar-fixed-top' role='navigation'>
 113    <div class='container-fluid'>
 114     <div class='navbar-header'>
 115      <button type='button' class='navbar-toggle' data-toggle='collapse' data-target='#topmenu-collapse'>
 116       <span class='sr-only'>Toggle menu</span>
 117       <span class='icon-bar'></span>
 118       <span class='icon-bar'></span>
 119       <span class='icon-bar'></span>
 120      </button>
 121      <span class='navbar-brand'><a href="http://nitlanguage.org/">Nitlanguage.org</a></span>
 122     </div>
 123     <div class='collapse navbar-collapse' id='topmenu-collapse'>
 124      <ul class='nav navbar-nav'>
 125       <li><a href="{{{rootpath / "index.html"}}}">Catalog</a></li>
 126      </ul>
 127     </div>
 128    </div>
 129   </nav>
 130  </div>
 131 """
 132         end
 133
 134         redef fun rendering
 135         do
 136                 add """
 137 </div> <!-- container-fluid -->
 138 <script src='https://code.jquery.com/jquery-latest.min.js'></script>
 139 <script src='https://maxcdn.bootstrapcdn.com/bootstrap/3.3.1/js/bootstrap.min.js'></script>
 140 <script src='https://cdnjs.cloudflare.com/ajax/libs/bootstrap-table/1.8.1/bootstrap-table-all.min.js'></script>
 141 </body>
 142 </html>
 143 """
 144         end
 145 end
 146
 147 redef class Int
 148         # Returns `log(self+1)`. Used to compute score of packages
 149         fun score: Float do return (self+1).to_f.log
 150 end
 151
 152 # The main class of the calatog generator that has the knowledge
 153 class Catalog
 154
 155         # The modelbuilder
 156         # used to access the files and count source lines of code
 157         var modelbuilder: ModelBuilder
 158
 159         # Packages by tag
 160         var tag2proj = new MultiHashMap[String, MPackage]
 161
 162         # Packages by category
 163         var cat2proj = new MultiHashMap[String, MPackage]
 164
 165         # Packages by maintainer
 166         var maint2proj = new MultiHashMap[String, MPackage]
 167
 168         # Packages by contributors
 169         var contrib2proj = new MultiHashMap[String, MPackage]
 170
 171         # Dependency between packages
 172         var deps = new POSet[MPackage]
 173
 174         # Number of modules by package
 175         var mmodules = new Counter[MPackage]
 176
 177         # Number of classes by package
 178         var mclasses = new Counter[MPackage]
 179
 180         # Number of methods by package
 181         var mmethods = new Counter[MPackage]
 182
 183         # Number of line of code by package
 184         var loc = new Counter[MPackage]
 185
 186         # Number of commits by package
 187         var commits = new Counter[MPackage]
 188
 189         # Score by package
 190         #
 191         # The score is loosely computed using other metrics
 192         var score = new Counter[MPackage]
 193
 194         # Scan, register and add a contributor to a package
 195         fun add_contrib(person: String, mpackage: MPackage, res: Template)
 196         do
 197                 var projs = contrib2proj[person]
 198                 if not projs.has(mpackage) then projs.add mpackage
 199                 var name = person
 200                 var email = null
 201                 var page = null
 202
 203                 # Regular expressions are broken, need to investigate.
 204                 # So split manually.
 205                 #
 206                 #var re = "([^<(]*?)(<([^>]*?)>)?(\\((.*)\\))?".to_re
 207                 #var m = (person+" ").search(re)
 208                 #print "{person}: `{m or else "?"}` `{m[1] or else "?"}` `{m[3] or else "?"}` `{m[5] or else "?"}`"
 209                 do
 210                         var sp1 = person.split_once_on("<")
 211                         if sp1.length < 2 then
 212                                 break
 213                         end
 214                         var sp2 = sp1.last.split_once_on(">")
 215                         if sp2.length < 2 then
 216                                 break
 217                         end
 218                         name = sp1.first.trim
 219                         email = sp2.first.trim
 220                         var sp3 = sp2.last.split_once_on("(")
 221                         if sp3.length < 2 then
 222                                 break
 223                         end
 224                         var sp4 = sp3.last.split_once_on(")")
 225                         if sp4.length < 2 then
 226                                 break
 227                         end
 228                         page = sp4.first.trim
 229                 end
 230
 231                 var e = name.html_escape
 232                 res.add "<li>"
 233                 if page != null then
 234                         res.add "<a href=\"{page.html_escape}\">"
 235                 end
 236                 if email != null then
 237                         # TODO get more things from github by using the email as a key
 238                         # "https://api.github.com/search/users?q={email}+in:email"
 239                         var md5 = email.md5.to_lower
 240                         res.add "<img src=\"https://secure.gravatar.com/avatar/{md5}?size=20&amp;default=retro\">&nbsp;"
 241                 end
 242                 res.add "{e}"
 243                 if page != null then res.add "</a>"
 244                 res.add "</li>"
 245         end
 246
 247         # Recursively generate a level in the file tree of the *content* section
 248         private fun gen_content_level(ot: OrderedTree[Object], os: Array[Object], res: Template)
 249         do
 250                 res.add "<ul>\n"
 251                 for o in os do
 252                         res.add "<li>"
 253                         if o isa MGroup then
 254                                 var d = ""
 255                                 var mdoc = o.mdoc
 256                                 if mdoc != null then d = ": {mdoc.html_synopsis.write_to_string}"
 257                                 res.add "<strong>{o.name}</strong>{d} ({o.filepath.to_s})"
 258                         else if o isa ModulePath then
 259                                 var d = ""
 260                                 var m = o.mmodule
 261                                 if m != null then
 262                                         var mdoc = m.mdoc
 263                                         if mdoc != null then d = ": {mdoc.html_synopsis.write_to_string}"
 264                                 end
 265                                 res.add "<strong>{o.name}</strong>{d} ({o.filepath.to_s})"
 266                         else
 267                                 abort
 268                         end
 269                         var subs = ot.sub.get_or_null(o)
 270                         if subs != null then gen_content_level(ot, subs, res)
 271                         res.add "</li>\n"
 272                 end
 273                 res.add "</ul>\n"
 274         end
 275
 276         # Compute information and generate a full HTML page for a package
 277         fun package_page(mpackage: MPackage): Writable
 278         do
 279                 var res = new CatalogPage("..")
 280                 var score = score[mpackage].to_f
 281                 var name = mpackage.name.html_escape
 282                 res.more_head.add """<title>{{{name}}}</title>"""
 283
 284                 res.add """
 285 <div class="content">
 286 <h1 class="package-name">{{{name}}}</h1>
 287 """
 288                 var mdoc = mpackage.mdoc_or_fallback
 289                 if mdoc != null then
 290                         score += 100.0
 291                         res.add mdoc.html_documentation
 292                         score += mdoc.content.length.score
 293                 end
 294
 295                 res.add "<h2>Content</h2>"
 296                 var ot = new OrderedTree[Object]
 297                 for g in mpackage.mgroups do
 298                         var pa = g.parent
 299                         if g.is_interesting then
 300                                 ot.add(pa, g)
 301                                 pa = g
 302                         end
 303                         for mp in g.module_paths do
 304                                 ot.add(pa, mp)
 305                         end
 306                 end
 307                 ot.sort_with(alpha_comparator)
 308                 gen_content_level(ot, ot.roots, res)
 309
 310
 311                 res.add """
 312 </div>
 313 <div class="sidebar">
 314 <ul class="box">
 315 """
 316                 var homepage = mpackage.metadata("upstream.homepage")
 317                 if homepage != null then
 318                         score += 5.0
 319                         var e = homepage.html_escape
 320                         res.add "<li><a href=\"{e}\">{e}</a></li>\n"
 321                 end
 322                 var maintainer = mpackage.metadata("package.maintainer")
 323                 if maintainer != null then
 324                         score += 5.0
 325                         add_contrib(maintainer, mpackage, res)
 326                         mpackage.maintainers.add maintainer
 327                         var projs = maint2proj[maintainer]
 328                         if not projs.has(mpackage) then projs.add mpackage
 329                 end
 330                 var license = mpackage.metadata("package.license")
 331                 if license != null then
 332                         score += 5.0
 333                         var e = license.html_escape
 334                         res.add "<li><a href=\"http://opensource.org/licenses/{e}\">{e}</a> license</li>\n"
 335                 end
 336                 res.add "</ul>\n"
 337
 338                 res.add "<h3>Source Code</h3>\n<ul class=\"box\">\n"
 339                 var browse = mpackage.metadata("upstream.browse")
 340                 if browse != null then
 341                         score += 5.0
 342                         var e = browse.html_escape
 343                         res.add "<li><a href=\"{e}\">{e}</a></li>\n"
 344                 end
 345                 var git = mpackage.metadata("upstream.git")
 346                 if git != null then
 347                         var e = git.html_escape
 348                         res.add "<li><tt>{e}</tt></li>\n"
 349                 end
 350                 var last_date = mpackage.last_date
 351                 if last_date != null then
 352                         var e = last_date.html_escape
 353                         res.add "<li>most recent commit: {e}</li>\n"
 354                 end
 355                 var first_date = mpackage.first_date
 356                 if first_date != null then
 357                         var e = first_date.html_escape
 358                         res.add "<li>oldest commit: {e}</li>\n"
 359                 end
 360                 var commits = commits[mpackage]
 361                 if commits != 0 then
 362                         res.add "<li>{commits} commits</li>\n"
 363                 end
 364                 res.add "</ul>\n"
 365
 366                 res.add "<h3>Tags</h3>\n"
 367                 var tags = mpackage.metadata("package.tags")
 368                 var ts2 = new Array[String]
 369                 var cat = null
 370                 if tags != null then
 371                         var ts = tags.split(",")
 372                         for t in ts do
 373                                 t = t.trim
 374                                 if t == "" then continue
 375                                 if cat == null then cat = t
 376                                 tag2proj[t].add mpackage
 377                                 t = t.html_escape
 378                                 ts2.add "<a href=\"../index.html#tag_{t}\">{t}</a>"
 379                         end
 380                         res.add_list(ts2, ", ", ", ")
 381                 end
 382                 if ts2.is_empty then
 383                         var t = "none"
 384                         cat = t
 385                         tag2proj[t].add mpackage
 386                         res.add "<a href=\"../index.html#tag_{t}\">{t}</a>"
 387                 end
 388                 if cat != null then cat2proj[cat].add mpackage
 389                 score += ts2.length.score
 390
 391                 if deps.has(mpackage) then
 392                         var reqs = deps[mpackage].greaters.to_a
 393                         reqs.remove(mpackage)
 394                         alpha_comparator.sort(reqs)
 395                         res.add "<h3>Requirements</h3>\n"
 396                         if reqs.is_empty then
 397                                 res.add "none"
 398                         else
 399                                 var list = new Array[String]
 400                                 for r in reqs do
 401                                         var direct = deps.has_direct_edge(mpackage, r)
 402                                         var s = "<a href=\"{r}.html\">"
 403                                         if direct then s += "<strong>"
 404                                         s += r.to_s
 405                                         if direct then s += "</strong>"
 406                                         s += "</a>"
 407                                         list.add s
 408                                 end
 409                                 res.add_list(list, ", ", " and ")
 410                         end
 411
 412                         reqs = deps[mpackage].smallers.to_a
 413                         reqs.remove(mpackage)
 414                         alpha_comparator.sort(reqs)
 415                         res.add "<h3>Clients</h3>\n"
 416                         if reqs.is_empty then
 417                                 res.add "none"
 418                         else
 419                                 var list = new Array[String]
 420                                 for r in reqs do
 421                                         var direct = deps.has_direct_edge(r, mpackage)
 422                                         var s = "<a href=\"{r}.html\">"
 423                                         if direct then s += "<strong>"
 424                                         s += r.to_s
 425                                         if direct then s += "</strong>"
 426                                         s += "</a>"
 427                                         list.add s
 428                                 end
 429                                 res.add_list(list, ", ", " and ")
 430                         end
 431
 432                         score += deps[mpackage].greaters.length.score
 433                         score += deps[mpackage].direct_greaters.length.score
 434                         score += deps[mpackage].smallers.length.score
 435                         score += deps[mpackage].direct_smallers.length.score
 436                 end
 437
 438                 var contributors = mpackage.contributors
 439                 if not contributors.is_empty then
 440                         res.add "<h3>Contributors</h3>\n<ul class=\"box\">"
 441                         for c in contributors do
 442                                 add_contrib(c, mpackage, res)
 443                         end
 444                         res.add "</ul>"
 445                 end
 446                 score += contributors.length.to_f
 447
 448                 var mmodules = 0
 449                 var mclasses = 0
 450                 var mmethods = 0
 451                 var loc = 0
 452                 for g in mpackage.mgroups do
 453                         mmodules += g.module_paths.length
 454                         for m in g.mmodules do
 455                                 var am = modelbuilder.mmodule2node(m)
 456                                 if am != null then
 457                                         var file = am.location.file
 458                                         if file != null then
 459                                                 loc += file.line_starts.length - 1
 460                                         end
 461                                 end
 462                                 for cd in m.mclassdefs do
 463                                         mclasses += 1
 464                                         for pd in cd.mpropdefs do
 465                                                 if not pd isa MMethodDef then continue
 466                                                 mmethods += 1
 467                                         end
 468                                 end
 469                         end
 470                 end
 471                 self.mmodules[mpackage] = mmodules
 472                 self.mclasses[mpackage] = mclasses
 473                 self.mmethods[mpackage] = mmethods
 474                 self.loc[mpackage] = loc
 475
 476                 #score += mmodules.score
 477                 score += mclasses.score
 478                 score += mmethods.score
 479                 score += loc.score
 480
 481                 res.add """
 482 <h3>Stats</h3>
 483 <ul class="box">
 484 <li>{{{mmodules}}} modules</li>
 485 <li>{{{mclasses}}} classes</li>
 486 <li>{{{mmethods}}} methods</li>
 487 <li>{{{loc}}} lines of code</li>
 488 </ul>
 489 """
 490
 491                 res.add """
 492 </div>
 493 """
 494                 self.score[mpackage] = score.to_i
 495
 496                 return res
 497         end
 498
 499         # Return a short HTML sequence for a package
 500         #
 501         # Intended to use in lists.
 502         fun li_package(p: MPackage): String
 503         do
 504                 var res = ""
 505                 var f = "p/{p.name}.html"
 506                 res += "<a href=\"{f}\">{p}</a>"
 507                 var d = p.mdoc_or_fallback
 508                 if d != null then res += " - {d.html_synopsis.write_to_string}"
 509                 return res
 510         end
 511
 512         # List packages by group.
 513         #
 514         # For each key of the `map` a `<h3>` is generated.
 515         # Each package is then listed.
 516         #
 517         # The list of keys is generated first to allow fast access to the correct `<h3>`.
 518         # `id_prefix` is used to give an id to the `<h3>` element.
 519         fun list_by(map: MultiHashMap[String, MPackage], id_prefix: String): Template
 520         do
 521                 var res = new Template
 522                 var keys = map.keys.to_a
 523                 alpha_comparator.sort(keys)
 524                 var list = [for x in keys do "<a href=\"#{id_prefix}{x.html_escape}\">{x.html_escape}</a>"]
 525                 res.add_list(list, ", ", " and ")
 526
 527                 for k in keys do
 528                         var projs = map[k].to_a
 529                         alpha_comparator.sort(projs)
 530                         var e = k.html_escape
 531                         res.add "<h3 id=\"{id_prefix}{e}\">{e} ({projs.length})</h3>\n<ul>\n"
 532                         for p in projs do
 533                                 res.add "<li>"
 534                                 res.add li_package(p)
 535                                 res.add "</li>"
 536                         end
 537                         res.add "</ul>"
 538                 end
 539                 return res
 540         end
 541
 542         # List the 10 best packages from `cpt`
 543         fun list_best(cpt: Counter[MPackage]): Template
 544         do
 545                 var res = new Template
 546                 res.add "<ul>"
 547                 var best = cpt.sort
 548                 for i in [1..10] do
 549                         if i > best.length then break
 550                         var p = best[best.length-i]
 551                         res.add "<li>"
 552                         res.add li_package(p)
 553                         # res.add " ({cpt[p]})"
 554                         res.add "</li>"
 555                 end
 556                 res.add "</ul>"
 557                 return res
 558         end
 559
 560         # Collect more information on a package using the `git` tool.
 561         fun git_info(mpackage: MPackage)
 562         do
 563                 var ini = mpackage.ini
 564                 if ini == null then return
 565
 566                 # TODO use real git info
 567                 #var repo = ini.get_or_null("upstream.git")
 568                 #var branch = ini.get_or_null("upstream.git.branch")
 569                 #var directory = ini.get_or_null("upstream.git.directory")
 570
 571                 var dirpath = mpackage.root.filepath
 572                 if dirpath == null then return
 573
 574                 # Collect commits info
 575                 var res = git_run("log", "--no-merges", "--follow", "--pretty=tformat:%ad;%aN <%aE>", "--", dirpath)
 576                 var contributors = new Counter[String]
 577                 var commits = res.split("\n")
 578                 if commits.not_empty and commits.last == "" then commits.pop
 579                 self.commits[mpackage] = commits.length
 580                 for l in commits do
 581                         var s = l.split_once_on(';')
 582                         if s.length != 2 or s.last == "" then continue
 583
 584                         # Collect date of last and first commit
 585                         if mpackage.last_date == null then mpackage.last_date = s.first
 586                         mpackage.first_date = s.first
 587
 588                         # Count contributors
 589                         contributors.inc(s.last)
 590                 end
 591                 for c in contributors.sort.reverse_iterator do
 592                         mpackage.contributors.add c
 593                 end
 594
 595         end
 596
 597         # Produce a HTML table containig information on the packages
 598         #
 599         # `package_page` must have been called before so that information is computed.
 600         fun table_packages(mpackages: Array[MPackage]): Template
 601         do
 602                 alpha_comparator.sort(mpackages)
 603                 var res = new Template
 604                 res.add "<table data-toggle=\"table\" data-sort-name=\"name\" data-sort-order=\"desc\" width=\"100%\">\n"
 605                 res.add "<thead><tr>\n"
 606                 res.add "<th data-field=\"name\" data-sortable=\"true\">name</th>\n"
 607                 res.add "<th data-field=\"maint\" data-sortable=\"true\">maint</th>\n"
 608                 res.add "<th data-field=\"contrib\" data-sortable=\"true\">contrib</th>\n"
 609                 if deps.not_empty then
 610                         res.add "<th data-field=\"reqs\" data-sortable=\"true\">reqs</th>\n"
 611                         res.add "<th data-field=\"dreqs\" data-sortable=\"true\">direct<br>reqs</th>\n"
 612                         res.add "<th data-field=\"cli\" data-sortable=\"true\">clients</th>\n"
 613                         res.add "<th data-field=\"dcli\" data-sortable=\"true\">direct<br>clients</th>\n"
 614                 end
 615                 res.add "<th data-field=\"mod\" data-sortable=\"true\">modules</th>\n"
 616                 res.add "<th data-field=\"cla\" data-sortable=\"true\">classes</th>\n"
 617                 res.add "<th data-field=\"met\" data-sortable=\"true\">methods</th>\n"
 618                 res.add "<th data-field=\"loc\" data-sortable=\"true\">lines</th>\n"
 619                 res.add "<th data-field=\"score\" data-sortable=\"true\">score</th>\n"
 620                 res.add "</tr></thead>"
 621                 for p in mpackages do
 622                         res.add "<tr>"
 623                         res.add "<td><a href=\"p/{p.name}.html\">{p.name}</a></td>"
 624                         var maint = "?"
 625                         if p.maintainers.not_empty then maint = p.maintainers.first
 626                         res.add "<td>{maint}</td>"
 627                         res.add "<td>{p.contributors.length}</td>"
 628                         if deps.not_empty then
 629                                 res.add "<td>{deps[p].greaters.length-1}</td>"
 630                                 res.add "<td>{deps[p].direct_greaters.length}</td>"
 631                                 res.add "<td>{deps[p].smallers.length-1}</td>"
 632                                 res.add "<td>{deps[p].direct_smallers.length}</td>"
 633                         end
 634                         res.add "<td>{mmodules[p]}</td>"
 635                         res.add "<td>{mclasses[p]}</td>"
 636                         res.add "<td>{mmethods[p]}</td>"
 637                         res.add "<td>{loc[p]}</td>"
 638                         res.add "<td>{score[p]}</td>"
 639                         res.add "</tr>\n"
 640                 end
 641                 res.add "</table>\n"
 642                 return res
 643         end
 644 end
 645
 646 # Execute a git command and return the result
 647 fun git_run(command: String...): String
 648 do
 649         # print "git {command.join(" ")}"
 650         var p = new ProcessReader("git", command...)
 651         var res = p.read_all
 652         p.close
 653         p.wait
 654         return res
 655 end
 656
 657 var model = new Model
 658 var tc = new ToolContext
 659
 660 var opt_dir = new OptionString("Directory where the HTML files are generated", "-d", "--dir")
 661 var opt_no_git = new OptionBool("Do not gather git information from the working directory", "--no-git")
 662 var opt_no_parse = new OptionBool("Do not parse nit files (no importation information)", "--no-parse")
 663 var opt_no_model = new OptionBool("Do not analyse nit files (no class/method information)", "--no-model")
 664
 665 tc.option_context.add_option(opt_dir, opt_no_git, opt_no_parse, opt_no_model)
 666
 667 tc.process_options(sys.args)
 668 tc.keep_going = true
 669
 670 var modelbuilder = new ModelBuilder(model, tc)
 671 var catalog = new Catalog(modelbuilder)
 672
 673 # Get files or groups
 674 for a in tc.option_context.rest do
 675         modelbuilder.get_mgroup(a)
 676         modelbuilder.identify_file(a)
 677 end
 678
 679 # Scan packages and compute information
 680 for p in model.mpackages do
 681         var g = p.root
 682         assert g != null
 683         modelbuilder.scan_group(g)
 684
 685         # Load the module to process importation information
 686         if opt_no_parse.value then continue
 687         modelbuilder.parse_group(g)
 688
 689         catalog.deps.add_node(p)
 690         for gg in p.mgroups do for m in gg.mmodules do
 691                 for im in m.in_importation.direct_greaters do
 692                         var ip = im.mpackage
 693                         if ip == null or ip == p then continue
 694                         catalog.deps.add_edge(p, ip)
 695                 end
 696         end
 697 end
 698
 699 if not opt_no_git.value then for p in model.mpackages do
 700         catalog.git_info(p)
 701 end
 702
 703 # Run phases to modelize classes and properties (so we can count them)
 704 if not opt_no_model.value then
 705         modelbuilder.run_phases
 706 end
 707
 708 var out = opt_dir.value or else "catalog.out"
 709 (out/"p").mkdir
 710
 711 # Generate the css (hard coded)
 712 var css = """
 713 body {
 714 margin-top:                     15px;
 715 background-color:               #f8f8f8;
 716 }
 717
 718 a {
 719 color:                          #0D8921;
 720 text-decoration:                none;
 721 }
 722
 723 a:hover {
 724 color:                          #333;
 725 text-decoration:                none;
 726 }
 727
 728 h1 {
 729 font-weight:                    bold;
 730 color:                          #0D8921;
 731 font-size:                      22px;
 732 }
 733
 734 h2 {
 735 color:                          #6C6C6C;
 736 font-size:                      18px;
 737 border-bottom:                  solid 3px #CCC;
 738 }
 739
 740 h3 {
 741 color:                          #6C6C6C;
 742 font-size:                      15px;
 743 border-bottom:                  solid 1px #CCC;
 744 }
 745
 746 ul {
 747 list-style-type:                square;
 748 }
 749
 750 dd {
 751 color:                          #6C6C6C;
 752 margin-top:                     1em;
 753 margin-bottom:                  1em;
 754 }
 755
 756 pre {
 757 border:                         1px solid #CCC;
 758 font-family:                    Monospace;
 759 color:                          #2d5003;
 760 background-color:               rgb(250, 250, 250);
 761 }
 762
 763 code {
 764 font-family:                    Monospace;
 765 color:                          #2d5003;
 766 }
 767
 768 footer {
 769 margin-top:                     20px;
 770 }
 771
 772 .container {
 773 margin:                         0 auto;
 774 padding:                        0 20px;
 775 }
 776
 777 .content {
 778 float:                          left;
 779 margin-top:                     40px;
 780 width:                          65%;
 781 }
 782
 783 .sidebar {
 784 float:                          right;
 785 margin-top:                     40px;
 786 width:                          30%
 787 }
 788
 789 .sidebar h3 {
 790 color:                          #0D8921;
 791 font-size:                      18px;
 792 border-bottom:                  0px;
 793 }
 794
 795 .box {
 796 margin:                         0;
 797 padding:                        0;
 798 }
 799
 800 .box li {
 801 line-height:                    2.5;
 802 white-space:                    nowrap;
 803 overflow:                       hidden;
 804 text-overflow:                  ellipsis;
 805 padding-right:                  10px;
 806 border-bottom:                  1px solid rgba(0,0,0,0.2);
 807 }
 808 """
 809 css.write_to_file(out/"style.css")
 810
 811 # PAGES
 812
 813 for p in model.mpackages do
 814         # print p
 815         var f = "p/{p.name}.html"
 816         catalog.package_page(p).write_to_file(out/f)
 817 end
 818
 819 # INDEX
 820
 821 var index = new CatalogPage("")
 822 index.more_head.add "<title>Packages in Nit</title>"
 823
 824 index.add """
 825 <div class="content">
 826 <h1>Packages in Nit</h1>
 827 """
 828
 829 index.add "<h2>Highlighted Packages</h2>\n"
 830 index.add catalog.list_best(catalog.score)
 831
 832 if catalog.deps.not_empty then
 833         index.add "<h2>Most Required</h2>\n"
 834         var reqs = new Counter[MPackage]
 835         for p in model.mpackages do
 836                 reqs[p] = catalog.deps[p].smallers.length - 1
 837         end
 838         index.add catalog.list_best(reqs)
 839 end
 840
 841 index.add "<h2>By First Tag</h2>\n"
 842 index.add catalog.list_by(catalog.cat2proj, "cat_")
 843
 844 index.add "<h2>By Any Tag</h2>\n"
 845 index.add catalog.list_by(catalog.tag2proj, "tag_")
 846
 847 index.add """
 848 </div>
 849 <div class="sidebar">
 850 <h3>Stats</h3>
 851 <ul class="box">
 852 <li>{{{model.mpackages.length}}} packages</li>
 853 <li>{{{catalog.maint2proj.length}}} maintainers</li>
 854 <li>{{{catalog.contrib2proj.length}}} contributors</li>
 855 <li>{{{catalog.tag2proj.length}}} tags</li>
 856 <li>{{{catalog.mmodules.sum}}} modules</li>
 857 <li>{{{catalog.mclasses.sum}}} classes</li>
 858 <li>{{{catalog.mmethods.sum}}} methods</li>
 859 <li>{{{catalog.loc.sum}}} lines of code</li>
 860 </ul>
 861 </div>
 862 """
 863
 864 index.write_to_file(out/"index.html")
 865
 866 # PEOPLE
 867
 868 var page = new CatalogPage("")
 869 page.more_head.add "<title>People of Nit</title>"
 870 page.add """<div class="content">\n<h1>People of Nit</h1>\n"""
 871 page.add "<h2>By Maintainer</h2>\n"
 872 page.add catalog.list_by(catalog.maint2proj, "maint_")
 873 page.add "<h2>By Contributor</h2>\n"
 874 page.add catalog.list_by(catalog.contrib2proj, "contrib_")
 875 page.add "</div>\n"
 876 page.write_to_file(out/"people.html")
 877
 878 # TABLE
 879
 880 page = new CatalogPage("")
 881 page.more_head.add "<title>Projets of Nit</title>"
 882 page.add """<div class="content">\n<h1>People of Nit</h1>\n"""
 883 page.add "<h2>Table of Projets</h2>\n"
 884 page.add catalog.table_packages(model.mpackages)
 885 page.add "</div>\n"
 886 page.write_to_file(out/"table.html")