src/separate_erasure_compiler.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Separate compilation of a Nit program with generic type erasure
  16 module separate_erasure_compiler
  17
  18 intrude import separate_compiler
  19
  20 # Add separate erased compiler specific options
  21 redef class ToolContext
  22         # --erasure
  23         var opt_erasure: OptionBool = new OptionBool("Erase generic types", "--erasure")
  24         # --no-check-erasure-cast
  25         var opt_no_check_erasure_cast: OptionBool = new OptionBool("Disable implicit casts on unsafe return with erasure-typing policy (dangerous)", "--no-check-erasure-cast")
  26
  27         redef init
  28         do
  29                 super
  30                 self.option_context.add_option(self.opt_erasure, self.opt_no_check_erasure_cast)
  31         end
  32 end
  33
  34 redef class ModelBuilder
  35         fun run_separate_erasure_compiler(mainmodule: MModule, runtime_type_analysis: nullable RapidTypeAnalysis)
  36         do
  37                 var time0 = get_time
  38                 self.toolcontext.info("*** GENERATING C ***", 1)
  39
  40                 var compiler = new SeparateErasureCompiler(mainmodule, self, runtime_type_analysis)
  41                 compiler.compile_header
  42
  43                 # compile class structures
  44                 self.toolcontext.info("Property coloring", 2)
  45                 compiler.new_file("{mainmodule.name}.tables")
  46                 compiler.do_property_coloring
  47                 for m in mainmodule.in_importation.greaters do
  48                         for mclass in m.intro_mclasses do
  49                                 compiler.compile_class_to_c(mclass)
  50                         end
  51                 end
  52                 compiler.compile_color_consts(compiler.vt_layout.pos)
  53
  54                 # The main function of the C
  55                 compiler.new_file("{mainmodule.name}.main")
  56                 compiler.compile_main_function
  57
  58                 # compile methods
  59                 for m in mainmodule.in_importation.greaters do
  60                         self.toolcontext.info("Generate C for module {m}", 2)
  61                         compiler.new_file("{m.name}.sep")
  62                         compiler.compile_module_to_c(m)
  63                 end
  64
  65                 compiler.display_stats
  66
  67                 var time1 = get_time
  68                 self.toolcontext.info("*** END GENERATING C: {time1-time0} ***", 2)
  69                 write_and_make(compiler)
  70         end
  71 end
  72
  73 class SeparateErasureCompiler
  74         super SeparateCompiler
  75
  76         private var class_layout: nullable Layout[MClass]
  77         protected var vt_layout: nullable Layout[MVirtualTypeProp]
  78
  79         init(mainmodule: MModule, mmbuilder: ModelBuilder, runtime_type_analysis: nullable RapidTypeAnalysis) do
  80                 super
  81
  82                 var mclasses = new HashSet[MClass].from(mmbuilder.model.mclasses)
  83
  84                 var layout_builder: TypingLayoutBuilder[MClass]
  85                 var class_colorer = new MClassColorer(mainmodule)
  86                 if modelbuilder.toolcontext.opt_phmod_typing.value then
  87                         layout_builder = new MClassHasher(new PHModOperator, mainmodule)
  88                         class_colorer.build_layout(mclasses)
  89                 else if modelbuilder.toolcontext.opt_phand_typing.value then
  90                         layout_builder = new MClassHasher(new PHAndOperator, mainmodule)
  91                         class_colorer.build_layout(mclasses)
  92                 else if modelbuilder.toolcontext.opt_bm_typing.value then
  93                         layout_builder = new MClassBMizer(mainmodule)
  94                         class_colorer.build_layout(mclasses)
  95                 else
  96                         layout_builder = class_colorer
  97                 end
  98                 self.class_layout = layout_builder.build_layout(mclasses)
  99                 self.class_tables = self.build_class_typing_tables(mclasses)
 100
 101                 # lookup vt to build layout with
 102                 var vts = new HashMap[MClass, Set[MVirtualTypeProp]]
 103                 for mclass in mclasses do
 104                         vts[mclass] = new HashSet[MVirtualTypeProp]
 105                         for mprop in self.mainmodule.properties(mclass) do
 106                                 if mprop isa MVirtualTypeProp then
 107                                         vts[mclass].add(mprop)
 108                                 end
 109                         end
 110                 end
 111
 112                 # vt coloration
 113                 var vt_coloring = new MPropertyColorer[MVirtualTypeProp](mainmodule, class_colorer)
 114                 var vt_layout = vt_coloring.build_layout(vts)
 115                 self.vt_tables = build_vt_tables(mclasses, vt_layout)
 116                 self.vt_layout = vt_layout
 117         end
 118
 119         fun build_vt_tables(mclasses: Set[MClass], layout: Layout[MProperty]): Map[MClass, Array[nullable MPropDef]] do
 120                 var tables = new HashMap[MClass, Array[nullable MPropDef]]
 121                 for mclass in mclasses do
 122                         var table = new Array[nullable MPropDef]
 123                         # first, fill table from parents by reverse linearization order
 124                         var parents = new Array[MClass]
 125                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 126                                 parents = mclass.in_hierarchy(mainmodule).greaters.to_a
 127                                 self.mainmodule.linearize_mclasses(parents)
 128                         end
 129                         for parent in parents do
 130                                 if parent == mclass then continue
 131                                 for mproperty in self.mainmodule.properties(parent) do
 132                                         if not mproperty isa MVirtualTypeProp then continue
 133                                         var color = layout.pos[mproperty]
 134                                         if table.length <= color then
 135                                                 for i in [table.length .. color[ do
 136                                                         table[i] = null
 137                                                 end
 138                                         end
 139                                         for mpropdef in mproperty.mpropdefs do
 140                                                 if mpropdef.mclassdef.mclass == parent then
 141                                                         table[color] = mpropdef
 142                                                 end
 143                                         end
 144                                 end
 145                         end
 146
 147                         # then override with local properties
 148                         for mproperty in self.mainmodule.properties(mclass) do
 149                                 if not mproperty isa MVirtualTypeProp then continue
 150                                 var color = layout.pos[mproperty]
 151                                 if table.length <= color then
 152                                         for i in [table.length .. color[ do
 153                                                 table[i] = null
 154                                         end
 155                                 end
 156                                 for mpropdef in mproperty.mpropdefs do
 157                                         if mpropdef.mclassdef.mclass == mclass then
 158                                                 table[color] = mpropdef
 159                                         end
 160                                 end
 161                         end
 162                         tables[mclass] = table
 163                 end
 164                 return tables
 165         end
 166
 167         # Build class tables
 168         fun build_class_typing_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MClass]] do
 169                 var tables = new HashMap[MClass, Array[nullable MClass]]
 170                 var layout = self.class_layout
 171                 for mclass in mclasses do
 172                         var table = new Array[nullable MClass]
 173                         var supers = new Array[MClass]
 174                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 175                                 supers = mclass.in_hierarchy(mainmodule).greaters.to_a
 176                         end
 177                         for sup in supers do
 178                                 var color: Int
 179                                 if layout isa PHLayout[MClass, MClass] then
 180                                         color = layout.hashes[mclass][sup]
 181                                 else
 182                                         color = layout.pos[sup]
 183                                 end
 184                                 if table.length <= color then
 185                                         for i in [table.length .. color[ do
 186                                                 table[i] = null
 187                                         end
 188                                 end
 189                                 table[color] = sup
 190                         end
 191                         tables[mclass] = table
 192                 end
 193                 return tables
 194         end
 195
 196         redef fun compile_header_structs do
 197                 self.header.add_decl("typedef void(*nitmethod_t)(void); /* general C type representing a Nit method. */")
 198                 self.compile_header_attribute_structs
 199                 self.header.add_decl("struct class \{ int id; const char *name; int box_kind; int color; const struct vts_table *vts_table; const struct type_table *type_table; nitmethod_t vft[]; \}; /* general C type representing a Nit class. */")
 200                 self.header.add_decl("struct type_table \{ int size; int table[]; \}; /* colorized type table. */")
 201                 self.header.add_decl("struct vts_entry \{ short int is_nullable; const struct class *class; \}; /* link (nullable or not) between the vts and is bound. */")
 202
 203                 if self.vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 204                         self.header.add_decl("struct vts_table \{ int mask; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 205                 else
 206                         self.header.add_decl("struct vts_table \{ int dummy; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 207                 end
 208
 209                 if modelbuilder.toolcontext.opt_phmod_typing.value then
 210                         self.header.add_decl("#define HASH(mask, id) ((mask)%(id))")
 211                 else if modelbuilder.toolcontext.opt_phand_typing.value then
 212                         self.header.add_decl("#define HASH(mask, id) ((mask)&(id))")
 213                 end
 214
 215                 self.header.add_decl("typedef struct instance \{ const struct class *class; nitattribute_t attrs[1]; \} val; /* general C type representing a Nit instance. */")
 216         end
 217
 218         redef fun compile_class_to_c(mclass: MClass)
 219         do
 220                 var mtype = mclass.intro.bound_mtype
 221                 var c_name = mclass.c_name
 222
 223                 var vft = self.method_tables[mclass]
 224                 var attrs = self.attr_tables[mclass]
 225                 var class_table = self.class_tables[mclass]
 226                 var v = self.new_visitor
 227
 228                 v.add_decl("/* runtime class {c_name} */")
 229
 230                 self.provide_declaration("class_{c_name}", "extern const struct class class_{c_name};")
 231                 v.add_decl("extern const struct type_table type_table_{c_name};")
 232
 233                 # Build class vft
 234                 v.add_decl("const struct class class_{c_name} = \{")
 235                 v.add_decl("{self.class_layout.ids[mclass]},")
 236                 v.add_decl("\"{mclass.name}\", /* class_name_string */")
 237                 v.add_decl("{self.box_kind_of(mclass)}, /* box_kind */")
 238                 var layout = self.class_layout
 239                 if layout isa PHLayout[MClass, MClass] then
 240                         v.add_decl("{layout.masks[mclass]},")
 241                 else
 242                         v.add_decl("{layout.pos[mclass]},")
 243                 end
 244                 if build_class_vts_table(mclass) then
 245                         v.require_declaration("vts_table_{c_name}")
 246                         v.add_decl("&vts_table_{c_name},")
 247                 else
 248                         v.add_decl("NULL,")
 249                 end
 250                 v.add_decl("&type_table_{c_name},")
 251                 v.add_decl("\{")
 252                 for i in [0 .. vft.length[ do
 253                         var mpropdef = vft[i]
 254                         if mpropdef == null then
 255                                 v.add_decl("NULL, /* empty */")
 256                         else
 257                                 if true or mpropdef.mclassdef.bound_mtype.ctype != "val*" then
 258                                         v.require_declaration("VIRTUAL_{mpropdef.c_name}")
 259                                         v.add_decl("(nitmethod_t)VIRTUAL_{mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 260                                 else
 261                                         v.require_declaration("{mpropdef.c_name}")
 262                                         v.add_decl("(nitmethod_t){mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 263                                 end
 264                         end
 265                 end
 266                 v.add_decl("\}")
 267                 v.add_decl("\};")
 268
 269                 # Build class type table
 270
 271                 v.add_decl("const struct type_table type_table_{c_name} = \{")
 272                 v.add_decl("{class_table.length},")
 273                 v.add_decl("\{")
 274                 for msuper in class_table do
 275                         if msuper == null then
 276                                 v.add_decl("-1, /* empty */")
 277                         else
 278                                 v.add_decl("{self.class_layout.ids[msuper]}, /* {msuper} */")
 279                         end
 280                 end
 281                 v.add_decl("\}")
 282                 v.add_decl("\};")
 283
 284                 if mtype.ctype != "val*" then
 285                         #Build instance struct
 286                         self.header.add_decl("struct instance_{c_name} \{")
 287                         self.header.add_decl("const struct class *class;")
 288                         self.header.add_decl("{mtype.ctype} value;")
 289                         self.header.add_decl("\};")
 290
 291                         #Build BOX
 292                         self.header.add_decl("val* BOX_{c_name}({mtype.ctype});")
 293                         v.add_decl("/* allocate {mtype} */")
 294                         v.add_decl("val* BOX_{mtype.c_name}({mtype.ctype} value) \{")
 295                         v.add("struct instance_{c_name}*res = nit_alloc(sizeof(struct instance_{c_name}));")
 296                         v.require_declaration("class_{c_name}")
 297                         v.add("res->class = &class_{c_name};")
 298                         v.add("res->value = value;")
 299                         v.add("return (val*)res;")
 300                         v.add("\}")
 301                         return
 302                 else if mclass.name == "NativeArray" then
 303                         #Build instance struct
 304                         self.header.add_decl("struct instance_{c_name} \{")
 305                         self.header.add_decl("const struct class *class;")
 306                         self.header.add_decl("val* values[];")
 307                         self.header.add_decl("\};")
 308
 309                         #Build NEW
 310                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(int length);")
 311                         v.add_decl("/* allocate {mtype} */")
 312                         v.add_decl("{mtype.ctype} NEW_{c_name}(int length) \{")
 313                         var res = v.new_named_var(mtype, "self")
 314                         res.is_exact = true
 315                         var mtype_elt = mtype.arguments.first
 316                         v.add("{res} = nit_alloc(sizeof(struct instance_{c_name}) + length*sizeof({mtype_elt.ctype}));")
 317                         v.require_declaration("class_{c_name}")
 318                         v.add("{res}->class = &class_{c_name};")
 319                         v.add("return {res};")
 320                         v.add("\}")
 321                         return
 322                 end
 323
 324                 #Build NEW
 325                 self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(void);")
 326                 v.add_decl("/* allocate {mtype} */")
 327                 v.add_decl("{mtype.ctype} NEW_{c_name}(void) \{")
 328                 var res = v.new_named_var(mtype, "self")
 329                 res.is_exact = true
 330                 v.add("{res} = nit_alloc(sizeof(struct instance) + {attrs.length}*sizeof(nitattribute_t));")
 331                 v.require_declaration("class_{c_name}")
 332                 v.add("{res}->class = &class_{c_name};")
 333                 self.generate_init_attr(v, res, mtype)
 334                 v.add("return {res};")
 335                 v.add("\}")
 336         end
 337
 338         private fun build_class_vts_table(mclass: MClass): Bool do
 339                 if self.vt_tables[mclass].is_empty then return false
 340
 341                 self.provide_declaration("vts_table_{mclass.c_name}", "extern const struct vts_table vts_table_{mclass.c_name};")
 342
 343                 var v = new_visitor
 344                 v.add_decl("const struct vts_table vts_table_{mclass.c_name} = \{")
 345                 if self.vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 346                         #TODO redo this when PHPropertyLayoutBuilder will be implemented
 347                         #v.add_decl("{vt_masks[mclass]},")
 348                 else
 349                         v.add_decl("0, /* dummy */")
 350                 end
 351                 v.add_decl("\{")
 352
 353                 for vt in self.vt_tables[mclass] do
 354                         if vt == null then
 355                                 v.add_decl("\{-1, NULL\}, /* empty */")
 356                         else
 357                                 var is_null = 0
 358                                 var bound = retrieve_vt_bound(mclass.intro.bound_mtype, vt.as(MVirtualTypeDef).bound)
 359                                 while bound isa MNullableType do
 360                                         bound = retrieve_vt_bound(mclass.intro.bound_mtype, bound.mtype)
 361                                         is_null = 1
 362                                 end
 363                                 var vtclass = bound.as(MClassType).mclass
 364                                 v.require_declaration("class_{vtclass.c_name}")
 365                                 v.add_decl("\{{is_null}, &class_{vtclass.c_name}\}, /* {vt} */")
 366                         end
 367                 end
 368                 v.add_decl("\},")
 369                 v.add_decl("\};")
 370                 return true
 371         end
 372
 373         private fun retrieve_vt_bound(anchor: MClassType, mtype: nullable MType): MType do
 374                 if mtype == null then
 375                         print "NOT YET IMPLEMENTED: retrieve_vt_bound on null"
 376                         abort
 377                 end
 378                 if mtype isa MVirtualType then
 379                         return mtype.anchor_to(mainmodule, anchor)
 380                 else if mtype isa MParameterType then
 381                         return mtype.anchor_to(mainmodule, anchor)
 382                 else
 383                         return mtype
 384                 end
 385         end
 386
 387         redef fun new_visitor do return new SeparateErasureCompilerVisitor(self)
 388
 389         # Stats
 390
 391         private var class_tables: Map[MClass, Array[nullable MClass]]
 392         private var vt_tables: Map[MClass, Array[nullable MPropDef]]
 393
 394         redef fun display_sizes
 395         do
 396                 print "# size of subtyping tables"
 397                 print "\ttotal \tholes"
 398                 var total = 0
 399                 var holes = 0
 400                 for t, table in class_tables do
 401                         total += table.length
 402                         for e in table do if e == null then holes += 1
 403                 end
 404                 print "\t{total}\t{holes}"
 405
 406                 print "# size of resolution tables"
 407                 print "\ttotal \tholes"
 408                 total = 0
 409                 holes = 0
 410                 for t, table in vt_tables do
 411                         total += table.length
 412                         for e in table do if e == null then holes += 1
 413                 end
 414                 print "\t{total}\t{holes}"
 415
 416                 print "# size of methods tables"
 417                 print "\ttotal \tholes"
 418                 total = 0
 419                 holes = 0
 420                 for t, table in method_tables do
 421                         total += table.length
 422                         for e in table do if e == null then holes += 1
 423                 end
 424                 print "\t{total}\t{holes}"
 425
 426                 print "# size of attributes tables"
 427                 print "\ttotal \tholes"
 428                 total = 0
 429                 holes = 0
 430                 for t, table in attr_tables do
 431                         total += table.length
 432                         for e in table do if e == null then holes += 1
 433                 end
 434                 print "\t{total}\t{holes}"
 435         end
 436 end
 437
 438 class SeparateErasureCompilerVisitor
 439         super SeparateCompilerVisitor
 440
 441         redef fun compile_callsite(callsite, arguments)
 442         do
 443                 var res = super
 444                 if callsite.erasure_cast and not self.compiler.as(SeparateErasureCompiler).modelbuilder.toolcontext.opt_no_check_erasure_cast.value then
 445                         assert res != null
 446                         var mtype = callsite.msignature.return_mtype
 447                         assert mtype != null
 448                         self.add("/* Erasure cast for return {res} isa {mtype} */")
 449                         var cond = self.type_test(res, mtype, "erasure")
 450                         self.add("if (!{cond}) \{")
 451                         #var x = self.class_name_string(res)
 452                         #var y = self.class_name_string(arguments.first)
 453                         #self.add("fprintf(stderr, \"Erasure cast: expected {mtype} (self is %s), got %s for {res}\\n\", {y}, {x});")
 454                         self.add_abort("Cast failed")
 455                         self.add("\}")
 456                 end
 457                 return res
 458         end
 459
 460         redef fun init_instance(mtype)
 461         do
 462                 self.require_declaration("NEW_{mtype.mclass.c_name}")
 463                 return self.new_expr("NEW_{mtype.mclass.c_name}()", mtype)
 464         end
 465
 466         redef fun type_test(value, mtype, tag)
 467         do
 468                 self.add("/* type test for {value.inspect} isa {mtype} */")
 469
 470                 var res = self.new_var(bool_type)
 471
 472                 var cltype = self.get_name("cltype")
 473                 self.add_decl("int {cltype};")
 474                 var idtype = self.get_name("idtype")
 475                 self.add_decl("int {idtype};")
 476
 477                 var maybe_null = self.maybe_null(value)
 478                 var accept_null = "0"
 479                 if mtype isa MNullableType then
 480                         mtype = mtype.mtype
 481                         accept_null = "1"
 482                 end
 483                 if mtype isa MParameterType then
 484                         # Here we get the bound of the the formal type (eh, erasure...)
 485                         mtype = mtype.resolve_for(self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.mmodule, false)
 486                         if mtype isa MNullableType then
 487                                 mtype = mtype.mtype
 488                                 accept_null = "1"
 489                         end
 490                 end
 491
 492                 if value.mcasttype.is_subtype(self.frame.mpropdef.mclassdef.mmodule, self.frame.mpropdef.mclassdef.bound_mtype, mtype) then
 493                         self.add("{res} = 1; /* easy {value.inspect} isa {mtype}*/")
 494                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 495                                 self.compiler.count_type_test_skipped[tag] += 1
 496                                 self.add("count_type_test_skipped_{tag}++;")
 497                         end
 498                         return res
 499                 end
 500
 501                 var class_ptr
 502                 var type_table
 503                 if value.mtype.ctype == "val*" then
 504                         class_ptr = "{value}->class->"
 505                 else
 506                         var mclass = value.mtype.as(MClassType).mclass
 507                         self.require_declaration("class_{mclass.c_name}")
 508                         class_ptr = "class_{mclass.c_name}."
 509                 end
 510
 511                 if mtype isa MClassType then
 512                         self.require_declaration("class_{mtype.mclass.c_name}")
 513                         self.add("{cltype} = class_{mtype.mclass.c_name}.color;")
 514                         self.add("{idtype} = class_{mtype.mclass.c_name}.id;")
 515                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 516                                 self.compiler.count_type_test_resolved[tag] += 1
 517                                 self.add("count_type_test_resolved_{tag}++;")
 518                         end
 519                 else if mtype isa MVirtualType then
 520                         var recv = self.frame.arguments.first
 521                         var recv_ptr
 522                         if recv.mtype.ctype == "val*" then
 523                                 recv_ptr = "{recv}->class->"
 524                         else
 525                                 var mclass = recv.mtype.as(MClassType).mclass
 526                                 self.require_declaration("class_{mclass.c_name}")
 527                                 recv_ptr = "class_{mclass.c_name}."
 528                         end
 529                         var entry = self.get_name("entry")
 530                         self.add("struct vts_entry {entry};")
 531                         self.require_declaration(mtype.mproperty.const_color)
 532                         if self.compiler.as(SeparateErasureCompiler).vt_layout isa PHLayout[MClass, MVirtualTypeProp] then
 533                                 self.add("{entry} = {recv_ptr}vts_table->vts[HASH({recv_ptr}vts_table->mask, {mtype.mproperty.const_color})];")
 534                         else
 535                                 self.add("{entry} = {recv_ptr}vts_table->vts[{mtype.mproperty.const_color}];")
 536                         end
 537                         self.add("{cltype} = {entry}.class->color;")
 538                         self.add("{idtype} = {entry}.class->id;")
 539                         if maybe_null and accept_null == "0" then
 540                                 var is_nullable = self.get_name("is_nullable")
 541                                 self.add_decl("short int {is_nullable};")
 542                                 self.add("{is_nullable} = {entry}.is_nullable;")
 543                                 accept_null = is_nullable.to_s
 544                         end
 545                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 546                                 self.compiler.count_type_test_unresolved[tag] += 1
 547                                 self.add("count_type_test_unresolved_{tag}++;")
 548                         end
 549                 else
 550                         self.debug("type_test({value.inspect}, {mtype})")
 551                         abort
 552                 end
 553
 554                 # check color is in table
 555                 if maybe_null then
 556                         self.add("if({value} == NULL) \{")
 557                         self.add("{res} = {accept_null};")
 558                         self.add("\} else \{")
 559                 end
 560                 if self.compiler.as(SeparateErasureCompiler).class_layout isa PHLayout[MClass, MClass] then
 561                         self.add("{cltype} = HASH({class_ptr}color, {idtype});")
 562                 end
 563                 self.add("if({cltype} >= {class_ptr}type_table->size) \{")
 564                 self.add("{res} = 0;")
 565                 self.add("\} else \{")
 566                 self.add("{res} = {class_ptr}type_table->table[{cltype}] == {idtype};")
 567                 self.add("\}")
 568                 if maybe_null then
 569                         self.add("\}")
 570                 end
 571
 572                 return res
 573         end
 574
 575         redef fun class_name_string(value)
 576         do
 577                 var res = self.get_name("var_class_name")
 578                 self.add_decl("const char* {res};")
 579                 if value.mtype.ctype == "val*" then
 580                         self.add "{res} = {value} == NULL ? \"null\" : {value}->class->name;"
 581                 else
 582                         self.require_declaration("class_{value.mtype.c_name}")
 583                         self.add "{res} = class_{value.mtype.c_name}.name;"
 584                 end
 585                 return res
 586         end
 587
 588         redef fun array_instance(array, elttype)
 589         do
 590                 var nclass = self.get_class("NativeArray")
 591                 elttype = self.anchor(elttype)
 592                 var arraytype = self.get_class("Array").get_mtype([elttype])
 593                 var res = self.init_instance(arraytype)
 594                 self.add("\{ /* {res} = array_instance Array[{elttype}] */")
 595                 var nat = self.new_var(self.get_class("NativeArray").get_mtype([elttype]))
 596                 nat.is_exact = true
 597                 self.require_declaration("NEW_{nclass.c_name}")
 598                 self.add("{nat} = NEW_{nclass.c_name}({array.length});")
 599                 for i in [0..array.length[ do
 600                         var r = self.autobox(array[i], self.object_type)
 601                         self.add("((struct instance_{nclass.c_name}*){nat})->values[{i}] = (val*) {r};")
 602                 end
 603                 var length = self.int_instance(array.length)
 604                 self.send(self.get_property("with_native", arraytype), [res, nat, length])
 605                 self.add("\}")
 606                 return res
 607         end
 608
 609         redef fun calloc_array(ret_type, arguments)
 610         do
 611                 var ret = ret_type.as(MClassType)
 612                 self.require_declaration("NEW_{ret.mclass.c_name}")
 613                 self.ret(self.new_expr("NEW_{ret.mclass.c_name}({arguments[1]})", ret_type))
 614         end
 615 end