src/frontend/no_warning.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Fill toolcontext information about blacklisting of warnings.
  16 module no_warning
  17
  18 import modelbuilder
  19 private import literal
  20
  21 redef class ToolContext
  22         # The phase should be executed before any warning on the module is processed.
  23         var no_warning_phase: Phase = new NoWarningPhase(self, [literal_phase])
  24 end
  25
  26 private class NoWarningPhase
  27         super Phase
  28
  29         redef fun process_nmodule(nmodule)
  30         do
  31                 # Get the mmodule
  32                 var mmodule = nmodule.mmodule
  33                 assert mmodule != null
  34
  35                 # If no decl block then quit
  36                 var nmoduledecl = nmodule.n_moduledecl
  37                 if nmoduledecl == null then return
  38
  39                 var modelbuilder = toolcontext.modelbuilder
  40
  41                 # Get all the new annotations
  42                 var name = "no_warning"
  43                 var annots = nmoduledecl.get_annotations(name)
  44
  45                 if annots.is_empty then return
  46
  47                 var source = nmodule.location.file
  48                 if source == null then
  49                         modelbuilder.warning(annots.first, "file-less-module", "Warning: annotation `{name}` does not currently work on file-less modules.")
  50                         return
  51                 end
  52
  53                 for annot in annots do
  54                         var args = annot.n_args
  55                         if args.is_empty then
  56                                 modelbuilder.error(annot, "Annotation error: `{name}` needs a list of warnings. Use `\"all\"` to disable all warnings.")
  57                                 continue
  58                         end
  59                         for arg in args do
  60                                 var tag = arg.as_string
  61                                 if tag == null then
  62                                         modelbuilder.error(arg, "Annotation error: `{name}` expects String as arguments.")
  63                                         continue
  64                                 end
  65
  66                                 toolcontext.warning_blacklist[source].add(tag)
  67                         end
  68                 end
  69         end
  70 end