src/nitlight.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Tool that produces highlighting for Nit programs
  16 module nitlight
  17
  18 import highlight
  19
  20 var toolcontext = new ToolContext
  21
  22 var opt_fragment = new OptionBool("Omit document header and footer", "-f", "--fragment")
  23 var opt_first_line = new OptionInt("Start the source file at this line (default: 1)", 0, "--first-line")
  24 var opt_last_line = new OptionInt("End the source file at this line (default: to the end)", 0, "--last-line")
  25 var opt_dir = new OptionString("Output html files in a specific directory (required if more than one module)", "-d", "--dir")
  26 var opt_full = new OptionBool("Process also imported modules", "--full")
  27 var opt_ast = new OptionBool("Generate specific HTML elements for each Node of the AST", "--ast")
  28 toolcontext.option_context.add_option(opt_fragment, opt_first_line, opt_last_line, opt_dir, opt_full)
  29 toolcontext.tooldescription = "Usage: nitlight [OPTION]... <file.nit>...\nGenerates HTML of highlited code from Nit source files."
  30
  31 var model = new Model
  32 var modelbuilder = new ModelBuilder(model, toolcontext)
  33
  34 toolcontext.process_options(args)
  35 var args = toolcontext.option_context.rest
  36
  37 var mmodules = modelbuilder.parse(args)
  38 modelbuilder.run_phases
  39
  40 if opt_full.value then mmodules = model.mmodules
  41
  42 var dir = opt_dir.value
  43 if dir != null then
  44         dir.mkdir
  45 else if mmodules.length > 1 then
  46         print "More than one module to render, use option -d"
  47         return
  48 end
  49
  50 for mm in mmodules do
  51         if dir != null then toolcontext.info("write {dir}/{mm.name}.html", 1)
  52
  53         var v = new HighlightVisitor
  54
  55         if opt_first_line.value != 0 then v.first_line = opt_first_line.value
  56         if opt_last_line.value != 0 then v.last_line = opt_last_line.value
  57         if opt_ast.value then v.with_ast = true
  58         var page = null
  59         if not opt_fragment.value then
  60                 page = new HTMLTag("html")
  61                 page.add_raw_html """<head>
  62                 <meta charset="utf-8">"""
  63                 if dir == null then
  64                         page.add_raw_html """
  65                         <style type="text/css">
  66                         {{{v.css_content}}}
  67                         </style>
  68                         """
  69                 else
  70                         page.add_raw_html """<link rel="stylesheet" type="text/css" href="style.css" />"""
  71                 end
  72                 page.add_raw_html "</head><body><pre>"
  73         end
  74         var m = modelbuilder.mmodule2nmodule[mm]
  75         v.enter_visit(m)
  76         if not opt_fragment.value then
  77                 page.add(v.html)
  78                 page.add_raw_html "</pre></body>"
  79         else
  80                 page = v.html
  81         end
  82
  83         if dir != null then
  84                 page.write_to_file("{dir}/{mm.name}.html")
  85         else
  86                 page.write_to(stdout)
  87         end
  88 end
  89
  90 if dir != null then
  91         toolcontext.info("write {dir}/index.html", 1)
  92
  93         var page = new HTMLTag("html")
  94         page.add_raw_html """<head>
  95         <meta charset="utf-8">
  96         </head><body><ul>
  97         """
  98         for mm in mmodules do
  99                 var n = new HTMLTag("li")
 100                 var n2 = new HTMLTag("a")
 101                 page.add n
 102                 n.add n2
 103                 n2.attr("href", "{mm.name}.html")
 104                 n2.text(mm.name)
 105         end
 106         page.add_raw_html "</li></body>"
 107         page.write_to_file("{dir}/index.html")
 108
 109         var v = new HighlightVisitor
 110         toolcontext.info("write {dir}/style.css", 1)
 111         var f = new OFStream.open("{dir}/style.css")
 112         f.write v.css_content
 113         f.close
 114 end