lib/postgresql/postgres.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2016 Guilherme Mansur<guilhermerpmansur@gmail.com>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Services to manipulate a Postgres database
  18 #
  19 # For more information, refer to the documentation of http://www.postgresql.org/docs/manuals/
  20 #
  21 # ### Usage example
  22 #
  23 # ~~~
  24 # class Animal
  25 #   var name: String
  26 #   var kind: String
  27 #   var age: Int
  28 # end
  29 #
  30 # var animals = new Array[Animal]
  31 # var dog = new Animal("Lassy", "dog", 10)
  32 # var cat = new Animal("Garfield", "cat", 3)
  33 # var turtle = new Animal("George", "turtle", 123)
  34 #
  35 # animals.add(dog)
  36 # animals.add(cat)
  37 # animals.add(turtle)
  38 #
  39 # var db = new Postgres.open("dbname=postgres")
  40 #
  41 # assert db_is_open: not db.is_closed
  42 # assert create_table: db.create_table("IF NOT EXISTS animals (aname TEXT PRIMARY KEY, kind TEXT NOT NULL, age INT NOT NULL)") else print db.error
  43 #
  44 # for animal in animals do
  45 #   assert insert: db.insert("INTO animals VALUES('{animal.name}', '{animal.kind}', {animal.age})") else print db.error
  46 # end
  47 #
  48 # var result = db.raw_execute("SELECT * FROM animals")
  49 # assert  result.is_ok
  50 # assert drop_table: db.execute("DROP TABLE animals")
  51 # db.finish
  52 # assert db_is_closed: db.is_closed
  53 # ~~~
  54 module postgres
  55
  56 private import native_postgres
  57
  58 # A connection to a Postgres database
  59 class Postgres
  60   private var native_connection: NativePostgres
  61
  62   var is_closed = true
  63
  64   # Open the connnection with the database using the `conninfo`
  65   init open(conninfo: Text)
  66   do
  67     init(new NativePostgres.connectdb(conninfo))
  68     if native_connection.status.is_ok then is_closed = false
  69   end
  70
  71   # Close this connection with the database
  72   fun finish
  73   do
  74     if is_closed then return
  75
  76     is_closed = true
  77
  78     native_connection.finish
  79   end
  80
  81   fun prepare(stmt_name:String, query:String, num_params: Int):PGResult do return new PGResult(native_connection.prepare(stmt_name, query, num_params))
  82
  83   fun exec_prepared(stmt_name: String, num_params: Int, values: Array[String], param_lengths: Array[Int], param_formats: Array[Int], result_format: Int):PGResult do
  84     return new PGResult(native_connection.exec_prepared(stmt_name, num_params, values, param_lengths, param_formats, result_format))
  85   end
  86
  87   # Executes a `query` and returns the raw `PGResult`
  88   fun raw_execute(query: Text): PGResult do return new PGResult(native_connection.exec(query))
  89
  90   # Execute the `sql` statement and returns `true` on success
  91   fun execute(query: Text): Bool do return native_connection.exec(query).status.is_ok
  92
  93   # Create a table on the DB with a statement beginning with "CREATE TABLE ", followed by `rest`
  94   #
  95   # This method does not escape special characters.
  96   fun create_table(rest: Text): Bool do return execute("CREATE TABLE " + rest)
  97
  98   # Insert in the DB with a statement beginning with "INSERT ", followed by `rest`
  99   #
 100   # This method does not escape special characters.
 101   fun insert(rest: Text): Bool do return execute("INSERT " + rest)
 102
 103   # Replace in the DB with a statement beginning with "REPLACE", followed by `rest`
 104   #
 105   # This method does not escape special characters.
 106   fun replace(rest: Text): Bool do return execute("REPLACE " + rest)
 107
 108   # The latest error message on the connection an empty string if none
 109   fun error: String do return native_connection.error
 110
 111   # The status of this connection
 112   fun is_valid: Bool do return native_connection.status.is_ok
 113
 114   # Resets the connection to the database
 115   fun reset do native_connection.reset
 116 end
 117
 118 # The result of a given query
 119 class PGResult
 120   private var pg_result: NativePGResult
 121
 122   fun clear do pg_result.clear
 123
 124   # Returns the number of rows in the query result
 125   fun ntuples:Int do return pg_result.ntuples
 126
 127   # Returns the number of columns in each row of the query result
 128   fun nfields:Int do return pg_result.nfields
 129
 130   # Returns the ExecStatusType of a result
 131   fun is_ok:Bool do return pg_result.status.is_ok
 132
 133   # Returns the field name of a given `column_number`
 134   fun fname(column_number:Int):String do return pg_result.fname(column_number)
 135
 136   # Returns the column number associated with the `column_name`
 137   fun fnumber(column_name:String):Int do return pg_result.fnumber(column_name)
 138
 139   # Returns a single field value of one row of the result at `row_number`, `column_number`
 140   fun value(row_number:Int, column_number:Int):String  do return pg_result.value(row_number, column_number)
 141
 142   # Tests wether a field specified by the `row_number` and `column_number` is null.
 143   fun is_null(row_number:Int, column_number: Int): Bool do return pg_result.is_null(row_number, column_number)
 144 end