src/syntax/syntax.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2008 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Full syntax analysis of NIT AST.
  18 # Detect syntax and some metamodel errors.
  19 package syntax
  20
  21 import mmloader
  22 import mmbuilder
  23 import typing
  24 import icode_generation
  25
  26 # Loader of nit source files
  27 class SrcModuleLoader
  28         super ModuleLoader
  29         redef type MODULE: MMSrcModule
  30
  31         redef fun file_type do return "nit"
  32
  33         redef fun parse_file(context, file, filename, name, dir)
  34         do
  35                 var name_is_valid = name.to_s.length > 0 and name.to_s[0].is_lower
  36                 for char in name.to_s do        if not char.is_digit and not char.is_letter and not char == '_'
  37                 then
  38                         name_is_valid = false
  39                         break
  40                 end
  41                 if not name_is_valid then
  42                         context.error( null, "{filename}: Error module name \"{name}\", must start with a lower case letter and contain only letters, digits and '_'." )
  43                 end
  44
  45                 var source = new SourceFile(filename, file)
  46                 var lexer = new Lexer(source)
  47                 var parser = new Parser(lexer)
  48                 var node_tree = parser.parse
  49                 if node_tree.n_base == null then
  50                         var err = node_tree.n_eof
  51                         assert err isa AError
  52                         context.fatal_error(err.location, err.message)
  53                 end
  54                 var node_module = node_tree.n_base
  55                 assert node_module != null
  56                 var module_loc = new Location.with_file(source)
  57                 var mod = new MMSrcModule(context, node_module, dir, name, module_loc)
  58                 return mod
  59         end
  60
  61         redef fun process_metamodel(context, mod)
  62         do
  63                 mod.process_supermodules(context)
  64                 context.info("Syntax analysis for module: {mod.name}", 2)
  65                 mod.process_syntax(context)
  66         end
  67
  68         init do end
  69 end
  70
  71 redef class MMSrcModule
  72         # Loading and syntax analysis of super modules
  73         private fun process_supermodules(tc: ToolContext)
  74         do
  75                 node.import_super_modules(tc, self)
  76         end
  77
  78         # Syntax analysis and MM construction for the module
  79         # Require than supermodules are processed
  80         private fun process_syntax(tc: ToolContext)
  81         do
  82                 do_mmbuilder(tc)
  83                 tc.check_errors
  84
  85                 do_typing(tc)
  86                 tc.check_errors
  87
  88                 generate_icode(tc)
  89                 tc.check_errors
  90
  91                 if not tc.keep_ast then clear_ast
  92         end
  93 end
  94
  95 redef class ToolContext
  96         # Should the AST be preserved in source modules after syntax processing?
  97         # Default is false.
  98         readable writable var _keep_ast: Bool = false
  99 end