contrib/model_viewer/src/model_viewer.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Portable game to destroy asteroids
  16 module model_viewer is
  17         app_name "Model Viewer"
  18         app_namespace "org.nitlanguage.model_viewer"
  19         app_version(1, 0, git_revision)
  20
  21         android_manifest_activity """android:screenOrientation="landscape""""
  22         android_api_target 15
  23 end
  24
  25 import gamnit::depth
  26
  27 import globe
  28
  29 redef class App
  30
  31         # All available models
  32         var models: Array[Model] = [
  33                 new LeafModel(new Cube, new SmoothMaterial.default),
  34                 new LeafModel(new Mesh.uv_sphere(4.0, 32, 16), new SmoothMaterial.default),
  35                 new LeafModel(new Mesh.uv_sphere(4.0, 32, 16), new NormalsMaterial),
  36                 new Model("models/Tree_01.obj"),
  37                 new Model("models/Oak_Fall_01.obj"),
  38                 new Model("models/Quandtum_BA-2_v1_1.obj"),
  39                 new GlobeModel]
  40
  41         # Index of the current model in `models`
  42         var model_index = 0
  43
  44         # Texture "Previous model"
  45         var ui_prev = new Texture("ui/prev.png")
  46
  47         # Texture "Next model"
  48         var ui_next = new Texture("ui/next.png")
  49
  50         redef fun on_create
  51         do
  52                 super
  53
  54                 if args.length > 0 then
  55                         # Load a model passed as the first command line argument
  56                         var model_path = args.first
  57                         if model_path.has_prefix("assets/") then model_path = model_path.substring_from(7)
  58
  59                         var model = new Model(model_path)
  60                         models.unshift model
  61                 end
  62
  63                 world_camera.near = 1.0
  64                 world_camera.far = 1000.0
  65
  66                 for model in models do model.load
  67                 for texture in asset_textures_by_name.values do texture.load
  68
  69                 # Display the first model
  70                 model = models[model_index]
  71
  72                 # Setup UI
  73                 # Use 800 px in height as screen reference
  74                 ui_camera.reset_height 800.0
  75
  76                 var prev_sprite = new Sprite(ui_prev,
  77                         ui_camera.bottom_left.offset(200, -40, 0))
  78                 prev_sprite.scale = 0.5
  79                 ui_sprites.add prev_sprite
  80
  81                 var next_sprite = new Sprite(ui_next,
  82                         ui_camera.bottom_right.offset(-165, -40, 0))
  83                 next_sprite.scale = 0.5
  84                 ui_sprites.add next_sprite
  85         end
  86
  87         # Set the currently displayed model
  88         fun model=(model: Model)
  89         do
  90                 var actor = new Actor(model, new Point3d[Float](0.0, 0.0, 0.0))
  91
  92                 model = model.leaves.first
  93                 actor.center.x -= model.mesh.center.x
  94                 actor.center.y += model.mesh.center.y
  95                 actor.center.z -= model.mesh.center.z
  96
  97                 var height = model.mesh.dimensions.y
  98                 world_camera.reset_height(height * 3.0)
  99
 100                 actors.clear
 101                 actors.add actor
 102         end
 103
 104         # Cycle to the next or previous model, changing the index by `d`
 105         fun cycle_model(d: Int)
 106         do
 107                 model_index = (model_index + d + models.length) % models.length
 108                 model = models[model_index]
 109         end
 110
 111         redef fun accept_event(event)
 112         do
 113                 var display = display
 114                 if display == null then return super
 115
 116                 if event isa QuitEvent then
 117                         exit 0
 118                 else if event isa KeyEvent and event.is_down then
 119                         if event.is_arrow_right then
 120                                 cycle_model 1
 121                         else if event.is_arrow_left then
 122                                 cycle_model -1
 123                         end
 124                 else if event isa PointerEvent and event.pressed then
 125                         if event.x.to_i > display.width / 2 then
 126                                 cycle_model 1
 127                         else cycle_model -1
 128                 end
 129
 130                 return super
 131         end
 132
 133         private var clock = new Clock
 134
 135         redef fun update(dt)
 136         do
 137                 super
 138
 139                 var t = clock.total.to_f
 140
 141                 # Rotate the model
 142                 actors.first.rotation = t
 143
 144                 # Move the light source
 145                 var dist_to_light = 20.0
 146                 t *= 1.33
 147                 light.position.x = dist_to_light * t.cos
 148                 light.position.y = 4.0
 149                 light.position.z = dist_to_light * t.sin
 150         end
 151 end