src/doc/html_templates/html_templates.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Introduces templates that compose the documentation HTML rendering.
  16 module html_templates
  17
  18 import html_model
  19 import html::bootstrap
  20 import doc_phases::doc_structure
  21 import doc_phases::doc_hierarchies
  22 import doc_phases::doc_graphs
  23 import doc_phases::doc_intros_redefs
  24 import doc_phases::doc_lin
  25
  26 # Renders the page as HTML.
  27 redef class DocPage
  28         super Template
  29
  30         # Page url.
  31         var html_url: String is writable, noinit
  32
  33         # Directory where css, js and other assets can be found.
  34         var shareurl: String is writable, noinit
  35
  36         # Attributes of the body tag element.
  37         var body_attrs = new Array[TagAttribute]
  38
  39         # Top menu template if any.
  40         var topmenu: DocTopMenu is writable, noinit
  41
  42         # Sidebar template if any.
  43         var sidebar: nullable DocSideBar = null is writable
  44
  45         # Footer content if any.
  46         var footer: nullable Writable = null is writable
  47
  48         # JS scripts to append at the end of the body
  49         var scripts = new Array[TplScript]
  50
  51         # Renders the html `<head>`.
  52         private fun render_head do
  53                 var css = (self.shareurl / "css").html_escape
  54                 var vendors = (self.shareurl / "vendors").html_escape
  55
  56                 addn "<!DOCTYPE html>"
  57                 addn "<head>"
  58                 addn " <meta charset='utf-8'/>"
  59                 addn " <!--link rel='stylesheet' href='{css}/Nitdoc.UI.css' type='text/css'/-->"
  60                 addn " <link rel='stylesheet' href='{vendors}/bootstrap/css/bootstrap.min.css'/>"
  61                 addn " <link rel='stylesheet' href='{css}/nitdoc.bootstrap.css'/>"
  62                 addn " <link rel='stylesheet' href='{css}/nitdoc.css'/>"
  63                 addn " <link rel='stylesheet' href='{css}/Nitdoc.QuickSearch.css'/>"
  64                 addn " <link rel='stylesheet' href='{css}/Nitdoc.ModalBox.css'/>"
  65                 addn " <link rel='stylesheet' href='{css}/Nitdoc.GitHub.css'/>"
  66                 addn " <title>{title.html_escape}</title>"
  67                 addn "</head>"
  68                 add "<body"
  69                 for attr in body_attrs do add attr
  70                 addn ">"
  71         end
  72
  73         # Renders the footer and content.
  74         private fun render_content do
  75                 add root
  76                 if footer != null then
  77                         addn "<div class='well footer'>"
  78                         add footer.as(not null)
  79                         addn "</div>"
  80                 end
  81         end
  82
  83         # Render JS scripts
  84         private fun render_footer do
  85                 var vendors = (self.shareurl / "vendors").html_escape
  86                 var js = (self.shareurl / "js").html_escape
  87
  88                 addn "<script src='{vendors}/jquery/jquery-1.11.1.min.js'></script>"
  89                 addn "<script src='{vendors}/jquery/jquery-ui-1.10.4.custom.min.js'></script>"
  90                 addn "<script src='{vendors}/bootstrap/js/bootstrap.min.js'></script>"
  91                 addn "<script data-main='{js}/nitdoc' src='{js}/lib/require.js'></script>"
  92                 for script in scripts do add script
  93                 addn """<script>
  94                         $(function () {
  95                                 $("[data-toggle='tooltip']").tooltip();
  96                                 $("[data-toggle='popover']").popover();
  97                         });
  98                 </script>"""
  99                 addn "</body>"
 100                 addn "</html>"
 101         end
 102
 103         # Render the whole page
 104         redef fun rendering do
 105                 render_head
 106                 addn "<div class='container-fluid'>"
 107                 addn " <div class='row'>"
 108                 add topmenu
 109                 addn " </div>"
 110                 addn " <div class='row' id='content'>"
 111                 var sidebar = self.sidebar
 112                 if sidebar != null then
 113                         addn "<div class='col col-xs-3 col-lg-2'>"
 114                         add sidebar
 115                         addn "</div>"
 116                         addn "<div class='col col-xs-9 col-lg-10' data-spy='scroll' data-target='.summary'>"
 117                         render_content
 118                         addn "</div>"
 119                 else
 120                         addn "<div class='col col-xs-12'>"
 121                         render_content
 122                         addn "</div>"
 123                 end
 124                 addn " </div>"
 125                 addn "</div>"
 126                 render_footer
 127         end
 128
 129         # Render table of content for this page.
 130         fun html_toc: UnorderedList do
 131                 var lst = new UnorderedList
 132                 lst.css_classes.add "nav"
 133                 for child in root.children do
 134                         child.render_toc_item(lst)
 135                 end
 136                 return lst
 137         end
 138 end
 139
 140 # Top menu bar template.
 141 #
 142 # FIXME should be a Bootstrap component template
 143 # At this moment, the topmenu structure stills to specific to Nitdoc to use the
 144 # generic component.
 145 class DocTopMenu
 146         super UnorderedList
 147
 148         # Brand link to display in first position of the top menu.
 149         #
 150         # This is where you want to put your logo.
 151         var brand: nullable Writable is noinit, writable
 152
 153         # Active menu item.
 154         #
 155         # Depends on the current page, this allows to hilighted the current item.
 156         #
 157         # FIXME should be using Boostrap breadcrumbs component.
 158         # This will still like this to avoid diff and be changed in further fixes
 159         # when we will modify the output.
 160         var active_item: nullable ListItem is noinit, writable
 161
 162         redef fun rendering do
 163                 addn "<nav id='topmenu' class='navbar navbar-default navbar-fixed-top' role='navigation'>"
 164                 addn " <div class='container-fluid'>"
 165                 addn "  <div class='navbar-header'>"
 166                 add "   <button type='button' class='navbar-toggle' "
 167                 addn "       data-toggle='collapse' data-target='#topmenu-collapse'>"
 168                 addn "    <span class='sr-only'>Toggle menu</span>"
 169                 addn "    <span class='icon-bar'></span>"
 170                 addn "    <span class='icon-bar'></span>"
 171                 addn "    <span class='icon-bar'></span>"
 172                 addn "   </button>"
 173                 if brand != null then
 174                         add "<span class='navbar-brand'>"
 175                         add brand.write_to_string
 176                         add "</span>"
 177                 end
 178                 addn "  </div>"
 179                 addn "  <div class='collapse navbar-collapse' id='topmenu-collapse'>"
 180                 addn "   <ul class='nav navbar-nav'>"
 181                 for item in items do
 182                         if item == active_item then item.css_classes.add "active"
 183                         add item.write_to_string
 184                 end
 185                 addn "   </ul>"
 186                 addn "  </div>"
 187                 addn " </div>"
 188                 addn "</nav>"
 189         end
 190 end
 191
 192 # Nitdoc sidebar template.
 193 class DocSideBar
 194         super Template
 195
 196         # Sidebar contains `DocSideBox`.
 197         var boxes = new Array[DocSideBox]
 198
 199         redef fun rendering do
 200                 if boxes.is_empty then return
 201                 addn "<div id='sidebar'>"
 202                 for box in boxes do add box
 203                 addn "</div>"
 204         end
 205 end
 206
 207 # Something that can be put in a DocSideBar.
 208 class DocSideBox
 209         super Template
 210
 211         # Box HTML id, used for Bootstrap collapsing feature.
 212         #
 213         # Use `html_title.to_cmangle` by default.
 214         var id: String is lazy do return title.write_to_string.to_cmangle
 215
 216         # Title of the box to display.
 217         var title: Writable
 218
 219         # Content to display in the box.
 220         var content: Writable
 221
 222         # Is the box opened by default?
 223         #
 224         # Otherwise, the user will have to clic on the title to display the content.
 225         #
 226         # Default is `true`.
 227         var is_open = true is writable
 228
 229         redef fun rendering do
 230                 var open = ""
 231                 if is_open then open = "in"
 232                 addn "<div class='panel'>"
 233                 addn " <div class='panel-heading'>"
 234                 add "  <a data-toggle='collapse' data-parent='#sidebar'"
 235                 add "   data-target='#box_{id}' href='#'>"
 236                 add title
 237                 addn "  </a>"
 238                 addn " </div>"
 239                 addn " <div id='box_{id}' class='summary panel-body collapse {open}'>"
 240                 add content
 241                 addn " </div>"
 242                 addn "</div>"
 243         end
 244 end
 245
 246 redef class DocComposite
 247         super Template
 248
 249         # HTML anchor id
 250         var html_id: String is noinit, writable
 251
 252         # Title to display if any.
 253         #
 254         # This title can be decorated with HTML.
 255         var html_title: nullable Writable is noinit, writable
 256
 257         # Subtitle to display if any.
 258         var html_subtitle: nullable Writable is noinit, writable
 259
 260         # Render the element title and subtitle.
 261         private fun render_title do
 262                 if html_title != null then
 263                 var header = new Header(hlvl, html_title.write_to_string)
 264                 header.css_classes.add "signature"
 265                 if hlvl == 2 then header.css_classes.add "well well-sm"
 266                 addn header
 267                 end
 268                 if html_subtitle != null then
 269                         addn "<div class='info subtitle'>"
 270                         addn html_subtitle.write_to_string
 271                         addn "</div>"
 272                 end
 273         end
 274
 275         # Render the element body.
 276         private fun render_body do
 277                 for child in children do addn child.write_to_string
 278         end
 279
 280         redef fun rendering do
 281                 if is_hidden then return
 282                 render_title
 283                 render_body
 284         end
 285
 286         # Level <hX> for HTML heading.
 287         private fun hlvl: Int do
 288                 if parent == null then return 0
 289                 return parent.hlvl + 1
 290         end
 291
 292         # Is `self` not displayed in the page.
 293         #
 294         # By default, empty elements are hidden.
 295         fun is_hidden: Bool do return is_empty
 296
 297         # A short, undecorated title that goes in the table of contents.
 298         #
 299         # By default, returns `html_title.to_s`, subclasses should redefine it.
 300         var toc_title: String is lazy, writable do return html_title.to_s
 301
 302         # Is `self` hidden in the table of content?
 303         var is_toc_hidden = false is writable
 304
 305         # Render this element in a table of contents.
 306         private fun render_toc_item(lst: UnorderedList) do
 307                 if is_toc_hidden then return
 308
 309                 var content = new Template
 310                 content.add new Link("#{html_id}", toc_title)
 311
 312                 if not children.is_empty then
 313                         var sublst = new UnorderedList
 314                         sublst.css_classes.add "nav"
 315                         for child in children do
 316                                 child.render_toc_item(sublst)
 317                         end
 318                         content.add sublst
 319                 end
 320                 lst.add_li new ListItem(content)
 321         end
 322 end
 323
 324 redef class DocSection
 325         super BSComponent
 326
 327         redef fun rendering do
 328                 if is_hidden then
 329                         addn "<a id=\"{html_id}\"></a>"
 330                         return
 331                 end
 332                 addn "<section{render_css_classes} id=\"{html_id}\">"
 333                 render_title
 334                 render_body
 335                 addn "</section>"
 336         end
 337 end
 338
 339 redef class DocArticle
 340         super BSComponent
 341
 342         redef fun rendering do
 343                 if is_hidden then return
 344                 addn "<article{render_css_classes} id=\"{html_id}\">"
 345                 render_title
 346                 render_body
 347                 addn "</article>"
 348         end
 349 end
 350
 351 redef class HomeArticle
 352         redef var html_id = "article:home"
 353         redef var html_title = "Overview"
 354
 355         # HTML content to display on the home page.
 356         #
 357         # This attribute is set by the `doc_render` phase who knows the context.
 358         var content: nullable String is noinit, writable
 359
 360         redef fun render_body do
 361                 var content = self.content
 362                 if content != null then add content
 363                 super
 364         end
 365 end
 366
 367 redef class IndexArticle
 368         redef var html_id = "article:index"
 369         redef var html_title = "Index"
 370         redef fun is_empty do
 371                 return mmodules.is_empty and mclasses.is_empty and mprops.is_empty
 372         end
 373
 374         redef fun render_body do
 375                 addn "<div class='container-fluid'>"
 376                 addn " <div class='row'>"
 377                 render_list("Modules", mmodules)
 378                 render_list("Classes", mclasses)
 379                 render_list("Properties", mprops)
 380                 addn "</div>"
 381                 addn "</div>"
 382         end
 383
 384         # Displays a list from the content of `mentities`.
 385         private fun render_list(title: String, mentities: Array[MEntity]) do
 386                 if mentities.is_empty then return
 387                 addn "<div class='col-xs-4'>"
 388                 addn new Header(3, title)
 389                 var lst = new UnorderedList
 390                 for mentity in mentities do
 391                         if mentity isa MProperty then
 392                                 var tpl = new Template
 393                                 tpl.add mentity.intro.html_link
 394                                 tpl.add " ("
 395                                 tpl.add mentity.intro.mclassdef.mclass.html_link
 396                                 tpl.add ")"
 397                                 lst.add_li new ListItem(tpl)
 398                         else
 399                                 lst.add_li new ListItem(mentity.html_link)
 400                         end
 401                 end
 402                 addn lst
 403                 addn "</div>"
 404         end
 405 end
 406
 407 redef class ProjectsSection
 408         redef var html_id = "section:projects"
 409         redef var html_title = "Projects"
 410 end
 411
 412 redef class MEntityComposite
 413         redef var html_id is lazy do return mentity.nitdoc_id
 414         redef var html_title is lazy do return mentity.nitdoc_name
 415 end
 416
 417 redef class MEntitySection
 418         redef var html_id is lazy do return "section:{mentity.nitdoc_name}"
 419         redef var html_title is lazy do return mentity.html_name
 420         redef var html_subtitle is lazy do return mentity.html_declaration
 421 end
 422
 423 redef class ConcernSection
 424         redef var html_id is lazy do return "concern:{mentity.nitdoc_id}"
 425         redef var html_title is lazy do return "in {mentity.nitdoc_name}"
 426         redef fun is_toc_hidden do return is_empty
 427 end
 428
 429 redef class ImportationListSection
 430         redef var html_id is lazy do return "section:{mentity.nitdoc_id}.importation"
 431         redef var html_title is lazy do return "Dependencies"
 432 end
 433
 434 redef class InheritanceListSection
 435         redef var html_id is lazy do return "section:{mentity.nitdoc_id}.inheritance"
 436         redef var html_title is lazy do return "Inheritance"
 437 end
 438
 439 redef class IntroArticle
 440         redef var html_id is lazy do return "article:{mentity.nitdoc_id}.intro"
 441         redef var html_title = null
 442         redef var is_hidden = false
 443         redef var is_toc_hidden = true
 444
 445         # Link to source to display if any.
 446         var html_source_link: nullable Writable is noinit, writable
 447
 448         redef fun render_title do
 449                 var lnk = html_source_link
 450                 if lnk != null then
 451                         add "<div class='source-link'>"
 452                         add lnk
 453                         addn "</div>"
 454                 end
 455                 super
 456         end
 457
 458         redef fun render_body do
 459                 var comment = mentity.html_comment
 460                 if comment != null then addn comment
 461                 super
 462         end
 463 end
 464
 465 redef class ConcernsArticle
 466         redef var html_id is lazy do return "article:{mentity.nitdoc_id}.concerns"
 467         redef var html_title = "Concerns"
 468         redef fun is_hidden do return concerns.is_empty
 469         redef fun render_body do add concerns.html_list
 470 end
 471
 472 redef class DefinitionArticle
 473         redef var html_id is lazy do return "article:{mentity.nitdoc_id}.definition"
 474         redef var html_title is lazy do return mentity.html_name
 475         redef var html_subtitle is lazy do return mentity.html_declaration
 476         redef var is_hidden = false
 477
 478         # Does `self` display only it's title and no body?
 479         #
 480         # FIXME diff hack
 481         var is_no_body: Bool = false is writable
 482
 483         # Does `self` display only the short content as definition?
 484         #
 485         # FIXME diff hack
 486         var is_short_comment: Bool = false is writable
 487
 488         # Link to source to display if any.
 489         var html_source_link: nullable Writable is noinit, writable
 490
 491         redef fun render_title do
 492                 var lnk = html_source_link
 493                 if lnk != null then
 494                         add "<div class='source-link'>"
 495                         add lnk
 496                         addn "</div>"
 497                 end
 498                 super
 499         end
 500
 501         redef fun render_body do
 502                 if not is_no_body then
 503                         var comment
 504                         if is_short_comment then
 505                                 comment = mentity.html_short_comment
 506                         else
 507                                 comment = mentity.html_comment
 508                         end
 509                         if comment != null then addn comment
 510                 end
 511                 super
 512         end
 513 end
 514
 515 redef class HierarchyListArticle
 516         redef var html_id is lazy do return "article:{list_title}_{mentity.nitdoc_id}.hierarchy"
 517         redef var html_title is lazy do return list_title
 518         redef fun is_empty do return mentities.is_empty
 519         redef fun is_toc_hidden do return mentities.is_empty
 520
 521         redef fun render_body do
 522                 var lst = new UnorderedList
 523                 lst.css_classes.add "list-unstyled list-definition"
 524                 for mentity in mentities do
 525                         lst.add_li mentity.html_list_item
 526                 end
 527                 addn lst
 528         end
 529 end
 530
 531 redef class IntrosRedefsListArticle
 532         redef var html_id is lazy do return "article:{mentity.nitdoc_id}.intros_redefs"
 533         redef var html_title is lazy do return list_title
 534         redef fun is_hidden do return mentities.is_empty
 535         redef var is_toc_hidden = true
 536
 537         redef fun render_body do
 538                 var lst = new UnorderedList
 539                 lst.css_classes.add "list-unstyled list-labeled"
 540                 for mentity in mentities do
 541                         lst.add_li mentity.html_list_item
 542                 end
 543                 add lst
 544         end
 545 end
 546
 547 redef class DefinitionLinArticle
 548         redef var html_id is lazy do return "article:{mentity.nitdoc_id}.lin"
 549         redef var html_title is lazy do return "Linearization"
 550         redef fun is_hidden do return mentities.is_empty
 551         redef var is_toc_hidden = true
 552
 553         redef fun render_body do
 554                 var lst = new UnorderedList
 555                 lst.css_classes.add "list-unstyled list-labeled"
 556                 for mentity in mentities do
 557                         if not mentity isa MPropDef then continue # TODO handle all mentities
 558                         var tpl = new Template
 559                         tpl.add mentity.mclassdef.html_namespace
 560                         var comment = mentity.mclassdef.html_short_comment
 561                         if comment != null then
 562                                 tpl.add ": "
 563                                 tpl.add comment
 564                         end
 565                         var li = new ListItem(tpl)
 566                         li.css_classes.add "signature"
 567                         lst.add_li li
 568                 end
 569                 add lst
 570         end
 571 end
 572
 573 redef class GraphArticle
 574         redef var html_id is lazy do return "article:{mentity.nitdoc_id}.graph"
 575         redef var html_title = null
 576         redef var toc_title do return "Graph"
 577         redef var is_hidden = false
 578         redef var is_toc_hidden = true
 579
 580         # HTML map used to display link.
 581         #
 582         # This attribute is set by the `doc_render` phase who knows the context.
 583         var map: String is noinit, writable
 584
 585         redef fun render_body do
 586                 addn "<div class=\"text-center\">"
 587                 addn " <img src='{id}.png' usemap='#{id}' style='margin:auto'"
 588                 addn "  alt='{graph_title}'/>"
 589                 add map
 590                 addn "</div>"
 591         end
 592 end