src/global_compiler.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Global compilation of a Nit program
  18 #
  19 # Techniques used are:
  20 #   * heterogeneous generics
  21 #   * customization
  22 #   * switch dispatch
  23 #   * inlining
  24 module global_compiler
  25
  26 import abstract_compiler
  27 import rapid_type_analysis
  28 import compiler_ffi
  29
  30 redef class ModelBuilder
  31         # Entry point to performs a global compilation on the AST of a complete program.
  32         # `mainmodule` is the main module of the program
  33         # `runtime_type_analysis` is a already computer type analysis.
  34         fun run_global_compiler(mainmodule: MModule, runtime_type_analysis: RapidTypeAnalysis)
  35         do
  36                 var time0 = get_time
  37                 self.toolcontext.info("*** GENERATING C ***", 1)
  38
  39                 var compiler = new GlobalCompiler(mainmodule, self, runtime_type_analysis)
  40                 compiler.compile_header
  41
  42                 for t in runtime_type_analysis.live_types do
  43                         compiler.declare_runtimeclass(t)
  44                 end
  45
  46                 compiler.compile_class_names
  47
  48                 # Init instance code (allocate and init-arguments)
  49                 for t in runtime_type_analysis.live_types do
  50                         if t.ctype == "val*" then
  51                                 compiler.generate_init_instance(t)
  52                         else
  53                                 compiler.generate_box_instance(t)
  54                         end
  55                 end
  56
  57                 # The main function of the C
  58                 compiler.compile_main_function
  59
  60                 # Compile until all runtime_functions are visited
  61                 while not compiler.todos.is_empty do
  62                         var m = compiler.todos.shift
  63                         self.toolcontext.info("Compile {m} ({compiler.seen.length-compiler.todos.length}/{compiler.seen.length})", 3)
  64                         m.compile_to_c(compiler)
  65                 end
  66                 self.toolcontext.info("Total methods to compile to C: {compiler.seen.length}", 2)
  67
  68                 compiler.display_stats
  69
  70                 var time1 = get_time
  71                 self.toolcontext.info("*** END GENERATING C: {time1-time0} ***", 2)
  72                 write_and_make(compiler)
  73         end
  74 end
  75
  76 # Compiler that use global compilation and perform hard optimisations like:
  77 #   * customization
  78 #   * switch dispatch
  79 #   * inlining
  80 class GlobalCompiler
  81         super AbstractCompiler
  82
  83         redef type VISITOR: GlobalCompilerVisitor
  84
  85         # The result of the RTA (used to know live types and methods)
  86         var runtime_type_analysis: RapidTypeAnalysis
  87
  88         init(mainmodule: MModule, modelbuilder: ModelBuilder, runtime_type_analysis: RapidTypeAnalysis)
  89         do
  90                 super(mainmodule, modelbuilder)
  91                 var file = new_file("{mainmodule.name}.nitgg")
  92                 self.header = new CodeWriter(file)
  93                 self.runtime_type_analysis = runtime_type_analysis
  94                 self.live_primitive_types = new Array[MClassType]
  95                 for t in runtime_type_analysis.live_types do
  96                         if t.ctype != "val*" then
  97                                 self.live_primitive_types.add(t)
  98                         end
  99                 end
 100         end
 101
 102         # Compile class names (for the class_name and output_class_name methods)
 103         protected fun compile_class_names do
 104                 var v = new_visitor
 105                 self.header.add_decl("extern const char const * class_names[];")
 106                 v.add("const char const * class_names[] = \{")
 107                 for t in self.runtime_type_analysis.live_types do
 108                         v.add("\"{t}\", /* {self.classid(t)} */")
 109                 end
 110                 v.add("\};")
 111         end
 112
 113         # Return the C symbol associated to a live type runtime
 114         # REQUIRE: self.runtime_type_analysis.live_types.has(mtype)
 115         fun classid(mtype: MClassType): String
 116         do
 117                 if self.classids.has_key(mtype) then
 118                         return self.classids[mtype]
 119                 end
 120                 print "No classid for {mtype}"
 121                 abort
 122         end
 123
 124         # Cache for classid
 125         protected var classids: HashMap[MClassType, String] = new HashMap[MClassType, String]
 126
 127         # Declaration of structures the live Nit types
 128         # Each live type is generated as an independent C `struct` type.
 129         # They only share a common first field `classid` used to implement the polymorphism.
 130         # Usualy, all C variables that refers to a Nit object are typed on the abstract struct `val` that contains only the `classid` field.
 131         redef fun compile_header_structs do
 132                 self.header.add_decl("typedef struct \{int classid;\} val; /* general C type representing a Nit instance. */")
 133         end
 134
 135         # Subset of runtime_type_analysis.live_types that contains only primitive types
 136         # Used to implement the equal test
 137         var live_primitive_types: Array[MClassType]
 138
 139         # Add a new todo task
 140         fun todo(m: AbstractRuntimeFunction)
 141         do
 142                 if seen.has(m) then return
 143                 todos.add(m)
 144                 seen.add(m)
 145         end
 146
 147         # runtime_functions that need to be compiled
 148         private var todos: List[AbstractRuntimeFunction] = new List[AbstractRuntimeFunction]
 149
 150         # runtime_functions already seen (todo or done)
 151         private var seen: HashSet[AbstractRuntimeFunction] = new HashSet[AbstractRuntimeFunction]
 152
 153         # Declare C structures and identifiers for a runtime class
 154         fun declare_runtimeclass(mtype: MClassType)
 155         do
 156                 var v = self.header
 157                 assert self.runtime_type_analysis.live_types.has(mtype)
 158                 v.add_decl("/* runtime class {mtype} */")
 159                 var idnum = classids.length
 160                 var idname = "ID_" + mtype.c_name
 161                 self.classids[mtype] = idname
 162                 v.add_decl("#define {idname} {idnum} /* {mtype} */")
 163
 164                 v.add_decl("struct {mtype.c_name} \{")
 165                 v.add_decl("int classid; /* must be {idname} */")
 166
 167                 if mtype.mclass.name == "NativeArray" then
 168                         # NativeArrays are just a instance header followed by an array of values
 169                         v.add_decl("{mtype.arguments.first.ctype} values[1];")
 170                 end
 171
 172                 if mtype.ctype != "val*" then
 173                         # Is the Nit type is native then the struct is a box with two fields:
 174                         # * the `classid` to be polymorph
 175                         # * the `value` that contains the native value.
 176                         v.add_decl("{mtype.ctype} value;")
 177                 end
 178
 179                 # Collect all attributes and associate them a field in the structure.
 180                 # Note: we do not try to optimize the order and helps CC to optimize the client code.
 181                 for cd in mtype.collect_mclassdefs(self.mainmodule) do
 182                         for p in cd.intro_mproperties do
 183                                 if not p isa MAttribute then continue
 184                                 var t = p.intro.static_mtype.as(not null)
 185                                 t = t.anchor_to(self.mainmodule, mtype)
 186                                 v.add_decl("{t.ctype} {p.intro.c_name}; /* {p}: {t} */")
 187                         end
 188                 end
 189                 v.add_decl("\};")
 190         end
 191
 192         # Generate the init-instance of a live type (allocate + init-instance)
 193         fun generate_init_instance(mtype: MClassType)
 194         do
 195                 assert self.runtime_type_analysis.live_types.has(mtype)
 196                 assert mtype.ctype == "val*"
 197                 var v = self.new_visitor
 198
 199                 var is_native_array = mtype.mclass.name == "NativeArray"
 200
 201                 var sig
 202                 if is_native_array then
 203                         sig = "int length"
 204                 else
 205                         sig = "void"
 206                 end
 207
 208                 self.header.add_decl("{mtype.ctype} NEW_{mtype.c_name}({sig});")
 209                 v.add_decl("/* allocate {mtype} */")
 210                 v.add_decl("{mtype.ctype} NEW_{mtype.c_name}({sig}) \{")
 211                 var res = v.new_var(mtype)
 212                 res.is_exact = true
 213                 if is_native_array then
 214                         var mtype_elt = mtype.arguments.first
 215                         v.add("{res} = nit_alloc(sizeof(struct {mtype.c_name}) + length*sizeof({mtype_elt.ctype}));")
 216                 else
 217                         v.add("{res} = nit_alloc(sizeof(struct {mtype.c_name}));")
 218                 end
 219                 v.add("{res}->classid = {self.classid(mtype)};")
 220
 221                 self.generate_init_attr(v, res, mtype)
 222                 v.add("return {res};")
 223                 v.add("\}")
 224         end
 225
 226         fun generate_box_instance(mtype: MClassType)
 227         do
 228                 assert self.runtime_type_analysis.live_types.has(mtype)
 229                 assert mtype.ctype != "val*"
 230                 var v = self.new_visitor
 231
 232                 self.header.add_decl("val* BOX_{mtype.c_name}({mtype.ctype});")
 233                 v.add_decl("/* allocate {mtype} */")
 234                 v.add_decl("val* BOX_{mtype.c_name}({mtype.ctype} value) \{")
 235                 v.add("struct {mtype.c_name}*res = nit_alloc(sizeof(struct {mtype.c_name}));")
 236                 v.add("res->classid = {self.classid(mtype)};")
 237                 v.add("res->value = value;")
 238                 v.add("return (val*)res;")
 239                 v.add("\}")
 240         end
 241
 242         redef fun new_visitor do return new GlobalCompilerVisitor(self)
 243
 244         private var collect_types_cache: HashMap[MType, Array[MClassType]] = new HashMap[MType, Array[MClassType]]
 245
 246         redef fun compile_nitni_structs
 247         do
 248                 self.header.add_decl("struct nitni_instance \{ val *value; \};")
 249         end
 250
 251         redef fun supports_ffi do return true
 252 end
 253
 254 # A visitor on the AST of property definition that generate the C code.
 255 # Because of inlining, a visitor can visit more than one property.
 256 class GlobalCompilerVisitor
 257         super AbstractCompilerVisitor
 258
 259         redef type COMPILER: GlobalCompiler
 260
 261         redef fun autobox(value, mtype)
 262         do
 263                 if value.mtype == mtype then
 264                         return value
 265                 else if value.mtype.ctype == "val*" and mtype.ctype == "val*" then
 266                         return value
 267                 else if value.mtype.ctype == "val*" then
 268                         return self.new_expr("((struct {mtype.c_name}*){value})->value; /* autounbox from {value.mtype} to {mtype} */", mtype)
 269                 else if mtype.ctype == "val*" then
 270                         var valtype = value.mtype.as(MClassType)
 271                         var res = self.new_var(mtype)
 272                         if not compiler.runtime_type_analysis.live_types.has(valtype) then
 273                                 self.add("/*no autobox from {value.mtype} to {mtype}: {value.mtype} is not live! */")
 274                                 self.add("printf(\"Dead code executed!\\n\"); show_backtrace(1);")
 275                                 return res
 276                         end
 277                         self.add("{res} = BOX_{valtype.c_name}({value}); /* autobox from {value.mtype} to {mtype} */")
 278                         return res
 279                 else if value.mtype.cname_blind == "void*" and mtype.cname_blind == "void*" then
 280                         return value
 281                 else
 282                         # Bad things will appen!
 283                         var res = self.new_var(mtype)
 284                         self.add("/* {res} left unintialized (cannot convert {value.mtype} to {mtype}) */")
 285                         self.add("printf(\"Cast error: Cannot cast %s to %s.\\n\", \"{value.mtype}\", \"{mtype}\"); show_backtrace(1);")
 286                         return res
 287                 end
 288         end
 289
 290         # The runtime types that are acceptable for a given receiver.
 291         fun collect_types(recv: RuntimeVariable): Array[MClassType]
 292         do
 293                 var mtype = recv.mcasttype
 294                 if recv.is_exact then
 295                         assert mtype isa MClassType
 296                         assert self.compiler.runtime_type_analysis.live_types.has(mtype)
 297                         var types = [mtype]
 298                         return types
 299                 end
 300                 var cache = self.compiler.collect_types_cache
 301                 if cache.has_key(mtype) then
 302                         return cache[mtype]
 303                 end
 304                 var types = new Array[MClassType]
 305                 var mainmodule = self.compiler.mainmodule
 306                 for t in self.compiler.runtime_type_analysis.live_types do
 307                         if not t.is_subtype(mainmodule, null, mtype) then continue
 308                         types.add(t)
 309                 end
 310                 cache[mtype] = types
 311                 return types
 312         end
 313
 314         redef fun native_array_def(pname, ret_type, arguments)
 315         do
 316                 var elttype = arguments.first.mtype
 317                 var recv = "((struct {arguments[0].mcasttype.c_name}*){arguments[0]})->values"
 318                 if pname == "[]" then
 319                         self.ret(self.new_expr("{recv}[{arguments[1]}]", ret_type.as(not null)))
 320                         return
 321                 else if pname == "[]=" then
 322                         self.add("{recv}[{arguments[1]}]={arguments[2]};")
 323                         return
 324                 else if pname == "copy_to" then
 325                         var recv1 = "((struct {arguments[1].mcasttype.c_name}*){arguments[1]})->values"
 326                         self.add("memcpy({recv1},{recv},{arguments[2]}*sizeof({elttype.ctype}));")
 327                         return
 328                 end
 329         end
 330
 331         redef fun calloc_array(ret_type, arguments)
 332         do
 333                 self.ret(self.new_expr("NEW_{ret_type.c_name}({arguments[1]})", ret_type))
 334         end
 335
 336         redef fun send(m, args)
 337         do
 338                 var types = self.collect_types(args.first)
 339
 340                 var res: nullable RuntimeVariable
 341                 var ret = m.intro.msignature.return_mtype
 342                 if m.is_new then
 343                         ret = args.first.mtype
 344                         res = self.new_var(ret)
 345                 else if ret == null then
 346                         res = null
 347                 else
 348                         ret = self.resolve_for(ret, args.first)
 349                         res = self.new_var(ret)
 350                 end
 351
 352                 self.add("/* send {m} on {args.first.inspect} */")
 353                 if args.first.mtype.ctype != "val*" then
 354                         var mclasstype = args.first.mtype.as(MClassType)
 355                         if not self.compiler.runtime_type_analysis.live_types.has(mclasstype) then
 356                                 self.add("/* skip, no method {m} */")
 357                                 return res
 358                         end
 359                         var propdef = m.lookup_first_definition(self.compiler.mainmodule, mclasstype)
 360                         var res2 = self.call(propdef, mclasstype, args)
 361                         if res != null then self.assign(res, res2.as(not null))
 362                         return res
 363                 end
 364                 var consider_null = not self.compiler.modelbuilder.toolcontext.opt_no_check_other.value or m.name == "==" or m.name == "!="
 365                 if args.first.mcasttype isa MNullableType or args.first.mcasttype isa MNullType and consider_null then
 366                         # The reciever is potentially null, so we have to 3 cases: ==, != or NullPointerException
 367                         self.add("if ({args.first} == NULL) \{ /* Special null case */")
 368                         if m.name == "==" then
 369                                 assert res != null
 370                                 if args[1].mcasttype isa MNullableType then
 371                                         self.add("{res} = ({args[1]} == NULL);")
 372                                 else if args[1].mcasttype isa MNullType then
 373                                         self.add("{res} = 1; /* is null */")
 374                                 else
 375                                         self.add("{res} = 0; /* {args[1].inspect} cannot be null */")
 376                                 end
 377                         else if m.name == "!=" then
 378                                 assert res != null
 379                                 if args[1].mcasttype isa MNullableType then
 380                                         self.add("{res} = ({args[1]} != NULL);")
 381                                 else if args[1].mcasttype isa MNullType then
 382                                         self.add("{res} = 0; /* is null */")
 383                                 else
 384                                         self.add("{res} = 1; /* {args[1].inspect} cannot be null */")
 385                                 end
 386                         else
 387                                 self.add_abort("Receiver is null")
 388                         end
 389                         self.add "\} else"
 390                 end
 391                 if types.is_empty then
 392                         self.add("\{")
 393                         self.add("/*BUG: no live types for {args.first.inspect} . {m}*/")
 394                         self.bugtype(args.first)
 395                         self.add("\}")
 396                         return res
 397                 end
 398
 399                 self.add("switch({args.first}->classid) \{")
 400                 var last = types.last
 401                 var defaultpropdef: nullable MMethodDef = null
 402                 for t in types do
 403                         var propdef = m.lookup_first_definition(self.compiler.mainmodule, t)
 404                         if propdef.mclassdef.mclass.name == "Object" and t.ctype == "val*" then
 405                                 defaultpropdef = propdef
 406                                 continue
 407                         end
 408                         if not self.compiler.hardening and t == last and defaultpropdef == null then
 409                                 self.add("default: /* test {t} */")
 410                         else
 411                                 self.add("case {self.compiler.classid(t)}: /* test {t} */")
 412                         end
 413                         var res2 = self.call(propdef, t, args)
 414                         if res != null then self.assign(res, res2.as(not null))
 415                         self.add "break;"
 416                 end
 417                 if defaultpropdef != null then
 418                         self.add("default: /* default is Object */")
 419                         var res2 = self.call(defaultpropdef, defaultpropdef.mclassdef.bound_mtype, args)
 420                         if res != null then self.assign(res, res2.as(not null))
 421                 else if self.compiler.hardening then
 422                         self.add("default: /* bug */")
 423                         self.bugtype(args.first)
 424                 end
 425                 self.add("\}")
 426                 return res
 427         end
 428
 429         fun check_valid_reciever(recvtype: MClassType)
 430         do
 431                 if self.compiler.runtime_type_analysis.live_types.has(recvtype) or recvtype.mclass.name == "Object" then return
 432                 print "{recvtype} is not a live type"
 433                 abort
 434         end
 435
 436         # Subpart of old call function
 437         #
 438         # Checks if the type of the receiver is valid and corrects it if necessary
 439         private fun get_recvtype(m: MMethodDef, recvtype: MClassType, args: Array[RuntimeVariable]): MClassType
 440         do
 441                 check_valid_reciever(recvtype)
 442                 #debug("call {m} on {recvtype} on {args.first}:{args.first.mtype}")
 443                 if m.mclassdef.mclass.name == "Object" and recvtype.ctype == "val*" then
 444                         recvtype = m.mclassdef.bound_mtype
 445                 end
 446                 return recvtype
 447         end
 448
 449         # Subpart of old call function
 450         # Gets the receiver boxed and casted if necessary
 451         private fun get_recv(recvtype: MClassType, args: Array[RuntimeVariable]): RuntimeVariable
 452         do
 453                 return self.autoadapt(self.autobox(args.first, recvtype), recvtype)
 454         end
 455
 456         # Finalizes a call to a method ´m´ on type ´recvtype´ with arguments ´args´
 457         private fun finalize_call(m: MMethodDef, recvtype: MClassType, args: Array[RuntimeVariable]): nullable RuntimeVariable
 458         do
 459                 assert args.length == m.msignature.arity + 1 else debug("Invalid arity for {m}. {args.length} arguments given.")
 460
 461                 var rm = new CustomizedRuntimeFunction(m, recvtype)
 462                 return rm.call(self, args)
 463         end
 464
 465         redef fun call(m, recvtype, args)
 466         do
 467                 var recv_type = get_recvtype(m, recvtype, args)
 468                 var recv = get_recv(recv_type, args)
 469                 var new_args = args.to_a
 470                 self.varargize(m, m.msignature.as(not null), new_args)
 471                 new_args.first = recv
 472                 return finalize_call(m, recv_type, new_args)
 473         end
 474
 475         # Does a call without encapsulating varargs into an array
 476         # Avoids multiple encapsulation when calling a super in a variadic function
 477         fun call_without_varargize(m: MMethodDef, recvtype: MClassType, args: Array[RuntimeVariable]): nullable RuntimeVariable
 478         do
 479                 var recv_type = get_recvtype(m, recvtype, args)
 480                 var recv = get_recv(recv_type, args)
 481                 var new_args = args.to_a
 482                 new_args.first = recv
 483                 return finalize_call(m, recv_type, new_args)
 484         end
 485
 486         redef fun supercall(m: MMethodDef, recvtype: MClassType, args: Array[RuntimeVariable]): nullable RuntimeVariable
 487         do
 488                 var types = self.collect_types(args.first)
 489
 490                 var res: nullable RuntimeVariable
 491                 var ret = m.mproperty.intro.msignature.return_mtype
 492                 if ret == null then
 493                         res = null
 494                 else
 495                         ret = self.resolve_for(ret, args.first)
 496                         res = self.new_var(ret)
 497                 end
 498
 499                 self.add("/* super {m} on {args.first.inspect} */")
 500                 if args.first.mtype.ctype != "val*" then
 501                         var mclasstype = args.first.mtype.as(MClassType)
 502                         if not self.compiler.runtime_type_analysis.live_types.has(mclasstype) then
 503                                 self.add("/* skip, no method {m} */")
 504                                 return res
 505                         end
 506                         var propdef = m.lookup_next_definition(self.compiler.mainmodule, mclasstype)
 507                         var res2 = self.call_without_varargize(propdef, mclasstype, args)
 508                         if res != null then self.assign(res, res2.as(not null))
 509                         return res
 510                 end
 511
 512                 if types.is_empty then
 513                         self.add("\{")
 514                         self.add("/*BUG: no live types for {args.first.inspect} . {m}*/")
 515                         self.bugtype(args.first)
 516                         self.add("\}")
 517                         return res
 518                 end
 519
 520                 self.add("switch({args.first}->classid) \{")
 521                 var last = types.last
 522                 for t in types do
 523                         var propdef = m.lookup_next_definition(self.compiler.mainmodule, t)
 524                         if not self.compiler.hardening and t == last then
 525                                 self.add("default: /* test {t} */")
 526                         else
 527                                 self.add("case {self.compiler.classid(t)}: /* test {t} */")
 528                         end
 529                         var res2 = self.call_without_varargize(propdef, t, args)
 530                         if res != null then self.assign(res, res2.as(not null))
 531                         self.add "break;"
 532                 end
 533                 if self.compiler.hardening then
 534                         self.add("default: /* bug */")
 535                         self.bugtype(args.first)
 536                 end
 537                 self.add("\}")
 538                 return res
 539         end
 540
 541         redef fun adapt_signature(m, args)
 542         do
 543                 var recv = args.first
 544                 for i in [0..m.msignature.arity[ do
 545                         var t = m.msignature.mparameters[i].mtype
 546                         if i == m.msignature.vararg_rank then
 547                                 t = args[i+1].mtype
 548                         end
 549                         t = self.resolve_for(t, recv)
 550                         args[i+1] = self.autobox(args[i+1], t)
 551                 end
 552         end
 553
 554         # FIXME: this is currently buggy since recv is not exact
 555         redef fun vararg_instance(mpropdef, recv, varargs, elttype)
 556         do
 557                 elttype = self.resolve_for(elttype, recv)
 558                 return self.array_instance(varargs, elttype)
 559         end
 560
 561         fun bugtype(recv: RuntimeVariable)
 562         do
 563                 if recv.mtype.ctype != "val*" then return
 564                 self.add("fprintf(stderr, \"BTD BUG: Dynamic type is %s, static type is %s\\n\", class_names[{recv}->classid], \"{recv.mcasttype}\");")
 565                 self.add("show_backtrace(1);")
 566         end
 567
 568         redef fun isset_attribute(a, recv)
 569         do
 570                 check_recv_notnull(recv)
 571
 572                 var types = self.collect_types(recv)
 573                 var res = self.new_var(bool_type)
 574
 575                 if types.is_empty then
 576                         self.add("/*BUG: no live types for {recv.inspect} . {a}*/")
 577                         self.bugtype(recv)
 578                         return res
 579                 end
 580                 self.add("/* isset {a} on {recv.inspect} */")
 581                 self.add("switch({recv}->classid) \{")
 582                 var last = types.last
 583                 for t in types do
 584                         if not self.compiler.hardening and t == last then
 585                                 self.add("default: /*{self.compiler.classid(t)}*/")
 586                         else
 587                                 self.add("case {self.compiler.classid(t)}:")
 588                         end
 589                         var recv2 = self.autoadapt(recv, t)
 590                         var ta = a.intro.static_mtype.as(not null)
 591                         ta = self.resolve_for(ta, recv2)
 592                         var attr = self.new_expr("((struct {t.c_name}*){recv})->{a.intro.c_name}", ta)
 593                         if not ta isa MNullableType then
 594                                 if ta.ctype == "val*" then
 595                                         self.add("{res} = ({attr} != NULL);")
 596                                 else
 597                                         self.add("{res} = 1; /*NOTYET isset on primitive attributes*/")
 598                                 end
 599                         end
 600                         self.add("break;")
 601                 end
 602                 if self.compiler.hardening then
 603                         self.add("default: /* Bug */")
 604                         self.bugtype(recv)
 605                 end
 606                 self.add("\}")
 607
 608                 return res
 609         end
 610
 611         redef fun read_attribute(a, recv)
 612         do
 613                 check_recv_notnull(recv)
 614
 615                 var types = self.collect_types(recv)
 616
 617                 var ret = a.intro.static_mtype.as(not null)
 618                 ret = self.resolve_for(ret, recv)
 619                 var res = self.new_var(ret)
 620
 621                 if types.is_empty then
 622                         self.add("/*BUG: no live types for {recv.inspect} . {a}*/")
 623                         self.bugtype(recv)
 624                         return res
 625                 end
 626                 self.add("/* read {a} on {recv.inspect} */")
 627                 self.add("switch({recv}->classid) \{")
 628                 var last = types.last
 629                 for t in types do
 630                         if not self.compiler.hardening and t == last then
 631                                 self.add("default: /*{self.compiler.classid(t)}*/")
 632                         else
 633                                 self.add("case {self.compiler.classid(t)}:")
 634                         end
 635                         var recv2 = self.autoadapt(recv, t)
 636                         var ta = a.intro.static_mtype.as(not null)
 637                         ta = self.resolve_for(ta, recv2)
 638                         var res2 = self.new_expr("((struct {t.c_name}*){recv})->{a.intro.c_name}", ta)
 639                         if not ta isa MNullableType and not self.compiler.modelbuilder.toolcontext.opt_no_check_other.value then
 640                                 if ta.ctype == "val*" then
 641                                         self.add("if ({res2} == NULL) \{")
 642                                         self.add_abort("Uninitialized attribute {a.name}")
 643                                         self.add("\}")
 644                                 else
 645                                         self.add("/*NOTYET isset on primitive attributes*/")
 646                                 end
 647                         end
 648                         self.assign(res, res2)
 649                         self.add("break;")
 650                 end
 651                 if self.compiler.hardening then
 652                         self.add("default: /* Bug */")
 653                         self.bugtype(recv)
 654                 end
 655                 self.add("\}")
 656
 657                 return res
 658         end
 659
 660         redef fun write_attribute(a, recv, value)
 661         do
 662                 check_recv_notnull(recv)
 663
 664                 var types = self.collect_types(recv)
 665
 666                 if types.is_empty then
 667                         self.add("/*BUG: no live types for {recv.inspect} . {a}*/")
 668                         self.bugtype(recv)
 669                         return
 670                 end
 671                 self.add("/* write {a} on {recv.inspect} */")
 672                 self.add("switch({recv}->classid) \{")
 673                 var last = types.last
 674                 for t in types do
 675                         if not self.compiler.hardening and t == last then
 676                                 self.add("default: /*{self.compiler.classid(t)}*/")
 677                         else
 678                                 self.add("case {self.compiler.classid(t)}:")
 679                         end
 680                         var recv2 = self.autoadapt(recv, t)
 681                         var ta = a.intro.static_mtype.as(not null)
 682                         ta = self.resolve_for(ta, recv2)
 683                         self.add("((struct {t.c_name}*){recv})->{a.intro.c_name} = {self.autobox(value, ta)};")
 684                         self.add("break;")
 685                 end
 686                 if self.compiler.hardening then
 687                         self.add("default: /* Bug*/")
 688                         self.bugtype(recv)
 689                 end
 690                 self.add("\}")
 691         end
 692
 693         redef fun init_instance(mtype)
 694         do
 695                 mtype = self.anchor(mtype).as(MClassType)
 696                 if not self.compiler.runtime_type_analysis.live_types.has(mtype) then
 697                         debug "problem: {mtype} was detected dead"
 698                 end
 699                 var res = self.new_expr("NEW_{mtype.c_name}()", mtype)
 700                 res.is_exact = true
 701                 return res
 702         end
 703
 704         redef fun type_test(value, mtype, tag)
 705         do
 706                 mtype = self.anchor(mtype)
 707                 if not self.compiler.runtime_type_analysis.live_cast_types.has(mtype) then
 708                         debug "problem: {mtype} was detected cast-dead"
 709                         abort
 710                 end
 711
 712                 var types = self.collect_types(value)
 713                 var res = self.new_var(bool_type)
 714
 715                 self.add("/* isa {mtype} on {value.inspect} */")
 716                 if value.mtype.ctype != "val*" then
 717                         if value.mtype.is_subtype(self.compiler.mainmodule, null, mtype) then
 718                                 self.add("{res} = 1;")
 719                         else
 720                                 self.add("{res} = 0;")
 721                         end
 722                         return res
 723                 end
 724                 if value.mcasttype isa MNullableType or value.mcasttype isa MNullType then
 725                         self.add("if ({value} == NULL) \{")
 726                         if mtype isa MNullableType then
 727                                 self.add("{res} = 1; /* isa {mtype} */")
 728                         else
 729                                 self.add("{res} = 0; /* not isa {mtype} */")
 730                         end
 731                         self.add("\} else ")
 732                 end
 733                 self.add("switch({value}->classid) \{")
 734                 for t in types do
 735                         if t.is_subtype(self.compiler.mainmodule, null, mtype) then
 736                                 self.add("case {self.compiler.classid(t)}: /* {t} */")
 737                         end
 738                 end
 739                 self.add("{res} = 1;")
 740                 self.add("break;")
 741                 self.add("default:")
 742                 self.add("{res} = 0;")
 743                 self.add("\}")
 744
 745                 return res
 746         end
 747
 748         redef fun is_same_type_test(value1, value2)
 749         do
 750                 var res = self.new_var(bool_type)
 751                 if value2.mtype.ctype == "val*" then
 752                         if value1.mtype.ctype == "val*" then
 753                                 self.add "{res} = {value1}->classid == {value2}->classid;"
 754                         else
 755                                 self.add "{res} = {self.compiler.classid(value1.mtype.as(MClassType))} == {value2}->classid;"
 756                         end
 757                 else
 758                         if value1.mtype.ctype == "val*" then
 759                                 self.add "{res} = {value1}->classid == {self.compiler.classid(value2.mtype.as(MClassType))};"
 760                         else if value1.mcasttype == value2.mcasttype then
 761                                 self.add "{res} = 1;"
 762                         else
 763                                 self.add "{res} = 0;"
 764                         end
 765                 end
 766                 return res
 767         end
 768
 769         redef fun class_name_string(value)
 770         do
 771                 var res = self.get_name("var_class_name")
 772                 self.add_decl("const char* {res};")
 773                 if value.mtype.ctype == "val*" then
 774                         self.add "{res} = class_names[{value}->classid];"
 775                 else
 776                         self.add "{res} = class_names[{self.compiler.classid(value.mtype.as(MClassType))}];"
 777                 end
 778                 return res
 779         end
 780
 781         redef fun equal_test(value1, value2)
 782         do
 783                 var res = self.new_var(bool_type)
 784                 if value2.mtype.ctype != "val*" and value1.mtype.ctype == "val*" then
 785                         var tmp = value1
 786                         value1 = value2
 787                         value2 = tmp
 788                 end
 789                 if value1.mtype.ctype != "val*" then
 790                         if value2.mtype == value1.mtype then
 791                                 self.add("{res} = {value1} == {value2};")
 792                         else if value2.mtype.ctype != "val*" then
 793                                 self.add("{res} = 0; /* incompatible types {value1.mtype} vs. {value2.mtype}*/")
 794                         else
 795                                 var mtype1 = value1.mtype.as(MClassType)
 796                                 self.add("{res} = ({value2} != NULL) && ({value2}->classid == {self.compiler.classid(mtype1)});")
 797                                 self.add("if ({res}) \{")
 798                                 self.add("{res} = ({self.autobox(value2, value1.mtype)} == {value1});")
 799                                 self.add("\}")
 800                         end
 801                 else
 802                         var s = new Array[String]
 803                         for t in self.compiler.live_primitive_types do
 804                                 if not t.is_subtype(self.compiler.mainmodule, null, value1.mcasttype) then continue
 805                                 if not t.is_subtype(self.compiler.mainmodule, null, value2.mcasttype) then continue
 806                                 s.add "({value1}->classid == {self.compiler.classid(t)} && ((struct {t.c_name}*){value1})->value == ((struct {t.c_name}*){value2})->value)"
 807                         end
 808                         if s.is_empty then
 809                                 self.add("{res} = {value1} == {value2};")
 810                         else
 811                                 self.add("{res} = {value1} == {value2} || ({value1} != NULL && {value2} != NULL && {value1}->classid == {value2}->classid && ({s.join(" || ")}));")
 812                         end
 813                 end
 814                 return res
 815         end
 816
 817         redef fun array_instance(array, elttype)
 818         do
 819                 elttype = self.anchor(elttype)
 820                 var arraytype = self.get_class("Array").get_mtype([elttype])
 821                 var res = self.init_instance(arraytype)
 822                 self.add("\{ /* {res} = array_instance Array[{elttype}] */")
 823                 var nat = self.new_var(self.get_class("NativeArray").get_mtype([elttype]))
 824                 nat.is_exact = true
 825                 self.add("{nat} = NEW_{nat.mtype.c_name}({array.length});")
 826                 for i in [0..array.length[ do
 827                         var r = self.autobox(array[i], elttype)
 828                         self.add("((struct {nat.mtype.c_name}*) {nat})->values[{i}] = {r};")
 829                 end
 830                 var length = self.int_instance(array.length)
 831                 self.send(self.get_property("with_native", arraytype), [res, nat, length])
 832                 self.add("\}")
 833                 return res
 834         end
 835 end
 836
 837 # A runtime function customized on a specific monomrph receiver type
 838 private class CustomizedRuntimeFunction
 839         super AbstractRuntimeFunction
 840
 841         redef type COMPILER: GlobalCompiler
 842         redef type VISITOR: GlobalCompilerVisitor
 843
 844         # The considered reciever
 845         # (usually is a live type but no strong guarantee)
 846         var recv: MClassType
 847
 848         init(mmethoddef: MMethodDef, recv: MClassType)
 849         do
 850                 super(mmethoddef)
 851                 self.recv = recv
 852         end
 853
 854         redef fun build_c_name
 855         do
 856                 var res = self.c_name_cache
 857                 if res != null then return res
 858                 if self.mmethoddef.mclassdef.bound_mtype == self.recv then
 859                         res = self.mmethoddef.c_name
 860                 else
 861                         res = "{mmethoddef.c_name}__{recv.c_name}"
 862                 end
 863                 self.c_name_cache = res
 864                 return res
 865         end
 866
 867         # used in the compiler worklist
 868         redef fun ==(o)
 869         do
 870                 if not o isa CustomizedRuntimeFunction then return false
 871                 if self.mmethoddef != o.mmethoddef then return false
 872                 if self.recv != o.recv then return false
 873                 return true
 874         end
 875
 876         # used in the compiler work-list
 877         redef fun hash do return self.mmethoddef.hash + self.recv.hash
 878
 879         redef fun to_s
 880         do
 881                 if self.mmethoddef.mclassdef.bound_mtype == self.recv then
 882                         return self.mmethoddef.to_s
 883                 else
 884                         return "{self.mmethoddef}@{self.recv}"
 885                 end
 886         end
 887
 888         # compile the code customized for the reciever
 889         redef fun compile_to_c(compiler)
 890         do
 891                 var recv = self.recv
 892                 var mmethoddef = self.mmethoddef
 893                 if not recv.is_subtype(compiler.mainmodule, null, mmethoddef.mclassdef.bound_mtype) then
 894                         print("problem: why do we compile {self} for {recv}?")
 895                         abort
 896                 end
 897
 898                 var v = compiler.new_visitor
 899                 var selfvar = new RuntimeVariable("self", recv, recv)
 900                 if compiler.runtime_type_analysis.live_types.has(recv) then
 901                         selfvar.is_exact = true
 902                 end
 903                 var arguments = new Array[RuntimeVariable]
 904                 var frame = new Frame(v, mmethoddef, recv, arguments)
 905                 v.frame = frame
 906
 907                 var sig = new FlatBuffer
 908                 var comment = new FlatBuffer
 909                 var ret = mmethoddef.msignature.return_mtype
 910                 if ret != null then
 911                         ret = v.resolve_for(ret, selfvar)
 912                         sig.append("{ret.ctype} ")
 913                 else if mmethoddef.mproperty.is_new then
 914                         ret = recv
 915                         sig.append("{ret.ctype} ")
 916                 else
 917                         sig.append("void ")
 918                 end
 919                 sig.append(self.c_name)
 920                 sig.append("({recv.ctype} {selfvar}")
 921                 comment.append("(self: {recv}")
 922                 arguments.add(selfvar)
 923                 for i in [0..mmethoddef.msignature.arity[ do
 924                         var mtype = mmethoddef.msignature.mparameters[i].mtype
 925                         if i == mmethoddef.msignature.vararg_rank then
 926                                 mtype = v.get_class("Array").get_mtype([mtype])
 927                         end
 928                         mtype = v.resolve_for(mtype, selfvar)
 929                         comment.append(", {mtype}")
 930                         sig.append(", {mtype.ctype} p{i}")
 931                         var argvar = new RuntimeVariable("p{i}", mtype, mtype)
 932                         arguments.add(argvar)
 933                 end
 934                 sig.append(")")
 935                 comment.append(")")
 936                 if ret != null then
 937                         comment.append(": {ret}")
 938                 end
 939                 compiler.header.add_decl("{sig};")
 940
 941                 v.add_decl("/* method {self} for {comment} */")
 942                 v.add_decl("{sig} \{")
 943                 #v.add("printf(\"method {self} for {comment}\\n\");")
 944                 if ret != null then
 945                         frame.returnvar = v.new_var(ret)
 946                 end
 947                 frame.returnlabel = v.get_name("RET_LABEL")
 948
 949                 mmethoddef.compile_inside_to_c(v, arguments)
 950
 951                 v.add("{frame.returnlabel.as(not null)}:;")
 952                 if ret != null then
 953                         v.add("return {frame.returnvar.as(not null)};")
 954                 end
 955                 v.add("\}")
 956                 if not self.c_name.has_substring("VIRTUAL", 0) then compiler.names[self.c_name] = "{mmethoddef.mclassdef.mmodule.name}::{mmethoddef.mclassdef.mclass.name}::{mmethoddef.mproperty.name} ({mmethoddef.location.file.filename}:{mmethoddef.location.line_start})"
 957         end
 958
 959         redef fun call(v: VISITOR, arguments: Array[RuntimeVariable]): nullable RuntimeVariable
 960         do
 961                 var ret = self.mmethoddef.msignature.return_mtype
 962                 if self.mmethoddef.mproperty.is_new then
 963                         ret = recv
 964                 end
 965                 if ret != null then
 966                         ret = v.resolve_for(ret, arguments.first)
 967                 end
 968                 if self.mmethoddef.can_inline(v) then
 969                         var frame = new Frame(v, self.mmethoddef, self.recv, arguments)
 970                         frame.returnlabel = v.get_name("RET_LABEL")
 971                         if ret != null then
 972                                 frame.returnvar = v.new_var(ret)
 973                         end
 974                         var old_frame = v.frame
 975                         v.frame = frame
 976                         v.add("\{ /* Inline {self} ({arguments.join(",")}) */")
 977                         self.mmethoddef.compile_inside_to_c(v, arguments)
 978                         v.add("{frame.returnlabel.as(not null)}:(void)0;")
 979                         v.add("\}")
 980                         v.frame = old_frame
 981                         return frame.returnvar
 982                 end
 983                 v.adapt_signature(self.mmethoddef, arguments)
 984                 v.compiler.todo(self)
 985                 if ret == null then
 986                         v.add("{self.c_name}({arguments.join(",")});")
 987                         return null
 988                 else
 989                         var res = v.new_var(ret)
 990                         v.add("{res} = {self.c_name}({arguments.join(",")});")
 991                         return res
 992                 end
 993         end
 994 end