src/metrics/generate_hierarchies.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Create dot files for various hierarchies of a model.
  18 # See graphviz http://www.graphviz.org/
  19 module generate_hierarchies
  20
  21 import model
  22 private import metrics_base
  23 import frontend
  24 import model_viz
  25
  26 redef class ToolContext
  27         var generate_hierarchies_phase: Phase = new GenerateHierarchyPhase(self, null)
  28 end
  29
  30 private class GenerateHierarchyPhase
  31         super Phase
  32
  33         redef fun process_mainmodule(mainmodule)
  34         do
  35                 if not toolcontext.opt_generate_hyperdoc.value and not toolcontext.opt_all.value then return
  36                 var model = toolcontext.modelbuilder.model
  37                 generate_module_hierarchy(toolcontext, model)
  38                 generate_classdef_hierarchy(toolcontext, model)
  39                 generate_class_hierarchy(toolcontext, mainmodule)
  40         end
  41 end
  42
  43 # Create a dot file representing the module hierarchy of a model.
  44 # Importation relation is represented with arrow
  45 # Nesting relation is represented with nested boxes
  46 fun generate_module_hierarchy(toolcontext: ToolContext, model: Model)
  47 do
  48         var dot = new MProjectDot(model)
  49
  50         var projectpath = toolcontext.output_dir.join_path("project_hierarchy.dot")
  51         dot.mprojects.add(model.mprojects.first)
  52         dot.render(projectpath)
  53
  54         var modulepath = toolcontext.output_dir.join_path("module_hierarchy.dot")
  55         dot.mprojects.add_all(model.mprojects)
  56         dot.render(modulepath)
  57 end
  58
  59 # Create a dot file representing the class hierarchy of a model.
  60 fun generate_class_hierarchy(toolcontext: ToolContext, mmodule: MModule)
  61 do
  62         var buf = new FlatBuffer
  63         buf.append("digraph \{\n")
  64         buf.append("node [shape=box];\n")
  65         buf.append("rankdir=BT;\n")
  66         var hierarchy = mmodule.flatten_mclass_hierarchy
  67         for mclass in hierarchy do
  68                 buf.append("\"{mclass}\" [label=\"{mclass}\"];\n")
  69                 for s in hierarchy[mclass].direct_greaters do
  70                         buf.append("\"{mclass}\" -> \"{s}\";\n")
  71                 end
  72         end
  73         buf.append("\}\n")
  74         var f = new OFStream.open(toolcontext.output_dir.join_path("class_hierarchy.dot"))
  75         f.write(buf.to_s)
  76         f.close
  77 end
  78
  79 # Create a dot file representing the classdef hierarchy of a model.
  80 # For a simple user of the model, the classdef hierarchy is not really usefull, it is more an internal thing.
  81 fun generate_classdef_hierarchy(toolcontext: ToolContext, model: Model)
  82 do
  83         var buf = new FlatBuffer
  84         buf.append("digraph \{\n")
  85         buf.append("node [shape=box];\n")
  86         buf.append("rankdir=BT;\n")
  87         for mmodule in model.mmodules do
  88                 for mclassdef in mmodule.mclassdefs do
  89                         buf.append("\"{mclassdef} {mclassdef.bound_mtype}\" [label=\"{mclassdef.mmodule}\\n{mclassdef.bound_mtype}\"];\n")
  90                         for s in mclassdef.in_hierarchy.direct_greaters do
  91                                 buf.append("\"{mclassdef} {mclassdef.bound_mtype}\" -> \"{s} {s.bound_mtype}\";\n")
  92                         end
  93                 end
  94         end
  95         buf.append("\}\n")
  96         var f = new OFStream.open(toolcontext.output_dir.join_path("classdef_hierarchy.dot"))
  97         f.write(buf.to_s)
  98         f.close
  99 end