src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 extern_code_char
  44         = [all - ['`' + '\']]
  45         | '\' all
  46         ;
  47 extern_code_body = extern_code_char*;
  48
  49 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  50
  51 /*****************************************************************************/
  52 States
  53 /*****************************************************************************/
  54 initial;
  55
  56
  57 /*****************************************************************************/
  58 Tokens
  59 /*****************************************************************************/
  60
  61 blank = (' ' | tab)+;
  62
  63 eol = eol_helper;
  64 comment = '#' any* eol_helper?;
  65
  66 kwmodule = 'package'|'module';
  67 kwimport = 'import';
  68 kwclass = 'class';
  69 kwabstract = 'abstract';
  70 kwinterface = 'interface';
  71 kwenum = 'universal'|'enum';
  72 kwend = 'end';
  73 kwmeth = 'fun';
  74 kwtype = 'type';
  75 kwinit = 'init';
  76 kwredef = 'redef';
  77 kwis = 'is';
  78 kwdo = 'do';
  79 kwreadable = 'readable';
  80 kwwritable = 'writable';
  81 kwvar = 'var';
  82 kwintern = 'intern';
  83 kwextern = 'extern';
  84 kwprotected = 'protected';
  85 kwprivate = 'private';
  86 kwintrude = 'intrude';
  87 kwif = 'if';
  88 kwthen = 'then';
  89 kwelse = 'else';
  90 kwwhile = 'while';
  91 kwloop = 'loop';
  92 kwfor = 'for';
  93 kwin = 'in';
  94 kwand = 'and';
  95 kwor = 'or';
  96 kwnot = 'not';
  97 kwreturn = 'return';
  98 kwcontinue = 'continue';
  99 kwbreak = 'break';
 100 kwabort = 'abort';
 101 kwassert = 'assert';
 102 kwnew = 'new';
 103 kwisa = 'isa';
 104 kwonce = 'once';
 105 kwsuper = 'super';
 106 kwself = 'self';
 107 kwtrue = 'true';
 108 kwfalse = 'false';
 109 kwnull = 'null';
 110 kwas = 'as';
 111 kwnullable = 'nullable';
 112 kwisset = 'isset';
 113 kwlabel = 'label';
 114 kwdebug = '__debug__';
 115
 116 opar = '(';
 117 cpar = ')';
 118 obra = '[';
 119 cbra = ']';
 120 comma = ',';
 121 column = ':';
 122 quad = '::';
 123 assign = '=';
 124 pluseq = '+=';
 125 minuseq = '-=';
 126 dotdotdot = '...';
 127 dotdot = '..';
 128 dot = '.';
 129 plus = '+';
 130 minus = '-';
 131 star = '*';
 132 slash = '/';
 133 percent = '%';
 134 eq = '==';
 135 ne = '!=';
 136 lt = '<';
 137 le = '<=';
 138 ll = '<<';
 139 gt = '>';
 140 ge = '>=';
 141 gg = '>>';
 142 starship = '<=>';
 143 bang='!';
 144
 145 classid = uppercase letter*;
 146 id = lowercase letter*;
 147 attrid = '_' lowercase letter*;
 148
 149 number = digit+;
 150 float = digit* '.' digit+;
 151 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 152 string = '"' str_body '"';
 153 start_string = '"' str_body '{';
 154 mid_string = '}' str_body '{';
 155 end_string = '}' str_body '"';
 156 bad_char = ''' '\'? any;
 157 bad_string = ('"'|'}') str_body;
 158
 159 extern_code_segment = '`' '{' extern_code_body '`' '}';
 160
 161 /*****************************************************************************/
 162 Ignored Tokens
 163 /*****************************************************************************/
 164
 165 blank;
 166
 167 /*****************************************************************************/
 168 Productions
 169 /*****************************************************************************/
 170
 171 /* MODULES *******************************************************************/
 172 module
 173         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 174
 175 moduledecl
 176         = [doc]:no kwmodule no module_name [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, module_name)};
 177
 178 import
 179         = {std} [doc]:no visibility kwimport no module_name [n2]:n1 {-> New import.std(visibility, kwimport, module_name)}
 180         | {no} [doc]:no visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 181         ;
 182
 183 implicit_top_class {-> classdef}
 184         = propdefs_toplevel+ {-> New classdef.top([propdefs_toplevel.propdef])};
 185
 186 implicit_main_class {-> classdef?}
 187         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 188         | {null} n {-> Null}
 189         ;
 190 implicit_main_meth {-> propdef}
 191         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 192         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 193         ;
 194
 195 /* CLASSES *******************************************************************/
 196 classdef
 197         = [doc]:no redef visibility classkind no classid formaldefs? extern_code_block? [superclasses]:superclass* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], extern_code_block, [superclasses.superclass], [propdefs.propdef], kwend)};
 198 redef {-> kwredef?}
 199         = kwredef? {-> kwredef};
 200 classkind
 201         = {concrete} kwclass
 202         | {abstract} kwabstract kwclass
 203         | {interface} kwinterface
 204         | {enum} kwenum
 205         | {extern} kwextern
 206         ;
 207
 208 formaldefs {-> formaldef*}
 209         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 210 formaldefs_tail {-> formaldef}
 211         = comma no formaldef {-> formaldef};
 212 formaldef
 213         = classid typing? {-> New formaldef(classid, typing.type)};
 214
 215 superclass {-> superclass}
 216         = {super} no kwsuper [n2]:no type {-> New superclass(kwsuper, type)}
 217         ;
 218
 219 propdefs~toplevel {-> propdef}
 220         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 221         ;
 222 propdef~toplevel {-> propdef}
 223         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 224         | {assign_return} [doc]:no redef visibility kwmeth methid signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature_withret.signature, assign_return.expr)}
 225 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 226 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 227         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? extern_calls? extern_code_block? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string, extern_calls, extern_code_block)}
 228         | {extern_implicit} [doc]:no redef visibility kwmeth methid signature extern_calls? extern_code_block {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, Null, extern_calls, extern_code_block)}
 229 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null)}
 230 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, expr)}
 231 !toplevel| {var3} [doc]:no redef visibility kwvar id typing? writable2? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, Null)}
 232 !toplevel| {var4} [doc]:no redef visibility kwvar id typing? writable2? assign [n2]:no expr {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, expr)}
 233 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 234 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 235 !toplevel| {extern_init} [doc]:no redef visibility kwnew methid? signature kwis kwextern string? extern_calls? extern_code_block? {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls, extern_code_block)}
 236 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew methid? signature string? extern_calls? extern_code_block {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls, extern_code_block)}
 237         ;
 238 readable {-> able}
 239         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 240         ;
 241 writable {-> able}
 242         = redef kwwritable {-> New able.write(redef.kwredef, Null, kwwritable)}
 243         ;
 244 writable2 {-> able}
 245         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 246         ;
 247
 248 visibility
 249         = {public} {-> New visibility.public()}
 250         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 251         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 252         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 253         ;
 254
 255 methid {-> methid}
 256         = {id} id {-> New methid.id(id)}
 257         | {plus} plus {-> New methid.plus(plus)}
 258         | {minus} minus {-> New methid.minus(minus)}
 259         | {star} star {-> New methid.star(star)}
 260         | {slash} slash {-> New methid.slash(slash)}
 261         | {percent} percent {-> New methid.percent(percent)}
 262         | {eq} eq {-> New methid.eq(eq)}
 263         | {ne} ne {-> New methid.ne(ne)}
 264         | {le} le {-> New methid.le(le)}
 265         | {ge} ge {-> New methid.ge(ge)}
 266         | {lt} lt {-> New methid.lt(lt)}
 267         | {gt} gt {-> New methid.gt(gt)}
 268         | {ll} ll {-> New methid.ll(ll)}
 269         | {gg} gg {-> New methid.gg(gg)}
 270         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 271         | {starship} starship {-> New methid.starship(starship)}
 272         | {assign} id assign {-> New methid.assign(id, assign)}
 273         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 274         ;
 275
 276 signature~withret {-> signature}
 277         = opar no params? cpar typing [no2]:no closure_decls? {-> New signature(opar, [params.param], cpar, typing.type, [closure_decls.closure_decl])}
 278 !withret| {noret} opar no params? cpar [no2]:no closure_decls? {-> New signature(opar, [params.param], cpar, Null, [closure_decls.closure_decl])}
 279         | {nopar} typing no closure_decls? {-> New signature(Null, [], Null, typing.type, [closure_decls.closure_decl])}
 280 !withret| {noparnoret} no closure_decls? {-> New signature(Null, [], Null, Null, [closure_decls.closure_decl])}
 281         ;
 282
 283 signature_noclosures {-> signature}
 284         = opar no params? cpar typing? {-> New signature(opar, [params.param], cpar, typing.type, [])}
 285         | {nopar} typing? {-> New signature(Null, [], Null, typing.type, [])}
 286         ;
 287
 288 params {-> param*}
 289         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 290         ;
 291 params_tail {-> param}
 292         = comma no param {-> param};
 293 param
 294         = {untyped} id {-> New param(id, Null, Null)}
 295         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 296         ;
 297
 298 closure_decls {->closure_decl*}
 299         = closure_decl+ {-> [closure_decl]};
 300 closure_decl
 301         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 302         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 303         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 304         ;
 305
 306 assign_return{-> expr}
 307         = expr_final {-> New expr.return(Null, expr_final.expr)}
 308         ;
 309
 310 extern_calls {-> extern_calls}
 311         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 312         ;
 313 extern_call_tail {-> extern_call}
 314         = comma no extern_call {-> extern_call};
 315 extern_call {-> extern_call}
 316     = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 317     | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 318         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 319     ;
 320 extern_call_prop {-> extern_call}
 321     = {local} methid {-> New extern_call.local_prop( methid )}
 322         | {full} classid quad methid {-> New extern_call.full_prop( classid, quad, methid )}
 323         | {init} classid {-> New extern_call.init_prop( classid )}
 324         ;
 325 extern_call_cast {-> extern_call}
 326     = {as_cast} [from_type]:type kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, kwas, to_type)}
 327         | {as_nullable} type kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 328         | {as_not_nullable} type kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 329         ;
 330
 331 in_language = kwin string;
 332 extern_code_block = in_language? extern_code_segment;
 333 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 334
 335 /* TYPES *********************************************************************/
 336 type~nobra {-> type}
 337         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 338 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 339         ;
 340 types {-> type*}
 341         = type types_tail* {-> [type, types_tail.type]};
 342 types_tail {-> type}
 343         = comma no type {-> type};
 344 typing {-> type}
 345         = column no type {-> type};
 346
 347 /* STATMENTS *****************************************************************/
 348 stmtso~withelse~withend {-> expr?}
 349         = {block} n stmtsnend {-> stmtsnend.expr}
 350         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 351         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 352 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 353         ;
 354 stmts {-> expr}
 355         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 356 stmtsn {-> expr}
 357         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 358 stmtsnend {-> expr}
 359         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 360 stmts_tail {-> expr}
 361         = n stmt {-> stmt.expr};
 362 stmt~withelse {-> expr}
 363         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 364         | {assign} assignment~withelse {-> assignment~withelse.expr}
 365         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 366         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 367         | {abort} kwabort {-> New expr.abort(kwabort)}
 368         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 369         | {do} do~withelse {-> do~withelse.expr}
 370         | {if} if~withelse {-> if~withelse.expr}
 371         | {while} while~withelse {-> while~withelse.expr}
 372         | {loop} loop~withelse {-> loop~withelse.expr}
 373         | {for} for~withelse {-> for~withelse.expr}
 374         | {assert} assert~withelse {-> assert~withelse.expr}
 375         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, args_nopar.exprs, [closure_defs~withelse.closure_def])}
 376         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, args_nopar.exprs)}
 377         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 378         | {debug_type_is} kwdebug kwtype type column expr_final~withelse {-> New expr.debug_type(kwdebug, kwtype, expr_final~withelse.expr, type) }
 379         ;
 380
 381 label= kwlabel id;
 382
 383 closure_defs~withelse {-> closure_def*}
 384         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 385         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 386         ;
 387
 388 closure_def_last~withelse {-> closure_def}
 389         = bang [id]:closure_id idlist? kwdo stmtso_withend label {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso_withend.expr, label)}
 390         | {nolabel} bang [id]:closure_id idlist? kwdo stmtso~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse.expr, Null)}
 391         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 392         ;
 393
 394 closure_def {-> closure_def}
 395         = bang [id]:closure_id idlist? kwdo n stmtsn {-> New closure_def(bang, id, [idlist.id], kwdo, stmtsn.expr, Null)}
 396         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 397         ;
 398 closure_id
 399         = {simple} id
 400         | {break} kwbreak
 401         ;
 402
 403 assign_continue~withelse{-> expr}
 404         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 405         ;
 406
 407 vardecl~withelse{-> expr}
 408         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 409         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 410         ;
 411
 412 assignment~withelse {-> expr}
 413         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 414         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, args.exprs, assign,  expr_final~withelse.expr)}
 415         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, braargs.exprs, assign,  expr_final~withelse.expr)}
 416         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 417         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, args.exprs, assign_op,  expr_final~withelse.expr)}
 418         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, braargs.exprs, assign_op,  expr_final~withelse.expr)}
 419         ;
 420 assign_op
 421         = {plus} pluseq
 422         | {minus} minuseq
 423         ;
 424
 425 do~withelse {-> expr}
 426         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 427         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 428         ;
 429
 430 if~withelse {-> expr}
 431         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 432 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 433 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 434 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 435         ;
 436 elsepartblock {-> expr?}
 437         = {else} kwelse stmtso {-> stmtso.expr}
 438         | {empty} kwend {-> New expr.block([], kwend)}
 439         ;
 440
 441 loop~withelse {-> expr}
 442         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 443         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 444         ;
 445
 446 while~withelse {-> expr}
 447         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 448         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 449         ;
 450
 451 for~withelse {-> expr}
 452         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 453         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 454         ;
 455
 456 assert~withelse {-> expr}
 457         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 458 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 459         ;
 460 assertid {-> id}
 461         = id column {-> id};
 462
 463 /* EXPRESSIONS ***************************************************************/
 464 expr_final~nopar~withelse~nobra {-> expr}
 465         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 466         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, args.exprs, [closure_defs~withelse.closure_def])}
 467 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, braargs.exprs, [closure_defs~withelse.closure_def])}
 468         ;
 469
 470 expr~nopar~nobra {-> expr}
 471         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 472         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 473         ;
 474
 475 expr_and~nopar~nobra {-> expr}
 476         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 477         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 478         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 479         | {or_else} expr_and~nopar~nobra kwor kwelse no expr_not~nopar~nobra {-> New expr.or_else(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 480         ;
 481
 482 expr_not~nopar~nobra {-> expr}
 483         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 484         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 485         ;
 486
 487 expr_eq~nopar~nobra {-> expr}
 488         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 489         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 490         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 491         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 492         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 493         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 494         | {ll} expr_eq~nopar~nobra ll no [expr2]:expr_add~nopar~nobra {-> New expr.ll(expr_eq~nopar~nobra.expr, expr2.expr)}
 495         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 496         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 497         | {gg} expr_eq~nopar~nobra gg no [expr2]:expr_add~nopar~nobra {-> New expr.gg(expr_eq~nopar~nobra.expr, expr2.expr)}
 498         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 499         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 500         ;
 501
 502 expr_add~nopar~nobra {-> expr}
 503         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 504         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 505         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 506         ;
 507
 508 expr_mul~nopar~nobra {-> expr}
 509         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 510         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 511         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 512         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 513         ;
 514
 515 expr_minus~nopar~nobra {-> expr}
 516         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 517         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 518         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 519         ;
 520
 521 expr_new~nopar~nobra {-> expr}
 522         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 523         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, args.exprs)}
 524         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 525         ;
 526
 527 expr_atom~nopar~nobra {-> expr}
 528         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 529         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, args.exprs, [])}
 530         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, args.exprs)}
 531         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 532 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs, [])}
 533         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, args.exprs)}
 534 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 535 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(obra, expr, expr2.expr, cbra)}
 536 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(obra, expr, expr2.expr, cbra)}
 537 !nobra!nopar    | {array} braargs {-> New expr.array(braargs.exprs)}
 538         | {self} kwself {-> New expr.self(kwself)}
 539         | {true} kwtrue {-> New expr.true(kwtrue)}
 540         | {false} kwfalse {-> New expr.false(kwfalse)}
 541         | {null} kwnull {-> New expr.null(kwnull)}
 542         | {int} number  {-> New expr.int(number)}
 543         | {float} float  {-> New expr.float(float)}
 544         | {char} char  {-> New expr.char(char)}
 545         | {string} string  {-> New expr.string(string)}
 546         | {superstring} superstring  {-> superstring.expr}
 547 !nopar  | {par} opar expr cpar {-> New expr.par(opar, expr, cpar)}
 548         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 549         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 550         ;
 551
 552 superstring {-> expr}
 553         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 554 superstring_start {-> expr*}
 555         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 556 start_string_p {-> expr}
 557         = start_string {-> New expr.start_string(start_string)};
 558 superstring_middle {-> expr*}
 559         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 560 mid_string_p {-> expr}
 561         = mid_string {-> New expr.mid_string(mid_string)};
 562 superstring_end {-> expr}
 563         = end_string {-> New expr.end_string(end_string)};
 564
 565 /* MISC **********************************************************************/
 566
 567 recv~nopar~nobra {-> expr}
 568         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 569         | {implicit} {-> New expr.implicit_self()}
 570         ;
 571
 572 args {-> exprs}
 573         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 574         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 575         | {empty} {-> New exprs.list([])}
 576         ;
 577 args_nopar {-> exprs}
 578         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 579         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 580         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 581         | {empty} {-> New exprs.list([])}
 582         ;
 583 braargs {-> exprs}
 584         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 585 expr_list {-> expr*}
 586         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 587 expr_tail {-> expr}
 588         = comma no expr [n2]:no {-> expr};
 589 idlist {-> id*}
 590         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 591         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 592         ;
 593 idlist_nopar {-> id*}
 594         = {single} id {-> [id]}
 595         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 596         ;
 597
 598 module_name {-> module_name}
 599         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 600         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 601         ;
 602
 603 qualified
 604         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 605         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 606         ;
 607 modquad {-> id}
 608         = id quad no {-> id};
 609 classquad {-> classid}
 610         = classid quad no {-> classid};
 611
 612 n1      = {a} comment | {b} eol;
 613 n {-> doc?}
 614         = {a} n2? comment+ {-> New doc([comment])}
 615         | {b} n2 {-> Null}
 616         ;
 617 no {-> doc?}
 618         = {empty} {-> Null}
 619         | n {-> n.doc}
 620         ;
 621
 622 n2
 623         = {a} n2? comment+ eol+
 624         | {b} eol+
 625         ;
 626
 627 /*****************************************************************************/
 628 Abstract Syntax Tree
 629 /*****************************************************************************/
 630
 631 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 632
 633 moduledecl
 634         = doc? kwmodule [name]:module_name;
 635
 636 import  = {std} visibility kwimport [name]:module_name
 637         | {no} visibility kwimport kwend
 638         ;
 639
 640 visibility
 641         = {public}
 642         | {private} kwprivate
 643         | {protected} kwprotected
 644         | {intrude} kwintrude
 645         ;
 646
 647 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* extern_code_block? [superclasses]:superclass* [propdefs]:propdef* kwend
 648         | {top} [propdefs]:propdef*
 649         | {main} [propdefs]:propdef*
 650         ;
 651 classkind
 652         = {concrete} kwclass
 653         | {abstract} kwabstract kwclass
 654         | {interface} kwinterface
 655         | {enum} kwenum
 656         | {extern} kwextern
 657         ;
 658 formaldef = [id]:classid type?;
 659 superclass = kwsuper type;
 660
 661
 662 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? expr?
 663         | {meth} doc? kwredef? visibility methid signature
 664         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 665         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 666         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string? extern_calls? extern_code_block?
 667         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 668         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 669         | {extern_init} doc? kwredef? visibility kwnew methid? signature [extern]:string? extern_calls? extern_code_block?
 670         | {main_meth} kwredef? [block]:expr?
 671         | {type} doc? kwredef? visibility kwtype [id]:classid type
 672         ;
 673
 674 able    = {read} kwredef? kwreadable
 675         | {write} kwredef? visibility? kwwritable
 676         ;
 677
 678 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 679
 680 signature = opar? [params]:param* cpar? type? [closure_decls]:closure_decl*;
 681
 682 param   = id type? dotdotdot?
 683         ;
 684
 685 closure_decl = kwbreak? bang id signature expr?
 686         ;
 687
 688 type    = kwnullable? [id]:classid [types]:type*;
 689
 690 label = kwlabel id;
 691
 692 expr    = {block} expr* kwend?
 693         | {vardecl} kwvar id type? assign? expr?
 694         | {return} kwreturn? expr?
 695         | {break} kwbreak label? expr?
 696         | {abort} kwabort
 697         | {continue} kwcontinue? label? expr?
 698         | {do} kwdo [block]:expr? label?
 699         | {if} kwif expr [then]:expr? [else]:expr?
 700         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 701         | {while} kwwhile expr kwdo [block]:expr? label?
 702         | {loop} kwloop [block]:expr? label?
 703         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 704         | {assert} kwassert id? expr [else]:expr?
 705         | {once} kwonce expr
 706         | {send} expr
 707         | {binop} expr [expr2]:expr
 708         | {or} expr [expr2]:expr
 709         | {and} expr [expr2]:expr
 710         | {or_else} expr [expr2]:expr
 711         | {not} kwnot expr
 712         | {eq} expr [expr2]:expr
 713         | {ee} expr [expr2]:expr
 714         | {ne} expr [expr2]:expr
 715         | {lt} expr [expr2]:expr
 716         | {le} expr [expr2]:expr
 717         | {ll} expr [expr2]:expr
 718         | {gt} expr [expr2]:expr
 719         | {ge} expr [expr2]:expr
 720         | {gg} expr [expr2]:expr
 721         | {isa} expr type
 722         | {plus} expr [expr2]:expr
 723         | {minus} expr [expr2]:expr
 724         | {starship} expr [expr2]:expr
 725         | {star} expr [expr2]:expr
 726         | {slash} expr [expr2]:expr
 727         | {percent} expr [expr2]:expr
 728         | {uminus} minus expr
 729         | {new} kwnew type id? [args]:exprs
 730         | {attr} expr [id]:attrid
 731         | {attr_assign} expr [id]:attrid assign [value]:expr
 732         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 733         | {call} expr id [args]:exprs [closure_defs]:closure_def*
 734         | {call_assign} expr id [args]:exprs assign [value]:expr
 735         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 736         | {super} qualified? kwsuper [args]:exprs
 737         | {init} expr kwinit [args]:exprs
 738         | {bra} expr [args]:exprs [closure_defs]:closure_def*
 739         | {bra_assign} expr [args]:exprs assign [value]:expr
 740         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 741         | {closure_call} id [args]:exprs [closure_defs]:closure_def*
 742         | {var} id
 743         | {var_assign} id assign [value]:expr
 744         | {var_reassign} id assign_op [value]:expr
 745         | {range} expr [expr2]:expr
 746         | {crange} obra expr [expr2]:expr cbra
 747         | {orange} obra expr [expr2]:expr [cbra]:obra
 748         | {array} [exprs]:exprs
 749         | {self} kwself
 750         | {implicit_self}
 751         | {true} kwtrue
 752         | {false} kwfalse
 753         | {null} kwnull
 754         | {int} number
 755         | {float} float
 756         | {char} char
 757         | {string} string
 758         | {start_string} [string]:start_string
 759         | {mid_string} [string]:mid_string
 760         | {end_string} [string]:end_string
 761         | {superstring} [exprs]:expr*
 762         | {par} opar expr cpar
 763         | {as_cast} expr kwas opar type cpar
 764         | {as_notnull} expr kwas opar kwnot kwnull cpar
 765         | {isset_attr} kwisset expr [id]:attrid
 766         | {debug_type} kwdebug kwtype expr type
 767         ;
 768 exprs
 769         = {list} [exprs]:expr*
 770         | {par} opar [exprs]:expr* cpar
 771         | {bra} obra [exprs]:expr* cbra
 772         ;
 773 assign_op
 774         = {plus} pluseq
 775         | {minus} minuseq
 776         ;
 777
 778 closure_def
 779         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 780         ;
 781 closure_id
 782         = {simple} id
 783         | {break} kwbreak
 784         ;
 785
 786 module_name = quad? [path]:id* id;
 787 extern_calls = kwimport [extern_calls]:extern_call*
 788         ;
 789 extern_call =
 790         | {super} kwsuper
 791         | {local_prop} methid
 792         | {full_prop} classid quad? methid
 793         | {init_prop} classid
 794         | {cast_as} [from_type]:type kwas [to_type]:type
 795         | {as_nullable} type kwas kwnullable
 796         | {as_not_nullable} type kwas kwnot kwnullable
 797         ;
 798 in_language = kwin string;
 799 extern_code_block = in_language? extern_code_segment;
 800
 801 qualified = id* classid? ;
 802
 803 doc = comment+;
 804
 805 /*****************************************************************************/
 806