contrib/nitiwiki/src/nitiwiki.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # A wiki engine based on markdown files and git.
  16 module nitiwiki
  17
  18 import wiki_html
  19 import markdown_highlight
  20
  21 # Locate nit directory
  22 private fun compute_nit_dir(opt_nit_dir: OptionString): String do
  23         # the option has precedence
  24         var res = opt_nit_dir.value
  25         if res != null then
  26                 if not check_nit_dir(res) then
  27                         print "Fatal Error: --nit-dir does not seem to be a valid base Nit directory: {res}"
  28                         exit 1
  29                 end
  30                 return res
  31         end
  32
  33         # then the environ variable has precedence
  34         res = "NIT_DIR".environ
  35         if not res.is_empty then
  36                 if not check_nit_dir(res) then
  37                         print "Fatal Error: NIT_DIR does not seem to be a valid base Nit directory: {res}"
  38                         exit 1
  39                 end
  40                 return res
  41         end
  42
  43         # find the runpath of the program from argv[0]
  44         res = "{sys.program_name.dirname}/.."
  45         if check_nit_dir(res) then return res.simplify_path
  46
  47         # find the runpath of the process from /proc
  48         var exe = "/proc/self/exe"
  49         if exe.file_exists then
  50                 res = exe.realpath
  51                 res = res.dirname.join_path("..")
  52                 if check_nit_dir(res) then return res.simplify_path
  53         end
  54
  55         # search in the PATH
  56         var ps = "PATH".environ.split(":")
  57         for p in ps do
  58                 res = p/".."
  59                 if check_nit_dir(res) then return res.simplify_path
  60         end
  61
  62         print "Fatal Error: Cannot locate a valid base nit directory. It is quite unexpected. Try to set the environment variable `NIT_DIR` or to use the `--nit-dir` option."
  63         exit 1
  64         abort
  65 end
  66
  67 private fun check_nit_dir(res: String): Bool do
  68         return res.file_exists and "{res}/src/nit.nit".file_exists
  69 end
  70
  71 var opt_help = new OptionBool("Display this help message", "-h", "--help")
  72 var opt_verbose = new OptionCount("Verbose level", "-v")
  73 var opt_config = new OptionString("Path to config.ini file", "-c", "--config")
  74 var opt_init = new OptionBool("Initialize a new wiki in the current directory", "--init")
  75 var opt_status = new OptionBool("Display wiki status", "--status")
  76 var opt_render = new OptionBool("Render the out directory from markdown sources", "-r", "--render")
  77 var opt_force = new OptionBool("Force render even if source files are unchanged", "-f", "--force")
  78 var opt_clean = new OptionBool("Clean the output directory", "--clean")
  79 var opt_rsync = new OptionBool("Synchronize outdir with distant wiki using rsync", "-s", "--rsync")
  80 var opt_fetch = new OptionBool("Render local source from git repo", "--fetch")
  81 var opt_nit_dir = new OptionString("Nit base directory", "--nit-dir")
  82
  83 var context = new OptionContext
  84 context.add_option(opt_help, opt_verbose, opt_config)
  85 context.add_option(opt_init, opt_status, opt_render, opt_force)
  86 context.add_option(opt_clean, opt_rsync, opt_fetch, opt_nit_dir)
  87 context.parse(args)
  88
  89 var config_filename = "config.ini"
  90
  91 # --help
  92 if opt_help.value then
  93         context.usage
  94         exit 0
  95 end
  96
  97 # --init
  98 if opt_init.value then
  99         if config_filename.file_exists then
 100                 print "Already in a nitiwiki directory."
 101                 exit 0
 102         end
 103         var nitiwiki_home = "{compute_nit_dir(opt_nit_dir)}/contrib/nitiwiki"
 104         var tpl = "{nitiwiki_home}/examples/default/"
 105         if not tpl.file_exists then
 106                 print "Cannot find {tpl} files."
 107                 print "Maybe your NIT_DIR is not set properly?"
 108                 print "You can initialize nitiwiki manually by copying the default skeletton here."
 109                 exit 1
 110         end
 111         sys.system "cp -R -- {tpl.escape_to_sh}/* ."
 112         print "Initialized new nitiwiki."
 113         print "Set wiki settings by editing {config_filename}."
 114         exit 0
 115 end
 116
 117 # load config files
 118
 119 # --config
 120 var config_file = opt_config.value
 121 if config_file == null then
 122         config_file = config_filename
 123 end
 124
 125 if not config_file.file_exists then
 126         print "Not in a nitiwiki directory."
 127         print "Use --init to initialize one here."
 128         exit 0
 129 end
 130
 131 var config = new WikiConfig(config_file)
 132 var wiki = new Nitiwiki(config)
 133
 134 # --verbose
 135 wiki.verbose_level = opt_verbose.value
 136
 137 # --clean
 138 if opt_clean.value then
 139         wiki.clean
 140 end
 141
 142 # --fetch
 143 if opt_fetch.value then
 144         wiki.fetch
 145 end
 146
 147 # --render
 148 if opt_render.value then
 149         wiki.parse
 150         # --force
 151         wiki.force_render = opt_force.value
 152         wiki.render
 153 end
 154
 155 # --rsync
 156 if opt_rsync.value then
 157         wiki.sync
 158 end
 159
 160 # --status
 161 if opt_status.value or
 162         (not opt_clean.value and
 163          not opt_fetch.value and
 164          not opt_render.value and
 165          not opt_rsync.value) then
 166         wiki.parse
 167         wiki.status
 168 end