src/compiler/compiler_ffi.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2013 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # FFI support for the compilers
  18 module compiler_ffi
  19
  20 intrude import abstract_compiler
  21 intrude import common_ffi
  22 import nitni
  23
  24 redef class MModule
  25         private var foreign_callbacks = new ForeignCallbackSet
  26         var nitni_ccu: nullable CCompilationUnit = null
  27
  28         private fun nmodule(v: AbstractCompilerVisitor): nullable AModule
  29         do
  30                 var m2n = v.compiler.modelbuilder.mmodule2nmodule
  31                 return m2n.get_or_null(self)
  32         end
  33
  34         redef fun finalize_ffi(compiler: AbstractCompiler)
  35         do
  36                 if not uses_ffi then return
  37
  38                 var v = compiler.new_visitor
  39                 var n = nmodule(v)
  40                 if n == null then return
  41                 n.ensure_compile_ffi_wrapper
  42                 finalize_ffi_wrapper(v.compiler.modelbuilder.compile_dir, v.compiler.mainmodule)
  43                 for file in ffi_files do v.compiler.extern_bodies.add(file)
  44
  45                 ensure_compile_nitni_base(v)
  46
  47                 nitni_ccu.header_c_types.add("#include \"{name}._ffi.h\"\n")
  48                 nitni_ccu.header_c_types.add """
  49 extern void nitni_global_ref_incr(void*);
  50 extern void nitni_global_ref_decr(void*);
  51 """
  52
  53                 nitni_ccu.write_as_nitni(self, v.compiler.modelbuilder.compile_dir)
  54
  55                 for file in nitni_ccu.files do
  56                         v.compiler.extern_bodies.add(new ExternCFile(file, c_compiler_options))
  57                 end
  58
  59                 # reset FFI things so the next compilation job, if any, starts with a clean context
  60                 # FIXME clean and rationalize this
  61                 nitni_ccu = null
  62                 compiled_ffi_methods.clear
  63                 ffi_ccu = null
  64                 ffi_files.clear
  65                 compiled_callbacks.clear
  66                 #Do not reset `foreign_callbacks` and `ffi_callbacks` because they are computed in previous phases
  67         end
  68
  69         private fun ensure_compile_nitni_base(v: AbstractCompilerVisitor)
  70         do
  71                 if nitni_ccu != null then return
  72
  73                 nitni_ccu = new CCompilationUnit
  74         end
  75
  76         redef fun collect_linker_libs
  77         do
  78                 var s = c_linker_options
  79                 if s.is_empty then return null
  80                 var res = new ArraySet[String]
  81                 res.add s
  82                 return res
  83         end
  84
  85         private var compiled_callbacks: Array[NitniCallback] = new Array[NitniCallback]
  86
  87         # Returns true if callbacks has yet to be generated and register it as being generated
  88         private fun check_callback_compilation(cb: NitniCallback): Bool
  89         do
  90                 var compiled = compiled_callbacks.has(cb)
  91                 if not compiled then compiled_callbacks.add(cb)
  92                 return not compiled
  93         end
  94 end
  95
  96 redef class AMethPropdef
  97         private fun compile_ffi_support_to_c(v: AbstractCompilerVisitor)
  98         do
  99                 var mmodule = mpropdef.mclassdef.mmodule
 100                 var mainmodule = v.compiler.mainmodule
 101                 var amainmodule = v.compiler.modelbuilder.mmodule2nmodule[mainmodule]
 102                 var amodule = v.compiler.modelbuilder.mmodule2nmodule[mmodule]
 103                 var mclass_type = mpropdef.mclassdef.bound_mtype
 104
 105                 # Declare as extern
 106                 var csignature = mpropdef.mproperty.build_csignature(mclass_type, mmodule, "___impl", long_signature, internal_call_context)
 107                 v.declare_once("{csignature};")
 108
 109                 # FFI part
 110                 amodule.ensure_compile_ffi_wrapper
 111                 compile_ffi_method(mmodule)
 112
 113                 # nitni - Compile missing callbacks
 114                 mmodule.ensure_compile_nitni_base(v)
 115                 var ccu = mmodule.nitni_ccu.as(not null)
 116
 117                 for mtype in foreign_callbacks.types do
 118                         if not mtype.is_cprimitive then
 119                                 mtype.compile_extern_type(v, ccu)
 120
 121                                 # has callbacks already been compiled? (this may very well happen with global compilation)
 122                                 if mmodule.check_callback_compilation(mtype) then mtype.compile_extern_helper_functions(v, ccu)
 123                         end
 124                 end
 125
 126                 # compile callbacks
 127                 for cb in foreign_callbacks.callbacks do if mainmodule.check_callback_compilation(cb) then
 128                         cb.compile_extern_callback(v, ccu)
 129                 end
 130
 131                 for cb in foreign_callbacks.supers do if mainmodule.check_callback_compilation(cb) then
 132                         cb.compile_extern_callback(v, ccu)
 133                 end
 134
 135                 for cb in foreign_callbacks.casts do if mainmodule.check_callback_compilation(cb) then
 136                         cb.compile_extern_callbacks(v, ccu)
 137                 end
 138
 139                 # manage nitni callback set
 140                 mmodule.foreign_callbacks.join(foreign_callbacks)
 141         end
 142
 143         redef fun compile_externmeth_to_c(v, mpropdef, arguments)
 144         do
 145                 # if using the old native interface fallback on previous implementation
 146                 if n_extern_code_block == null then return super
 147
 148                 var mmodule = mpropdef.mclassdef.mmodule
 149                 mmodule.uses_ffi = true
 150
 151                 var mclass_type = mpropdef.mclassdef.bound_mtype
 152
 153                 # Outgoing code in compiler
 154                 var externname = mpropdef.mproperty.build_cname(mpropdef.mclassdef.bound_mtype, mmodule, "___impl", long_signature)
 155                 var recv_var: nullable RuntimeVariable = null
 156                 var return_mtype = mpropdef.msignature.return_mtype
 157                 if return_mtype != null then
 158                         return_mtype = return_mtype.anchor_to(mmodule, mclass_type)
 159                         recv_var = v.new_var(return_mtype)
 160                 end
 161
 162                 v.adapt_signature(mpropdef, arguments)
 163                 v.unbox_signature_extern(mpropdef, arguments)
 164
 165                 var arguments_for_c = new Array[String]
 166                 for a in [0..arguments.length[ do
 167                         var arg = arguments[a]
 168                         var param_mtype: MType
 169                         if a == 0 then
 170                                 param_mtype = mpropdef.mclassdef.mclass.mclass_type
 171                         else param_mtype = mpropdef.msignature.mparameters[a-1].mtype
 172
 173                         param_mtype = param_mtype.anchor_to(mmodule, mclass_type)
 174
 175                         if param_mtype.is_cprimitive then
 176                                 arguments_for_c.add(arg.name)
 177                         else
 178                                 v.add("struct nitni_instance* var_for_c_{a};")
 179                                 v.add("var_for_c_{a} = nit_alloc(sizeof(struct nitni_instance));")
 180                                 v.add("var_for_c_{a}->value = {arg.name};")
 181                                 arguments_for_c.add("var_for_c_{a}")
 182                         end
 183                 end
 184
 185                 if recv_var == null then
 186                         v.add("{externname}({arguments_for_c.join(", ")});")
 187                 else
 188                         assert return_mtype != null
 189                         if return_mtype.is_cprimitive then
 190                                 v.add("{recv_var} = {externname}({arguments_for_c.join(", ")});")
 191                         else
 192                                 v.add("struct nitni_instance* ret_var;")
 193                                 v.add("ret_var = {externname}({arguments_for_c.join(", ")});")
 194                                 v.add("{recv_var} = ret_var->value;")
 195                         end
 196                         recv_var = v.box_extern(recv_var, return_mtype)
 197                         v.ret(recv_var)
 198                 end
 199
 200                 compile_ffi_support_to_c(v)
 201                 return true
 202         end
 203
 204         redef fun compile_externinit_to_c(v, mpropdef, arguments)
 205         do
 206                 # if using the old native interface fallback on previous implementation
 207                 if n_extern_code_block == null then return super
 208
 209                 var mmodule = mpropdef.mclassdef.mmodule
 210                 mmodule.uses_ffi = true
 211
 212                 var mclass_type = mpropdef.mclassdef.bound_mtype
 213
 214                 var externname = mpropdef.mproperty.build_cname(mpropdef.mclassdef.bound_mtype, mmodule, "___impl", long_signature)
 215                 var return_mtype = arguments.first.mtype
 216                 var recv_var = v.new_var(return_mtype)
 217
 218                 v.adapt_signature(mpropdef, arguments)
 219                 v.unbox_signature_extern(mpropdef, arguments)
 220
 221                 arguments.shift
 222
 223                 var arguments_for_c = new Array[String]
 224                 for a in [0..arguments.length[ do
 225                         var arg = arguments[a]
 226                         var param_mtype: MType
 227                         param_mtype = mpropdef.msignature.mparameters[a].mtype
 228                         param_mtype = param_mtype.anchor_to(mmodule, mclass_type)
 229
 230                         if param_mtype.is_cprimitive then
 231                                 arguments_for_c.add(arg.name)
 232                         else
 233                                 v.add("struct nitni_instance* var_for_c_{a};")
 234                                 v.add("var_for_c_{a} = nit_alloc(sizeof(struct nitni_instance));")
 235                                 v.add("var_for_c_{a}->value = {arg.name};")
 236                                 arguments_for_c.add("var_for_c_{a}")
 237                         end
 238                 end
 239
 240                 if return_mtype.is_cprimitive then
 241                         v.add("{recv_var} = {externname}({arguments_for_c.join(", ")});")
 242                 else
 243                         v.add("struct nitni_instance* ret_var;")
 244                         v.add("ret_var = {externname}({arguments_for_c.join(", ")});")
 245                         v.add("{recv_var} = ret_var->value;")
 246                 end
 247                 recv_var = v.box_extern(recv_var, return_mtype)
 248                 v.ret(recv_var)
 249
 250                 compile_ffi_support_to_c(v)
 251                 return true
 252         end
 253 end
 254
 255 redef class CCompilationUnit
 256         fun write_as_nitni(mmodule: MModule, compdir: String)
 257         do
 258                 var base_name = "{mmodule.name}._nitni"
 259
 260                 var h_file = "{base_name}.h"
 261                 write_header_to_file( mmodule, "{compdir}/{h_file}", new Array[String],
 262                         "{mmodule.cname.to_s.to_upper}_NITG_NITNI_H")
 263
 264                 var c_file = "{base_name}.c"
 265                 write_body_to_file( mmodule, "{compdir}/{c_file}", ["\"{h_file}\""] )
 266
 267                 files.add( "{compdir}/{c_file}" )
 268         end
 269 end
 270
 271 redef class AbstractCompiler
 272         # Cache to avoid multiple compilation of NULL values
 273         # see FIXME in `MNullableType#compile_extern_helper_functions`
 274         private var compiled_null_types = new Array[MNullableType]
 275 end
 276
 277 redef class AbstractCompilerVisitor
 278         # Create a `RuntimeVariable` for this C variable originating from C user code
 279         private fun var_from_c(name: String, mtype: MType): RuntimeVariable
 280         do
 281                 if mtype.is_cprimitive then
 282                         return new RuntimeVariable(name, mtype, mtype)
 283                 else
 284                         return new RuntimeVariable("{name}->value", mtype, mtype)
 285                 end
 286         end
 287
 288         # Return a `RuntimeVarible` to C user code
 289         private fun ret_to_c(src: RuntimeVariable, mtype: MType)
 290         do
 291                 if mtype.is_cprimitive then
 292                         add("return {src};")
 293                 else
 294                         add("struct nitni_instance* ret_for_c;")
 295                         add("ret_for_c = nit_alloc(sizeof(struct nitni_instance));")
 296                         add("ret_for_c->value = {src};")
 297                         add("return ret_for_c;")
 298                 end
 299         end
 300 end
 301
 302 redef class MType
 303         private fun compile_extern_type(v: AbstractCompilerVisitor, ccu: CCompilationUnit)
 304         do
 305                 assert not is_cprimitive
 306
 307                 # define friendly type
 308                 ccu.header_c_types.add("#ifndef NIT_TYPE_{cname}\n")
 309                 ccu.header_c_types.add("#define NIT_TYPE_{cname} 1\n")
 310                 ccu.header_c_types.add("typedef struct nitni_instance *{cname};\n")
 311                 ccu.header_c_types.add("#endif\n")
 312         end
 313
 314         private fun compile_extern_helper_functions(v: AbstractCompilerVisitor, ccu: CCompilationUnit)
 315         do
 316                 # actually, we do not need to do anything when using the bohem garbage collector
 317                 var call_context = from_c_call_context
 318
 319                 # incr_ref
 320                 ccu.header_decl.add "#ifndef {mangled_cname}_incr_ref\n"
 321                 ccu.header_decl.add "   #define {mangled_cname}_incr_ref(from) nitni_global_ref_incr(({call_context.name_mtype(self)})(from))\n"
 322                 ccu.header_decl.add "#endif\n"
 323
 324                 # decr_ref
 325                 ccu.header_decl.add "#ifndef {mangled_cname}_decr_ref\n"
 326                 ccu.header_decl.add "   #define {mangled_cname}_decr_ref(from) nitni_global_ref_decr(({call_context.name_mtype(self)})(from))\n"
 327                 ccu.header_decl.add "#endif\n"
 328         end
 329 end
 330
 331 redef class MNullableType
 332         redef fun compile_extern_helper_functions(v, ccu)
 333         do
 334                 super
 335
 336                 var base_cname = "null_{mtype.mangled_cname}"
 337                 var full_cname = "NIT_NULL___{base_cname}"
 338
 339                 # In nitni files, declare internal function as extern
 340                 var full_friendly_csignature = "{cname_blind} {full_cname}()"
 341                 ccu.header_decl.add("extern {full_friendly_csignature};\n")
 342
 343                 # In nitni files, #define friendly as extern
 344                 ccu.header_decl.add("#define {base_cname} {full_cname}\n")
 345
 346                 # FIXME: This is ugly an broke the separate compilation principle
 347                 # The real function MUST be compiled only once, #define pragma only protect the compiler, not the loader
 348                 # However, I am not sure of the right approach here (eg. week refs are ugly)
 349                 if v.compiler.compiled_null_types.has(self) then return
 350                 v.compiler.compiled_null_types.add self
 351
 352                 # Internally, implement internal function
 353                 var nitni_visitor = v.compiler.new_visitor
 354                 nitni_visitor.frame = v.frame
 355                 var full_internal_csignature = "{cname_blind} {full_cname}()"
 356                 nitni_visitor.add("{full_internal_csignature} \{")
 357                 nitni_visitor.add("struct nitni_instance* ret_for_c;")
 358                 nitni_visitor.add("ret_for_c = nit_alloc(sizeof(struct nitni_instance));")
 359                 nitni_visitor.add("ret_for_c->value = NULL;")
 360                 nitni_visitor.add("return ret_for_c;")
 361                 nitni_visitor.add("\}")
 362         end
 363 end
 364
 365 redef class MExplicitCall
 366         private fun compile_extern_callback(v: AbstractCompilerVisitor, ccu: CCompilationUnit)
 367         do
 368                 var mproperty = mproperty
 369                 assert mproperty isa MMethod
 370
 371                 # In nitni files, declare internal function as extern
 372                 var full_friendly_csignature = mproperty.build_csignature(recv_mtype, v.compiler.mainmodule, null, long_signature, internal_call_context)
 373                 ccu.header_decl.add("extern {full_friendly_csignature};\n")
 374
 375                 # Internally, implement internal function
 376                 var nitni_visitor = v.compiler.new_visitor
 377                 nitni_visitor.frame = v.frame
 378                 var msignature = mproperty.lookup_first_definition(v.compiler.mainmodule, recv_mtype).msignature
 379                 var csignature_blind = mproperty.build_csignature(recv_mtype, v.compiler.mainmodule, null, long_signature, internal_call_context)
 380
 381                 nitni_visitor.add_decl("/* nitni callback for {mproperty.full_name} */")
 382                 nitni_visitor.add_decl("{csignature_blind} \{")
 383
 384                 var vars = new Array[RuntimeVariable]
 385                 var mtype: MType = recv_mtype
 386                 var recv_var = null
 387                 if mproperty.is_init then
 388                         var recv_mtype = recv_mtype
 389                         recv_var = nitni_visitor.init_instance(recv_mtype)
 390                         nitni_visitor.add("{mtype.ctype} recv /* var self: {mtype} */;")
 391                         nitni_visitor.add("recv = {recv_var};")
 392                 else
 393                         mtype = mtype.anchor_to(v.compiler.mainmodule, recv_mtype)
 394                         recv_var = nitni_visitor.var_from_c("recv", mtype)
 395                         recv_var = nitni_visitor.box_extern(recv_var, mtype)
 396                 end
 397
 398                 vars.add(recv_var)
 399
 400                 for p in msignature.mparameters do
 401                         var arg_mtype = p.mtype.anchor_to(v.compiler.mainmodule, recv_mtype)
 402                         var arg = nitni_visitor.var_from_c(p.name, arg_mtype)
 403                         arg = nitni_visitor.box_extern(arg, arg_mtype)
 404                         vars.add(arg)
 405                 end
 406
 407                 var ret_var = nitni_visitor.send(mproperty, vars)
 408
 409                 var return_mtype = msignature.return_mtype
 410                 if mproperty.is_init then
 411                         if recv_mtype.mclass.kind != extern_kind then ret_var = recv_var
 412                         return_mtype = recv_mtype
 413                 end
 414                 if return_mtype != null then
 415                         assert ret_var != null
 416                         return_mtype = return_mtype.anchor_to(v.compiler.mainmodule, recv_mtype)
 417                         ret_var = nitni_visitor.autobox(ret_var, return_mtype)
 418                         ret_var = nitni_visitor.unbox_extern(ret_var, return_mtype)
 419                         nitni_visitor.ret_to_c(ret_var, return_mtype)
 420                 end
 421                 nitni_visitor.add("\}")
 422         end
 423 end
 424
 425 redef class MExplicitSuper
 426         private fun compile_extern_callback(v: AbstractCompilerVisitor, ccu: CCompilationUnit)
 427         do
 428                 var mproperty = from.mproperty
 429                 assert mproperty isa MMethod
 430                 var mclass_type = from.mclassdef.mclass.mclass_type
 431                 var mmodule = from.mclassdef.mmodule
 432
 433                 # In nitni files, declare internal function as extern
 434                 var internal_csignature = mproperty.build_csignature(mclass_type, v.compiler.mainmodule, "___super", long_signature, internal_call_context)
 435                 ccu.header_decl.add("extern {internal_csignature};\n")
 436
 437                 # In nitni files, #define friendly as extern
 438                 var friendly_cname = mproperty.build_cname(mclass_type, v.compiler.mainmodule, "___super", short_signature)
 439                 var internal_cname = mproperty.build_cname(mclass_type, v.compiler.mainmodule, "___super", long_signature)
 440                 ccu.header_decl.add("#define {friendly_cname} {internal_cname}\n")
 441
 442                 # Internally, implement internal function
 443                 var nitni_visitor = v.compiler.new_visitor
 444                 nitni_visitor.frame = v.frame
 445                 var msignature = mproperty.lookup_first_definition(v.compiler.mainmodule, mclass_type).msignature
 446
 447                 var csignature_blind = mproperty.build_csignature(mclass_type, v.compiler.mainmodule, "___super", long_signature, internal_call_context)
 448
 449                 nitni_visitor.add_decl("/* nitni callback to super for {mproperty.full_name} */")
 450                 nitni_visitor.add_decl("{csignature_blind} \{")
 451
 452                 var vars = new Array[RuntimeVariable]
 453
 454                 var recv_var = nitni_visitor.var_from_c("recv", mclass_type)
 455                 recv_var = nitni_visitor.box_extern(recv_var, mclass_type)
 456                 vars.add(recv_var)
 457
 458                 for p in msignature.mparameters do
 459                         var arg_mtype = v.anchor(p.mtype)
 460                         var arg = nitni_visitor.var_from_c(p.name, arg_mtype)
 461                         arg = nitni_visitor.box_extern(arg, arg_mtype)
 462                         vars.add(arg)
 463                 end
 464
 465                 var ret_var = nitni_visitor.supercall(from.as(MMethodDef), mclass_type, vars)
 466
 467                 var return_mtype = msignature.return_mtype
 468                 if return_mtype != null then
 469                         assert ret_var != null
 470                         return_mtype = v.anchor(return_mtype)
 471                         ret_var = nitni_visitor.autobox(ret_var, return_mtype)
 472                         ret_var = nitni_visitor.unbox_extern(ret_var, return_mtype)
 473                         nitni_visitor.ret_to_c(ret_var, return_mtype)
 474                 end
 475                 nitni_visitor.add("\}")
 476         end
 477 end
 478
 479 redef class MExplicitCast
 480         private fun compile_extern_callbacks(v: AbstractCompilerVisitor, ccu: CCompilationUnit)
 481         do
 482                 var from = from
 483                 var to = to
 484
 485                 #
 486                 ## check type
 487                 #
 488
 489                 # In nitni files, declare internal function as extern
 490                 var full_friendly_csignature = "int {v.compiler.mainmodule.name }___{from.mangled_cname}_is_a_{to.mangled_cname}({from.cname_blind})"
 491                 ccu.header_decl.add("extern {full_friendly_csignature};\n")
 492
 493                 # In nitni files, #define friendly as extern
 494                 ccu.header_decl.add("#define {check_cname} {v.compiler.mainmodule.name}___{check_cname}\n")
 495
 496                 # Internally, implement internal function
 497                 var nitni_visitor = v.compiler.new_visitor
 498                 nitni_visitor.frame = v.frame
 499
 500                 var full_internal_csignature = "int {v.compiler.mainmodule.name }___{from.mangled_cname}_is_a_{to.mangled_cname}({internal_call_context.name_mtype(from)} from)"
 501
 502                 nitni_visitor.add_decl("/* nitni check for {from} to {to} */")
 503                 nitni_visitor.add_decl("{full_internal_csignature} \{")
 504
 505                 #var from_var = new RuntimeVariable("from->value", from, from)
 506                 var from_var = nitni_visitor.var_from_c("from", from)
 507                 from_var = nitni_visitor.box_extern(from_var, from)
 508                 var recv_var = nitni_visitor.type_test(from_var, to, "FFI isa")
 509                 nitni_visitor.add("return {recv_var};")
 510
 511                 nitni_visitor.add("\}")
 512
 513                 # special checks
 514                 if from == to.as_nullable then
 515                         # format A_is_null
 516                         ccu.header_decl.add("#define {from.mangled_cname}_is_null !{from.mangled_cname}_is_a_{to.mangled_cname}\n")
 517                 end
 518
 519                 #
 520                 ## cast
 521                 #
 522
 523                 # In nitni files, declare internal function as extern
 524                 full_friendly_csignature = "{to.cname_blind} {v.compiler.mainmodule.name }___{from.mangled_cname}_as_{to.mangled_cname}({from.cname_blind})"
 525                 ccu.header_decl.add("extern {full_friendly_csignature};\n")
 526
 527                 # In nitni files, #define friendly as extern
 528                 ccu.header_decl.add("#define {cast_cname} {v.compiler.mainmodule.name}___{cast_cname}\n")
 529
 530                 # Internally, implement internal function
 531                 nitni_visitor = v.compiler.new_visitor
 532                 nitni_visitor.frame = v.frame
 533
 534                 full_internal_csignature = "{to.cname_blind} {v.compiler.mainmodule.name }___{from.mangled_cname}_as_{to.mangled_cname}({internal_call_context.name_mtype(from)} from)"
 535                 nitni_visitor.add_decl("/* nitni cast for {from} to {to} */")
 536                 nitni_visitor.add_decl("{full_internal_csignature} \{")
 537
 538                 from_var = nitni_visitor.var_from_c("from", from)
 539                 from_var = nitni_visitor.box_extern(from_var, from)
 540
 541                 ## test type
 542                 var check = nitni_visitor.type_test(from_var, to, "FFI cast")
 543                 nitni_visitor.add("if (!{check}) \{")
 544                 nitni_visitor.add_abort("FFI cast failed")
 545                 nitni_visitor.add("\}")
 546
 547                 ## internal cast
 548                 recv_var = nitni_visitor.autobox(from_var, to)
 549                 recv_var = nitni_visitor.unbox_extern(recv_var, to)
 550
 551                 nitni_visitor.ret_to_c(recv_var, to)
 552
 553                 nitni_visitor.add("\}")
 554
 555                 # special casts
 556                 if from.as_nullable == to then
 557                         # format A_as_nullable
 558                         ccu.header_decl.add("#define {from.mangled_cname}_as_nullable {from.mangled_cname}_as_{to.mangled_cname}\n")
 559                 end
 560
 561                 if from == to.as_nullable then
 562                         # format A_as_nullable
 563                         ccu.header_decl.add("#define {to.mangled_cname}_as_not_nullable {from.mangled_cname}_as_{to.mangled_cname}\n")
 564                 end
 565         end
 566 end