src/common_ffi/common_ffi.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2013 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # FFI concers common between the compilers and the interpreter.
  18 # Offers services to compile modules using foreign code. Mainly allows
  19 # to wrap foreign code in Nit methods.
  20 module common_ffi
  21
  22 import modelbuilder
  23
  24 import nitni
  25
  26 intrude import ffi_base
  27 import extern_classes
  28 import header_dependency
  29 import pkgconfig
  30 import c_compiler_options
  31 import c
  32 import cpp
  33 import java
  34 import extra_java_files
  35
  36 redef class MModule
  37         # Does this module uses the FFI?
  38         var uses_ffi: Bool = false
  39
  40         # C compilation unit for the FFI files
  41         private var ffi_ccu: nullable CCompilationUnit = null
  42
  43         # Foreign language used in this AModule
  44         private var present_languages = new HashSet[FFILanguage]
  45
  46         # Complete the compilation of the FFI code
  47         fun finalize_ffi_wrapper(compdir: String, mainmodule: MModule)
  48         do
  49                 for language in ffi_callbacks.keys do
  50                         for callback in ffi_callbacks[language] do
  51                                 language.compile_callback(callback, self, mainmodule, ffi_ccu.as(not null))
  52                         end
  53
  54                         language.compile_to_files(self, compdir)
  55                 end
  56
  57                 # include dependancies FFI
  58                 for mod in header_dependencies do
  59                         if mod.uses_ffi then ffi_ccu.header_custom.add("#include \"{mod.name}._ffi.h\"\n")
  60                 end
  61
  62                 ffi_ccu.write_as_impl(self, compdir)
  63                 for filename in ffi_ccu.files do ffi_files.add(new ExternCFile(filename, c_compiler_options))
  64         end
  65
  66         # Avoid the compile a ffi propdef more than once
  67         # See `AMethPropdef::compile_ffi_method`
  68         # FIXME find a better way
  69         private var compiled_ffi_methods = new HashSet[AMethPropdef]
  70 end
  71
  72 redef class AModule
  73
  74         # Ensures all of the general foreign code of the module has been analyzed.
  75         # Manages header blocks, extern class types and foreign dependancies between modules
  76         fun ensure_compile_ffi_wrapper
  77         do
  78                 var mmodule = mmodule
  79                 if mmodule == null or mmodule.ffi_ccu != null then return
  80
  81                 # ready extern code compiler
  82                 var ffi_ccu = new CCompilationUnit
  83                 mmodule.ffi_ccu = ffi_ccu
  84
  85                 # generate code
  86                 for block in n_extern_code_blocks do
  87                         var language = block.language
  88                         assert language != null
  89                         mmodule.present_languages.add(language)
  90                         language.compile_module_block(block, ffi_ccu, mmodule)
  91                 end
  92
  93                 ffi_ccu.header_c_base.add( "#include \"{mmodule.name}._nitni.h\"\n" )
  94
  95                 ffi_ccu.body_decl.add("#ifdef ANDROID\n")
  96                 ffi_ccu.body_decl.add(" #include <android/log.h>\n")
  97                 ffi_ccu.body_decl.add(" #define PRINT_ERROR(...) (void)__android_log_print(ANDROID_LOG_WARN, \"Nit\", __VA_ARGS__)\n")
  98                 ffi_ccu.body_decl.add("#else\n")
  99                 ffi_ccu.body_decl.add(" #define PRINT_ERROR(...) fprintf(stderr, __VA_ARGS__)\n")
 100                 ffi_ccu.body_decl.add("#endif\n")
 101
 102                 for nclassdef in n_classdefs do
 103                         # Does it declares an extern type?
 104                         if nclassdef isa AStdClassdef and nclassdef.n_extern_code_block != null then
 105                                 mmodule.uses_ffi = true
 106                                 var language = nclassdef.n_extern_code_block.language
 107                                 assert language != null
 108                                 mmodule.present_languages.add(language)
 109                                 nclassdef.n_extern_code_block.language.compile_extern_class(
 110                                         nclassdef.n_extern_code_block.as(not null), nclassdef, ffi_ccu, mmodule)
 111                         end
 112                 end
 113         end
 114 end
 115
 116 redef class AMethPropdef
 117         # Compile the necessary wrapper around this extern method or constructor
 118         fun compile_ffi_method(mmodule: MModule)
 119         do
 120                 assert n_extern_code_block != null
 121
 122                 if mmodule.compiled_ffi_methods.has(self) then return
 123                 mmodule.compiled_ffi_methods.add self
 124
 125                 var language = n_extern_code_block.language
 126                 assert language != null
 127                 mmodule.present_languages.add(language)
 128                 n_extern_code_block.language.compile_extern_method(
 129                         n_extern_code_block.as(not null), self, mmodule.ffi_ccu.as(not null), mmodule)
 130         end
 131 end
 132
 133 redef class VerifyNitniCallbacksPhase
 134         redef fun process_npropdef(npropdef)
 135         do
 136                 super
 137
 138                 if not npropdef isa AExternPropdef then return
 139
 140                 var code_block = npropdef.n_extern_code_block
 141                 if code_block == null then return
 142
 143                 var lang = code_block.language
 144                 assert lang != null
 145
 146                 # Associate callbacks used by an extern method to its foreign language
 147                 for callback in npropdef.foreign_callbacks.all do
 148                         var map = npropdef.mpropdef.mclassdef.mmodule.ffi_callbacks
 149                         if not map.keys.has(lang) then map[lang] = new HashSet[NitniCallback]
 150                         map[lang].add(callback)
 151                 end
 152         end
 153 end