src/common_ffi/pkgconfig.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2013 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Offers the `PkgconfigPhase` to use the external program "pkg-config" in order
  18 # to discover what options to pass to the C or C++ compiler.
  19 module pkgconfig
  20
  21 import c
  22 private import annotation
  23 private import literal
  24
  25 redef class ToolContext
  26         var pkgconfig_phase: Phase = new PkgconfigPhase(self, [literal_phase])
  27 end
  28
  29 # Detects the `pkgconfig` annotation on the module declaration only.
  30 class PkgconfigPhase
  31         super Phase
  32
  33         redef fun process_annotated_node(nmoduledecl, nat)
  34         do
  35                 # Skip if we are not interested
  36                 if nat.name != "pkgconfig" then return
  37
  38                 # Do some validity checks and print errors if the annotation is used incorrectly
  39                 var modelbuilder = toolcontext.modelbuilder
  40
  41                 if not nmoduledecl isa AModuledecl then
  42                         modelbuilder.error(nat, "Syntax error: only the declaration of modules may use \"pkgconfig\".")
  43                         return
  44                 end
  45
  46                 var args = nat.n_args
  47                 if args.is_empty then
  48                         modelbuilder.error(nat, "Syntax error: \"pkgconfig\" expects at least one argument.")
  49                         return
  50                 end
  51
  52                 var pkgs = new Array[String]
  53                 for arg in args do
  54                         var pkg = arg.as_string
  55                         if pkg == null then
  56                                 modelbuilder.error(nat, "Syntax error: \"pkgconfig\" expects its arguments to be the name of the package as String literals.")
  57                                 return
  58                         end
  59
  60                         pkgs.add(pkg)
  61                 end
  62
  63                 # retreive module
  64                 var nmodule = nmoduledecl.parent.as(AModule)
  65                 var mmodule = nmodule.mmodule.as(not null)
  66
  67                 # check availability of pkg-config
  68                 var proc_which = new IProcess("which", "pkg-config")
  69                 proc_which.wait
  70                 var status = proc_which.status
  71                 if status != 0 then
  72                         modelbuilder.error(nat, "Error: program pkg-config not found, make sure it is installed.")
  73                         return
  74                 end
  75
  76                 for pkg in pkgs do
  77                         var proc_exist = new Process("pkg-config", "--exists", pkg)
  78                         proc_exist.wait
  79                         status = proc_exist.status
  80                         if status == 1 then
  81                                 modelbuilder.error(nat, "Error: package \"{pkg}\" unknown by pkg-config, make sure the development package is be installed.")
  82                                 return
  83                         else if status != 0 then
  84                                 modelbuilder.error(nat, "Error: something went wrong calling pkg-config, make sure it is correctly installed.")
  85                                 return
  86                         end
  87
  88                         # compiler
  89                         var proc = new IProcess("pkg-config", "--cflags", pkg)
  90                         var compiler_opts = proc.read_all
  91                         mmodule.c_compiler_options = "{mmodule.c_compiler_options} {compiler_opts.replace("\n", " ")}"
  92
  93                         # linker
  94                         proc = new IProcess("pkg-config", "--libs", pkg)
  95                         var linker_opts = proc.read_all
  96                         mmodule.c_linker_options = "{mmodule.c_linker_options} {linker_opts.replace("\n", " ")}"
  97                 end
  98
  99         end
 100 end