src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwpackage = 'package';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwuniversal = 'universal';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'meth';
  69 kwtype = 'type';
  70 kwattr = 'attr';
  71 kwinit = 'init';
  72 kwredef = 'redef';
  73 kwis = 'is';
  74 kwdo = 'do';
  75 kwreadable = 'readable';
  76 kwwritable = 'writable';
  77 kwvar = 'var';
  78 kwintern = 'intern';
  79 kwextern = 'extern';
  80 kwprotected = 'protected';
  81 kwprivate = 'private';
  82 kwintrude = 'intrude';
  83 kwif = 'if';
  84 kwthen = 'then';
  85 kwelse = 'else';
  86 kwwhile = 'while';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105
 106 opar = '(';
 107 cpar = ')';
 108 obra = '[';
 109 cbra = ']';
 110 comma = ',';
 111 column = ':';
 112 quad = '::';
 113 assign = '=';
 114 pluseq = '+=';
 115 minuseq = '-=';
 116 dotdotdot = '...';
 117 dotdot = '..';
 118 dot = '.';
 119 plus = '+';
 120 minus = '-';
 121 star = '*';
 122 slash = '/';
 123 percent = '%';
 124 eq = '==';
 125 ne = '!=';
 126 lt = '<';
 127 le = '<=';
 128 gt = '>';
 129 ge = '>=';
 130 starship = '<=>';
 131
 132 classid = uppercase letter*;
 133 id = lowercase letter*;
 134 attrid = '_' lowercase letter*;
 135
 136 number = digit+;
 137 float = digit* '.' digit+;
 138 char = ''' [any - ''']* ''';
 139 string = '"' str_body '"';
 140 start_string = '"' str_body '{';
 141 mid_string = '}' str_body '{';
 142 end_string = '}' str_body '"';
 143
 144
 145 /*****************************************************************************/
 146 Ignored Tokens
 147 /*****************************************************************************/
 148
 149 blank;
 150
 151 /*****************************************************************************/
 152 Productions
 153 /*****************************************************************************/
 154
 155 /* MODULES *******************************************************************/
 156 module
 157         = packagedecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(packagedecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 158
 159 packagedecl
 160         = [doc]:no kwpackage no id [n2]:n1 {-> New packagedecl(doc.doc, kwpackage, id)};
 161
 162 import
 163         = [doc]:no visibility kwimport no id [n2]:n1            {-> New import(visibility, kwimport, id)}
 164         | {no} [doc]:no visibility kwimport no kwend [n2]:n1    {-> New import.no(visibility, kwimport, kwend)}
 165         ;
 166
 167 implicit_top_class {-> classdef}
 168         = tl_propdefs {-> New classdef.top([tl_propdefs.propdef])};
 169
 170 implicit_main_class {-> classdef?}
 171         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 172         | {null} n {-> Null}
 173         ;
 174 implicit_main_meth {-> propdef}
 175         = [doc]:no stmts no {-> New propdef.main_meth(Null, stmts.expr)};
 176
 177 /* CLASSES *******************************************************************/
 178 classdef
 179         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs? [n2]:no kwend {-> New classdef(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef])};
 180 redef {-> kwredef?}
 181         = kwredef? {-> kwredef};
 182 classkind
 183         = {concrete} kwclass
 184         | {abstract} kwabstract kwclass
 185         | {interface} kwinterface
 186         | {universal} kwuniversal
 187         ;
 188
 189 formaldefs {-> formaldef*}
 190         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 191 formaldefs_tail {-> formaldef}
 192         = comma no formaldef {-> formaldef};
 193 formaldef
 194         = classid typing? {-> New formaldef(classid, typing.type)};
 195
 196 special {-> superclass}
 197         = no kwspecial [n2]:no type {-> New superclass(kwspecial, type)};
 198
 199 propdefs {-> propdef*}
 200         = propdef n1 propdefs_tail* {-> [propdef, propdefs_tail.propdef]};
 201 propdefs_tail {-> propdef}
 202         = propdef n1 {-> propdef};
 203 propdef
 204         = {attr} [doc]:no readable writable redef visibility kwattr attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwattr, attrid, typing.type, Null)}
 205         | {attr2} [doc]:no readable writable redef visibility kwattr attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwattr, attrid, typing.type, expr)}
 206         | {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature)}
 207         | {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature)}
 208         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, string)}
 209         | {meth} [doc]:no redef visibility kwmeth methid signature no kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 210         | {init} [doc]:no redef visibility kwinit methid? signature no kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 211         | {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 212         ;
 213 readable {-> able?}
 214         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 215         | {empty} {-> Null}
 216         ;
 217 writable {-> able?}
 218         = redef kwwritable {-> New able.write(redef.kwredef, kwwritable)}
 219         | {empty} {-> Null}
 220         ;
 221
 222 tl_propdefs {-> propdef*}
 223         = tl_propdef n1 tl_propdefs_tail* {-> [tl_propdef.propdef, tl_propdefs_tail.propdef]};
 224 tl_propdefs_tail {-> propdef}
 225         = tl_propdef n1 {-> tl_propdef.propdef};
 226 tl_propdef {-> propdef}
 227         = {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, string)}
 228         | {meth} [doc]:no redef visibility kwmeth methid signature no kwdo stmtso {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 229         ;
 230
 231 visibility
 232         = {public} {-> New visibility.public()}
 233         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 234         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 235         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 236         ;
 237
 238 methid
 239         = {id} id
 240         | {plus} plus
 241         | {minus} minus
 242         | {star} star
 243         | {slash} slash
 244         | {percent} percent
 245         | {eq} eq
 246         | {ne} ne
 247         | {le} le
 248         | {ge} ge
 249         | {lt} lt
 250         | {gt} gt
 251         | {bra} obra cbra
 252         | {starship} starship
 253         | {assign} id assign
 254         | {braassign} obra cbra assign
 255         ;
 256
 257 signature
 258         = params? typing? {-> New signature([params.param], typing.type)};
 259
 260 params {-> param*}
 261         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 262         | {empty} opar no cpar {-> []}
 263         ;
 264 params_tail {-> param}
 265         = comma no param {-> param};
 266 param
 267         = {untyped} id {-> New param(id, Null, Null)}
 268         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 269         ;
 270
 271 /* TYPES *********************************************************************/
 272 type/*B3*//*B*/ {-> type}
 273         = {simple} classid {-> New type(classid, [])}
 274 /*N*/   | {generic} classid obra no types [n2]:no cbra {-> New type(classid, [types.type])}
 275         ;
 276 /*E*/
 277 types {-> type*}
 278         = type types_tail* {-> [type, types_tail.type]};
 279 types_tail {-> type}
 280         = comma no type {-> type};
 281 typing {-> type}
 282         = column no type {-> type};
 283
 284 /* STATMENTS *****************************************************************/
 285 stmtso/*B2*/ {-> expr?}
 286         = {oneline} stmt/*B2*/ {-> stmt/*B2*/.expr}
 287         | {block} n stmts [n2]:n kwend {-> stmts.expr}
 288         | {emptyblock} n kwend {-> Null}
 289         | {emptyoneline} kwend {-> Null}
 290         ;
 291 stmts {-> expr}
 292         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr])};
 293 stmts_tail {-> expr}
 294         = n stmt {-> stmt.expr};
 295 stmt/*B2*/ {-> expr}
 296         = {vardecl} vardecl {-> vardecl.expr}
 297         | {assign} assignment {-> assignment.expr}
 298         | {return} kwreturn expr? {-> New expr.return(kwreturn, expr)}
 299         | {break} kwbreak {-> New expr.break(kwbreak)}
 300         | {abort} kwabort {-> New expr.abort(kwabort)}
 301         | {continue} kwcontinue {-> New expr.continue(kwcontinue)}
 302         | {do} do/*B2*/ {-> do/*B2*/.expr}
 303         | {if} if/*B2*/ {-> if/*B2*/.expr}
 304         | {while} while/*B2*/ {-> while/*B2*/.expr}
 305         | {for} for/*B2*/ {-> for/*B2*/.expr}
 306         | {assert} assert {-> assert.expr}
 307 //      | {expr} expr {-> expr.expr}
 308         | {call} recv id args_nopar {-> New expr.call(recv.expr, id, [args_nopar.expr])}
 309         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 310         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 311         ;
 312
 313 vardecl {-> expr}
 314         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 315         | {assign} kwvar id typing? assign no expr {-> New expr.vardecl(kwvar, id, typing.type, assign, expr)}
 316         ;
 317
 318 assignment {-> expr}
 319         = {attr} recv attrid assign expr {-> New expr.attr_assign(recv.expr, attrid, assign, expr)}
 320         | {call} recv id args assign expr {-> New expr.call_assign(recv.expr, id, [args.expr], assign, expr)}
 321         | {bra} expr_atom braargs assign expr {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign, expr)}
 322         | {attr_re} recv attrid assign_op expr {-> New expr.attr_reassign(recv.expr, attrid, assign_op, expr)}
 323         | {call_re} recv id args assign_op expr {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op, expr)}
 324         | {bra_re} expr_atom braargs assign_op expr {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op, expr)}
 325         ;
 326 assign_op
 327         = {plus} pluseq
 328         | {minus} minuseq
 329         ;
 330
 331 do/*B2*/ {-> expr}
 332         = kwdo stmtso/*B2*/ {-> New expr.do(kwdo, stmtso/*B2*/.expr)}
 333         ;
 334
 335 if/*B2*/ {-> expr}
 336         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso/*B2*/ {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso/*B2*/.expr)}
 337 /*N2*/  | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 338 /*N2*/  | {block} kwif no expr [n2]:no kwthen [n3]:n stmts [n4]:n elsepartblock {-> New expr.if(kwif, expr, stmts.expr, elsepartblock.expr)}
 339 /*N2*/  | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 340         ;
 341 elsepartblock {-> expr?}
 342         = {else} kwelse stmtso {-> stmtso.expr}
 343         | {empty} kwend {-> Null}
 344         ;
 345
 346 while/*B2*/ {-> expr}
 347         = kwwhile no expr [n2]:no kwdo stmtso/*B2*/ {-> New expr.while(kwwhile, expr, kwdo, stmtso/*B2*/.expr)};
 348
 349 for/*B2*/ {-> expr}
 350         = for_vardecl [n4]:no kwdo stmtso/*B2*/ {-> New expr.for(for_vardecl.expr, kwdo, stmtso/*B2*/.expr)};
 351 for_vardecl {-> expr}
 352         = kwfor no id [n2]:no kwin [n3]:no expr {-> New expr.for_vardecl(kwfor, id, expr)};
 353
 354 assert {-> expr}
 355         = kwassert assertid? expr {-> New expr.assert(kwassert, assertid.id, expr)};
 356 assertid {-> id}
 357         = id column {-> id};
 358
 359 /* EXPRESSIONS ***************************************************************/
 360 expr/*B3*//*B*/ {-> expr}
 361         = expr_and/*B3*//*B*/ {-> expr_and/*B3*//*B*/.expr}
 362         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr/*B3*//*B*/ {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 363         ;
 364
 365 expr_and/*B3*//*B*/ {-> expr}
 366         = expr_not/*B3*//*B*/ {-> expr_not/*B3*//*B*/.expr}
 367         | {or} expr_and/*B3*//*B*/ kwor no expr_not/*B3*//*B*/ {-> New expr.or(expr_and/*B3*//*B*/.expr, expr_not/*B3*//*B*/.expr)}
 368         | {and} expr_and/*B3*//*B*/ kwand no expr_not/*B3*//*B*/ {-> New expr.and(expr_and/*B3*//*B*/.expr, expr_not/*B3*//*B*/.expr)}
 369         ;
 370
 371 expr_not/*B3*//*B*/ {-> expr}
 372         = expr_eq/*B3*//*B*/ {-> expr_eq/*B3*//*B*/.expr}
 373         | {not} kwnot no expr_not/*B3*//*B*/ {-> New expr.not(kwnot, expr_not/*B3*//*B*/.expr)}
 374         ;
 375
 376 expr_eq/*B3*//*B*/ {-> expr}
 377         = expr_add/*B3*//*B*/ {-> expr_add/*B3*//*B*/.expr}
 378         | {eq} expr_add/*B3*//*B*/ eq no [expr2]:expr_add/*B3*//*B*/ {-> New expr.eq(expr_add/*B3*//*B*/.expr, expr2.expr)}
 379         | {ee} expr_add/*B3*//*B*/ kwis no [expr2]:expr_add/*B3*//*B*/ {-> New expr.ee(expr_add/*B3*//*B*/.expr, expr2.expr)}
 380         | {ne} expr_add/*B3*//*B*/ ne no [expr2]:expr_add/*B3*//*B*/ {-> New expr.ne(expr_add/*B3*//*B*/.expr, expr2.expr)}
 381         | {lt} expr_add/*B3*//*B*/ lt no [expr2]:expr_add/*B3*//*B*/ {-> New expr.lt(expr_add/*B3*//*B*/.expr, expr2.expr)}
 382         | {le} expr_add/*B3*//*B*/ le no [expr2]:expr_add/*B3*//*B*/ {-> New expr.le(expr_add/*B3*//*B*/.expr, expr2.expr)}
 383         | {gt} expr_add/*B3*//*B*/ gt no [expr2]:expr_add/*B3*//*B*/ {-> New expr.gt(expr_add/*B3*//*B*/.expr, expr2.expr)}
 384         | {ge} expr_add/*B3*//*B*/ ge no [expr2]:expr_add/*B3*//*B*/ {-> New expr.ge(expr_add/*B3*//*B*/.expr, expr2.expr)}
 385         | {starship} expr_add/*B3*//*B*/ starship no [expr2]:expr_add/*B3*//*B*/ {-> New expr.starship(expr_add/*B3*//*B*/.expr, expr2.expr)}
 386         | {isa} expr_add/*B3*//*B*/ kwisa no type/*B3*//*B*/ {-> New expr.isa(expr_add/*B3*//*B*/.expr, type/*B3*//*B*/.type)}
 387         ;
 388
 389 expr_add/*B3*//*B*/ {-> expr}
 390         =  expr_mul/*B3*//*B*/ {-> expr_mul/*B3*//*B*/.expr}
 391         | {plus} expr_add/*B3*//*B*/ plus no [expr2]:expr_mul/*B3*//*B*/ {-> New expr.plus(expr_add/*B3*//*B*/.expr, expr2.expr)}
 392         | {minus} expr_add/*B3*//*B*/ minus no [expr2]:expr_mul/*B3*//*B*/ {-> New expr.minus(expr_add/*B3*//*B*/.expr, expr2.expr)}
 393         ;
 394
 395 expr_mul/*B3*//*B*/ {-> expr}
 396         = expr_minus/*B3*//*B*/ {-> expr_minus/*B3*//*B*/.expr}
 397         | {star} expr_mul/*B3*//*B*/ star no [expr2]:expr_minus/*B3*//*B*/ {-> New expr.star(expr_mul/*B3*//*B*/.expr, expr2.expr)}
 398         | {slash} expr_mul/*B3*//*B*/ slash no [expr2]:expr_minus/*B3*//*B*/ {-> New expr.slash(expr_mul/*B3*//*B*/.expr, expr2.expr)}
 399         | {percent} expr_mul/*B3*//*B*/ percent no [expr2]:expr_minus/*B3*//*B*/ {-> New expr.percent(expr_mul/*B3*//*B*/.expr, expr2.expr)}
 400         ;
 401
 402 expr_minus/*B3*//*B*/ {-> expr}
 403         = expr_new/*B3*//*B*/ {-> expr_new/*B3*//*B*/.expr}
 404         | {minus} minus no expr_minus/*B3*//*B*/ {-> New expr.uminus(minus, expr_minus/*B3*//*B*/.expr)}
 405         | {once} kwonce no expr_minus/*B3*//*B*/ {-> New expr.once(kwonce, expr_minus/*B3*//*B*/.expr)}
 406         ;
 407
 408 expr_new/*B3*//*B*/ {-> expr}
 409         = expr_atom/*B3*//*B*/ {-> expr_atom/*B3*//*B*/.expr}
 410         | {new} kwnew no type/*B3*//*B*/ args {-> New expr.new(kwnew, type/*B3*//*B*/.type, Null, [args.expr])}
 411         ;
 412
 413 expr_atom/*B3*//*B*/ {-> expr}
 414         = {attr} recv/*B3*//*B*/ attrid {-> New expr.attr(recv/*B3*//*B*/.expr, attrid)}
 415         | {call} recv/*B3*//*B*/ id args {-> New expr.call(recv/*B3*//*B*/.expr, id, [args.expr])}
 416         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 417         | {init} recv/*B3*//*B*/ kwinit args {-> New expr.init(recv/*B3*//*B*/.expr, kwinit, [args.expr])}
 418 /*N*//*N3*/     | {bra} expr_atom braargs {-> New expr.bra(expr_atom.expr, [braargs.expr])}
 419         | {new} kwnew no type/*B3*//*B*/ dot [n2]:no id args {-> New expr.new(kwnew, type/*B3*//*B*/.type, id, [args.expr])}
 420 /*N*//*N3*/     | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 421 /*N*//*N3*/     | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 422 /*N*//*N3*/     | {array} braargs {-> New expr.array([braargs.expr])}
 423         | {self} kwself {-> New expr.self(kwself)}
 424         | {true} kwtrue {-> New expr.true(kwtrue)}
 425         | {false} kwfalse {-> New expr.false(kwfalse)}
 426         | {null} kwnull {-> New expr.null(kwnull)}
 427         | {int} number  {-> New expr.int(number)}
 428         | {float} float  {-> New expr.float(float)}
 429         | {char} char  {-> New expr.char(char)}
 430         | {string} string  {-> New expr.string(string)}
 431         | {superstring} superstring  {-> superstring.expr}
 432 /*N3*/  | {par} opar expr cpar {-> expr}
 433         ;
 434
 435 superstring {-> expr}
 436         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 437 superstring_start {-> expr*}
 438         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 439 start_string_p {-> expr}
 440         = start_string {-> New expr.start_string(start_string)};
 441 superstring_middle {-> expr*}
 442         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 443 mid_string_p {-> expr}
 444         = mid_string {-> New expr.mid_string(mid_string)};
 445 superstring_end {-> expr}
 446         = end_string {-> New expr.end_string(end_string)};
 447
 448 /* MISC **********************************************************************/
 449
 450 recv/*B3*//*B*/ {-> expr}
 451         = expr_atom/*B3*//*B*/ dot no {-> expr_atom/*B3*//*B*/.expr}
 452         | {implicit} {-> New expr.implicit_self()}
 453         ;
 454
 455 args {-> expr*}
 456         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 457         | {emptypar} opar no cpar {-> []}
 458         | {empty} {-> []}
 459         ;
 460 args_nopar {-> expr*}
 461         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 462         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 463         | {emptypar} opar no cpar {-> []}
 464         | {empty} {-> []}
 465         ;
 466 braargs {-> expr*}
 467         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 468 args_tail {-> expr}
 469         = comma no expr [n2]:no {-> expr};
 470
 471 qualified
 472         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 473         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 474         ;
 475 modquad {-> id}
 476         = id quad no {-> id};
 477 classquad {-> classid}
 478         = classid quad no {-> classid};
 479
 480 n1      = {a} comment | {b} eol;
 481 n {-> doc?}
 482         = {a} n2? comment+ {-> New doc([comment])}
 483         | {b} n2 {-> Null}
 484         ;
 485 no {-> doc?}
 486         = {empty} {-> Null}
 487         | n {-> n.doc}
 488         ;
 489
 490 n2
 491         = {a} n2? comment+ eol+
 492         | {b} eol+
 493         ;
 494
 495 /* EXPR NO BRACKETS **********************************************************/
 496 /* since there is no shift/reduce conflict handling in sablecc, the following
 497  * is a duplication of previous productions minus some alternative where '['
 498  * are not protected. */
 499
 500 /*I*/
 501 /*I2*/
 502 /*I3*/
 503
 504 /*****************************************************************************/
 505 Abstract Syntax Tree
 506 /*****************************************************************************/
 507
 508 module  = packagedecl? [imports]:import* [classdefs]:classdef*;
 509
 510 packagedecl
 511         = doc? kwpackage id;
 512
 513 import  =  visibility kwimport id
 514         | {no} visibility kwimport kwend
 515         ;
 516
 517 visibility
 518         = {public}
 519         | {private} kwprivate
 520         | {protected} kwprotected
 521         | {intrude} kwintrude
 522         ;
 523
 524 classdef = doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef*
 525         | {top} [propdefs]:propdef*
 526         | {main} [propdefs]:propdef*
 527         ;
 528 classkind
 529         = {concrete} kwclass
 530         | {abstract} kwabstract kwclass
 531         | {interface} kwinterface
 532         | {universal} kwuniversal
 533         ;
 534 formaldef = [id]:classid type?;
 535 superclass = kwspecial type;
 536
 537
 538 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwattr [id]:attrid type? expr?
 539         | {meth} doc? kwredef? visibility methid signature
 540         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 541         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 542         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string?
 543         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 544         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 545         | {main_meth} kwredef? [block]:expr?
 546         | {type} doc? kwredef? visibility kwtype [id]:classid type
 547         ;
 548
 549 able    = {read} kwredef? kwreadable
 550         | {write} kwredef? kwwritable
 551         ;
 552
 553 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 554
 555 signature = [params]:param* type?;
 556
 557 param   = id type? dotdotdot?
 558         ;
 559
 560 type    = [id]:classid [types]:type*;
 561
 562 expr    = {block} expr*
 563         | {vardecl} kwvar id type? assign? expr?
 564         | {return} kwreturn expr?
 565         | {break} kwbreak
 566         | {abort} kwabort
 567         | {continue} kwcontinue
 568         | {do} kwdo [block]:expr?
 569         | {if} kwif expr [then]:expr? [else]:expr?
 570         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 571         | {while} kwwhile expr kwdo [block]:expr?
 572         | {for} [vardecl]:expr kwdo [block]:expr?
 573         | {for_vardecl} kwfor id expr
 574         | {assert} kwassert id? expr
 575         | {once} kwonce expr
 576         | {send} expr
 577         | {binop} expr [expr2]:expr
 578         | {or} expr [expr2]:expr
 579         | {and} expr [expr2]:expr
 580         | {not} kwnot expr
 581         | {eq} expr [expr2]:expr
 582         | {ee} expr [expr2]:expr
 583         | {ne} expr [expr2]:expr
 584         | {lt} expr [expr2]:expr
 585         | {le} expr [expr2]:expr
 586         | {gt} expr [expr2]:expr
 587         | {ge} expr [expr2]:expr
 588         | {isa} expr type
 589         | {plus} expr [expr2]:expr
 590         | {minus} expr [expr2]:expr
 591         | {starship} expr [expr2]:expr
 592         | {star} expr [expr2]:expr
 593         | {slash} expr [expr2]:expr
 594         | {percent} expr [expr2]:expr
 595         | {uminus} minus expr
 596         | {new} kwnew type id? [args]:expr*
 597         | {attr} expr [id]:attrid
 598         | {attr_assign} expr [id]:attrid assign [value]:expr
 599         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 600         | {call} expr id [args]:expr*
 601         | {call_assign} expr id [args]:expr* assign [value]:expr
 602         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 603         | {super} qualified? kwsuper [args]:expr*
 604         | {init} expr kwinit [args]:expr*
 605         | {bra} expr [args]:expr*
 606         | {bra_assign} expr [args]:expr* assign [value]:expr
 607         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 608         | {var} id
 609         | {var_assign} id assign [value]:expr
 610         | {var_reassign} id assign_op [value]:expr
 611         | {range} expr [expr2]:expr
 612         | {crange} expr [expr2]:expr
 613         | {orange} expr [expr2]:expr
 614         | {array} [exprs]:expr*
 615         | {self} kwself
 616         | {implicit_self}
 617         | {true} kwtrue
 618         | {false} kwfalse
 619         | {null} kwnull
 620         | {int} number
 621         | {float} float
 622         | {char} char
 623         | {string} string
 624         | {start_string} [string]:start_string
 625         | {mid_string} [string]:mid_string
 626         | {end_string} [string]:end_string
 627         | {superstring} [exprs]:expr*
 628         | {par} expr
 629         ;
 630 assign_op
 631         = {plus} pluseq
 632         | {minus} minuseq
 633         ;
 634
 635 qualified = id* classid? ;
 636
 637 doc = comment+;
 638
 639 /*****************************************************************************/
 640