src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 hexdigit = ['0'..'9'] | ['a'..'f'] | ['A'..'F'];
  31 letter = lowercase | uppercase | digit | '_';
  32
  33 tab = 9;
  34 cr = 13;
  35 lf = 10;
  36 any = [all - [cr + lf]];
  37 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  38
  39 // characers inside strings and super-strings (atomaton powaa)
  40 str_char
  41         = [any - [['"' + '{'] + '\']]
  42         | '\' any
  43         ;
  44 str_body = str_char*;
  45
  46 sstr_char
  47         = [any - [''' + '\']]
  48         | '\' any
  49         ;
  50
  51 sstr_body = sstr_char*;
  52
  53 long_str_char = str_char | cr | lf;
  54
  55 // because no substraction in sablecc3, complex long strings are difficult to express
  56 ls1 = '"' '"'? ;
  57 ls2 = '{' '{'? ;
  58 ls12 = ls1? (ls2 ls1)* ls2?;
  59
  60 long_str_part
  61         = ls12 long_str_char
  62         ;
  63
  64 long_str_body = long_str_part*;
  65 lsend1 = ls2? (ls1 ls2)* '"""' '"'*;
  66 lsend2 = ls1? (ls2 ls1)* '{{{' '{'*;
  67
  68 long_sstr_char = sstr_char | cr | lf;
  69 long_sstr_part
  70         = long_sstr_char
  71         | ''' long_sstr_char
  72         | ''' ''' long_sstr_char
  73         ;
  74
  75 long_sstr_body = long_sstr_part*;
  76
  77
  78 extern_code_char
  79         = [all - ['`' + '\']]
  80         | '\' all
  81         ;
  82 extern_code_body = extern_code_char*;
  83
  84 /*****************************************************************************/
  85 States
  86 /*****************************************************************************/
  87 initial;
  88
  89
  90 /*****************************************************************************/
  91 Tokens
  92 /*****************************************************************************/
  93
  94 blank = (' ' | tab)+;
  95
  96 eol = eol_helper;
  97 comment = '#' any* eol_helper?;
  98
  99 kwpackage = 'package';
 100 kwmodule = 'module';
 101 kwimport = 'import';
 102 kwclass = 'class';
 103 kwabstract = 'abstract';
 104 kwinterface = 'interface';
 105 kwenum = 'universal'|'enum';
 106 kwend = 'end';
 107 kwmeth = 'fun';
 108 kwtype = 'type';
 109 kwinit = 'init';
 110 kwredef = 'redef';
 111 kwis = 'is';
 112 kwdo = 'do';
 113 kwvar = 'var';
 114 kwextern = 'extern';
 115 kwpublic = 'public';
 116 kwprotected = 'protected';
 117 kwprivate = 'private';
 118 kwintrude = 'intrude';
 119 kwif = 'if';
 120 kwthen = 'then';
 121 kwelse = 'else';
 122 kwwhile = 'while';
 123 kwloop = 'loop';
 124 kwfor = 'for';
 125 kwin = 'in';
 126 kwand = 'and';
 127 kwor = 'or';
 128 kwnot = 'not';
 129 kwimplies = 'implies';
 130 kwreturn = 'return';
 131 kwcontinue = 'continue';
 132 kwbreak = 'break';
 133 kwabort = 'abort';
 134 kwassert = 'assert';
 135 kwnew = 'new';
 136 kwisa = 'isa';
 137 kwonce = 'once';
 138 kwsuper = 'super';
 139 kwself = 'self';
 140 kwtrue = 'true';
 141 kwfalse = 'false';
 142 kwnull = 'null';
 143 kwas = 'as';
 144 kwnullable = 'nullable';
 145 kwisset = 'isset';
 146 kwlabel = 'label';
 147 kwdebug = '__debug__';
 148
 149 opar = '(';
 150 cpar = ')';
 151 obra = '[';
 152 cbra = ']';
 153 comma = ',';
 154 column = ':';
 155 quad = '::';
 156 assign = '=';
 157 pluseq = '+=';
 158 minuseq = '-=';
 159 dotdotdot = '...';
 160 dotdot = '..';
 161 dot = '.';
 162 plus = '+';
 163 minus = '-';
 164 star = '*';
 165 starstar = '**';
 166 slash = '/';
 167 percent = '%';
 168 eq = '==';
 169 ne = '!=';
 170 lt = '<';
 171 le = '<=';
 172 ll = '<<';
 173 gt = '>';
 174 ge = '>=';
 175 gg = '>>';
 176 starship = '<=>';
 177 bang='!';
 178 at='@';
 179
 180 classid = uppercase letter*;
 181 id = lowercase letter*;
 182 attrid = '_' lowercase letter*;
 183
 184 number = digit+;
 185 hex_number = ('0x' | '0X') hexdigit+;
 186 float = digit* '.' digit+;
 187 string = '"' str_body '"' | '"' '"' '"' long_str_body lsend1 | ''' ''' ''' long_sstr_body ''' ''' ''';
 188 start_string = '"' str_body '{' | '"' '"' '"' long_str_body lsend2;
 189 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body lsend2;
 190 end_string = '}' str_body '"' | '}' '}' '}' long_str_body lsend1;
 191 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 192 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 193 bad_char = ''' '\'? any;
 194
 195 extern_code_segment = '`' '{' extern_code_body '`' '}';
 196
 197 /*****************************************************************************/
 198 Ignored Tokens
 199 /*****************************************************************************/
 200
 201 blank;
 202
 203 /*****************************************************************************/
 204 Productions
 205 /*****************************************************************************/
 206
 207 /* MODULES *******************************************************************/
 208 module
 209         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:topdef* implicit_main_class {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_main_class.classdef])};
 210
 211 moduledecl
 212         = [doc]:no redef visibility kwmodule no module_name annotation_withend [n2]:n1 {-> New moduledecl(doc.doc, redef.kwredef, visibility, kwmodule, module_name, annotation_withend.annotations)};
 213
 214 import
 215         = {std} [doc]:no redef visibility kwimport no module_name annotation_withend [n2]:n1 {-> New import.std(visibility, kwimport, module_name, annotation_withend.annotations)}
 216         | {no} [doc]:no redef visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 217         ;
 218
 219 topdef {-> classdef}
 220         = {classdef} classdef {-> classdef}
 221         | propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])}
 222         ;
 223
 224 implicit_main_class {-> classdef?}
 225         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 226         | {null} n? {-> Null}
 227         ;
 228 implicit_main_meth {-> propdef}
 229         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 230         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 231         ;
 232
 233 /* CLASSES *******************************************************************/
 234 classdef
 235         = [doc]:no redef visibility classkind no qclassid formaldefs line_annotations_forclass? extern_code_block? [superclasses]:superclass* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, qclassid.classid, [formaldefs.formaldef], line_annotations_forclass.annotations, extern_code_block, [superclasses.superclass], [propdefs.propdef], kwend)};
 236 redef {-> kwredef?}
 237         = kwredef? {-> kwredef};
 238 classkind
 239         = {concrete} kwclass
 240         | {abstract} kwabstract kwclass
 241         | {interface} kwinterface
 242         | {enum} kwenum
 243         | {extern} kwextern kwclass
 244         ;
 245
 246 formaldefs {-> formaldef*}
 247         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]}
 248         | {null} {-> []}
 249         ;
 250 formaldefs_tail {-> formaldef}
 251         = comma no formaldef {-> formaldef};
 252 formaldef
 253         = classid annotations? typing_o {-> New formaldef(classid, typing_o.type, annotations)};
 254
 255 superclass {-> superclass}
 256         = {super} no kwsuper [n2]:no type annotation_withend {-> New superclass(kwsuper, type, annotation_withend.annotations)}
 257         ;
 258
 259 propdefs~toplevel {-> propdef}
 260         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 261         ;
 262 propdef~toplevel {-> propdef}
 263         = {meth} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 264         | {nobody} [doc]:no redef visibility kwmeth qmethid signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 265 !toplevel| {intern_new} [doc]:no redef visibility kwnew qmethid? signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 266 !toplevel| {new} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 267         | {extern_implicit} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 268 !toplevel| {var3} [doc]:no redef visibility kwvar id typing_o annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_withend.annotations, Null)}
 269 !toplevel| {var4} [doc]:no redef visibility kwvar id typing_o assign [n2]:no expr annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, expr.expr, annotation_withend.annotations, Null)}
 270 !toplevel| {var5} [doc]:no redef visibility kwvar id typing_o annotation_noend? kwdo stmtso kwend? {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_noend.annotations, stmtso.expr)}
 271 !toplevel| {init} [doc]:no redef visibility kwinit qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, kwinit, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 272 !toplevel| {type} [doc]:no redef visibility kwtype classid typing annotation_withend {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type, annotation_withend.annotations)}
 273 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 274         ;
 275 annotation_withend~nonull {-> annotations?}
 276         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 277         | {more} kwis n1 line_annotations kwend {-> line_annotations.annotations}
 278 !nonull | {null} {-> Null}
 279         ;
 280 annotation_noend {-> annotations}
 281         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 282         | {more} kwis n1 line_annotations {-> line_annotations.annotations}
 283         ;
 284
 285 visibility
 286         = {public} {-> New visibility.public(Null)}
 287         | {public2} kwpublic no {-> New visibility.public(kwpublic)}
 288         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 289         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 290         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 291         ;
 292
 293 methid~noid {-> methid}
 294         = {plus} plus {-> New methid.plus(plus)}
 295         | {minus} minus {-> New methid.minus(minus)}
 296         | {star} star {-> New methid.star(star)}
 297         | {starstar} starstar {-> New methid.starstar(starstar)}
 298         | {slash} slash {-> New methid.slash(slash)}
 299         | {percent} percent {-> New methid.percent(percent)}
 300         | {eq} eq {-> New methid.eq(eq)}
 301         | {ne} ne {-> New methid.ne(ne)}
 302         | {le} le {-> New methid.le(le)}
 303         | {ge} ge {-> New methid.ge(ge)}
 304         | {lt} lt {-> New methid.lt(lt)}
 305         | {gt} gt {-> New methid.gt(gt)}
 306         | {ll} ll {-> New methid.ll(ll)}
 307         | {gg} gg {-> New methid.gg(gg)}
 308         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 309         | {starship} starship {-> New methid.starship(starship)}
 310         | {assign} id assign {-> New methid.assign(id, assign)}
 311         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 312 !noid   | {id} id {-> New methid.id(id)}
 313         ;
 314
 315 signature {-> signature}
 316         = opar no params cpar typing [no2]:no {-> New signature(opar, [params.param], cpar, typing.type)}
 317         | {noret} opar no params cpar [no2]:no {-> New signature(opar, [params.param], cpar, Null)}
 318         | {nopar} typing no {-> New signature(Null, [], Null, typing.type)}
 319         | {noparnoret} no {-> New signature(Null, [], Null, Null)}
 320         ;
 321
 322 params {-> param*}
 323         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 324         | {null} {-> []}
 325         ;
 326 params_tail {-> param}
 327         = comma no param {-> param};
 328 param
 329         = {untyped} id annotations_o {-> New param(id, Null, Null, annotations_o.annotations)}
 330         | id annotations? typing dotdotdot? {-> New param(id, typing.type, dotdotdot, annotations)}
 331         ;
 332
 333 extern_calls {-> extern_calls?}
 334         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 335         | {null} {-> Null}
 336         ;
 337 extern_call_tail {-> extern_call}
 338         = comma no extern_call {-> extern_call};
 339 extern_call {-> extern_call}
 340         = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 341         | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 342         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 343         ;
 344 extern_call_prop {-> extern_call}
 345         = {local} qmethid {-> New extern_call.local_prop( qmethid.methid )}
 346         | {full} type dot qmethid {-> New extern_call.full_prop( type, dot, qmethid.methid )}
 347         | {init} type {-> New extern_call.init_prop( type )}
 348         ;
 349 extern_call_cast {-> extern_call}
 350         = {as_cast} [from_type]:type dot kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 351         | {as_cast2}[from_type]:type dot kwas [n2]:no [to_type]:type {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 352         | {as_nullable} type dot kwas [n2]:no opar [n3]:no kwnullable [n4]:no cpar {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 353         | {as_nullable2}type dot kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 354         | {as_not_nullable} type dot kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnullable [n5]:no cpar {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 355         | {as_not_nullable2}type dot kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 356         ;
 357
 358 string_o {->string?} = string? {-> string};
 359
 360 in_language = kwin no string [n1]:no {-> New in_language(kwin, string)};
 361 extern_code_block = in_language? extern_code_segment;
 362 extern_code_block_o {-> extern_code_block?}
 363         = extern_code_block {-> extern_code_block}
 364         | {null} {-> Null}
 365         ;
 366 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 367
 368 /* TYPES *********************************************************************/
 369 type~nobra~nopar {-> type}
 370         = {simple} kwnullable? classid annotations_o~nopar {-> New type(kwnullable, classid, [], annotations_o~nopar.annotations)}
 371 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra annotations_o~nopar {-> New type(kwnullable, classid, [types.type], annotations_o~nopar.annotations)}
 372         ;
 373 types {-> type*}
 374         = type types_tail* {-> [type, types_tail.type]};
 375 types_tail {-> type}
 376         = comma no type {-> type};
 377 typing {-> type}
 378         = column no type {-> type};
 379 typing_o {-> type?}
 380         = column no type {-> type}
 381         | {null} {-> Null}
 382         ;
 383
 384 /* STATMENTS *****************************************************************/
 385 stmtso~withelse~withend {-> expr?}
 386         = {block} n stmtsnend {-> stmtsnend.expr}
 387         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 388         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 389 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 390         ;
 391 stmts {-> expr}
 392         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 393 stmtsn {-> expr}
 394         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 395 stmtsnend {-> expr}
 396         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 397 stmts_tail {-> expr}
 398         = n stmt {-> stmt.expr};
 399 stmt~withelse~noexpr~nopar {-> expr}
 400         = {vardecl} vardecl {-> vardecl.expr}
 401         | {assign} assignment~nopar {-> assignment~nopar.expr}
 402         | {return} kwreturn expr? {-> New expr.return(kwreturn, expr)}
 403         | {break} kwbreak label? {-> New expr.break(kwbreak, label)}
 404         | {abort} kwabort {-> New expr.abort(kwabort)}
 405         | {continue} kwcontinue label? {-> New expr.continue(kwcontinue, label)}
 406         | {do} do~withelse {-> do~withelse.expr}
 407 !noexpr | {if} if~withelse {-> if~withelse.expr}
 408         | {while} while~withelse {-> while~withelse.expr}
 409         | {loop} loop~withelse {-> loop~withelse.expr}
 410         | {for} for~withelse {-> for~withelse.expr}
 411         | {assert} assert~withelse {-> assert~withelse.expr}
 412 !noexpr | {call} recv qid args_nopar {-> New expr.call(recv.expr, qid.id, args_nopar.exprs)}
 413 !noexpr | {super} qualified_o kwsuper args_nopar {-> New expr.super(qualified_o.qualified, kwsuper, args_nopar.exprs)}
 414 !noexpr | {init} recv qualified? kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 415         | {debug_type_is} kwdebug kwtype type column expr {-> New expr.debug_type(kwdebug, kwtype, expr.expr, type) }
 416         ;
 417
 418 label= kwlabel id?;
 419
 420 vardecl{-> expr}
 421         = kwvar id annotations? typing_o {-> New expr.vardecl(kwvar, id, typing_o.type, Null, Null, annotations)}
 422         | {assign} kwvar id annotations? typing_o assign no expr {-> New expr.vardecl(kwvar, id, typing_o.type, assign, expr.expr, annotations)}
 423         ;
 424
 425 assignment~nopar {-> expr}
 426         = {attr} recv~nopar qualified_o attrid assign expr {-> New expr.attr_assign(recv~nopar.expr, attrid, assign, expr)}
 427         | {call} recv~nopar qid args assign expr {-> New expr.call_assign(recv~nopar.expr, qid.id, args.exprs, assign,  expr)}
 428         | {bra} expr_atom~nopar braargs assign expr {-> New expr.bra_assign(expr_atom~nopar.expr, braargs.exprs, assign,  expr)}
 429         | {attr_re} recv~nopar qualified_o attrid assign_op expr {-> New expr.attr_reassign(recv~nopar.expr, attrid, assign_op,  expr)}
 430         | {call_re} recv~nopar qid args assign_op expr {-> New expr.call_reassign(recv~nopar.expr, qid.id, args.exprs, assign_op,  expr)}
 431         | {bra_re} expr_atom~nopar braargs assign_op expr {-> New expr.bra_reassign(expr_atom~nopar.expr, braargs.exprs, assign_op,  expr)}
 432         ;
 433 assign_op
 434         = {plus} pluseq
 435         | {minus} minuseq
 436         ;
 437
 438 do~withelse {-> expr}
 439         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 440         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 441         ;
 442
 443 if~withelse {-> expr}
 444         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 445 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 446 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 447 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 448         ;
 449 elsepartblock {-> expr?}
 450         = {else} kwelse stmtso {-> stmtso.expr}
 451         | {empty} kwend {-> New expr.block([], kwend)}
 452         ;
 453
 454 loop~withelse {-> expr}
 455         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 456         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 457         ;
 458
 459 while~withelse {-> expr}
 460         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 461         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 462         ;
 463
 464 for~withelse {-> expr}
 465         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 466         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 467         ;
 468
 469 assert~withelse {-> expr}
 470         = {else} kwassert assertid? expr kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr, stmtso~withelse.expr)}
 471 !withelse| {noelse} kwassert assertid? expr {-> New expr.assert(kwassert, assertid.id, expr, Null)}
 472         ;
 473 assertid {-> id}
 474         = id column {-> id};
 475
 476 /* EXPRESSIONS ***************************************************************/
 477 expr~nopar~nobra {-> expr}
 478         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 479         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 480         ;
 481
 482 expr_and~nopar~nobra {-> expr}
 483         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 484         | {:or} expr_and~nopar~nobra :kwor :no expr_not~nopar~nobra
 485         | {:and} expr_and~nopar~nobra :kwand :no expr_not~nopar~nobra
 486         | {:or_else} expr_and~nopar~nobra :kwor :kwelse :no expr_not~nopar~nobra
 487         | {:implies} expr_and~nopar~nobra :kwimplies :no expr_not~nopar~nobra
 488         ;
 489
 490 expr_not~nopar~nobra {-> expr}
 491         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 492         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 493         ;
 494
 495 expr_eq~nopar~nobra {-> expr}
 496         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 497         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 498         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 499         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 500         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 501         | {:ll} expr_eq~nopar~nobra :ll :no [expr2]:expr_add~nopar~nobra
 502         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 503         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 504         | {:gg} expr_eq~nopar~nobra :gg :no [expr2]:expr_add~nopar~nobra
 505         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 506         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 507         ;
 508
 509 expr_add~nopar~nobra {-> expr}
 510         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 511         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 512         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 513         ;
 514
 515 expr_mul~nopar~nobra {-> expr}
 516         = expr_pow~nopar~nobra {-> expr_pow~nopar~nobra.expr}
 517         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_pow~nopar~nobra
 518         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_pow~nopar~nobra
 519         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_pow~nopar~nobra
 520         ;
 521
 522 expr_pow~nopar~nobra {-> expr}
 523         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 524         | {:starstar} expr_minus~nopar~nobra :starstar :no [expr2]:expr_pow~nopar~nobra
 525         ;
 526
 527 expr_minus~nopar~nobra {-> expr}
 528         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 529         | {:uminus} minus expr_minus~nobra
 530         | {:once} kwonce :no expr_minus~nobra
 531         ;
 532
 533 expr_new~nopar~nobra {-> expr}
 534         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 535         | {new} kwnew no type~nobra_nopar args {-> New expr.new(kwnew, type~nobra_nopar.type, Null, args.exprs)}
 536         | {isset_attr} kwisset recv~nopar~nobra qualified_o attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 537         ;
 538
 539 expr_atom~nopar~nobra {-> expr}
 540         = expr_single~nopar~nobra {-> expr_single~nopar~nobra.expr}
 541         | {attr} recv~nopar~nobra qualified_o attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 542         | {call} recv~nopar~nobra qid args {-> New expr.call(recv~nopar~nobra.expr, qid.id, args.exprs)}
 543         | {super} qualified_o kwsuper args {-> New expr.super(qualified_o.qualified, kwsuper, args.exprs)}
 544         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 545 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs)}
 546         | {new} kwnew no type~nobra_nopar dot [n2]:no qid args {-> New expr.new(kwnew, type~nobra_nopar.type, qid.id, args.exprs)}
 547         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 548         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 549         | {as_notnull2}expr_atom~nopar~nobra dot no kwas [n2]:no kwnot [n4]:no kwnull {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, Null, kwnot, kwnull, Null)}
 550         | {vararg} [expr]:expr_atom~nopar~nobra dotdotdot {-> New expr.vararg(expr.expr, dotdotdot)}
 551         ;
 552
 553 expr_single~nopar~nobra {-> expr}
 554         = {self} kwself annotations_o {-> New expr.self(kwself, annotations_o.annotations)}
 555         | {true} kwtrue annotations_o {-> New expr.true(kwtrue, annotations_o.annotations)}
 556         | {false} kwfalse annotations_o {-> New expr.false(kwfalse, annotations_o.annotations)}
 557         | {null} kwnull annotations_o {-> New expr.null(kwnull, annotations_o.annotations)}
 558         | {int} number annotations_o {-> New expr.dec_int(number, annotations_o.annotations)}
 559         | {hex_int} hex_number annotations_o {-> New expr.hex_int(hex_number, annotations_o.annotations)}
 560         | {float} float annotations_o {-> New expr.float(float, annotations_o.annotations)}
 561         | {char} char annotations_o {-> New expr.char(char, annotations_o.annotations)}
 562         | {string} string annotations_o {-> New expr.string(string, annotations_o.annotations)}
 563         | {superstring} superstring  {-> superstring.expr}
 564 !nopar  | {par} expr_par {-> expr_par.expr}
 565 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 566 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra annotations_o {-> New expr.crange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 567 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra annotations_o {-> New expr.orange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 568 !nobra!nopar    | {array} obra no args_list typing_o cbra annotations_o {-> New expr.array(obra, args_list.exprs, typing_o.type, cbra, annotations_o.annotations)}
 569         ;
 570
 571 expr_par {-> expr}
 572         = {par} opar no any_expr [n2]:no cpar annotations_o {-> New expr.par(opar, any_expr.expr, cpar, annotations_o.annotations)}
 573         | {tuple} opar no many_expr [n2]:no cpar annotations_o {-> New expr.par(opar, many_expr.expr, cpar, annotations_o.annotations)}
 574         ;
 575
 576 many_expr {->expr}
 577         = any_expr many_expr_tail+ {-> New expr.many([any_expr.expr, many_expr_tail.expr])}
 578         ;
 579
 580 many_expr_tail {->expr}
 581         = comma no any_expr {-> any_expr.expr}
 582         ;
 583
 584 superstring {-> expr}
 585         = superstring_start superstring_middle* superstring_end annotations_o {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr], annotations_o.annotations)};
 586 superstring_start {-> expr*}
 587         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]}
 588         | {noexpr} start_string_p no {-> [start_string_p.expr]}
 589         ;
 590 start_string_p {-> expr}
 591         = start_string {-> New expr.start_string(start_string)};
 592 superstring_middle {-> expr*}
 593         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]}
 594         | {noexpr} mid_string_p no {-> [mid_string_p.expr]}
 595         ;
 596 mid_string_p {-> expr}
 597         = mid_string {-> New expr.mid_string(mid_string)};
 598 superstring_end {-> expr}
 599         = end_string {-> New expr.end_string(end_string)};
 600
 601 /* ANNOTATIONS *******************************************************************/
 602
 603 annotations~nopar {-> annotations}
 604         = {one} at one_annotation~nopar {-> New annotations(at, Null, [one_annotation~nopar.annotation], Null)}
 605         | {many} at opar no annotation_list [n2]:no cpar {-> New annotations(at, opar, [annotation_list.annotation], cpar)}
 606         ;
 607 annotations_o~nopar {-> annotations?}
 608         = annotations~nopar {-> annotations~nopar.annotations}
 609         | {null} {-> Null}
 610         ;
 611
 612 one_annotation~nopar {-> annotation}
 613         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 614 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 615 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 616         ;
 617
 618 many_annotations {-> annotations}
 619         = {many} annotation_list {-> New annotations(Null, Null, [annotation_list.annotation], Null)}
 620         ;
 621
 622 annotation_list {-> annotation*}
 623         = {many} one_annotation_list annotations_tail* {-> [one_annotation_list.annotation, annotations_tail.annotation] }
 624         ;
 625
 626 one_annotation_list~nopar {-> annotation}
 627         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 628 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 629 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 630 !nopar  | {nopar} redef visibility atid at_arg_single {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [at_arg_single.expr], Null, Null)}
 631         ;
 632 at_arg_single {-> expr}
 633 // FIXME: why expr_single but not expr_atom is not clear :(
 634         = {expr} [expr]:expr_single_nopar {-> expr.expr}
 635         ;
 636
 637 annotations_tail {-> annotation}
 638         = comma no one_annotation_list {-> one_annotation_list.annotation}
 639         ;
 640
 641 line_annotations {-> annotations}
 642         = line_annotation+ {-> New annotations(Null, Null, [line_annotation.annotation], Null) }
 643         ;
 644 line_annotation {-> annotation}
 645         = [doc]:no redef visibility atid annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [], Null, annotations)}
 646         | {args} [doc]:no redef visibility atid opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, opar, [at_args.expr], cpar, annotations)}
 647         | {nopar} [doc]:no redef visibility atid at_args_nopar n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [at_args_nopar.expr], Null, Null)}
 648         ;
 649 line_annotations_forclass {-> annotations}
 650         = line_annotation_forclass+ {-> New annotations(Null, Null, [line_annotation_forclass.annotation], Null) }
 651         ;
 652 line_annotation_forclass {-> annotation}
 653         = [doc]:no atid_forclass annotations? n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, Null, [], Null, annotations)}
 654         | {args} [doc]:no atid_forclass opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, opar, [at_args.expr], cpar, annotations)}
 655         | {nopar} [doc]:no atid_forclass at_args_nopar n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, Null, [at_args_nopar.expr], Null, Null)}
 656         ;
 657
 658 at_args~nopar {-> expr* }
 659         = {many} any_expr~nopar at_args_tail* {-> [any_expr~nopar.expr, at_args_tail.expr]}
 660         ;
 661
 662 at_args_tail {-> expr}
 663         = comma no any_expr {-> any_expr.expr}
 664         ;
 665
 666 any_expr~nopar {-> expr}
 667         = {type} type {-> New expr.type(type)}
 668         | {expr} expr~nopar {-> expr~nopar.expr}
 669         | {stmt} stmt_noexpr~nopar {-> stmt_noexpr~nopar.expr}
 670         | {methid} recv~nopar qmethid_noid {-> New expr.methid(recv~nopar.expr, qmethid_noid.methid)}
 671 !nopar  | {at} annotations {-> New expr.at(annotations.annotations)}
 672         ;
 673
 674 atid~forclass {-> atid}
 675         = {id}  id {-> New atid.id(id)}
 676 !forclass       | {kwextern} kwextern {-> New atid.kwextern(kwextern)}
 677 //      | {kwimport} kwimport {-> New atid.kwimport(kwimport)}
 678         | {kwabstract} kwabstract {-> New atid.kwabstract(kwabstract)}
 679         ;
 680
 681 /* MISC **********************************************************************/
 682
 683 recv~nopar~nobra {-> expr}
 684         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 685         | {implicit} {-> New expr.implicit_self()}
 686         ;
 687
 688 args {-> exprs}
 689         = args_n {-> args_n.exprs}
 690         | {empty} {-> New exprs.list([])}
 691         ;
 692 args_n {-> exprs}
 693         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 694         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 695         ;
 696 args_nopar {-> exprs}
 697         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 698         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 699         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 700         | {empty} {-> New exprs.list([])}
 701         ;
 702 braargs {-> exprs}
 703         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 704 args_list {-> exprs}
 705         = expr_list {-> New exprs.list([expr_list.expr])};
 706 expr_list {-> expr*}
 707         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 708 expr_tail {-> expr}
 709         = comma no expr [n2]:no {-> expr};
 710 idlist {-> id*}
 711         = opar no idlist_nopar [n2]:no cpar {-> [idlist_nopar.id]}
 712         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 713         ;
 714 idlist_nopar {-> id*}
 715         = {single} id {-> [id]}
 716         | {more} idlist_nopar comma [n2]:no id {-> [idlist_nopar.id, id]}
 717         ;
 718
 719 module_name {-> module_name}
 720         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 721         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 722         ;
 723
 724 qualified
 725         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 726         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 727         ;
 728 qualified_o {-> qualified?}
 729         = qualified {-> qualified}
 730         | {null} {-> Null}
 731         ;
 732 qid {-> id}
 733         = qualified? id {-> id}
 734         ;
 735 qclassid {-> classid}
 736         = qualified? classid {-> classid}
 737         ;
 738 qmethid~noid {-> methid}
 739         = qualified? methid~noid {-> methid~noid.methid}
 740         ;
 741 modquad {-> id}
 742         = id quad no {-> id};
 743 classquad {-> classid}
 744         = classid quad no {-> classid};
 745
 746 kwend_o {-> kwend?}
 747         = kwend? {-> kwend}
 748         ;
 749
 750 n1      = {a} comment | {b} eol;
 751 n {-> doc?}
 752         = {a} n2? comment+ {-> New doc([comment])}
 753         | {b} n2 {-> Null}
 754         ;
 755 no {-> doc?}
 756         = {empty} {-> Null}
 757         | n {-> n.doc}
 758         ;
 759
 760 n2
 761         = {a} n2? comment+ eol+
 762         | {b} eol+
 763         ;
 764
 765 /*****************************************************************************/
 766 Abstract Syntax Tree
 767 /*****************************************************************************/
 768
 769 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 770
 771 moduledecl
 772         = doc? kwredef? visibility kwmodule [name]:module_name annotations?;
 773
 774 import  = {std} visibility kwimport [name]:module_name annotations?
 775         | {no} visibility kwimport kwend
 776         ;
 777
 778 visibility
 779         = {public} kwpublic?
 780         | {private} kwprivate
 781         | {protected} kwprotected
 782         | {intrude} kwintrude
 783         ;
 784
 785 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* annotations? extern_code_block? [superclasses]:superclass* [propdefs]:propdef* kwend
 786         | {top} [propdefs]:propdef*
 787         | {main} [propdefs]:propdef*
 788         ;
 789 classkind
 790         = {concrete} kwclass
 791         | {abstract} kwabstract kwclass
 792         | {interface} kwinterface
 793         | {enum} kwenum
 794         | {extern} kwextern kwclass?
 795         ;
 796 formaldef = [id]:classid type? annotations?;
 797 superclass = kwsuper type annotations?;
 798
 799
 800 propdef = {attr} doc? kwredef? visibility kwvar [id2]:id type? expr? annotations? [block]:expr?
 801         | {main_meth} kwredef? [block]:expr?
 802         | {type} doc? kwredef? visibility kwtype [id]:classid type annotations?
 803         | {meth} doc? kwredef? visibility kwmeth? kwinit? kwnew? methid? signature annotations? extern_calls? extern_code_block? [block]:expr?
 804         ;
 805
 806 methid = {id} id | {plus} plus | {minus} minus | {star} star | {starstar} starstar | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 807
 808 signature = opar? [params]:param* cpar? type?;
 809
 810 param   = id type? dotdotdot? annotations?
 811         ;
 812
 813 type    = kwnullable? [id]:classid [types]:type* annotations?;
 814
 815 label = kwlabel id?;
 816
 817 expr    = {block} expr* kwend?
 818         | {vardecl} kwvar id type? assign? expr? annotations?
 819         | {return} kwreturn? expr?
 820         | {break} kwbreak label?
 821         | {abort} kwabort
 822         | {continue} kwcontinue? label?
 823         | {do} kwdo [block]:expr? label?
 824         | {if} kwif expr [then]:expr? [else]:expr?
 825         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 826         | {while} kwwhile expr kwdo [block]:expr? label?
 827         | {loop} kwloop [block]:expr? label?
 828         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 829         | {assert} kwassert id? expr [else]:expr?
 830         | {once} kwonce expr
 831         | {send} expr
 832         | {binop} expr [expr2]:expr
 833         | {or} expr [expr2]:expr
 834         | {and} expr [expr2]:expr
 835         | {or_else} expr [expr2]:expr
 836         | {implies} expr [expr2]:expr
 837         | {not} kwnot expr
 838         | {eq} expr [expr2]:expr
 839         | {ne} expr [expr2]:expr
 840         | {lt} expr [expr2]:expr
 841         | {le} expr [expr2]:expr
 842         | {ll} expr [expr2]:expr
 843         | {gt} expr [expr2]:expr
 844         | {ge} expr [expr2]:expr
 845         | {gg} expr [expr2]:expr
 846         | {isa} expr type
 847         | {plus} expr [expr2]:expr
 848         | {minus} expr [expr2]:expr
 849         | {starship} expr [expr2]:expr
 850         | {star} expr [expr2]:expr
 851         | {starstar} expr [expr2]:expr
 852         | {slash} expr [expr2]:expr
 853         | {percent} expr [expr2]:expr
 854         | {uminus} minus expr
 855         | {new} kwnew type id? [args]:exprs
 856         | {attr} expr [id]:attrid
 857         | {attr_assign} expr [id]:attrid assign [value]:expr
 858         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 859         | {call} expr id [args]:exprs
 860         | {call_assign} expr id [args]:exprs assign [value]:expr
 861         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 862         | {super} qualified? kwsuper [args]:exprs
 863         | {init} expr kwinit [args]:exprs
 864         | {bra} expr [args]:exprs
 865         | {bra_assign} expr [args]:exprs assign [value]:expr
 866         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 867         | {var} id
 868         | {var_assign} id assign [value]:expr
 869         | {var_reassign} id assign_op [value]:expr
 870         | {range} expr [expr2]:expr annotations?
 871         | {crange} obra expr [expr2]:expr cbra annotations?
 872         | {orange} obra expr [expr2]:expr [cbra]:obra annotations?
 873         | {array} obra [exprs]:exprs type? cbra annotations?
 874         | {self} kwself annotations?
 875         | {implicit_self}
 876         | {true} kwtrue annotations?
 877         | {false} kwfalse annotations?
 878         | {null} kwnull annotations?
 879         | {dec_int} number annotations?
 880         | {hex_int} hex_number annotations?
 881         | {float} float annotations?
 882         | {char} char annotations?
 883         | {string} string annotations?
 884         | {start_string} [string]:start_string
 885         | {mid_string} [string]:mid_string
 886         | {end_string} [string]:end_string
 887         | {superstring} [exprs]:expr* annotations?
 888         | {par} opar expr cpar annotations?
 889         | {as_cast} expr kwas opar? type cpar?
 890         | {as_notnull} expr kwas opar? kwnot kwnull cpar?
 891         | {isset_attr} kwisset expr [id]:attrid
 892         | {debug_type} kwdebug kwtype expr type
 893         | {vararg} expr dotdotdot
 894         | {type} type
 895         | {methid} expr [id]:methid
 896         | {at} annotations
 897         | {many} [exprs]:expr*
 898         ;
 899 exprs
 900         = {list} [exprs]:expr*
 901         | {par} opar [exprs]:expr* cpar
 902         | {bra} obra [exprs]:expr* cbra
 903         ;
 904 assign_op
 905         = {plus} pluseq
 906         | {minus} minuseq
 907         ;
 908
 909 module_name = quad? [path]:id* id;
 910 extern_calls = kwimport [extern_calls]:extern_call*
 911         ;
 912 extern_call =
 913         | {super} kwsuper
 914         | {local_prop} methid
 915         | {full_prop} type dot? methid
 916         | {init_prop} type
 917         | {cast_as} [from_type]:type dot? kwas [to_type]:type
 918         | {as_nullable} type kwas kwnullable
 919         | {as_not_nullable} type kwas kwnot kwnullable
 920         ;
 921 in_language = kwin string;
 922 extern_code_block = in_language? extern_code_segment;
 923
 924 qualified = id* classid? ;
 925
 926 doc = comment+;
 927
 928 annotations = at? opar? [items]:annotation* cpar?;
 929
 930 annotation = doc? kwredef? visibility? atid opar? [args]:expr* cpar? annotations?;
 931
 932 atid = {id} id | {kwextern} [id]:kwextern | {kwabstract} [id]:kwabstract | {kwimport} [id]:kwimport;
 933
 934 /*****************************************************************************/
 935