src/literal.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Parsing of literal values in the abstract syntax tree.
  18 module literal
  19
  20 import phase
  21
  22 redef class ToolContext
  23         # Parses literal values in the whole AST and produces errors if needed
  24         var literal_phase: Phase = new LiteralPhase(self, null)
  25 end
  26
  27 private class LiteralPhase
  28         super Phase
  29
  30         redef fun process_nmodule(nmodule) do nmodule.do_literal(toolcontext)
  31 end
  32
  33 redef class AModule
  34         # Visit the module to compute the real value of the literal-related node of the AST.
  35         # Warnings and errors are displayed on the toolcontext.
  36         fun do_literal(toolcontext: ToolContext)
  37         do
  38                 var v = new LiteralVisitor(toolcontext)
  39                 v.enter_visit(self)
  40         end
  41 end
  42
  43 private class LiteralVisitor
  44         super Visitor
  45
  46         var toolcontext: ToolContext
  47
  48         redef fun visit(n)
  49         do
  50                 n.accept_literal(self)
  51                 n.visit_all(self)
  52         end
  53 end
  54
  55 redef class ANode
  56         private fun accept_literal(v: LiteralVisitor) do end
  57 end
  58
  59 redef class AExpr
  60         # Get `self` as a `String`.
  61         # Return null if not a string.
  62         fun as_string: nullable String
  63         do
  64                 if not self isa AStringFormExpr then return null
  65                 return self.value.as(not null)
  66         end
  67
  68         # Get `self` as an `Int`.
  69         # Return null if not an integer.
  70         fun as_int: nullable Int
  71         do
  72                 if not self isa AIntExpr then return null
  73                 return self.value.as(not null)
  74         end
  75 end
  76
  77 redef class Text
  78         private fun remove_underscores: Text do
  79                 var b = new FlatBuffer
  80                 for i in chars do
  81                         if i == '_' then continue
  82                         b.add i
  83                 end
  84                 return b
  85         end
  86 end
  87
  88 redef class AIntExpr
  89         # The value of the literal int once computed.
  90         var value: nullable Int
  91 end
  92
  93 redef class ADecIntExpr
  94         redef fun accept_literal(v)
  95         do
  96                 value = self.n_number.text.remove_underscores.to_i
  97         end
  98 end
  99
 100 redef class AHexIntExpr
 101         redef fun accept_literal(v)
 102         do
 103                 var s = self.n_hex_number.text.substring_from(2).remove_underscores
 104                 if s.is_empty then
 105                         v.toolcontext.error(location, "Error: invalid hexadecimal literal")
 106                         return
 107                 end
 108                 value = s.to_hex
 109         end
 110 end
 111
 112 redef class ABinIntExpr
 113         redef fun accept_literal(v)
 114         do
 115                 var s = self.n_bin_number.text.substring_from(2).remove_underscores
 116                 if s.is_empty then
 117                         v.toolcontext.error(location, "Error: invalid binary literal")
 118                         return
 119                 end
 120                 value = s.to_bin
 121         end
 122 end
 123
 124 redef class AOctIntExpr
 125         redef fun accept_literal(v)
 126         do
 127                 var s = self.n_oct_number.text.substring_from(2).remove_underscores
 128                 if s.is_empty then
 129                         v.toolcontext.error(location, "Error: invalid octal literal")
 130                         return
 131                 end
 132                 value = s.to_oct
 133         end
 134 end
 135
 136 redef class AByteExpr
 137         # The value of the literal int once computed.
 138         var value: nullable Byte
 139 end
 140
 141 redef class ADecByteExpr
 142         redef fun accept_literal(v)
 143         do
 144                 var t = self.n_bytenum.text
 145                 value = t.substring(0, t.length - 2).remove_underscores.to_i.to_b
 146         end
 147 end
 148
 149 redef class AHexByteExpr
 150         redef fun accept_literal(v)
 151         do
 152                 var t = self.n_hex_bytenum.text
 153                 var s = t.substring(2, t.length - 4).remove_underscores
 154                 if s.is_empty then
 155                         v.toolcontext.error(location, "Error: invalid hexadecimal literal")
 156                         return
 157                 end
 158                 value = s.to_hex.to_b
 159         end
 160 end
 161
 162 redef class ABinByteExpr
 163         redef fun accept_literal(v)
 164         do
 165                 var t = self.n_bin_bytenum.text
 166                 var s = t.substring(2, t.length - 4).remove_underscores
 167                 if s.is_empty then
 168                         v.toolcontext.error(location, "Error: invalid binary literal")
 169                         return
 170                 end
 171                 value = s.to_bin.to_b
 172         end
 173 end
 174
 175 redef class AOctByteExpr
 176         redef fun accept_literal(v)
 177         do
 178                 var t = self.n_oct_bytenum.text
 179                 var s = t.substring(2, t.length - 4).remove_underscores
 180                 if s.is_empty then
 181                         v.toolcontext.error(location, "Error: invalid octal literal")
 182                         return
 183                 end
 184                 value = s.to_oct.to_b
 185         end
 186 end
 187
 188 redef class AFloatExpr
 189         # The value of the literal float once computed.
 190         var value: nullable Float
 191         redef fun accept_literal(v)
 192         do
 193                 self.value = self.n_float.text.to_f
 194         end
 195 end
 196
 197 redef class ACharExpr
 198         # The value of the literal char once computed.
 199         var value: nullable Char
 200         redef fun accept_literal(v)
 201         do
 202                 var txt = self.n_char.text.unescape_nit
 203                 if txt.length != 3 then
 204                         v.toolcontext.error(self.hot_location, "Syntax Error: invalid character literal `{txt}`.")
 205                         return
 206                 end
 207                 self.value = txt.chars[1]
 208         end
 209 end
 210
 211 redef class AStringFormExpr
 212         # The value of the literal string once computed.
 213         var value: nullable String
 214         redef fun accept_literal(v)
 215         do
 216                 var txt = self.n_string.text
 217                 var behead = 1
 218                 var betail = 1
 219                 if txt.chars[0] == txt.chars[1] and txt.length >= 6 then
 220                         behead = 3
 221                         betail = 3
 222                         if txt.chars[0] == '"' and txt.chars[3] == '\n' then behead = 4 # ignore first \n in """
 223                 end
 224                 self.value = txt.substring(behead, txt.length - behead - betail).unescape_nit
 225         end
 226 end