lib/gamnit/textures.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Load textures, create subtextures and manage their life-cycle
  16 module textures
  17
  18 import display
  19
  20 # Texture composed of pixels, loaded from the assets folder by default
  21 #
  22 # Most textures should be created with `App` (as attributes)
  23 # for the method `on_create` to load them.
  24 #
  25 # ~~~
  26 # import gamnit::flat
  27 #
  28 # redef class App
  29 #     # Create the texture object, it will be loaded automatically
  30 #     var texture = new Texture("path/in/assets.png")
  31 #
  32 #     redef fun on_create()
  33 #     do
  34 #         # Let `on_create` load the texture
  35 #         super
  36 #
  37 #         # Use the texture
  38 #         var sprite = new Sprite(texture, new Point3d[Float](0.0, 0.0, 0.0))
  39 #         app.sprites.add sprite
  40 #     end
  41 # end
  42 # ~~~
  43 #
  44 # Otherwise, they can be loaded and error checked explicitly after `on_create`.
  45 #
  46 # ~~~nitish
  47 # var texture = new Texture("path/in/assets.png")
  48 # texture.load
  49 # var error = texture.error
  50 # if error != null then print_error error
  51 # ~~~
  52 #
  53 # A texture may also be created programmatically, like `CheckerTexture`,
  54 # or derived from another texture, using `subtexture`.
  55 # Textures with actual pixel data (not `Subtexture`) are `RootTexture`.
  56 # Texture loaded from the assets folder may in the PNG or JPG formats.
  57 abstract class Texture
  58
  59         # Prepare a texture located at `path` within the `assets` folder
  60         new (path: Text) do return new TextureAsset(path.to_s)
  61
  62         # Root texture from which `self` is derived
  63         fun root: RootTexture is abstract
  64
  65         # Width in pixels of this texture
  66         var width = 0.0
  67
  68         # Height in pixels of this texture
  69         var height = 0.0
  70
  71         # Load this texture, force reloading it if `force`
  72         fun load(force: nullable Bool) do end
  73
  74         # Last error on this texture
  75         var error: nullable Error = null
  76
  77         # OpenGL handle to this texture
  78         fun gl_texture: Int do return root.gl_texture
  79
  80         # Prepare a subtexture from this texture, from the given pixel offsets
  81         fun subtexture(left, top, width, height: Numeric): Subtexture
  82         do
  83                 # Setup the subtexture
  84                 var subtex = new Subtexture(root, self, left.to_f, top.to_f, width.to_f, height.to_f)
  85                 return subtex
  86         end
  87
  88         # Offset of the left border on `root` from 0.0 to 1.0
  89         fun offset_left: Float do return 0.0
  90
  91         # Offset of the top border on `root` from 0.0 to 1.0
  92         fun offset_top: Float do return 0.0
  93
  94         # Offset of the right border on `root` from 0.0 to 1.0
  95         fun offset_right: Float do return 1.0
  96
  97         # Offset of the bottom border on `root` from 0.0 to 1.0
  98         fun offset_bottom: Float do return 1.0
  99
 100         # Should this texture be drawn pixelated when magnified? otherwise it is interpolated
 101         #
 102         # This setting affects all the textures based on the same pixel data, or `root`.
 103         #
 104         # Must be set after a successful call to `load`.
 105         fun pixelated=(pixelated: Bool)
 106         do
 107                 if root.gl_texture == -1 then return
 108
 109                 # TODO do not modify `root` by using *sampler objects* in glesv3
 110                 glBindTexture(gl_TEXTURE_2D, root.gl_texture)
 111
 112                 var param = if pixelated then gl_NEAREST else gl_LINEAR
 113                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_MAG_FILTER, param)
 114         end
 115 end
 116
 117 # Colorful small texture of 32x32 pixels by default
 118 class CheckerTexture
 119         super RootTexture
 120
 121         # Width and height in pixels, defaults to 32
 122         var size = 32 is optional
 123
 124         redef fun load(force)
 125         do
 126                 if gl_texture != -1 then return
 127                 load_checker size
 128                 loaded = true
 129         end
 130 end
 131
 132 # Custom texture with pixel values filled programmatically
 133 #
 134 # At creation, the texture is composed of `width` by `height` (rounded down)
 135 # transparent pixels. The pixels value can be set using `[]=`.
 136 #
 137 # ~~~
 138 # # Build a texture with 4 colors
 139 # var tex = new CustomTexture(2.0, 2.0)
 140 # tex[0, 0] = [1.0, 0.0, 0.0] # Red
 141 # tex[0, 1] = [0.0, 1.0, 0.0] # Green
 142 # tex[1, 0] = [0.0, 0.0, 1.0] # Blue
 143 # tex[1, 1] = [1.0, 1.0, 1.0, 0.5] # Transparent white
 144 # tex.load
 145 # ~~~
 146 class CustomTexture
 147         super RootTexture
 148
 149         redef var width
 150         redef var height
 151
 152         private var cpixels = new CByteArray(4*width.to_i*height.to_i) is lazy
 153
 154         # Set the `color` of the pixel at `x`, `y` (from the top-left corner)
 155         #
 156         # The argument `color` should be an array of up to 4 floats (RGBA).
 157         # If `color` has less than 4 items, the missing items are replaced by 1.0.
 158         #
 159         # Require: `not loaded and x < width.to_i and y < height.to_i`
 160         fun []=(x, y: Int, color: Array[Float])
 161         do
 162                 assert not loaded else print_error "{class_name}::[]= already loaded"
 163                 assert x < width.to_i and y < height.to_i else print_error "{class_name}::[] out of bounds"
 164
 165                 # Simple conversion from [0.0..1.0] to [0..255]
 166                 var bytes = [for c in color do (c*255.0).round.to_i.clamp(0, 255).to_bytes.last]
 167                 while bytes.length < 4 do bytes.add 255u8
 168
 169                 var offset = 4*(x + y*width.to_i)
 170                 for i in [0..4[ do cpixels[offset+i] = bytes[i]
 171         end
 172
 173         # Overwrite all pixels with `color`
 174         #
 175         # The argument `color` should be an array of up to 4 floats (RGBA).
 176         # If `color` has less than 4 items, the missing items are replaced by 1.0.
 177         #
 178         # Require: `not loaded`
 179         fun fill(color: Array[Float])
 180         do
 181                 assert not loaded else print_error "{class_name}::fill already loaded"
 182
 183                 # Simple conversion from [0.0..1.0] to [0..255]
 184                 var bytes = [for c in color do (c*255.0).round.to_i.clamp(0, 255).to_bytes.last]
 185                 while bytes.length < 4 do bytes.add 255u8
 186
 187                 var i = 0
 188                 for x in [0..width.to_i[ do
 189                         for y in [0..height.to_i[ do
 190                                 for j in [0..4[ do cpixels[i+j] = bytes[j]
 191                                 i += 4
 192                         end
 193                 end
 194         end
 195
 196         redef fun load(force)
 197         do
 198                 if loaded then return
 199
 200                 # Round down the desired dimension
 201                 var width = width.to_i
 202                 var height = height.to_i
 203                 self.width = width.to_f
 204                 self.height = height.to_f
 205
 206                 load_from_pixels(cpixels.native_array, width, height, gl_RGBA)
 207
 208                 cpixels.destroy
 209                 loaded = true
 210         end
 211 end
 212
 213 # Texture with its own pixels
 214 class RootTexture
 215         super Texture
 216
 217         redef fun root do return self
 218
 219         # Has this texture been loaded yet?
 220         var loaded = false
 221
 222         redef var gl_texture = -1
 223
 224         init do all_root_textures.add self
 225
 226         private fun load_from_pixels(pixels: Pointer, width, height: Int, format: GLPixelFormat)
 227         do
 228                 var max_texture_size = glGetIntegerv(gl_MAX_TEXTURE_SIZE, 0)
 229                 if width > max_texture_size or height > max_texture_size then
 230                         error = new Error("Texture {self} width or height is over the GL_MAX_TEXTURE_SIZE of {max_texture_size}")
 231                         return
 232                 end
 233
 234                 glPixelStorei(gl_UNPACK_ALIGNEMENT, 1)
 235                 var tex = glGenTextures(1)[0]
 236                 gl_texture = tex
 237
 238                 glBindTexture(gl_TEXTURE_2D, tex)
 239                 glTexImage2D(gl_TEXTURE_2D, 0, format, width, height, 0, format, gl_UNSIGNED_BYTE, pixels)
 240
 241                 glHint(gl_GENERATE_MIPMAP_HINT, gl_NICEST)
 242                 glGenerateMipmap(gl_TEXTURE_2D)
 243         end
 244
 245         private fun load_checker(size: Int)
 246         do
 247                 var cpixels = new CByteArray(3*size*size)
 248
 249                 var i = 0
 250                 for x in [0..size[ do
 251                         var quadrant_x = if x < size/2 then 0 else 1
 252                         for y in [0..size[ do
 253                                 var quadrant_y = if y < size/2 then 0 else 1
 254                                 var color = if quadrant_x == quadrant_y then
 255                                         [0u8, 0u8, 0u8, 255u8]
 256                                 else [255u8, 255u8, 255u8, 255u8]
 257
 258                                 for j in [0..3[ do cpixels[i+j] = color[j]
 259                                 i += 3
 260                         end
 261                 end
 262
 263                 width = size.to_f
 264                 height = size.to_f
 265                 load_from_pixels(cpixels.native_array, size, size, gl_RGB)
 266
 267                 cpixels.destroy
 268         end
 269
 270         # Has this resource been deleted?
 271         var deleted = false
 272
 273         # Delete this texture and free all its resources
 274         #
 275         # Use caution with this service as the subtextures may rely on the deleted data.
 276         fun delete
 277         do
 278                 if deleted or not loaded then return
 279
 280                 deleted = true
 281         end
 282 end
 283
 284 # Texture loaded from the assets folder
 285 class TextureAsset
 286         super RootTexture
 287
 288         # Path to this texture within the `assets` folder
 289         var path: String
 290
 291         redef fun load(force)
 292         do
 293                 if loaded and force != true then return
 294
 295                 load_from_platform
 296
 297                 # If no pixel data was loaded, load the pixel default texture
 298                 if gl_texture == -1 then load_checker 32
 299
 300                 loaded = true
 301         end
 302
 303         # Partially load this texture from platform-specific features
 304         #
 305         # This method should fill `width`, `height` and `pixels`.
 306         private fun load_from_platform is abstract
 307
 308         redef fun to_s do return "<{class_name} path:{path}>"
 309 end
 310
 311 # Texture derived from another texture, does not own its pixels
 312 class Subtexture
 313         super Texture
 314
 315         redef var root
 316
 317         # Parent texture, from which this texture was created
 318         var parent: Texture
 319
 320         # Left border of this texture compared to `parent`
 321         var left: Float
 322
 323         # Top border of this texture compared to `parent`
 324         var top: Float
 325
 326         private fun set_wh(width, height: Float)
 327         is autoinit do
 328                 self.width = width
 329                 self.height = height
 330         end
 331
 332         redef fun load(force) do root.load(force)
 333
 334         redef var offset_left = parent.offset_left + left / root.width is lazy
 335         redef var offset_top = parent.offset_top + top / root.height is lazy
 336         redef var offset_right = offset_left + width / root.width is lazy
 337         redef var offset_bottom = offset_top + height / root.height is lazy
 338 end
 339
 340 redef class Sys
 341         # All declared root textures
 342         var all_root_textures = new TextureSet
 343 end
 344
 345 # Group of `Texture`
 346 class TextureSet
 347         super HashSet[Texture]
 348
 349         # Load all texture of this set
 350         fun load_all do for t in self do t.load
 351 end