src/loader.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Loading of Nit source files
  18 module loader
  19
  20 import modelbuilder_base
  21
  22 redef class ToolContext
  23         # Option --path
  24         var opt_path = new OptionArray("Set include path for loaders (may be used more than once)", "-I", "--path")
  25
  26         # Option --only-metamodel
  27         var opt_only_metamodel = new OptionBool("Stop after meta-model processing", "--only-metamodel")
  28
  29         # Option --only-parse
  30         var opt_only_parse = new OptionBool("Only proceed to parse step of loaders", "--only-parse")
  31
  32         redef init
  33         do
  34                 super
  35                 option_context.add_option(opt_path, opt_only_parse, opt_only_metamodel)
  36         end
  37 end
  38
  39 redef class ModelBuilder
  40         redef init
  41         do
  42                 super
  43
  44                 # Setup the paths value
  45                 paths.append(toolcontext.opt_path.value)
  46
  47                 var path_env = "NIT_PATH".environ
  48                 if not path_env.is_empty then
  49                         paths.append(path_env.split_with(':'))
  50                 end
  51
  52                 var nit_dir = toolcontext.nit_dir
  53                 var libname = "{nit_dir}/lib"
  54                 if libname.file_exists then paths.add(libname)
  55         end
  56
  57         # Load a bunch of modules.
  58         # `modules` can contains filenames or module names.
  59         # Imported modules are automatically loaded and modelized.
  60         # The result is the corresponding model elements.
  61         # Errors and warnings are printed with the toolcontext.
  62         #
  63         # Note: class and property model elements are not analysed.
  64         fun parse(modules: Sequence[String]): Array[MModule]
  65         do
  66                 var time0 = get_time
  67                 # Parse and recursively load
  68                 self.toolcontext.info("*** PARSE ***", 1)
  69                 var mmodules = new ArraySet[MModule]
  70                 for a in modules do
  71                         var nmodule = self.load_module(a)
  72                         if nmodule == null then continue # Skip error
  73                         # Load imported module
  74                         build_module_importation(nmodule)
  75
  76                         mmodules.add(nmodule.mmodule.as(not null))
  77                 end
  78                 var time1 = get_time
  79                 self.toolcontext.info("*** END PARSE: {time1-time0} ***", 2)
  80
  81                 self.toolcontext.check_errors
  82
  83                 if toolcontext.opt_only_parse.value then
  84                         self.toolcontext.info("*** ONLY PARSE...", 1)
  85                         exit(0)
  86                 end
  87
  88                 return mmodules.to_a
  89         end
  90
  91         # The list of directories to search for top level modules
  92         # The list is initially set with:
  93         #
  94         #   * the toolcontext --path option
  95         #   * the NIT_PATH environment variable
  96         #   * `toolcontext.nit_dir`
  97         # Path can be added (or removed) by the client
  98         var paths = new Array[String]
  99
 100         # Like (and used by) `get_mmodule_by_name` but just return the ModulePath
 101         fun search_mmodule_by_name(anode: nullable ANode, mgroup: nullable MGroup, name: String): nullable ModulePath
 102         do
 103                 # First, look in groups
 104                 var c = mgroup
 105                 while c != null do
 106                         var dirname = c.filepath
 107                         if dirname == null then break # virtual group
 108                         if dirname.has_suffix(".nit") then break # singleton project
 109
 110                         # Second, try the directory to find a file
 111                         var try_file = dirname + "/" + name + ".nit"
 112                         if try_file.file_exists then
 113                                 var res = self.identify_file(try_file.simplify_path)
 114                                 assert res != null
 115                                 return res
 116                         end
 117
 118                         # Third, try if the requested module is itself a group
 119                         try_file = dirname + "/" + name + "/" + name + ".nit"
 120                         if try_file.file_exists then
 121                                 var res = self.identify_file(try_file.simplify_path)
 122                                 assert res != null
 123                                 return res
 124                         end
 125
 126                         c = c.parent
 127                 end
 128
 129                 # Look at some known directories
 130                 var lookpaths = self.paths
 131
 132                 # Look in the directory of the group project also (even if not explicitly in the path)
 133                 if mgroup != null then
 134                         # path of the root group
 135                         var dirname = mgroup.mproject.root.filepath
 136                         if dirname != null then
 137                                 dirname = dirname.join_path("..").simplify_path
 138                                 if not lookpaths.has(dirname) and dirname.file_exists then
 139                                         lookpaths = lookpaths.to_a
 140                                         lookpaths.add(dirname)
 141                                 end
 142                         end
 143                 end
 144
 145                 var candidate = search_module_in_paths(anode.hot_location, name, lookpaths)
 146
 147                 if candidate == null then
 148                         if mgroup != null then
 149                                 error(anode, "Error: cannot find module {name} from {mgroup.name}. tried {lookpaths.join(", ")}")
 150                         else
 151                                 error(anode, "Error: cannot find module {name}. tried {lookpaths.join(", ")}")
 152                         end
 153                         return null
 154                 end
 155                 return candidate
 156         end
 157
 158         # Get a module by its short name; if required, the module is loaded, parsed and its hierarchies computed.
 159         # If `mgroup` is set, then the module search starts from it up to the top level (see `paths`);
 160         # if `mgroup` is null then the module is searched in the top level only.
 161         # If no module exists or there is a name conflict, then an error on `anode` is displayed and null is returned.
 162         fun get_mmodule_by_name(anode: nullable ANode, mgroup: nullable MGroup, name: String): nullable MModule
 163         do
 164                 var path = search_mmodule_by_name(anode, mgroup, name)
 165                 if path == null then return null # Forward error
 166                 var res = self.load_module(path.filepath)
 167                 if res == null then return null # Forward error
 168                 # Load imported module
 169                 build_module_importation(res)
 170                 return res.mmodule.as(not null)
 171         end
 172
 173         # Search a module `name` from path `lookpaths`.
 174         # If found, the path of the file is returned
 175         private fun search_module_in_paths(location: nullable Location, name: String, lookpaths: Collection[String]): nullable ModulePath
 176         do
 177                 var candidate: nullable String = null
 178                 for dirname in lookpaths do
 179                         var try_file = (dirname + "/" + name + ".nit").simplify_path
 180                         if try_file.file_exists then
 181                                 if candidate == null then
 182                                         candidate = try_file
 183                                 else if candidate != try_file then
 184                                         # try to disambiguate conflicting modules
 185                                         var abs_candidate = module_absolute_path(candidate)
 186                                         var abs_try_file = module_absolute_path(try_file)
 187                                         if abs_candidate != abs_try_file then
 188                                                 toolcontext.error(location, "Error: conflicting module file for {name}: {candidate} {try_file}")
 189                                         end
 190                                 end
 191                         end
 192                         try_file = (dirname + "/" + name + "/" + name + ".nit").simplify_path
 193                         if try_file.file_exists then
 194                                 if candidate == null then
 195                                         candidate = try_file
 196                                 else if candidate != try_file then
 197                                         # try to disambiguate conflicting modules
 198                                         var abs_candidate = module_absolute_path(candidate)
 199                                         var abs_try_file = module_absolute_path(try_file)
 200                                         if abs_candidate != abs_try_file then
 201                                                 toolcontext.error(location, "Error: conflicting module file for {name}: {candidate} {try_file}")
 202                                         end
 203                                 end
 204                         end
 205                 end
 206                 if candidate == null then return null
 207                 return identify_file(candidate)
 208         end
 209
 210         # Cache for `identify_file` by realpath
 211         private var identified_files = new HashMap[String, nullable ModulePath]
 212
 213         # Identify a source file
 214         # Load the associated project and groups if required
 215         #
 216         # Silently return `null` if `path` is not a valid module path.
 217         fun identify_file(path: String): nullable ModulePath
 218         do
 219                 # special case for not a nit file
 220                 if path.file_extension != "nit" then
 221                         # search dirless files in known -I paths
 222                         if path.dirname == "" then
 223                                 var res = search_module_in_paths(null, path, self.paths)
 224                                 if res != null then return res
 225                         end
 226
 227                         # Found nothing? maybe it is a group...
 228                         var candidate = null
 229                         if path.file_exists then
 230                                 var mgroup = get_mgroup(path)
 231                                 if mgroup != null then
 232                                         var owner_path = mgroup.filepath.join_path(mgroup.name + ".nit")
 233                                         if owner_path.file_exists then candidate = owner_path
 234                                 end
 235                         end
 236
 237                         if candidate == null then
 238                                 return null
 239                         end
 240                         path = candidate
 241                 end
 242
 243                 # Fast track, the path is already known
 244                 var pn = path.basename(".nit")
 245                 var rp = module_absolute_path(path)
 246                 if identified_files.has_key(rp) then return identified_files[rp]
 247
 248                 # Search for a group
 249                 var mgrouppath = path.join_path("..").simplify_path
 250                 var mgroup = get_mgroup(mgrouppath)
 251
 252                 if mgroup == null then
 253                         # singleton project
 254                         var mproject = new MProject(pn, model)
 255                         mgroup = new MGroup(pn, mproject, null) # same name for the root group
 256                         mgroup.filepath = path
 257                         mproject.root = mgroup
 258                         toolcontext.info("found project `{pn}` at {path}", 2)
 259                 end
 260
 261                 var res = new ModulePath(pn, path, mgroup)
 262                 mgroup.module_paths.add(res)
 263
 264                 identified_files[rp] = res
 265                 return res
 266         end
 267
 268         # Groups by path
 269         private var mgroups = new HashMap[String, nullable MGroup]
 270
 271         # Return the mgroup associated to a directory path.
 272         # If the directory is not a group null is returned.
 273         fun get_mgroup(dirpath: String): nullable MGroup
 274         do
 275                 var rdp = module_absolute_path(dirpath)
 276                 if mgroups.has_key(rdp) then
 277                         return mgroups[rdp]
 278                 end
 279
 280                 # Hack, a group is determined by:
 281                 # * the presence of a honomymous nit file
 282                 # * the fact that the directory is named `src`
 283                 var pn = rdp.basename(".nit")
 284                 var mp = dirpath.join_path(pn + ".nit").simplify_path
 285
 286                 var dirpath2 = dirpath
 287                 if not mp.file_exists then
 288                         if pn == "src" then
 289                                 # With a src directory, the group name is the name of the parent directory
 290                                 dirpath2 = rdp.dirname
 291                                 pn = dirpath2.basename("")
 292                         else
 293                                 return null
 294                         end
 295                 end
 296
 297                 # check parent directory
 298                 var parentpath = dirpath.join_path("..").simplify_path
 299                 var parent = get_mgroup(parentpath)
 300
 301                 var mgroup
 302                 if parent == null then
 303                         # no parent, thus new project
 304                         var mproject = new MProject(pn, model)
 305                         mgroup = new MGroup(pn, mproject, null) # same name for the root group
 306                         mproject.root = mgroup
 307                         toolcontext.info("found project `{mproject}` at {dirpath}", 2)
 308                 else
 309                         mgroup = new MGroup(pn, parent.mproject, parent)
 310                         toolcontext.info("found sub group `{mgroup.full_name}` at {dirpath}", 2)
 311                 end
 312                 var readme = dirpath2.join_path("README.md")
 313                 if not readme.file_exists then readme = dirpath2.join_path("README")
 314                 if readme.file_exists then
 315                         var mdoc = new MDoc
 316                         var s = new IFStream.open(readme)
 317                         while not s.eof do
 318                                 mdoc.content.add(s.read_line)
 319                         end
 320                         mgroup.mdoc = mdoc
 321                         mdoc.original_mentity = mgroup
 322                 end
 323                 mgroup.filepath = dirpath
 324                 mgroups[rdp] = mgroup
 325                 return mgroup
 326         end
 327
 328         # Force the identification of all ModulePath of the group and sub-groups.
 329         fun visit_group(mgroup: MGroup) do
 330                 var p = mgroup.filepath
 331                 for f in p.files do
 332                         var fp = p/f
 333                         var g = get_mgroup(fp)
 334                         if g != null then visit_group(g)
 335                         identify_file(fp)
 336                 end
 337         end
 338
 339         # Transform relative paths (starting with '../') into absolute paths
 340         private fun module_absolute_path(path: String): String do
 341                 return getcwd.join_path(path).simplify_path
 342         end
 343
 344         # Try to load a module AST using a path.
 345         # Display an error if there is a problem (IO / lexer / parser) and return null
 346         fun load_module_ast(filename: String): nullable AModule
 347         do
 348                 if filename.file_extension != "nit" then
 349                         self.toolcontext.error(null, "Error: file {filename} is not a valid nit module.")
 350                         return null
 351                 end
 352                 if not filename.file_exists then
 353                         self.toolcontext.error(null, "Error: file {filename} not found.")
 354                         return null
 355                 end
 356
 357                 self.toolcontext.info("load module {filename}", 2)
 358
 359                 # Load the file
 360                 var file = new IFStream.open(filename)
 361                 var lexer = new Lexer(new SourceFile(filename, file))
 362                 var parser = new Parser(lexer)
 363                 var tree = parser.parse
 364                 file.close
 365
 366                 # Handle lexer and parser error
 367                 var nmodule = tree.n_base
 368                 if nmodule == null then
 369                         var neof = tree.n_eof
 370                         assert neof isa AError
 371                         error(neof, neof.message)
 372                         return null
 373                 end
 374
 375                 return nmodule
 376         end
 377
 378         # Try to load a module using a path.
 379         # Display an error if there is a problem (IO / lexer / parser) and return null.
 380         # Note: usually, you do not need this method, use `get_mmodule_by_name` instead.
 381         #
 382         # The MModule is created however, the importation is not performed,
 383         # therefore you should call `build_module_importation`.
 384         fun load_module(filename: String): nullable AModule
 385         do
 386                 # Look for the module
 387                 var file = identify_file(filename)
 388                 if file == null then
 389                         toolcontext.error(null, "Error: cannot find module `{filename}`.")
 390                         return null
 391                 end
 392
 393                 # Already known and loaded? then return it
 394                 var mmodule = file.mmodule
 395                 if mmodule != null then
 396                         return mmodule2nmodule[mmodule]
 397                 end
 398
 399                 # Load it manually
 400                 var nmodule = load_module_ast(file.filepath)
 401                 if nmodule == null then return null # forward error
 402
 403                 # build the mmodule and load imported modules
 404                 mmodule = build_a_mmodule(file.mgroup, file.name, nmodule)
 405
 406                 if mmodule == null then return null # forward error
 407
 408                 # Update the file information
 409                 file.mmodule = mmodule
 410
 411                 return nmodule
 412         end
 413
 414         # Injection of a new module without source.
 415         # Used by the interpreter.
 416         fun load_rt_module(parent: nullable MModule, nmodule: AModule, mod_name: String): nullable AModule
 417         do
 418                 # Create the module
 419
 420                 var mgroup = null
 421                 if parent != null then mgroup = parent.mgroup
 422                 var mmodule = new MModule(model, mgroup, mod_name, nmodule.location)
 423                 nmodule.mmodule = mmodule
 424                 nmodules.add(nmodule)
 425                 self.mmodule2nmodule[mmodule] = nmodule
 426
 427                 if parent!= null then
 428                         var imported_modules = new Array[MModule]
 429                         imported_modules.add(parent)
 430                         mmodule.set_visibility_for(parent, intrude_visibility)
 431                         mmodule.set_imported_mmodules(imported_modules)
 432                 else
 433                         build_module_importation(nmodule)
 434                 end
 435
 436                 return nmodule
 437         end
 438
 439         # Visit the AST and create the `MModule` object
 440         private fun build_a_mmodule(mgroup: nullable MGroup, mod_name: String, nmodule: AModule): nullable MModule
 441         do
 442                 # Check the module name
 443                 var decl = nmodule.n_moduledecl
 444                 if decl == null then
 445                         #warning(nmodule, "Warning: Missing 'module' keyword") #FIXME: NOT YET FOR COMPATIBILITY
 446                 else
 447                         var decl_name = decl.n_name.n_id.text
 448                         if decl_name != mod_name then
 449                                 error(decl.n_name, "Error: module name missmatch; declared {decl_name} file named {mod_name}")
 450                         end
 451                 end
 452
 453                 # Create the module
 454                 var mmodule = new MModule(model, mgroup, mod_name, nmodule.location)
 455                 nmodule.mmodule = mmodule
 456                 nmodules.add(nmodule)
 457                 self.mmodule2nmodule[mmodule] = nmodule
 458
 459                 if decl != null then
 460                         var ndoc = decl.n_doc
 461                         if ndoc != null then
 462                                 var mdoc = ndoc.to_mdoc
 463                                 mmodule.mdoc = mdoc
 464                                 mdoc.original_mentity = mmodule
 465                         else
 466                                 advice(decl, "missing-doc", "Documentation warning: Undocumented module `{mmodule}`")
 467                         end
 468                 end
 469
 470                 return mmodule
 471         end
 472
 473         # Analyze the module importation and fill the module_importation_hierarchy
 474         #
 475         # Unless you used `load_module`, the importation is already done and this method does a no-op.
 476         fun build_module_importation(nmodule: AModule)
 477         do
 478                 if nmodule.is_importation_done then return
 479                 nmodule.is_importation_done = true
 480                 var mmodule = nmodule.mmodule.as(not null)
 481                 var stdimport = true
 482                 var imported_modules = new Array[MModule]
 483                 for aimport in nmodule.n_imports do
 484                         stdimport = false
 485                         if not aimport isa AStdImport then
 486                                 continue
 487                         end
 488                         var mgroup = mmodule.mgroup
 489                         if aimport.n_name.n_quad != null then mgroup = null # Start from top level
 490                         for grp in aimport.n_name.n_path do
 491                                 var path = search_mmodule_by_name(grp, mgroup, grp.text)
 492                                 if path == null then return # Skip error
 493                                 mgroup = path.mgroup
 494                         end
 495                         var mod_name = aimport.n_name.n_id.text
 496                         var sup = self.get_mmodule_by_name(aimport.n_name, mgroup, mod_name)
 497                         if sup == null then continue # Skip error
 498                         aimport.mmodule = sup
 499                         imported_modules.add(sup)
 500                         var mvisibility = aimport.n_visibility.mvisibility
 501                         if mvisibility == protected_visibility then
 502                                 error(aimport.n_visibility, "Error: only properties can be protected.")
 503                                 return
 504                         end
 505                         if sup == mmodule then
 506                                 error(aimport.n_name, "Error: Dependency loop in module {mmodule}.")
 507                         end
 508                         if sup.in_importation < mmodule then
 509                                 error(aimport.n_name, "Error: Dependency loop between modules {mmodule} and {sup}.")
 510                                 return
 511                         end
 512                         mmodule.set_visibility_for(sup, mvisibility)
 513                 end
 514                 if stdimport then
 515                         var mod_name = "standard"
 516                         var sup = self.get_mmodule_by_name(nmodule, null, mod_name)
 517                         if sup != null then # Skip error
 518                                 imported_modules.add(sup)
 519                                 mmodule.set_visibility_for(sup, public_visibility)
 520                         end
 521                 end
 522                 self.toolcontext.info("{mmodule} imports {imported_modules.join(", ")}", 3)
 523                 mmodule.set_imported_mmodules(imported_modules)
 524
 525                 # Force standard to be public if imported
 526                 for sup in mmodule.in_importation.greaters do
 527                         if sup.name == "standard" then
 528                                 mmodule.set_visibility_for(sup, public_visibility)
 529                         end
 530                 end
 531
 532                 # TODO: Correctly check for useless importation
 533                 # It is even doable?
 534                 var directs = mmodule.in_importation.direct_greaters
 535                 for nim in nmodule.n_imports do
 536                         if not nim isa AStdImport then continue
 537                         var im = nim.mmodule
 538                         if im == null then continue
 539                         if directs.has(im) then continue
 540                         # This generates so much noise that it is simpler to just comment it
 541                         #warning(nim, "Warning: possible useless importation of {im}")
 542                 end
 543         end
 544
 545         # All the loaded modules
 546         var nmodules = new Array[AModule]
 547
 548         # Register the nmodule associated to each mmodule
 549         # FIXME: why not refine the `MModule` class with a nullable attribute?
 550         var mmodule2nmodule = new HashMap[MModule, AModule]
 551 end
 552
 553 # File-system location of a module (file) that is identified but not always loaded.
 554 class ModulePath
 555         # The name of the module
 556         # (it's the basename of the filepath)
 557         var name: String
 558
 559         # The human path of the module
 560         var filepath: String
 561
 562         # The group (and the project) of the possible module
 563         var mgroup: MGroup
 564
 565         # The loaded module (if any)
 566         var mmodule: nullable MModule = null
 567
 568         redef fun to_s do return filepath
 569 end
 570
 571 redef class MGroup
 572         # Modules paths associated with the group
 573         var module_paths = new Array[ModulePath]
 574
 575         # Is the group interesting for a final user?
 576         #
 577         # Groups are mandatory in the model but for simple projects they are not
 578         # always interesting.
 579         #
 580         # A interesting group has, at least, one of the following true:
 581         #
 582         # * it has 2 modules or more
 583         # * it has a subgroup
 584         # * it has a documentation
 585         fun is_interesting: Bool
 586         do
 587                 return module_paths.length > 1 or mmodules.length > 1 or not in_nesting.direct_smallers.is_empty or mdoc != null
 588         end
 589
 590 end
 591
 592 redef class AStdImport
 593         # The imported module once determined
 594         var mmodule: nullable MModule = null
 595 end
 596
 597 redef class AModule
 598         # The associated MModule once build by a `ModelBuilder`
 599         var mmodule: nullable MModule
 600         # Flag that indicate if the importation is already completed
 601         var is_importation_done: Bool = false
 602 end