lib/nitcc_runtime.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Runtime library required by parsers and lexers generated by nitcc
  16 module nitcc_runtime
  17
  18 # A abstract parser engine generated by nitcc
  19 abstract class Parser
  20         # The list of tokens
  21         # FIXME: provide something better, like a lexer?
  22         var tokens = new CircularArray[NToken]
  23
  24         # Look at the next token
  25         # Used by generated parsers
  26         fun peek_token: NToken do return tokens.first
  27
  28         # Consume the next token
  29         # Used by generated parsers
  30         fun get_token: NToken do return tokens.shift
  31
  32         # Consume the next token and shift to the state `dest`.
  33         # Used by generated parsers
  34         fun shift(dest: LRState)
  35         do
  36                 var t = get_token
  37                 #print "shift {t} -> {dest}"
  38                 node_stack.push t
  39                 state_stack.push state
  40                 state = dest
  41         end
  42
  43         # After a reduction on `goto` go to the next state
  44         # Used by generated parsers
  45         fun goto(goto: LRGoto)
  46         do
  47                 #print "reduce from {state} -> {prod}"
  48                 state.goto(self, goto)
  49         end
  50
  51         # push a new state on the stack of states (
  52         # Used by generated parsers
  53         fun push(dest: LRState)
  54         do
  55                 #print "push prod {prod} -> {dest}"
  56                 state_stack.push state
  57                 state = dest
  58         end
  59
  60         # Pop and return the last node
  61         # Also pop (and discard) the associated state
  62         # Used by generated parsers
  63         fun pop: Node
  64         do
  65                 var res = node_stack.pop
  66                 state = state_stack.pop
  67                 return res
  68         end
  69
  70         # Produce a parse error and stop the parsing
  71         # Used by generated parsers
  72         fun parse_error
  73         do
  74                 var token = peek_token
  75                 #print "* parse error in state {state} on token {token}"
  76                 #print "  expected: {state.error_msg}"
  77                 #print "  node_stack={node_stack.join(", ")}"
  78                 #print "  state_stack={state_stack.join(", ")}"
  79                 node_stack.push(token)
  80                 var error: NError
  81                 if token isa NLexerError then
  82                         error = token
  83                 else
  84                         error = new NParserError
  85                         error.position = token.position
  86                         error.text = token.text
  87                         error.token = token
  88                 end
  89                 error.error_tree.children.add_all(node_stack)
  90                 error.expected = state.error_msg
  91                 node_stack.clear
  92                 node_stack.add error
  93                 stop = true
  94         end
  95
  96         # The stating state for parsing
  97         # Used by generated parsers
  98         protected fun start_state: LRState is abstract
  99
 100         # The current state
 101         # Used by generated parsers
 102         var state: LRState is noinit
 103
 104         init
 105         do
 106                 state = start_state
 107         end
 108
 109         # The stack of nodes
 110         # Used by generated parsers
 111         var node_stack = new Array[Node]
 112
 113         # The stack of states
 114         # Used by generated parsers
 115         var state_stack = new Array[LRState]
 116
 117         # Should the parser stop
 118         # Used by generated parsers
 119         var stop = true is writable
 120
 121         # Parse a full sequence of tokens and return a complete syntactic tree
 122         fun parse: Node
 123         do
 124                 state = start_state
 125                 state_stack.clear
 126                 node_stack.clear
 127                 stop = false
 128                 while not stop do
 129                         #print "* current state {state}"
 130                         #print "  tokens={tokens.join(" ")}"
 131                         #print "  node_stack={node_stack.join(" ")}"
 132                         #print "  state_stack={state_stack.join(" ")}"
 133                         state.action(self)
 134                 end
 135                 #print "* over"
 136                 return node_stack.first
 137         end
 138 end
 139
 140 # A state in a parser LR automaton generated by nitcc
 141 # Used by generated parsers
 142 abstract class LRState
 143         fun action(parser: Parser) is abstract
 144         fun goto(parser: Parser, goto: LRGoto) is abstract
 145         fun error_msg: String do return "FIXME"
 146 end
 147
 148 # A concrete production in a parser LR automation generated by nitcc
 149 # Used by generated parsers
 150 abstract class LRGoto
 151 end
 152
 153 ###
 154
 155 # A abstract lexer engine generated by nitcc
 156 abstract class Lexer
 157         # The input stream of characters
 158         var stream: String
 159
 160         # The stating state for lexing
 161         # Used by generated parsers
 162         protected fun start_state: DFAState is abstract
 163
 164         # Lexize a stream of characters and return a sequence of tokens
 165         fun lex: CircularArray[NToken]
 166         do
 167                 var res = new CircularArray[NToken]
 168                 var state = start_state
 169                 var pos = 0
 170                 var pos_start = 0
 171                 var pos_end = 0
 172                 var line = 1
 173                 var line_start = 1
 174                 var line_end = 0
 175                 var col = 1
 176                 var col_start = 1
 177                 var col_end = 0
 178                 var last_state: nullable DFAState = null
 179                 var text = stream
 180                 var length = text.length
 181                 loop
 182                         if state.is_accept then
 183                                 pos_end = pos - 1
 184                                 line_end = line
 185                                 col_end = col
 186                                 last_state = state
 187                         end
 188                         var c
 189                         var next
 190                         if pos >= length then
 191                                 c = '\0'
 192                                 next = null
 193                         else
 194                                 c = text.chars[pos]
 195                                 next = state.trans(c)
 196                         end
 197                         if next == null then
 198                                 if pos_start < length then
 199                                         if last_state == null then
 200                                                 var token = new NLexerError
 201                                                 var position = new Position(pos_start, pos, line_start, line, col_start, col)
 202                                                 token.position = position
 203                                                 token.text = text.substring(pos_start, pos-pos_start+1)
 204                                                 res.push token
 205                                                 break
 206                                         end
 207                                         if not last_state.is_ignored then
 208                                                 var position = new Position(pos_start, pos_end, line_start, line_end, col_start, col_end)
 209                                                 var token = last_state.make_token(position, text)
 210                                                 if token != null then res.push(token)
 211                                         end
 212                                 end
 213                                 if pos >= length then
 214                                         var token = new NEof
 215                                         var position = new Position(pos, pos, line, line, col, col)
 216                                         token.position = position
 217                                         token.text = ""
 218                                         res.push token
 219                                         break
 220                                 end
 221                                 state = start_state
 222                                 pos_start = pos_end + 1
 223                                 pos = pos_start
 224                                 line_start = line_end
 225                                 line = line_start
 226                                 col_start = col_end
 227                                 col = col_start
 228
 229                                 last_state = null
 230                                 continue
 231                         end
 232                         state = next
 233                         pos += 1
 234                         col += 1
 235                         if c == '\n' then
 236                                 line += 1
 237                                 col = 1
 238                         end
 239                 end
 240                 return res
 241         end
 242 end
 243
 244 # A state in a lexer automaton generated by nitcc
 245 # Used by generated lexers
 246 interface DFAState
 247         fun is_accept: Bool do return false
 248         fun trans(c: Char): nullable DFAState do return null
 249         fun make_token(position: Position, source: String): nullable NToken is abstract
 250         fun is_ignored: Bool do return false
 251 end
 252
 253 ###
 254
 255 # A abstract visitor on syntactic trees generated by nitcc
 256 abstract class Visitor
 257         # The main entry point to visit a node `n`
 258         # Should not be redefined
 259         fun enter_visit(n: Node)
 260         do
 261                 visit(n)
 262         end
 263
 264         # The specific implementation of a visit
 265         #
 266         # Should be redefined by concrete visitors
 267         #
 268         # Should not be called directly (use `enter_visit` instead)
 269         #
 270         # By default, the visitor just rescursively visit the children of `n`
 271         protected fun visit(n: Node)
 272         do
 273                 n.visit_children(self)
 274         end
 275 end
 276
 277 # Print a node (using to_s) on a line and recustively each children indented (with two spaces)
 278 class TreePrinterVisitor
 279         super Visitor
 280         var writer: Writer
 281         private var indent = 0
 282         redef fun visit(n)
 283         do
 284                 for i in [0..indent[ do writer.write("  ")
 285                 writer.write(n.to_s)
 286                 writer.write("\n")
 287                 indent += 1
 288                 super
 289                 indent -= 1
 290         end
 291 end
 292
 293 # A position into a input stream
 294 # Used to give position to tokens
 295 class Position
 296         var pos_start: Int
 297         var pos_end: Int
 298         var line_start: Int
 299         var line_end: Int
 300         var col_start: Int
 301         var col_end: Int
 302
 303         redef fun to_s do return "{line_start}:{col_start}-{line_end}:{col_end}"
 304
 305         # Extract the content from the given source
 306         fun extract(source: String): String
 307         do
 308                 return source.substring(pos_start, pos_end-pos_start+1)
 309         end
 310
 311         # Get the lines covered by `self` and underline the target columns.
 312         #
 313         # This is useful for pretty printing errors or debug the output
 314         #
 315         # ~~~
 316         # var src = "var Foo = new Array[Int]"
 317         # var pos = new Position(0,0, 1, 1, 5, 8)
 318         #
 319         # assert pos.underline(src) == """
 320         # var Foo = new Array[Int]
 321         #     ^^^"""
 322         # ~~~
 323         fun underline(source: Text): String
 324         do
 325                 var res = new FlatBuffer
 326
 327                 # All the concerned lines
 328                 var lines = source.split("\n")
 329                 for line in [line_start..line_end] do
 330                         res.append lines[line-1]
 331                         res.append "\n"
 332                 end
 333
 334                 # Cover all columns, no matter their lines
 335                 var col_start = col_start.min(col_end)
 336                 var col_end = self.col_start.max(col_end)
 337
 338                 # "           ^^^^"
 339                 var ptr = " "*(col_start-1).max(0) + "^"*(col_end-col_start)
 340                 res.append ptr
 341
 342                 return res.to_s
 343         end
 344 end
 345
 346 # A node of a syntactic tree
 347 abstract class Node
 348         # The name of the node (as used in the grammar file)
 349         fun node_name: String do return class_name
 350
 351         # A point of view on the direct children of the node
 352         fun children: SequenceRead[nullable Node] is abstract
 353
 354         # A point of view of a depth-first visit of all non-null children
 355         var depth: Collection[Node] = new DephCollection(self) is lazy
 356
 357         # Visit all the children of the node with the visitor `v`
 358         protected fun visit_children(v: Visitor)
 359         do
 360                 for c in children do if c != null then v.enter_visit(c)
 361         end
 362
 363         # The position of the node in the input stream
 364         var position: nullable Position = null is writable
 365
 366         # Produce a graphiz file for the syntaxtic tree rooted at `self`.
 367         fun to_dot(filepath: String)
 368         do
 369                 var f = new FileWriter.open(filepath)
 370                 f.write("digraph g \{\n")
 371                 f.write("rankdir=BT;\n")
 372
 373                 var a = new Array[NToken]
 374                 to_dot_visitor(f, a)
 375
 376                 f.write("\{ rank=same\n")
 377                 var first = true
 378                 for n in a do
 379                         if first then
 380                                 first = false
 381                         else
 382                                 f.write("->")
 383                         end
 384                         f.write("n{n.object_id}")
 385                 end
 386                 f.write("[style=invis];\n")
 387                 f.write("\}\n")
 388
 389                 f.write("\}\n")
 390                 f.close
 391         end
 392
 393         private fun to_dot_visitor(f: Writer, a: Array[NToken])
 394         do
 395                 f.write("n{object_id} [label=\"{node_name}\"];\n")
 396                 for x in children do
 397                         if x == null then continue
 398                         f.write("n{x.object_id} -> n{object_id};\n")
 399                         x.to_dot_visitor(f,a )
 400                 end
 401         end
 402
 403         redef fun to_s do
 404                 var pos = position
 405                 if pos == null then
 406                         return "{node_name}"
 407                 else
 408                         return "{node_name}@({pos})"
 409                 end
 410         end
 411 end
 412
 413 private class DephCollection
 414         super Collection[Node]
 415         var node: Node
 416         redef fun iterator do return new DephIterator([node].iterator)
 417 end
 418
 419 private class DephIterator
 420         super Iterator[Node]
 421
 422         var stack = new Array[Iterator[nullable Node]]
 423
 424         init(i: Iterator[nullable Node]) is old_style_init do
 425                 stack.push i
 426         end
 427
 428         redef fun is_ok do return not stack.is_empty
 429         redef fun item do return stack.last.item.as(not null)
 430         redef fun next
 431         do
 432                 var i = stack.last
 433                 stack.push i.item.children.iterator
 434                 i.next
 435                 while is_ok do
 436                         if not stack.last.is_ok then
 437                                 stack.pop
 438                                 continue
 439                         end
 440                         if stack.last.item == null then
 441                                 stack.last.next
 442                                 continue
 443                         end
 444                         return
 445                 end
 446         end
 447 end
 448
 449 # A token produced by the lexer and used in a syntactic tree
 450 abstract class NToken
 451         super Node
 452
 453         redef fun children do return once new Array[Node]
 454
 455         redef fun to_dot_visitor(f, a)
 456         do
 457                 var labe = "{node_name}"
 458                 var pos = position
 459                 if pos != null then labe += "\\n{pos}"
 460                 var text = self.text
 461                 if node_name != "'{text}'" then
 462                         labe += "\\n'{text.escape_to_c}'"
 463                 end
 464                 f.write("n{object_id} [label=\"{labe}\",shape=box];\n")
 465                 a.add(self)
 466         end
 467
 468         # The text associated with the token
 469         var text: String = "" is writable
 470
 471         redef fun to_s do
 472                 var res = super
 473                 var text = self.text
 474                 if node_name != "'{text}'" then
 475                         res += "='{text.escape_to_c}'"
 476                 end
 477                 return res
 478         end
 479 end
 480
 481 # The special token for the end of stream
 482 class NEof
 483         super NToken
 484 end
 485
 486 # A special token used to represent a parser or lexer error
 487 abstract class NError
 488         super NToken
 489
 490         # All the partially built tree during parsing (aka the node_stack)
 491         var error_tree = new Nodes[Node]
 492
 493         # The things unexpected
 494         fun unexpected: String is abstract
 495
 496         # The things expected (if any)
 497         var expected: nullable String = null
 498
 499         # The error message,using `expected` and `unexpected`
 500         fun message: String
 501         do
 502                 var exp = expected
 503                 var res = "Unexpected {unexpected}"
 504                 if exp != null then res += "; is acceptable instead: {exp}"
 505                 return res
 506         end
 507 end
 508
 509 # A lexer error as a token for the unexpected characted
 510 class NLexerError
 511         super NError
 512
 513         redef fun unexpected do return "character '{text.chars.first}'"
 514 end
 515
 516 # A parser error linked to a unexpected token
 517 class NParserError
 518         super NError
 519
 520         # The unexpected token
 521         var token: nullable NToken = null
 522
 523         redef fun unexpected
 524         do
 525                 var res = token.node_name
 526                 var text = token.text
 527                 if not text.is_empty and res != "'{text}'" then
 528                         res += " '{text.escape_to_c}'"
 529                 end
 530                 return res
 531         end
 532 end
 533
 534 # A hogeneous sequence of node, used to represent unbounded lists (and + modifier)
 535 class Nodes[T: Node]
 536         super Node
 537         redef var children: Array[T] = new Array[T]
 538 end
 539
 540 # A production with a specific, named and statically typed children
 541 abstract class NProd
 542         super Node
 543         redef var children: SequenceRead[nullable Node] = new NProdChildren(self)
 544
 545         # The exact number of direct children
 546         # Used to implement `children` by generated parsers
 547         fun number_of_children: Int is abstract
 548
 549         # The specific children got by its index
 550         # Used to implement `children` by generated parsers
 551         fun child(x: Int): nullable Node is abstract
 552 end
 553
 554
 555 private class NProdChildren
 556         super SequenceRead[nullable Node]
 557         var prod: NProd
 558         redef fun iterator do return new NProdIterator(prod)
 559         redef fun length do return prod.number_of_children
 560         redef fun is_empty do return prod.number_of_children == 0
 561         redef fun [](i) do return prod.child(i)
 562 end
 563
 564 private class NProdIterator
 565         super IndexedIterator[nullable Node]
 566         var prod: NProd
 567         redef var index = 0
 568         redef fun is_ok do return index < prod.number_of_children
 569         redef fun next do index += 1
 570         redef fun item do return prod.child(index)
 571 end
 572
 573 # All-in-one abstract class to test generated parsers on a given
 574 abstract class TestParser
 575         # How to get a new lexer on a given stream of character
 576         fun new_lexer(text: String): Lexer is abstract
 577
 578         # How to get a new parser
 579         fun new_parser: Parser is abstract
 580
 581         # The name of the language (used for generated files)
 582         fun name: String is abstract
 583
 584         # Use the class as the main enrty point of the program
 585         # - parse arguments and options of the command
 586         # - test the parser (see `work`)
 587         fun main: Node
 588         do
 589                 if args.is_empty then
 590                         print "usage {name}_test <filepath> | - | -e <text>"
 591                         exit 0
 592                 end
 593
 594                 var filepath = args.shift
 595                 var text
 596                 if filepath == "-" then
 597                         text = sys.stdin.read_all
 598                 else if filepath == "-e" then
 599                         if args.is_empty then
 600                                 print "Error: -e need a text"
 601                                 exit 1
 602                         end
 603                         text = args.shift
 604                 else
 605                         var f = new FileReader.open(filepath)
 606                         text = f.read_all
 607                         f.close
 608                 end
 609
 610                 if not args.is_empty then
 611                         print "Error: superfluous arguments."
 612                         exit 1
 613                 end
 614
 615                 return work(text)
 616         end
 617
 618         # Produce a full syntactic tree for a given stream of character
 619         # Produce also statistics and output files
 620         fun work(text: String): Node
 621         do
 622                 print "INPUT: {text.length} chars"
 623                 var l = new_lexer(text)
 624                 var tokens = l.lex
 625
 626                 var tokout = "{name}.tokens.out"
 627                 print "TOKEN: {tokens.length} tokens (see {tokout})"
 628
 629                 var f = new FileWriter.open(tokout)
 630                 for t in tokens do
 631                         f.write "{t.to_s}\n"
 632                 end
 633                 f.close
 634
 635                 var p = new_parser
 636                 p.tokens.add_all(tokens)
 637
 638                 var n = p.parse
 639
 640                 var astout = "{name}.ast.out"
 641                 f = new FileWriter.open(astout)
 642                 var tpv = new TreePrinterVisitor(f)
 643                 var astdotout = "{name}.ast.dot"
 644                 if n isa NError then
 645                         print "Syntax error: {n.message}"
 646                         print "ERROR: {n} (see {astout} and {astdotout})"
 647                         tpv.enter_visit(n)
 648                         n = n.error_tree
 649                 else
 650                         print "ROOT: {n}; {n.depth.length} nodes (see {astout} and {astdotout})"
 651                 end
 652                 tpv.enter_visit(n)
 653                 n.to_dot(astdotout)
 654                 f.close
 655
 656                 return n
 657         end
 658 end