src/model/model_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # The abstract concept of model and related common things
  18 module model_base
  19
  20 # The container class of a Nit object-oriented model.
  21 # A model knows modules, classes and properties and can retrieve them.
  22 class Model
  23         super MEntity
  24 end
  25
  26 # A named and possibly documented entity in the model.
  27 # This class is useful to generalize presentation of entities to the human.
  28 abstract class MEntity
  29         # The short (unqualified) name of this model entity.
  30         #
  31         # The short-name is based from the identifiers used to declare or denote the entity.
  32         # It is usually globally ambiguous but is often enough in a precise local context.
  33         #
  34         # It is suitable to use the short-name in message to the user.
  35         # However, special care must be used in case of potential ambiguities or name conflict.
  36         fun name: String is abstract
  37
  38         # A fully-qualified name of this model entity.
  39         #
  40         # The full-name is based on the short name and is usually prefixed by the name of an outer entity.
  41         # Usually the quad (`::`) is used to separate the different names.
  42         #
  43         # The full-name is expected to be unique and unambiguous in lawful Nit models for the same kind of entity.
  44         #
  45         # It is often suitable to use it in message to the user.
  46         # However, some full-name could be long and verbose,
  47         #
  48         # See the specific implementation in subclasses for details.
  49         fun full_name: String is abstract
  50
  51         # A fully-qualified C-like identifier of this model entity.
  52         #
  53         # The C-name is a name that respects the rule of identifiers in the C language:
  54         # it is only made of alphanumeric characters and starts with a letter (or a underscore).
  55         #
  56         # The C-name can be seen as a mangled version of the `full_name`.
  57         # Therefore, it is expected to be unique and unambiguous in lawful Nit models for the same kind of entity.
  58         #
  59         # The C-name is used by tools that need some identifiers in generated files to designate the
  60         # entity.
  61         #
  62         # Is is not suitable to use it directly with the user (e.g. in message) and
  63         # indirect use should be restricted (e.g. to name a web-page)
  64         fun c_name: String is abstract
  65
  66         # A Model Entity has a direct link to its model
  67         fun model: Model is abstract
  68
  69         # The indication that the entity did not pass some semantic verifications.
  70         #
  71         # This simple flag is set by a given analysis to say that the entity is broken and unusable in
  72         # an execution.
  73         # When an entity status is set to broken, it is usually associated with a error message.
  74         #
  75         # If it is safe to do so, clients of the model SHOULD just skip broken entities in their processing.
  76         # Clients that do not care about the executability (e.g. metrics) MAY still process the entity or
  77         # perform specific checks to determinate the validity of the entity.
  78         #
  79         # Note that the broken status is not propagated to enclosing and enclosed entities.
  80         # e.g. a broken method does not make the whole module broken.
  81         var is_broken = false is writable
  82 end
  83
  84 # Something that represents a concern
  85 abstract class MConcern
  86         super MEntity
  87         # The concern that contains `self` or null if `self` is the root of the concern hierarchy
  88         fun parent_concern: nullable MConcern is abstract
  89 end
  90
  91 # A visibility (for modules, class and properties)
  92 # Valid visibility are:
  93 #
  94 #  * `intrude_visibility`
  95 #  * `public_visibility`
  96 #  * `protected_visibility`
  97 #  * `none_visibility`
  98 #  * `private_visiblity`
  99 #
 100 # Note this class is basically an enum.
 101 # FIXME: use a real enum once user-defined enums are available
 102 class MVisibility
 103         super Comparable
 104         redef type OTHER: MVisibility
 105
 106         redef var to_s: String
 107
 108         private var level: Int
 109
 110         # TODO: private init because enumeration.
 111
 112         # Is self give less visibility than other
 113         # none < private < protected < public < intrude
 114         redef fun <(other)
 115         do
 116                 return self.level < other.level
 117         end
 118 end
 119
 120 # A `Comparator` to sort mentities by their names.
 121 class MEntityNameSorter
 122         super Comparator
 123
 124         redef type COMPARED: MEntity
 125
 126         # Returns `a.name <=> b.name`.
 127         redef fun compare(a, b) do return a.name <=> b.name
 128 end
 129
 130 # The visibility level `intrude`
 131 fun intrude_visibility: MVisibility do return once new MVisibility("intrude", 5)
 132 # The visibility level `public`
 133 fun public_visibility: MVisibility do return once new MVisibility("public", 4)
 134 # The visibility level `protected`
 135 fun protected_visibility: MVisibility do return once new MVisibility("protected", 3)
 136 # The visibility level `private`
 137 fun private_visibility: MVisibility do return once new MVisibility("private", 2)
 138 # The visibility level `none` (no visibility)
 139 fun none_visibility: MVisibility do return once new MVisibility("none", 1)