contrib/nitrpg/src/templates/panels.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014-2015 Alexandre Terrasa <alexandre@moz-code.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Panels templates for `nitpg`.
  18 module panels
  19
  20 import templates_base
  21
  22 # A panel can be displayed in a html page.
  23 #
  24 # This display a Bootstrap panel.
  25 class Panel
  26         super Template
  27
  28         redef fun rendering do
  29                 add """<div class="panel panel-default">
  30                             <div class="panel-heading">
  31                                  <h3 class="panel-title">"""
  32                 render_title
  33                 add """  </h3>
  34                             </div>
  35                            <div class="panel-body">"""
  36                 render_body
  37                 add """</div>
  38                           </div>"""
  39         end
  40
  41         # Render the panel title.
  42         # Betweem `<h4>` tags.
  43         fun render_title do end
  44
  45         # Render the panel body.
  46         fun render_body do end
  47 end
  48
  49 # A panel that contain only a table as body.
  50 class TablePanel
  51         super Panel
  52
  53         redef fun rendering do
  54                 add """<div class="panel panel-default">
  55                             <div class="panel-heading">
  56                              <h3 class="panel-title">"""
  57                 render_title
  58                 add """
  59                              </h3>
  60                             </div>"""
  61                 render_body
  62                 add """</div>"""
  63         end
  64 end
  65
  66 # Display an error message within a panel.
  67 class ErrorPanel
  68         super Panel
  69
  70         redef fun rendering do
  71                 add """
  72 <div class="panel panel-danger">
  73         <div class="panel-heading">
  74                 <h3 class="panel-title">"""
  75                 render_title
  76                 add """
  77                 </h3>
  78         </div>
  79         <div class="panel-body">"""
  80                 render_body
  81                 add """
  82         </div>
  83 </div>
  84 """
  85         end
  86
  87         # The error message to display as panel body.
  88         var msg: String
  89
  90         redef fun render_title do
  91                 add "<span class=\"glyphicon glyphicon-warning-sign\"></span>&nbsp;&nbsp;"
  92                 add "Error"
  93         end
  94
  95         redef fun render_body do
  96                 add msg.html_escape
  97         end
  98
  99 end
 100
 101 # A panel that display repo statistics.
 102 class GameStatusPanel
 103         super Panel
 104
 105         # Repo to display.
 106         var game: Game
 107
 108         redef fun render_title do
 109                 add "<span class=\"glyphicon glyphicon-home\"></span>&nbsp;&nbsp;"
 110                 add "<a href=\"{game.url}\">{game.name}</a>"
 111         end
 112
 113         redef fun render_body do
 114                 add "<strong class=\"text-success\">{game.load_players.length}</strong>"
 115                 add " <a href=\"{game.url}/players\">players</a><br>"
 116                 add "<strong class=\"text-success\">{game.stats["pulls"]}</strong> pull requests"
 117                 add " (<strong>{game.stats["pulls_open"]}</strong> open)<br>"
 118                 add "<strong class=\"text-success\">{game.stats["issues"]}</strong> issues"
 119                 add " (<strong>{game.stats["issues_open"]}</strong> open)<br>"
 120         end
 121 end
 122
 123 # Player status panel.
 124 class PlayerStatusPanel
 125         super Panel
 126
 127         # Game instance.
 128         var game: Game
 129
 130         # Target player.
 131         var player: Player
 132
 133         redef fun render_title do
 134                 add "<a href=\"{player.url}\">"
 135                 add " <img class=\"img-circle\" style=\"width: 30px\""
 136                 add "   src=\"{player.user.avatar_url}\" alt=\"{player.name}\">"
 137                 add "</a>&nbsp;&nbsp;"
 138                 add "<a href=\"{player.url}\">{player.name}</a>"
 139         end
 140
 141         redef fun render_body do
 142                 var ranking = game.player_ranking
 143                 # TODO player.rank
 144                 add "<p class=\"lead\">ranked "
 145                 add " <span class=\"text-success\"># {ranking[player.name]}</span></p>"
 146                 add "<strong class=\"text-success\">{player.nitcoins}</strong> nitcoins<br>"
 147         end
 148 end
 149
 150 # A panel that display a list of player in a repo.
 151 class ShortListPlayersPanel
 152         super Panel
 153
 154         # Game instance.
 155         var game: Game
 156
 157         redef fun render_title do
 158                 add "<span class=\"glyphicon glyphicon-user\"></span>&nbsp;&nbsp;"
 159                 add "<a href=\"{game.url}/players\">Players</a>"
 160         end
 161
 162         redef fun render_body do
 163                 var players = game.load_players.values.to_a
 164                 if players.is_empty then
 165                         add "<em>No player yet...</em>"
 166                         return
 167                 end
 168                 (new PlayerCoinComparator).sort(players)
 169                 for player in players do
 170                         add "<a href=\"{player.url}\">"
 171                         add player.name
 172                         add "</a>&nbsp;({player.nitcoins})<br>"
 173                 end
 174         end
 175 end
 176
 177 # A panel that display a list of player in a repo.
 178 class ListPlayersPanel
 179         super TablePanel
 180
 181         # Game instance.
 182         var game: Game
 183
 184         redef fun render_title do
 185                 add "<span class=\"glyphicon glyphicon-user\"></span>&nbsp;&nbsp;"
 186                 add "<a href=\"{game.url}/players\">Players</a>"
 187         end
 188
 189         redef fun render_body do
 190                 var players = game.load_players.values.to_a
 191                 (new PlayerCoinComparator).sort(players)
 192                 if players.is_empty then
 193                         add "<div class=\"panel-body\">"
 194                         add "<em>No player yet...</em>"
 195                         add "</div>"
 196                         return
 197                 end
 198                 add """<table class="table table-striped table-hover">
 199                             <tr>
 200                                  <th>#</th>
 201                                  <th>Player</th>
 202                                  <th>Nitcoins</th>
 203                                 </tr>"""
 204                 var rank = 1
 205                 for player in players do
 206                         add "<tr>"
 207                         add " <td>{rank}</td>"
 208                         add " <td><a href=\"{player.url}\">{player.name}</a></td>"
 209                         add " <td>{player.nitcoins}</td>"
 210                         add "</tr>"
 211                         rank += 1
 212                 end
 213                 add "</table>"
 214         end
 215 end
 216
 217 # A panel that display the podium.
 218 class PodiumPanel
 219         super Panel
 220
 221         # Game instance.
 222         var game: Game
 223
 224         redef fun render_title do
 225                 add "<span class=\"glyphicon glyphicon-stats\"></span>&nbsp;&nbsp;Hall of fame"
 226         end
 227
 228         redef fun render_body do
 229                 var players = game.load_players.values.to_a
 230                 (new PlayerCoinComparator).sort(players)
 231                 if players.is_empty then
 232                         add "<em>No players yet...</em>"
 233                         return
 234                 end
 235                 add """
 236                         <div class="container-fluid">
 237                                 <div id="podium" class="row row-sm-height">"""
 238                 var max = players.first.nitcoins
 239                 var orders = [3, 1, 0, 2, 4]
 240                 for order in orders do
 241                         if order >= players.length then continue
 242                         var player = players[order]
 243                         var size = 0
 244                         if max > 0 then size = player.nitcoins * 300 / max
 245                         add """
 246                                 <div class="col-xs-2 col-xs-height col-xs-offset-{{{order}}} col-bottom"
 247                                         style="text-align: center;">
 248                                         <p>
 249                                                 <a href="{{{player.url}}}">
 250                                                         <img class="img-circle" style="width: 80px"
 251                                                                 src="{{{player.user.avatar_url}}}" alt="{{{player.name}}}">
 252                                                 </a>
 253                                         </p>
 254                                         <p><a href="{{{player.url}}}">{{{player.name}}}</a></p>
 255                                         <p>{{{player.nitcoins}}}</p>
 256                                         <div class=" progress-bar-warning progress-bar-striped"
 257                                                 style="height: {{{size}}}px;"></div>
 258                                 </div>"""
 259                 end
 260                 add """
 261                                 </div>
 262                         </div>"""
 263         end
 264 end
 265
 266 # A `Panel` that displays the list of PR to review for a `Player`.
 267 class PlayerReviewsPanel
 268         super Panel
 269
 270         # Repo to display.
 271         var game: Game
 272
 273         # Player to display customized list for.
 274         var player: Player
 275
 276         redef fun render_title do
 277                 add "<span class=\"glyphicon glyphicon-check\"></span>&nbsp;&nbsp;"
 278                 add "Review pull requests to gain nitcoins!"
 279         end
 280
 281         redef fun render_body do
 282                 var q = "is:open label:need_review sort:updated-asc " +
 283                         "-involves:{player.name}"
 284
 285                 var issues = game.repo.search_issues(q)
 286                 if issues.is_empty then
 287                         add "<em>No pull request to review yet...</em>"
 288                         return
 289                 end
 290                 for issue in issues do
 291                         add """<div class="media">
 292                                 <a class="media-left" href="{{{player.url}}}">
 293                                          <img class=\"img-circle\" style="width:50px"
 294                                            src="{{{issue.user.avatar_url}}}" alt="{{{issue.user.login}}}">
 295                                         </a>
 296                                         <div class="media-body">
 297                                          <h4 class="media-heading">
 298                                          <a href="{{{issue.html_url}}}">#{{{issue.number}}} {{{issue.title}}}</a></h4>
 299                                          <span class="text-muted">opened by </span>
 300                                          <a href="{{{player.url}}}">{{{issue.user.login}}}</a>
 301                                         </div>
 302                                    </div>"""
 303                 end
 304         end
 305 end