src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper?;
  59
  60 kwmodule = 'package'|'module';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwenum = 'universal'|'enum';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'fun';
  69 kwtype = 'type';
  70 kwinit = 'init';
  71 kwredef = 'redef';
  72 kwis = 'is';
  73 kwdo = 'do';
  74 kwreadable = 'readable';
  75 kwwritable = 'writable';
  76 kwvar = 'var';
  77 kwintern = 'intern';
  78 kwextern = 'extern';
  79 kwprotected = 'protected';
  80 kwprivate = 'private';
  81 kwintrude = 'intrude';
  82 kwif = 'if';
  83 kwthen = 'then';
  84 kwelse = 'else';
  85 kwwhile = 'while';
  86 kwloop = 'loop';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwnullable = 'nullable';
 107 kwisset = 'isset';
 108 kwlabel = 'label';
 109 kwdebug = '__debug__';
 110
 111 opar = '(';
 112 cpar = ')';
 113 obra = '[';
 114 cbra = ']';
 115 comma = ',';
 116 column = ':';
 117 quad = '::';
 118 assign = '=';
 119 pluseq = '+=';
 120 minuseq = '-=';
 121 dotdotdot = '...';
 122 dotdot = '..';
 123 dot = '.';
 124 plus = '+';
 125 minus = '-';
 126 star = '*';
 127 slash = '/';
 128 percent = '%';
 129 eq = '==';
 130 ne = '!=';
 131 lt = '<';
 132 le = '<=';
 133 ll = '<<';
 134 gt = '>';
 135 ge = '>=';
 136 gg = '>>';
 137 starship = '<=>';
 138 bang='!';
 139
 140 classid = uppercase letter*;
 141 id = lowercase letter*;
 142 attrid = '_' lowercase letter*;
 143
 144 number = digit+;
 145 float = digit* '.' digit+;
 146 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 147 string = '"' str_body '"';
 148 start_string = '"' str_body '{';
 149 mid_string = '}' str_body '{';
 150 end_string = '}' str_body '"';
 151 bad_char = ''' '\'? any;
 152 bad_string = ('"'|'}') str_body;
 153
 154
 155 /*****************************************************************************/
 156 Ignored Tokens
 157 /*****************************************************************************/
 158
 159 blank;
 160
 161 /*****************************************************************************/
 162 Productions
 163 /*****************************************************************************/
 164
 165 /* MODULES *******************************************************************/
 166 module
 167         = moduledecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(moduledecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 168
 169 moduledecl
 170         = [doc]:no kwmodule no module_name [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, module_name)};
 171
 172 import
 173         = {std} [doc]:no visibility kwimport no module_name [n2]:n1 {-> New import.std(visibility, kwimport, module_name)}
 174         | {no} [doc]:no visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 175         ;
 176
 177 implicit_top_class {-> classdef}
 178         = propdefs_toplevel+ {-> New classdef.top([propdefs_toplevel.propdef])};
 179
 180 implicit_main_class {-> classdef?}
 181         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 182         | {null} n {-> Null}
 183         ;
 184 implicit_main_meth {-> propdef}
 185         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 186         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 187         ;
 188
 189 /* CLASSES *******************************************************************/
 190 classdef
 191         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef], kwend)};
 192 redef {-> kwredef?}
 193         = kwredef? {-> kwredef};
 194 classkind
 195         = {concrete} kwclass
 196         | {abstract} kwabstract kwclass
 197         | {interface} kwinterface
 198         | {enum} kwenum
 199         | {extern} kwextern
 200         ;
 201
 202 formaldefs {-> formaldef*}
 203         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 204 formaldefs_tail {-> formaldef}
 205         = comma no formaldef {-> formaldef};
 206 formaldef
 207         = classid typing? {-> New formaldef(classid, typing.type)};
 208
 209 special {-> superclass}
 210         = {special} no kwspecial [n2]:no type {-> New superclass(kwspecial, Null, type)}
 211         | {super} no kwsuper [n2]:no type {-> New superclass(Null, kwsuper, type)}
 212         ;
 213
 214 propdefs~toplevel {-> propdef}
 215         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 216         ;
 217 propdef~toplevel {-> propdef}
 218         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 219         | {assign_return} [doc]:no redef visibility kwmeth methid signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature_withret.signature, assign_return.expr)}
 220 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 221 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 222         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? extern_calls? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string, extern_calls)}
 223 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null)}
 224 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, expr)}
 225 !toplevel| {var3} [doc]:no redef visibility kwvar id typing? writable2? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, Null)}
 226 !toplevel| {var4} [doc]:no redef visibility kwvar id typing? writable2? assign [n2]:no expr {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, expr)}
 227 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 228 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 229 !toplevel| {extern_init} [doc]:no redef visibility kwnew methid? signature kwis kwextern string? extern_calls? {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls)}
 230         ;
 231 readable {-> able}
 232         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 233         ;
 234 writable {-> able}
 235         = redef kwwritable {-> New able.write(redef.kwredef, Null, kwwritable)}
 236         ;
 237 writable2 {-> able}
 238         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 239         ;
 240
 241 visibility
 242         = {public} {-> New visibility.public()}
 243         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 244         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 245         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 246         ;
 247
 248 methid {-> methid}
 249         = {id} id {-> New methid.id(id)}
 250         | {plus} plus {-> New methid.plus(plus)}
 251         | {minus} minus {-> New methid.minus(minus)}
 252         | {star} star {-> New methid.star(star)}
 253         | {slash} slash {-> New methid.slash(slash)}
 254         | {percent} percent {-> New methid.percent(percent)}
 255         | {eq} eq {-> New methid.eq(eq)}
 256         | {ne} ne {-> New methid.ne(ne)}
 257         | {le} le {-> New methid.le(le)}
 258         | {ge} ge {-> New methid.ge(ge)}
 259         | {lt} lt {-> New methid.lt(lt)}
 260         | {gt} gt {-> New methid.gt(gt)}
 261         | {ll} ll {-> New methid.ll(ll)}
 262         | {gg} gg {-> New methid.gg(gg)}
 263         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 264         | {starship} starship {-> New methid.starship(starship)}
 265         | {assign} id assign {-> New methid.assign(id, assign)}
 266         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 267         ;
 268
 269 signature~withret {-> signature}
 270         = opar no params? cpar typing [no2]:no closure_decls? {-> New signature(opar, [params.param], cpar, typing.type, [closure_decls.closure_decl])}
 271 !withret| {noret} opar no params? cpar [no2]:no closure_decls? {-> New signature(opar, [params.param], cpar, Null, [closure_decls.closure_decl])}
 272         | {nopar} typing no closure_decls? {-> New signature(Null, [], Null, typing.type, [closure_decls.closure_decl])}
 273 !withret| {noparnoret} no closure_decls? {-> New signature(Null, [], Null, Null, [closure_decls.closure_decl])}
 274         ;
 275
 276 signature_noclosures {-> signature}
 277         = opar no params? cpar typing? {-> New signature(opar, [params.param], cpar, typing.type, [])}
 278         | {nopar} typing? {-> New signature(Null, [], Null, typing.type, [])}
 279         ;
 280
 281 params {-> param*}
 282         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 283         ;
 284 params_tail {-> param}
 285         = comma no param {-> param};
 286 param
 287         = {untyped} id {-> New param(id, Null, Null)}
 288         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 289         ;
 290
 291 closure_decls {->closure_decl*}
 292         = closure_decl+ {-> [closure_decl]};
 293 closure_decl
 294         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 295         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 296         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 297         ;
 298
 299 assign_return{-> expr}
 300         = expr_final {-> New expr.return(Null, expr_final.expr)}
 301         ;
 302
 303 extern_calls {-> extern_calls}
 304         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 305         ;
 306 extern_call_tail {-> extern_call}
 307         = comma no extern_call {-> extern_call};
 308 extern_call {-> extern_call}
 309     = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 310     | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 311         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 312     ;
 313 extern_call_prop {-> extern_call}
 314     = {local} methid {-> New extern_call.local_prop( methid )}
 315         | {full} classid quad methid {-> New extern_call.full_prop( classid, quad, methid )}
 316         | {init} classid {-> New extern_call.init_prop( classid )}
 317         ;
 318 extern_call_cast {-> extern_call}
 319     = {as_cast} [from_type]:type kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, kwas, to_type)}
 320         | {as_nullable} type kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 321         | {as_not_nullable} type kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 322         ;
 323
 324
 325 /* TYPES *********************************************************************/
 326 type~nobra {-> type}
 327         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 328 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 329         ;
 330 types {-> type*}
 331         = type types_tail* {-> [type, types_tail.type]};
 332 types_tail {-> type}
 333         = comma no type {-> type};
 334 typing {-> type}
 335         = column no type {-> type};
 336
 337 /* STATMENTS *****************************************************************/
 338 stmtso~withelse~withend {-> expr?}
 339         = {block} n stmtsnend {-> stmtsnend.expr}
 340         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 341         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 342 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 343         ;
 344 stmts {-> expr}
 345         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 346 stmtsn {-> expr}
 347         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 348 stmtsnend {-> expr}
 349         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 350 stmts_tail {-> expr}
 351         = n stmt {-> stmt.expr};
 352 stmt~withelse {-> expr}
 353         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 354         | {assign} assignment~withelse {-> assignment~withelse.expr}
 355         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 356         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 357         | {abort} kwabort {-> New expr.abort(kwabort)}
 358         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 359         | {do} do~withelse {-> do~withelse.expr}
 360         | {if} if~withelse {-> if~withelse.expr}
 361         | {while} while~withelse {-> while~withelse.expr}
 362         | {loop} loop~withelse {-> loop~withelse.expr}
 363         | {for} for~withelse {-> for~withelse.expr}
 364         | {assert} assert~withelse {-> assert~withelse.expr}
 365         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, args_nopar.exprs, [closure_defs~withelse.closure_def])}
 366         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, args_nopar.exprs)}
 367         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 368         | {debug_type_is} kwdebug kwtype type column expr_final~withelse {-> New expr.debug_type(kwdebug, kwtype, expr_final~withelse.expr, type) }
 369         ;
 370
 371 label= kwlabel id;
 372
 373 closure_defs~withelse {-> closure_def*}
 374         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 375         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 376         ;
 377
 378 closure_def_last~withelse {-> closure_def}
 379         = bang [id]:closure_id idlist? kwdo stmtso_withend label {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso_withend.expr, label)}
 380         | {nolabel} bang [id]:closure_id idlist? kwdo stmtso~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse.expr, Null)}
 381         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 382         ;
 383
 384 closure_def {-> closure_def}
 385         = bang [id]:closure_id idlist? kwdo n stmtsn {-> New closure_def(bang, id, [idlist.id], kwdo, stmtsn.expr, Null)}
 386         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 387         ;
 388 closure_id
 389         = {simple} id
 390         | {break} kwbreak
 391         ;
 392
 393 assign_continue~withelse{-> expr}
 394         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 395         ;
 396
 397 vardecl~withelse{-> expr}
 398         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 399         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 400         ;
 401
 402 assignment~withelse {-> expr}
 403         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 404         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, args.exprs, assign,  expr_final~withelse.expr)}
 405         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, braargs.exprs, assign,  expr_final~withelse.expr)}
 406         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 407         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, args.exprs, assign_op,  expr_final~withelse.expr)}
 408         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, braargs.exprs, assign_op,  expr_final~withelse.expr)}
 409         ;
 410 assign_op
 411         = {plus} pluseq
 412         | {minus} minuseq
 413         ;
 414
 415 do~withelse {-> expr}
 416         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 417         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 418         ;
 419
 420 if~withelse {-> expr}
 421         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 422 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 423 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 424 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 425         ;
 426 elsepartblock {-> expr?}
 427         = {else} kwelse stmtso {-> stmtso.expr}
 428         | {empty} kwend {-> New expr.block([], kwend)}
 429         ;
 430
 431 loop~withelse {-> expr}
 432         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 433         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 434         ;
 435
 436 while~withelse {-> expr}
 437         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 438         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 439         ;
 440
 441 for~withelse {-> expr}
 442         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 443         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 444         ;
 445
 446 assert~withelse {-> expr}
 447         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 448 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 449         ;
 450 assertid {-> id}
 451         = id column {-> id};
 452
 453 /* EXPRESSIONS ***************************************************************/
 454 expr_final~nopar~withelse~nobra {-> expr}
 455         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 456         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, args.exprs, [closure_defs~withelse.closure_def])}
 457 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, braargs.exprs, [closure_defs~withelse.closure_def])}
 458         ;
 459
 460 expr~nopar~nobra {-> expr}
 461         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 462         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 463         ;
 464
 465 expr_and~nopar~nobra {-> expr}
 466         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 467         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 468         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 469         | {or_else} expr_and~nopar~nobra kwor kwelse no expr_not~nopar~nobra {-> New expr.or_else(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 470         ;
 471
 472 expr_not~nopar~nobra {-> expr}
 473         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 474         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 475         ;
 476
 477 expr_eq~nopar~nobra {-> expr}
 478         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 479         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 480         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 481         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 482         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 483         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 484         | {ll} expr_eq~nopar~nobra ll no [expr2]:expr_add~nopar~nobra {-> New expr.ll(expr_eq~nopar~nobra.expr, expr2.expr)}
 485         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 486         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 487         | {gg} expr_eq~nopar~nobra gg no [expr2]:expr_add~nopar~nobra {-> New expr.gg(expr_eq~nopar~nobra.expr, expr2.expr)}
 488         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 489         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 490         ;
 491
 492 expr_add~nopar~nobra {-> expr}
 493         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 494         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 495         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 496         ;
 497
 498 expr_mul~nopar~nobra {-> expr}
 499         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 500         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 501         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 502         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 503         ;
 504
 505 expr_minus~nopar~nobra {-> expr}
 506         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 507         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 508         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 509         ;
 510
 511 expr_new~nopar~nobra {-> expr}
 512         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 513         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, args.exprs)}
 514         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 515         ;
 516
 517 expr_atom~nopar~nobra {-> expr}
 518         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 519         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, args.exprs, [])}
 520         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, args.exprs)}
 521         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 522 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs, [])}
 523         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, args.exprs)}
 524 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 525 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(obra, expr, expr2.expr, cbra)}
 526 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(obra, expr, expr2.expr, cbra)}
 527 !nobra!nopar    | {array} braargs {-> New expr.array(braargs.exprs)}
 528         | {self} kwself {-> New expr.self(kwself)}
 529         | {true} kwtrue {-> New expr.true(kwtrue)}
 530         | {false} kwfalse {-> New expr.false(kwfalse)}
 531         | {null} kwnull {-> New expr.null(kwnull)}
 532         | {int} number  {-> New expr.int(number)}
 533         | {float} float  {-> New expr.float(float)}
 534         | {char} char  {-> New expr.char(char)}
 535         | {string} string  {-> New expr.string(string)}
 536         | {superstring} superstring  {-> superstring.expr}
 537 !nopar  | {par} opar expr cpar {-> New expr.par(opar, expr, cpar)}
 538         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 539         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 540         ;
 541
 542 superstring {-> expr}
 543         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 544 superstring_start {-> expr*}
 545         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 546 start_string_p {-> expr}
 547         = start_string {-> New expr.start_string(start_string)};
 548 superstring_middle {-> expr*}
 549         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 550 mid_string_p {-> expr}
 551         = mid_string {-> New expr.mid_string(mid_string)};
 552 superstring_end {-> expr}
 553         = end_string {-> New expr.end_string(end_string)};
 554
 555 /* MISC **********************************************************************/
 556
 557 recv~nopar~nobra {-> expr}
 558         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 559         | {implicit} {-> New expr.implicit_self()}
 560         ;
 561
 562 args {-> exprs}
 563         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 564         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 565         | {empty} {-> New exprs.list([])}
 566         ;
 567 args_nopar {-> exprs}
 568         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 569         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 570         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 571         | {empty} {-> New exprs.list([])}
 572         ;
 573 braargs {-> exprs}
 574         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 575 expr_list {-> expr*}
 576         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 577 expr_tail {-> expr}
 578         = comma no expr [n2]:no {-> expr};
 579 idlist {-> id*}
 580         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 581         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 582         ;
 583 idlist_nopar {-> id*}
 584         = {single} id {-> [id]}
 585         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 586         ;
 587
 588 module_name {-> module_name}
 589         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 590         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 591         ;
 592
 593 qualified
 594         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 595         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 596         ;
 597 modquad {-> id}
 598         = id quad no {-> id};
 599 classquad {-> classid}
 600         = classid quad no {-> classid};
 601
 602 n1      = {a} comment | {b} eol;
 603 n {-> doc?}
 604         = {a} n2? comment+ {-> New doc([comment])}
 605         | {b} n2 {-> Null}
 606         ;
 607 no {-> doc?}
 608         = {empty} {-> Null}
 609         | n {-> n.doc}
 610         ;
 611
 612 n2
 613         = {a} n2? comment+ eol+
 614         | {b} eol+
 615         ;
 616
 617 /*****************************************************************************/
 618 Abstract Syntax Tree
 619 /*****************************************************************************/
 620
 621 module  = moduledecl? [imports]:import* [classdefs]:classdef*;
 622
 623 moduledecl
 624         = doc? kwmodule [name]:module_name;
 625
 626 import  = {std} visibility kwimport [name]:module_name
 627         | {no} visibility kwimport kwend
 628         ;
 629
 630 visibility
 631         = {public}
 632         | {private} kwprivate
 633         | {protected} kwprotected
 634         | {intrude} kwintrude
 635         ;
 636
 637 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef* kwend
 638         | {top} [propdefs]:propdef*
 639         | {main} [propdefs]:propdef*
 640         ;
 641 classkind
 642         = {concrete} kwclass
 643         | {abstract} kwabstract kwclass
 644         | {interface} kwinterface
 645         | {enum} kwenum
 646         | {extern} kwextern
 647         ;
 648 formaldef = [id]:classid type?;
 649 superclass = kwspecial? kwsuper? type;
 650
 651
 652 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? expr?
 653         | {meth} doc? kwredef? visibility methid signature
 654         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 655         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 656         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string? extern_calls?
 657         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 658         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 659         | {extern_init} doc? kwredef? visibility kwnew methid? signature [extern]:string? extern_calls?
 660         | {main_meth} kwredef? [block]:expr?
 661         | {type} doc? kwredef? visibility kwtype [id]:classid type
 662         ;
 663
 664 able    = {read} kwredef? kwreadable
 665         | {write} kwredef? visibility? kwwritable
 666         ;
 667
 668 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 669
 670 signature = opar? [params]:param* cpar? type? [closure_decls]:closure_decl*;
 671
 672 param   = id type? dotdotdot?
 673         ;
 674
 675 closure_decl = kwbreak? bang id signature expr?
 676         ;
 677
 678 type    = kwnullable? [id]:classid [types]:type*;
 679
 680 label = kwlabel id;
 681
 682 expr    = {block} expr* kwend?
 683         | {vardecl} kwvar id type? assign? expr?
 684         | {return} kwreturn? expr?
 685         | {break} kwbreak label? expr?
 686         | {abort} kwabort
 687         | {continue} kwcontinue? label? expr?
 688         | {do} kwdo [block]:expr? label?
 689         | {if} kwif expr [then]:expr? [else]:expr?
 690         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 691         | {while} kwwhile expr kwdo [block]:expr? label?
 692         | {loop} kwloop [block]:expr? label?
 693         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 694         | {assert} kwassert id? expr [else]:expr?
 695         | {once} kwonce expr
 696         | {send} expr
 697         | {binop} expr [expr2]:expr
 698         | {or} expr [expr2]:expr
 699         | {and} expr [expr2]:expr
 700         | {or_else} expr [expr2]:expr
 701         | {not} kwnot expr
 702         | {eq} expr [expr2]:expr
 703         | {ee} expr [expr2]:expr
 704         | {ne} expr [expr2]:expr
 705         | {lt} expr [expr2]:expr
 706         | {le} expr [expr2]:expr
 707         | {ll} expr [expr2]:expr
 708         | {gt} expr [expr2]:expr
 709         | {ge} expr [expr2]:expr
 710         | {gg} expr [expr2]:expr
 711         | {isa} expr type
 712         | {plus} expr [expr2]:expr
 713         | {minus} expr [expr2]:expr
 714         | {starship} expr [expr2]:expr
 715         | {star} expr [expr2]:expr
 716         | {slash} expr [expr2]:expr
 717         | {percent} expr [expr2]:expr
 718         | {uminus} minus expr
 719         | {new} kwnew type id? [args]:exprs
 720         | {attr} expr [id]:attrid
 721         | {attr_assign} expr [id]:attrid assign [value]:expr
 722         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 723         | {call} expr id [args]:exprs [closure_defs]:closure_def*
 724         | {call_assign} expr id [args]:exprs assign [value]:expr
 725         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 726         | {super} qualified? kwsuper [args]:exprs
 727         | {init} expr kwinit [args]:exprs
 728         | {bra} expr [args]:exprs [closure_defs]:closure_def*
 729         | {bra_assign} expr [args]:exprs assign [value]:expr
 730         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 731         | {closure_call} id [args]:exprs [closure_defs]:closure_def*
 732         | {var} id
 733         | {var_assign} id assign [value]:expr
 734         | {var_reassign} id assign_op [value]:expr
 735         | {range} expr [expr2]:expr
 736         | {crange} obra expr [expr2]:expr cbra
 737         | {orange} obra expr [expr2]:expr [cbra]:obra
 738         | {array} [exprs]:exprs
 739         | {self} kwself
 740         | {implicit_self}
 741         | {true} kwtrue
 742         | {false} kwfalse
 743         | {null} kwnull
 744         | {int} number
 745         | {float} float
 746         | {char} char
 747         | {string} string
 748         | {start_string} [string]:start_string
 749         | {mid_string} [string]:mid_string
 750         | {end_string} [string]:end_string
 751         | {superstring} [exprs]:expr*
 752         | {par} opar expr cpar
 753         | {as_cast} expr kwas opar type cpar
 754         | {as_notnull} expr kwas opar kwnot kwnull cpar
 755         | {isset_attr} kwisset expr [id]:attrid
 756         | {debug_type} kwdebug kwtype expr type
 757         ;
 758 exprs
 759         = {list} [exprs]:expr*
 760         | {par} opar [exprs]:expr* cpar
 761         | {bra} obra [exprs]:expr* cbra
 762         ;
 763 assign_op
 764         = {plus} pluseq
 765         | {minus} minuseq
 766         ;
 767
 768 closure_def
 769         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 770         ;
 771 closure_id
 772         = {simple} id
 773         | {break} kwbreak
 774         ;
 775
 776 module_name = quad? [path]:id* id;
 777 extern_calls = kwimport [extern_calls]:extern_call*
 778         ;
 779 extern_call =
 780         | {super} kwsuper
 781         | {local_prop} methid
 782         | {full_prop} classid quad? methid
 783         | {init_prop} classid
 784         | {cast_as} [from_type]:type kwas [to_type]:type
 785         | {as_nullable} type kwas kwnullable
 786         | {as_not_nullable} type kwas kwnot kwnullable
 787         ;
 788
 789 qualified = id* classid? ;
 790
 791 doc = comment+;
 792
 793 /*****************************************************************************/
 794