src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 hexdigit = ['0'..'9'] | ['a'..'f'] | ['A'..'F'];
  31 letter = lowercase | uppercase | digit | '_';
  32
  33 tab = 9;
  34 cr = 13;
  35 lf = 10;
  36 any = [all - [cr + lf]];
  37 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  38
  39 // characers inside strings and super-strings (atomaton powaa)
  40 str_char
  41         = [any - [['"' + '{'] + '\']]
  42         | '\' any
  43         ;
  44 str_body = str_char*;
  45
  46 sstr_char
  47         = [any - [''' + '\']]
  48         | '\' any
  49         ;
  50
  51 sstr_body = sstr_char*;
  52
  53 long_str_char = str_char | cr | lf;
  54
  55 // because no substraction in sablecc3, complex long strings are difficult to express
  56 ls1 = '"' '"'? ;
  57 ls2 = '{' '{'? ;
  58 ls12 = ls1? (ls2 ls1)* ls2?;
  59
  60 long_str_part
  61         = ls12 long_str_char
  62         ;
  63
  64 long_str_body = long_str_part*;
  65 lsend1 = ls2? (ls1 ls2)* '"""' '"'*;
  66 lsend2 = ls1? (ls2 ls1)* '{{{' '{'*;
  67
  68 long_sstr_char = sstr_char | cr | lf;
  69 long_sstr_part
  70         = long_sstr_char
  71         | ''' long_sstr_char
  72         | ''' ''' long_sstr_char
  73         ;
  74
  75 long_sstr_body = long_sstr_part*;
  76
  77
  78 extern_code_char
  79         = [all - ['`' + '\']]
  80         | '\' all
  81         ;
  82 extern_code_body = extern_code_char*;
  83
  84 /*****************************************************************************/
  85 States
  86 /*****************************************************************************/
  87 initial;
  88
  89
  90 /*****************************************************************************/
  91 Tokens
  92 /*****************************************************************************/
  93
  94 blank = (' ' | tab)+;
  95
  96 eol = eol_helper;
  97 comment = '#' any* eol_helper?;
  98
  99 kwpackage = 'package';
 100 kwmodule = 'module';
 101 kwimport = 'import';
 102 kwclass = 'class';
 103 kwabstract = 'abstract';
 104 kwinterface = 'interface';
 105 kwenum = 'universal'|'enum';
 106 kwend = 'end';
 107 kwmeth = 'fun';
 108 kwtype = 'type';
 109 kwinit = 'init';
 110 kwredef = 'redef';
 111 kwis = 'is';
 112 kwdo = 'do';
 113 kwreadable = 'readable';
 114 kwwritable = 'writable';
 115 kwvar = 'var';
 116 kwintern = 'intern';
 117 kwextern = 'extern';
 118 kwpublic = 'public';
 119 kwprotected = 'protected';
 120 kwprivate = 'private';
 121 kwintrude = 'intrude';
 122 kwif = 'if';
 123 kwthen = 'then';
 124 kwelse = 'else';
 125 kwwhile = 'while';
 126 kwloop = 'loop';
 127 kwfor = 'for';
 128 kwin = 'in';
 129 kwand = 'and';
 130 kwor = 'or';
 131 kwnot = 'not';
 132 kwimplies = 'implies';
 133 kwreturn = 'return';
 134 kwcontinue = 'continue';
 135 kwbreak = 'break';
 136 kwabort = 'abort';
 137 kwassert = 'assert';
 138 kwnew = 'new';
 139 kwisa = 'isa';
 140 kwonce = 'once';
 141 kwsuper = 'super';
 142 kwself = 'self';
 143 kwtrue = 'true';
 144 kwfalse = 'false';
 145 kwnull = 'null';
 146 kwas = 'as';
 147 kwnullable = 'nullable';
 148 kwisset = 'isset';
 149 kwlabel = 'label';
 150 kwdebug = '__debug__';
 151
 152 opar = '(';
 153 cpar = ')';
 154 obra = '[';
 155 cbra = ']';
 156 comma = ',';
 157 column = ':';
 158 quad = '::';
 159 assign = '=';
 160 pluseq = '+=';
 161 minuseq = '-=';
 162 dotdotdot = '...';
 163 dotdot = '..';
 164 dot = '.';
 165 plus = '+';
 166 minus = '-';
 167 star = '*';
 168 slash = '/';
 169 percent = '%';
 170 eq = '==';
 171 ne = '!=';
 172 lt = '<';
 173 le = '<=';
 174 ll = '<<';
 175 gt = '>';
 176 ge = '>=';
 177 gg = '>>';
 178 starship = '<=>';
 179 bang='!';
 180 at='@';
 181
 182 classid = uppercase letter*;
 183 id = lowercase letter*;
 184 attrid = '_' lowercase letter*;
 185
 186 number = digit+;
 187 hex_number = ('0x' | '0X') hexdigit+;
 188 float = digit* '.' digit+;
 189 string = '"' str_body '"' | '"' '"' '"' long_str_body lsend1 | ''' ''' ''' long_sstr_body ''' ''' ''';
 190 start_string = '"' str_body '{' | '"' '"' '"' long_str_body lsend2;
 191 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body lsend2;
 192 end_string = '}' str_body '"' | '}' '}' '}' long_str_body lsend1;
 193 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 194 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 195 bad_char = ''' '\'? any;
 196
 197 extern_code_segment = '`' '{' extern_code_body '`' '}';
 198
 199 /*****************************************************************************/
 200 Ignored Tokens
 201 /*****************************************************************************/
 202
 203 blank;
 204
 205 /*****************************************************************************/
 206 Productions
 207 /*****************************************************************************/
 208
 209 /* MODULES *******************************************************************/
 210 module
 211         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:topdef* implicit_main_class {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_main_class.classdef])};
 212
 213 moduledecl
 214         = [doc]:no kwmodule no module_name annotation_withend [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, module_name, annotation_withend.annotations)};
 215
 216 import
 217         = {std} [doc]:no redef visibility kwimport no module_name annotation_withend [n2]:n1 {-> New import.std(visibility, kwimport, module_name, annotation_withend.annotations)}
 218         | {no} [doc]:no redef visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 219         ;
 220
 221 topdef {-> classdef}
 222         = {classdef} classdef {-> classdef}
 223         | propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])}
 224         ;
 225
 226 implicit_main_class {-> classdef?}
 227         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 228         | {null} n? {-> Null}
 229         ;
 230 implicit_main_meth {-> propdef}
 231         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 232         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 233         ;
 234
 235 /* CLASSES *******************************************************************/
 236 classdef
 237         = [doc]:no redef visibility classkind no qclassid formaldefs line_annotations_forclass? extern_code_block? [superclasses]:superclass* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, qclassid.classid, [formaldefs.formaldef], line_annotations_forclass.annotations, extern_code_block, [superclasses.superclass], [propdefs.propdef], kwend)};
 238 redef {-> kwredef?}
 239         = kwredef? {-> kwredef};
 240 classkind
 241         = {concrete} kwclass
 242         | {abstract} kwabstract kwclass
 243         | {interface} kwinterface
 244         | {enum} kwenum
 245         | {extern} kwextern kwclass
 246         ;
 247
 248 formaldefs {-> formaldef*}
 249         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]}
 250         | {null} {-> []}
 251         ;
 252 formaldefs_tail {-> formaldef}
 253         = comma no formaldef {-> formaldef};
 254 formaldef
 255         = classid annotations? typing_o {-> New formaldef(classid, typing_o.type, annotations)};
 256
 257 superclass {-> superclass}
 258         = {super} no kwsuper [n2]:no type annotation_withend {-> New superclass(kwsuper, type, annotation_withend.annotations)}
 259         ;
 260
 261 propdefs~toplevel {-> propdef}
 262         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 263         ;
 264 propdef~toplevel {-> propdef}
 265         = {meth} [doc]:no redef visibility kwmeth methid signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, annotation_noend.annotations, stmtso.expr)}
 266         | {nobody} [doc]:no redef visibility kwmeth methid signature annotation_withend_nonull {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, annotation_withend_nonull.annotations)}
 267 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, Null)}
 268 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 269         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string_o extern_calls extern_code_block_o {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string_o.string, extern_calls, extern_code_block_o.extern_code_block)}
 270         | {extern_implicit} [doc]:no redef visibility kwmeth methid signature extern_calls extern_code_block {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, Null, extern_calls, extern_code_block)}
 271 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing_o {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing_o.type, Null, Null)}
 272 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing_o assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing_o.type, Null, expr)}
 273 !toplevel| {var3} [doc]:no redef visibility kwvar id typing_o writable? annotation_withend {-> New propdef.attr(doc.doc, Null, writable.able, redef.kwredef, visibility, kwvar, Null, id, typing_o.type, annotation_withend.annotations, Null)}
 274 !toplevel| {var4} [doc]:no redef visibility kwvar id typing_o writable? assign [n2]:no expr annotation_withend {-> New propdef.attr(doc.doc, Null, writable.able, redef.kwredef, visibility, kwvar, Null, id, typing_o.type, annotation_withend.annotations, expr.expr)}
 275 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, annotation_noend.annotations, stmtso.expr)}
 276 !toplevel| {type} [doc]:no redef visibility kwtype classid typing annotation_withend {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type, annotation_withend.annotations)}
 277 !toplevel| {extern_init} [doc]:no redef visibility kwnew methid? signature kwis kwextern string_o extern_calls extern_code_block_o {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string_o.string, extern_calls, extern_code_block_o.extern_code_block)}
 278 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew methid? signature string_o extern_calls extern_code_block {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string_o.string, extern_calls, extern_code_block)}
 279         ;
 280 annotation_withend~nonull {-> annotations?}
 281         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 282         | {more} kwis n1 line_annotations kwend {-> line_annotations.annotations}
 283 !nonull | {null} {-> Null}
 284         ;
 285 annotation_noend {-> annotations}
 286         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 287         | {more} kwis n1 line_annotations {-> line_annotations.annotations}
 288         ;
 289 readable {-> able}
 290         = redef visibility kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 291         ;
 292 writable {-> able}
 293         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 294         ;
 295
 296 visibility
 297         = {public} {-> New visibility.public()}
 298         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 299         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 300         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 301         ;
 302
 303 methid {-> methid}
 304         = {id} id {-> New methid.id(id)}
 305         | {plus} plus {-> New methid.plus(plus)}
 306         | {minus} minus {-> New methid.minus(minus)}
 307         | {star} star {-> New methid.star(star)}
 308         | {slash} slash {-> New methid.slash(slash)}
 309         | {percent} percent {-> New methid.percent(percent)}
 310         | {eq} eq {-> New methid.eq(eq)}
 311         | {ne} ne {-> New methid.ne(ne)}
 312         | {le} le {-> New methid.le(le)}
 313         | {ge} ge {-> New methid.ge(ge)}
 314         | {lt} lt {-> New methid.lt(lt)}
 315         | {gt} gt {-> New methid.gt(gt)}
 316         | {ll} ll {-> New methid.ll(ll)}
 317         | {gg} gg {-> New methid.gg(gg)}
 318         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 319         | {starship} starship {-> New methid.starship(starship)}
 320         | {assign} id assign {-> New methid.assign(id, assign)}
 321         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 322         ;
 323
 324 signature {-> signature}
 325         = opar no params cpar typing [no2]:no {-> New signature(opar, [params.param], cpar, typing.type)}
 326         | {noret} opar no params cpar [no2]:no {-> New signature(opar, [params.param], cpar, Null)}
 327         | {nopar} typing no {-> New signature(Null, [], Null, typing.type)}
 328         | {noparnoret} no {-> New signature(Null, [], Null, Null)}
 329         ;
 330
 331 params {-> param*}
 332         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 333         | {null} {-> []}
 334         ;
 335 params_tail {-> param}
 336         = comma no param {-> param};
 337 param
 338         = {untyped} id annotations_o {-> New param(id, Null, Null, annotations_o.annotations)}
 339         | id annotations? typing dotdotdot? {-> New param(id, typing.type, dotdotdot, annotations)}
 340         ;
 341
 342 extern_calls {-> extern_calls?}
 343         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 344         | {null} {-> Null}
 345         ;
 346 extern_call_tail {-> extern_call}
 347         = comma no extern_call {-> extern_call};
 348 extern_call {-> extern_call}
 349         = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 350         | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 351         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 352         ;
 353 extern_call_prop {-> extern_call}
 354         = {local} methid {-> New extern_call.local_prop( methid )}
 355         | {full} type dot methid {-> New extern_call.full_prop( type, dot, methid )}
 356         | {init} type {-> New extern_call.init_prop( type )}
 357         ;
 358 extern_call_cast {-> extern_call}
 359         = {as_cast} [from_type]:type dot kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 360         | {as_cast2}[from_type]:type dot kwas [n2]:no [to_type]:type {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 361         | {as_nullable} type dot kwas [n2]:no opar [n3]:no kwnullable [n4]:no cpar {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 362         | {as_nullable2}type dot kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 363         | {as_not_nullable} type dot kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnullable [n5]:no cpar {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 364         | {as_not_nullable2}type dot kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 365         ;
 366
 367 string_o {->string?} = string? {-> string};
 368
 369 in_language = kwin no string [n1]:no {-> New in_language(kwin, string)};
 370 extern_code_block = in_language? extern_code_segment;
 371 extern_code_block_o {-> extern_code_block?}
 372         = extern_code_block {-> extern_code_block}
 373         | {null} {-> Null}
 374         ;
 375 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 376
 377 /* TYPES *********************************************************************/
 378 type~nobra~nopar {-> type}
 379         = {simple} kwnullable? classid annotations_o~nopar {-> New type(kwnullable, classid, [], annotations_o~nopar.annotations)}
 380 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra annotations_o~nopar {-> New type(kwnullable, classid, [types.type], annotations_o~nopar.annotations)}
 381         ;
 382 types {-> type*}
 383         = type types_tail* {-> [type, types_tail.type]};
 384 types_tail {-> type}
 385         = comma no type {-> type};
 386 typing {-> type}
 387         = column no type {-> type};
 388 typing_o {-> type?}
 389         = column no type {-> type}
 390         | {null} {-> Null}
 391         ;
 392
 393 /* STATMENTS *****************************************************************/
 394 stmtso~withelse~withend {-> expr?}
 395         = {block} n stmtsnend {-> stmtsnend.expr}
 396         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 397         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 398 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 399         ;
 400 stmts {-> expr}
 401         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 402 stmtsn {-> expr}
 403         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 404 stmtsnend {-> expr}
 405         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 406 stmts_tail {-> expr}
 407         = n stmt {-> stmt.expr};
 408 stmt~withelse~noexpr~nopar {-> expr}
 409         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 410         | {assign} assignment~withelse~nopar {-> assignment~withelse~nopar.expr}
 411         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 412         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 413         | {abort} kwabort {-> New expr.abort(kwabort)}
 414         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 415         | {do} do~withelse {-> do~withelse.expr}
 416 !noexpr | {if} if~withelse {-> if~withelse.expr}
 417         | {while} while~withelse {-> while~withelse.expr}
 418         | {loop} loop~withelse {-> loop~withelse.expr}
 419         | {for} for~withelse {-> for~withelse.expr}
 420         | {assert} assert~withelse {-> assert~withelse.expr}
 421 !noexpr | {call} recv qid args_nopar {-> New expr.call(recv.expr, qid.id, args_nopar.exprs)}
 422 !noexpr | {super} qualified_o kwsuper args_nopar {-> New expr.super(qualified_o.qualified, kwsuper, args_nopar.exprs)}
 423 !noexpr | {init} recv qualified? kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 424         | {debug_type_is} kwdebug kwtype type column expr_final~withelse {-> New expr.debug_type(kwdebug, kwtype, expr_final~withelse.expr, type) }
 425         ;
 426
 427 label= kwlabel id;
 428
 429 assign_continue~withelse{-> expr}
 430         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 431         ;
 432
 433 vardecl~withelse{-> expr}
 434         = kwvar id annotations? typing_o {-> New expr.vardecl(kwvar, id, typing_o.type, Null, Null, annotations)}
 435         | {assign} kwvar id annotations? typing_o assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing_o.type, assign, expr_final~withelse.expr, annotations)}
 436         ;
 437
 438 assignment~withelse~nopar {-> expr}
 439         = {attr} recv~nopar qualified_o attrid assign expr_final~withelse {-> New expr.attr_assign(recv~nopar.expr, attrid, assign, expr_final~withelse.expr)}
 440         | {call} recv~nopar qid args assign expr_final~withelse {-> New expr.call_assign(recv~nopar.expr, qid.id, args.exprs, assign,  expr_final~withelse.expr)}
 441         | {bra} expr_atom~nopar braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom~nopar.expr, braargs.exprs, assign,  expr_final~withelse.expr)}
 442         | {attr_re} recv~nopar qualified_o attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv~nopar.expr, attrid, assign_op,  expr_final~withelse.expr)}
 443         | {call_re} recv~nopar qid args assign_op expr_final~withelse {-> New expr.call_reassign(recv~nopar.expr, qid.id, args.exprs, assign_op,  expr_final~withelse.expr)}
 444         | {bra_re} expr_atom~nopar braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom~nopar.expr, braargs.exprs, assign_op,  expr_final~withelse.expr)}
 445         ;
 446 assign_op
 447         = {plus} pluseq
 448         | {minus} minuseq
 449         ;
 450
 451 do~withelse {-> expr}
 452         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 453         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 454         ;
 455
 456 if~withelse {-> expr}
 457         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 458 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 459 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 460 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 461         ;
 462 elsepartblock {-> expr?}
 463         = {else} kwelse stmtso {-> stmtso.expr}
 464         | {empty} kwend {-> New expr.block([], kwend)}
 465         ;
 466
 467 loop~withelse {-> expr}
 468         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 469         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 470         ;
 471
 472 while~withelse {-> expr}
 473         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 474         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 475         ;
 476
 477 for~withelse {-> expr}
 478         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 479         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 480         ;
 481
 482 assert~withelse {-> expr}
 483         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 484 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 485         ;
 486 assertid {-> id}
 487         = id column {-> id};
 488
 489 /* EXPRESSIONS ***************************************************************/
 490 expr_final~nopar~withelse~nobra {-> expr}
 491         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 492         ;
 493
 494 expr~nopar~nobra {-> expr}
 495         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 496         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 497         ;
 498
 499 expr_and~nopar~nobra {-> expr}
 500         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 501         | {:or} expr_and~nopar~nobra :kwor :no expr_not~nopar~nobra
 502         | {:and} expr_and~nopar~nobra :kwand :no expr_not~nopar~nobra
 503         | {:or_else} expr_and~nopar~nobra :kwor :kwelse :no expr_not~nopar~nobra
 504         | {:implies} expr_and~nopar~nobra :kwimplies :no expr_not~nopar~nobra
 505         ;
 506
 507 expr_not~nopar~nobra {-> expr}
 508         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 509         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 510         ;
 511
 512 expr_eq~nopar~nobra {-> expr}
 513         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 514         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 515         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 516         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 517         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 518         | {:ll} expr_eq~nopar~nobra :ll :no [expr2]:expr_add~nopar~nobra
 519         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 520         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 521         | {:gg} expr_eq~nopar~nobra :gg :no [expr2]:expr_add~nopar~nobra
 522         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 523         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 524         ;
 525
 526 expr_add~nopar~nobra {-> expr}
 527         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 528         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 529         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 530         ;
 531
 532 expr_mul~nopar~nobra {-> expr}
 533         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 534         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_minus~nopar~nobra
 535         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_minus~nopar~nobra
 536         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_minus~nopar~nobra
 537         ;
 538
 539 expr_minus~nopar~nobra {-> expr}
 540         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 541         | {:uminus} minus :no expr_minus~nopar~nobra
 542         | {:once} kwonce :no expr_minus~nopar~nobra
 543         ;
 544
 545 expr_new~nopar~nobra {-> expr}
 546         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 547         | {new} kwnew no type~nobra_nopar args {-> New expr.new(kwnew, type~nobra_nopar.type, Null, args.exprs)}
 548         | {isset_attr} kwisset recv~nopar~nobra qualified_o attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 549         ;
 550
 551 expr_atom~nopar~nobra {-> expr}
 552         = {attr} recv~nopar~nobra qualified_o attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 553         | {call} recv~nopar~nobra qid args {-> New expr.call(recv~nopar~nobra.expr, qid.id, args.exprs)}
 554         | {super} qualified_o kwsuper args {-> New expr.super(qualified_o.qualified, kwsuper, args.exprs)}
 555         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 556 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs)}
 557         | {new} kwnew no type~nobra_nopar dot [n2]:no qid args {-> New expr.new(kwnew, type~nobra_nopar.type, qid.id, args.exprs)}
 558 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 559 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra annotations_o {-> New expr.crange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 560 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra annotations_o {-> New expr.orange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 561 !nobra!nopar    | {array} braargs annotations_o {-> New expr.array(braargs.exprs, annotations_o.annotations)}
 562         | {self} kwself annotations_o {-> New expr.self(kwself, annotations_o.annotations)}
 563         | {true} kwtrue annotations_o {-> New expr.true(kwtrue, annotations_o.annotations)}
 564         | {false} kwfalse annotations_o {-> New expr.false(kwfalse, annotations_o.annotations)}
 565         | {null} kwnull annotations_o {-> New expr.null(kwnull, annotations_o.annotations)}
 566         | {int} number annotations_o {-> New expr.dec_int(number, annotations_o.annotations)}
 567         | {hex_int} hex_number annotations_o {-> New expr.hex_int(hex_number, annotations_o.annotations)}
 568         | {float} float annotations_o {-> New expr.float(float, annotations_o.annotations)}
 569         | {char} char annotations_o {-> New expr.char(char, annotations_o.annotations)}
 570         | {string} string annotations_o {-> New expr.string(string, annotations_o.annotations)}
 571         | {superstring} superstring  {-> superstring.expr}
 572 !nopar  | {par} opar no expr [n2]:no cpar annotations_o {-> New expr.par(opar, expr, cpar, annotations_o.annotations)}
 573         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 574         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 575         | {as_notnull2}expr_atom~nopar~nobra dot no kwas [n2]:no kwnot [n4]:no kwnull {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, Null, kwnot, kwnull, Null)}
 576         ;
 577
 578 superstring {-> expr}
 579         = superstring_start superstring_middle* superstring_end annotations_o {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr], annotations_o.annotations)};
 580 superstring_start {-> expr*}
 581         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]}
 582         | {noexpr} start_string_p no {-> [start_string_p.expr]}
 583         ;
 584 start_string_p {-> expr}
 585         = start_string {-> New expr.start_string(start_string)};
 586 superstring_middle {-> expr*}
 587         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]}
 588         | {noexpr} mid_string_p no {-> [mid_string_p.expr]}
 589         ;
 590 mid_string_p {-> expr}
 591         = mid_string {-> New expr.mid_string(mid_string)};
 592 superstring_end {-> expr}
 593         = end_string {-> New expr.end_string(end_string)};
 594
 595 /* ANNOTATIONS *******************************************************************/
 596
 597 annotations~nopar {-> annotations}
 598         = {one} at one_annotation~nopar {-> New annotations(at, Null, [one_annotation~nopar.annotation], Null)}
 599         | {many} at opar no annotation_list [n2]:no cpar {-> New annotations(at, opar, [annotation_list.annotation], cpar)}
 600         ;
 601 annotations_o~nopar {-> annotations?}
 602         = annotations~nopar {-> annotations~nopar.annotations}
 603         | {null} {-> Null}
 604         ;
 605
 606 one_annotation~nopar {-> annotation}
 607         = {alone} atid annotations_o~nopar {-> New annotation(atid, Null, [], Null, annotations_o~nopar.annotations)}
 608 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 609 !nopar  | {args} atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(atid, opar, [at_args.at_arg], cpar, annotations_o~nopar.annotations)}
 610         ;
 611
 612 many_annotations {-> annotations}
 613         = {many} annotation_list {-> New annotations(Null, Null, [annotation_list.annotation], Null)}
 614         ;
 615
 616 annotation_list {-> annotation*}
 617         = {many} one_annotation annotations_tail* {-> [one_annotation.annotation, annotations_tail.annotation] }
 618         ;
 619
 620 line_annotations~forclass {-> annotations}
 621         = line_annotation~forclass+ {-> New annotations(Null, Null, [line_annotation~forclass.annotation], Null) }
 622         ;
 623 line_annotation~forclass {-> annotation}
 624         = [doc]:no atid~forclass annotations? n1 {-> New annotation(atid~forclass.atid, Null, [], Null, annotations)}
 625         | {args} [doc]:no atid~forclass opar no at_args cpar annotations? n1 {-> New annotation(atid~forclass.atid, opar, [at_args.at_arg], cpar, annotations)}
 626         | {nopar} [doc]:no atid~forclass at_args_nopar n1 {-> New annotation(atid~forclass.atid, Null, [at_args_nopar.at_arg], Null, Null)}
 627         ;
 628
 629 annotations_tail {-> annotation}
 630         = comma no one_annotation {-> one_annotation.annotation}
 631         ;
 632
 633 at_args~nopar {-> at_arg* }
 634         = {many} at_arg~nopar at_args_tail* {-> [at_arg~nopar.at_arg, at_args_tail.at_arg]}
 635         ;
 636
 637 at_args_tail {-> at_arg}
 638         = comma no at_arg {-> at_arg}
 639         ;
 640
 641 at_arg~nopar {-> at_arg}
 642         = {type} type {-> New at_arg.type(type)}
 643         | {expr} expr~nopar {-> New at_arg.expr(expr~nopar.expr)}
 644         | {stmt} stmt_noexpr~nopar {-> New at_arg.expr(stmt_noexpr~nopar.expr)}
 645 !nopar  | {at} annotations {-> New at_arg.at(annotations.annotations)}
 646         ;
 647
 648 atid~forclass {-> atid}
 649         = {id}  id {-> New atid.id(id)}
 650 //!forclass     | {kwextern} kwextern {-> New atid.kwextern(kwextern)}
 651 //!forclass     | {kwintern} kwintern {-> New atid.kwintern(kwintern)}
 652 !forclass       | {kwreadable} kwreadable {-> New atid.kwreadable(kwreadable)}
 653 !forclass       | {kwwritable} kwwritable {-> New atid.kwwritable(kwwritable)}
 654         | {kwimport} kwimport {-> New atid.kwimport(kwimport)}
 655         ;
 656
 657 /* MISC **********************************************************************/
 658
 659 recv~nopar~nobra {-> expr}
 660         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 661         | {implicit} {-> New expr.implicit_self()}
 662         ;
 663
 664 args {-> exprs}
 665         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 666         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 667         | {empty} {-> New exprs.list([])}
 668         ;
 669 args_nopar {-> exprs}
 670         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 671         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 672         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 673         | {empty} {-> New exprs.list([])}
 674         ;
 675 braargs {-> exprs}
 676         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 677 expr_list {-> expr*}
 678         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 679 expr_tail {-> expr}
 680         = comma no expr [n2]:no {-> expr};
 681 idlist {-> id*}
 682         = opar no idlist_nopar [n2]:no cpar {-> [idlist_nopar.id]}
 683         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 684         ;
 685 idlist_nopar {-> id*}
 686         = {single} id {-> [id]}
 687         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 688         ;
 689
 690 module_name {-> module_name}
 691         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 692         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 693         ;
 694
 695 qualified
 696         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 697         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 698         ;
 699 qualified_o {-> qualified?}
 700         = qualified {-> qualified}
 701         | {null} {-> Null}
 702         ;
 703 qid {-> id}
 704         = qualified? id {-> id}
 705         ;
 706 qclassid {-> classid}
 707         = qualified? classid {-> classid}
 708         ;
 709 modquad {-> id}
 710         = id quad no {-> id};
 711 classquad {-> classid}
 712         = classid quad no {-> classid};
 713
 714 kwend_o {-> kwend?}
 715         = kwend? {-> kwend}
 716         ;
 717
 718 n1      = {a} comment | {b} eol;
 719 n {-> doc?}
 720         = {a} n2? comment+ {-> New doc([comment])}
 721         | {b} n2 {-> Null}
 722         ;
 723 no {-> doc?}
 724         = {empty} {-> Null}
 725         | n {-> n.doc}
 726         ;
 727
 728 n2
 729         = {a} n2? comment+ eol+
 730         | {b} eol+
 731         ;
 732
 733 /*****************************************************************************/
 734 Abstract Syntax Tree
 735 /*****************************************************************************/
 736
 737 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 738
 739 moduledecl
 740         = doc? kwmodule [name]:module_name annotations?;
 741
 742 import  = {std} visibility kwimport [name]:module_name annotations?
 743         | {no} visibility kwimport kwend
 744         ;
 745
 746 visibility
 747         = {public}
 748         | {private} kwprivate
 749         | {protected} kwprotected
 750         | {intrude} kwintrude
 751         ;
 752
 753 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* annotations? extern_code_block? [superclasses]:superclass* [propdefs]:propdef* kwend
 754         | {top} [propdefs]:propdef*
 755         | {main} [propdefs]:propdef*
 756         ;
 757 classkind
 758         = {concrete} kwclass
 759         | {abstract} kwabstract kwclass
 760         | {interface} kwinterface
 761         | {enum} kwenum
 762         | {extern} kwextern kwclass?
 763         ;
 764 formaldef = [id]:classid type? annotations?;
 765 superclass = kwsuper type annotations?;
 766
 767
 768 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? annotations? expr?
 769         | {meth} doc? kwredef? visibility methid signature
 770         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature annotations?
 771         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 772         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string? extern_calls? extern_code_block?
 773         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature annotations? [block]:expr?
 774         | {concrete_init} doc? kwredef? visibility kwinit methid? signature annotations? [block]:expr?
 775         //| {concrete_new} doc? kwredef? visibility kwnew methid? signature [block]:expr?
 776         | {extern_init} doc? kwredef? visibility kwnew methid? signature [extern]:string? extern_calls? extern_code_block?
 777         | {main_meth} kwredef? [block]:expr?
 778         | {type} doc? kwredef? visibility kwtype [id]:classid type annotations?
 779         ;
 780
 781 able    = {read} kwredef? kwreadable
 782         | {write} kwredef? visibility? kwwritable
 783         ;
 784
 785 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 786
 787 signature = opar? [params]:param* cpar? type?;
 788
 789 param   = id type? dotdotdot? annotations?
 790         ;
 791
 792 type    = kwnullable? [id]:classid [types]:type* annotations?;
 793
 794 label = kwlabel id;
 795
 796 expr    = {block} expr* kwend?
 797         | {vardecl} kwvar id type? assign? expr? annotations?
 798         | {return} kwreturn? expr?
 799         | {break} kwbreak label? expr?
 800         | {abort} kwabort
 801         | {continue} kwcontinue? label? expr?
 802         | {do} kwdo [block]:expr? label?
 803         | {if} kwif expr [then]:expr? [else]:expr?
 804         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 805         | {while} kwwhile expr kwdo [block]:expr? label?
 806         | {loop} kwloop [block]:expr? label?
 807         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 808         | {assert} kwassert id? expr [else]:expr?
 809         | {once} kwonce expr
 810         | {send} expr
 811         | {binop} expr [expr2]:expr
 812         | {or} expr [expr2]:expr
 813         | {and} expr [expr2]:expr
 814         | {or_else} expr [expr2]:expr
 815         | {implies} expr [expr2]:expr
 816         | {not} kwnot expr
 817         | {eq} expr [expr2]:expr
 818         | {ne} expr [expr2]:expr
 819         | {lt} expr [expr2]:expr
 820         | {le} expr [expr2]:expr
 821         | {ll} expr [expr2]:expr
 822         | {gt} expr [expr2]:expr
 823         | {ge} expr [expr2]:expr
 824         | {gg} expr [expr2]:expr
 825         | {isa} expr type
 826         | {plus} expr [expr2]:expr
 827         | {minus} expr [expr2]:expr
 828         | {starship} expr [expr2]:expr
 829         | {star} expr [expr2]:expr
 830         | {slash} expr [expr2]:expr
 831         | {percent} expr [expr2]:expr
 832         | {uminus} minus expr
 833         | {new} kwnew type id? [args]:exprs
 834         | {attr} expr [id]:attrid
 835         | {attr_assign} expr [id]:attrid assign [value]:expr
 836         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 837         | {call} expr id [args]:exprs
 838         | {call_assign} expr id [args]:exprs assign [value]:expr
 839         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 840         | {super} qualified? kwsuper [args]:exprs
 841         | {init} expr kwinit [args]:exprs
 842         | {bra} expr [args]:exprs
 843         | {bra_assign} expr [args]:exprs assign [value]:expr
 844         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 845         | {var} id
 846         | {var_assign} id assign [value]:expr
 847         | {var_reassign} id assign_op [value]:expr
 848         | {range} expr [expr2]:expr annotations?
 849         | {crange} obra expr [expr2]:expr cbra annotations?
 850         | {orange} obra expr [expr2]:expr [cbra]:obra annotations?
 851         | {array} [exprs]:exprs annotations?
 852         | {self} kwself annotations?
 853         | {implicit_self}
 854         | {true} kwtrue annotations?
 855         | {false} kwfalse annotations?
 856         | {null} kwnull annotations?
 857         | {dec_int} number annotations?
 858         | {hex_int} hex_number annotations?
 859         | {float} float annotations?
 860         | {char} char annotations?
 861         | {string} string annotations?
 862         | {start_string} [string]:start_string
 863         | {mid_string} [string]:mid_string
 864         | {end_string} [string]:end_string
 865         | {superstring} [exprs]:expr* annotations?
 866         | {par} opar expr cpar annotations?
 867         | {as_cast} expr kwas opar? type cpar?
 868         | {as_notnull} expr kwas opar? kwnot kwnull cpar?
 869         | {isset_attr} kwisset expr [id]:attrid
 870         | {debug_type} kwdebug kwtype expr type
 871         ;
 872 exprs
 873         = {list} [exprs]:expr*
 874         | {par} opar [exprs]:expr* cpar
 875         | {bra} obra [exprs]:expr* cbra
 876         ;
 877 assign_op
 878         = {plus} pluseq
 879         | {minus} minuseq
 880         ;
 881
 882 module_name = quad? [path]:id* id;
 883 extern_calls = kwimport [extern_calls]:extern_call*
 884         ;
 885 extern_call =
 886         | {super} kwsuper
 887         | {local_prop} methid
 888         | {full_prop} type dot? methid
 889         | {init_prop} type
 890         | {cast_as} [from_type]:type dot? kwas [to_type]:type
 891         | {as_nullable} type kwas kwnullable
 892         | {as_not_nullable} type kwas kwnot kwnullable
 893         ;
 894 in_language = kwin string;
 895 extern_code_block = in_language? extern_code_segment;
 896
 897 qualified = id* classid? ;
 898
 899 doc = comment+;
 900
 901 annotations = at? opar? [items]:annotation* cpar?;
 902
 903 annotation = atid opar? [args]:at_arg* cpar? annotations?;
 904
 905 at_arg
 906         = {type} type
 907         | {expr} expr
 908         | {at} annotations
 909         ;
 910 atid = {id} id | {kwextern} [id]:kwextern | {kwintern} [id]:kwintern | {kwreadable} [id]:kwreadable | {kwwritable} [id]:kwwritable | {kwimport} [id]:kwimport;
 911
 912 /*****************************************************************************/
 913