src/nitls.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Simple tool to list Nit source files
  18 module nitls
  19
  20 import modelbuilder
  21 intrude import loader
  22 import ordered_tree
  23 import console
  24
  25 class ProjTree
  26         super OrderedTree[Object]
  27
  28         var opt_paths = false
  29         var tc: ToolContext
  30
  31         redef fun display(o)
  32         do
  33                 if o isa MGroup then
  34                         if opt_paths then
  35                                 return o.filepath.as(not null)
  36                         else
  37                                 var d = ""
  38                                 if o.mdoc != null then
  39                                         if tc.opt_no_color.value then
  40                                                 d = ": {o.mdoc.content.first}"
  41                                         else
  42                                                 d = ": {o.mdoc.content.first.green}"
  43                                         end
  44                                 end
  45                                 if tc.opt_no_color.value then
  46                                         return "{o.name}{d} ({o.filepath.to_s})"
  47                                 else
  48                                         return "{o.name}{d} ({o.filepath.yellow})"
  49                                 end
  50                         end
  51                 else if o isa ModulePath then
  52                         if opt_paths then
  53                                 return o.filepath
  54                         else
  55                                 var d = ""
  56                                 var dd = ""
  57                                 if o.mmodule != null and o.mmodule.mdoc != null then
  58                                         if tc.opt_no_color.value then
  59                                                 d = ": {o.mmodule.mdoc.content.first}"
  60                                         else
  61                                                 d = ": {o.mmodule.mdoc.content.first.green}"
  62                                         end
  63                                 end
  64                                 if o.mmodule != null and not o.mmodule.in_importation.direct_greaters.is_empty then
  65                                         var ms = new Array[String]
  66                                         for m in o.mmodule.in_importation.direct_greaters do
  67                                                 if m.mgroup.mproject == o.mmodule.mgroup.mproject then
  68                                                         ms.add m.name
  69                                                 else
  70                                                         ms.add m.full_name
  71                                                 end
  72                                         end
  73                                         if tc.opt_no_color.value then
  74                                                 dd = " ({ms.join(" ")})"
  75                                         else
  76                                                 dd = " ({ms.join(" ")})".light_gray
  77                                         end
  78                                 end
  79                                 if tc.opt_no_color.value then
  80                                         return "{o.name.bold}{d} ({o.filepath.to_s}){dd}"
  81                                 else
  82                                         return "{o.name.bold}{d} ({o.filepath.yellow}){dd}"
  83                                 end
  84                         end
  85                 else
  86                         abort
  87                 end
  88         end
  89 end
  90
  91 class AlphaEntityComparator
  92         super Comparator
  93         fun nameof(a: COMPARED): String
  94         do
  95                 if a isa MGroup then
  96                         return a.name
  97                 else if a isa ModulePath then
  98                         return a.name
  99                 else
 100                         abort
 101                 end
 102         end
 103         redef fun compare(a,b)
 104         do
 105                 return nameof(a) <=> nameof(b)
 106         end
 107 end
 108
 109 var tc = new ToolContext
 110
 111 var opt_keep = new OptionBool("Ignore errors and files that are not a Nit source file", "-k", "--keep")
 112 var opt_recursive = new OptionBool("Process directories recussively", "-r", "--recursive")
 113 var opt_tree = new OptionBool("List source files in their groups and projects", "-t", "--tree")
 114 var opt_source = new OptionBool("List source files", "-s", "--source")
 115 var opt_project = new OptionBool("List projects paths (default)", "-P", "--project")
 116 var opt_depends = new OptionBool("List dependencies of given modules", "-d", "--depends")
 117 var opt_make = new OptionBool("List dependencies suitable for a rule in a Makefile. Alias for -d, -p and -s", "-M")
 118 var opt_paths = new OptionBool("List only path (instead of name + path)", "-p", "--path")
 119
 120 tc.option_context.add_option(opt_keep, opt_recursive, opt_tree, opt_source, opt_project, opt_depends, opt_paths, opt_make)
 121 tc.tooldescription = "Usage: nitls [OPTION]... <file.nit|directory>...\nLists the projects and/or paths of Nit sources files."
 122 tc.process_options(args)
 123
 124 if opt_make.value then
 125         opt_depends.value = true
 126         opt_paths.value = true
 127         opt_source.value = true
 128 end
 129
 130 var sum = opt_tree.value.to_i + opt_source.value.to_i + opt_project.value.to_i
 131 if sum > 1 then
 132         print "Error: options --tree, --source, and --project are exclusives."
 133         print tc.tooldescription
 134         exit 1
 135 end
 136
 137 tc.keep_going = opt_keep.value
 138
 139 var model = new Model
 140 var mb = new ModelBuilder(model, tc)
 141
 142 var files
 143 if opt_recursive.value then
 144         files = new Array[String]
 145         for d in tc.option_context.rest do
 146                 var pipe = new IProcess("find", d, "-name", "*.nit")
 147                 while not pipe.eof do
 148                         var l = pipe.read_line
 149                         if l == "" then break # last line
 150                         l = l.substring(0,l.length-1) # strip last oef
 151                         files.add l
 152                 end
 153                 pipe.close
 154                 pipe.wait
 155                 if pipe.status != 0 and not opt_keep.value then exit 1
 156         end
 157 else
 158         files = tc.option_context.rest
 159 end
 160
 161 for a in files do
 162         var mp = mb.identify_file(a)
 163         tc.check_errors
 164         if mp != null and not opt_paths.value then
 165                 var mm = mb.load_module(mp.filepath)
 166                 if mm != null and opt_depends.value then
 167                         mb.build_module_importation(mm)
 168                 end
 169                 tc.check_errors
 170         end
 171 end
 172
 173 if sum == 0 then opt_project.value = true
 174
 175 var ot = new ProjTree(tc)
 176 if opt_tree.value then
 177         ot.opt_paths = opt_paths.value
 178         for p in model.mprojects do
 179                 for g in p.mgroups do
 180                         var pa = g.parent
 181                         if g.is_interesting then
 182                                 ot.add(pa, g)
 183                                 pa = g
 184                         end
 185                         for mp in g.module_paths do
 186                                 ot.add(pa, mp)
 187                         end
 188                 end
 189         end
 190         ot.sort_with(new AlphaEntityComparator)
 191         ot.write_to(stdout)
 192 end
 193
 194 if opt_source.value then
 195         var list = new Array[String]
 196         for p in model.mprojects do
 197                 for g in p.mgroups do
 198                         for mp in g.module_paths do
 199                                 if opt_paths.value then
 200                                         list.add(mp.filepath)
 201                                 else
 202                                         list.add("{g.full_name}/{ot.display(mp)}")
 203                                 end
 204                         end
 205                 end
 206         end
 207         alpha_comparator.sort(list)
 208         for l in list do print l
 209 end
 210
 211 if opt_project.value then
 212         var list = new Array[String]
 213         for p in model.mprojects do
 214                 var path = p.root.filepath.as(not null)
 215                 if opt_paths.value then
 216                         list.add(path)
 217                 else
 218                         if tc.opt_no_color.value then
 219                                 list.add("{p.name} ({path})")
 220                         else
 221                                 list.add("{p.name} ({path.yellow})")
 222                         end
 223                 end
 224         end
 225         alpha_comparator.sort(list)
 226         for l in list do print l
 227 end