contrib/nitrpg/src/web.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014-2015 Alexandre Terrasa <alexandre@moz-code.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Display `nitrpg` data as a website.
  18 module web
  19
  20 import nitcorn
  21 import templates
  22
  23 # A custom action forn `nitrpg`.
  24 class RpgAction
  25         super Action
  26
  27         # Root URL is used as a prefix for all URL generated by the actions.
  28         var root_url: String
  29
  30         # Github oauth token used for GithubAPI.
  31         var auth: String is lazy do return get_github_oauth
  32
  33         # API client used to import data from Github.
  34         var api: GithubAPI is lazy do
  35                 var api = new GithubAPI(auth)
  36                 return api
  37         end
  38
  39         init do
  40                 super
  41                 if auth.is_empty then
  42                         print "Error: Invalid Github oauth token!"
  43                         exit 1
  44                 end
  45         end
  46
  47         # Return an Error reponse page.
  48         fun bad_request(msg: String): HttpResponse do
  49                 var rsp = new HttpResponse(400)
  50                 var page = new NitRpgPage(root_url)
  51                 var error = new ErrorPanel(msg)
  52                 page.flow_panels.add error
  53                 rsp.body = page.write_to_string
  54                 return rsp
  55         end
  56
  57         # Returns the game with `name` or null if no game exists with this name.
  58         fun load_game(name: String): nullable Game do
  59                 var repo = new Repo(api, name)
  60                 if api.was_error then return null
  61                 var game = new Game(api, repo)
  62                 game.root_url = root_url
  63                 return game
  64         end
  65
  66         # Returns the list of saved games from NitRPG data.
  67         fun load_games: Array[Game] do
  68                 var res = new Array[Game]
  69                 var rpgdir = "nitrpg_data"
  70                 if not rpgdir.file_exists then return res
  71                 for user in rpgdir.files do
  72                         for repo in "{rpgdir}/{user}".files do
  73                                 var game = load_game("{user}/{repo}")
  74                                 if game != null then res.add game
  75                         end
  76                 end
  77                 return res
  78         end
  79 end
  80
  81 # Repo overview page.
  82 class RpgHome
  83         super RpgAction
  84
  85         # Response page stub.
  86         var page: NitRpgPage is noinit
  87
  88         redef fun answer(request, url) do
  89                 var readme = load_readme
  90                 var games = load_games
  91                 var response = new HttpResponse(200)
  92                 page = new NitRpgPage(root_url)
  93                 page.side_panels.add new GamesShortListPanel(root_url, games)
  94                 page.flow_panels.add new MDPanel(readme)
  95                 response.body = page.write_to_string
  96                 return response
  97         end
  98
  99         # Load the string content of the nitrpg readme file.
 100         private fun load_readme: String do
 101                 var readme = "README.md"
 102                 if not readme.file_exists then
 103                         return "Unable to locate README file."
 104                 end
 105                 var file = new FileReader.open(readme)
 106                 var text = file.read_all
 107                 file.close
 108                 return text
 109         end
 110 end
 111
 112 # An action that require a game.
 113 class GameAction
 114         super RpgAction
 115
 116         # Response page stub.
 117         var page: NitRpgPage is noinit
 118
 119         # Target game.
 120         var game: Game is noinit
 121
 122         redef fun answer(request, url) is abstract
 123
 124         # Check errors and prepare response.
 125         private fun prepare_response(request: HttpRequest, url: String): HttpResponse do
 126                 var owner = request.param("owner")
 127                 var repo_name = request.param("repo")
 128                 if owner == null or repo_name == null then
 129                         var msg = "Bad request: should look like /games/:owner/:repo."
 130                         return bad_request(msg)
 131                 end
 132                 var game = load_game("{owner}/{repo_name}")
 133                 if game == null then
 134                         var msg = api.last_error.message
 135                         return bad_request("Repo Error: {msg}")
 136                 end
 137                 self.game = game
 138                 var response = new HttpResponse(200)
 139                 page = new NitRpgPage(root_url)
 140                 page.side_panels.add new GameStatusPanel(game)
 141                 page.breadcrumbs = new Breadcrumbs
 142                 page.breadcrumbs.add_link(game.url, game.name)
 143                 prepare_pagination(request)
 144                 return response
 145         end
 146
 147         # Parse pagination related parameters.
 148         private fun prepare_pagination(request: HttpRequest) do
 149                 var args = request.get_args
 150                 list_from = args.get_or_default("pfrom", "0").to_i
 151                 list_limit = args.get_or_default("plimit", "10").to_i
 152         end
 153
 154         # Limit of events to display in lists.
 155         var list_limit = 10
 156
 157         # From where to start the display of events related lists.
 158         var list_from = 0
 159 end
 160
 161 # Repo overview page.
 162 class RepoHome
 163         super GameAction
 164
 165         redef fun answer(request, url) do
 166                 var rsp = prepare_response(request, url)
 167                 page.side_panels.add new ShortListPlayersPanel(game)
 168                 page.flow_panels.add new PodiumPanel(game)
 169                 page.flow_panels.add new EventListPanel(game, list_limit, list_from)
 170                 page.flow_panels.add new AchievementsListPanel(game)
 171                 rsp.body = page.write_to_string
 172                 return rsp
 173         end
 174 end
 175
 176 # Repo players list.
 177 class ListPlayers
 178         super GameAction
 179
 180         redef fun answer(request, url) do
 181                 var rsp = prepare_response(request, url)
 182                 page.breadcrumbs.add_link(game.url / "players", "players")
 183                 page.flow_panels.add new ListPlayersPanel(game)
 184                 rsp.body = page.write_to_string
 185                 return rsp
 186         end
 187 end
 188
 189 # Player details page.
 190 class PlayerHome
 191         super GameAction
 192
 193         redef fun answer(request, url) do
 194                 var rsp = prepare_response(request, url)
 195                 var name = request.param("player")
 196                 if name == null then
 197                         var msg = "Bad request: should look like /:owner/:repo/:players/:name."
 198                         return bad_request(msg)
 199                 end
 200                 var player = game.load_player(name)
 201                 if player == null then
 202                         return bad_request("Request Error: unknown player {name}.")
 203                 end
 204                 page.breadcrumbs.add_link(game.url / "players", "players")
 205                 page.breadcrumbs.add_link(player.url, name)
 206                 page.side_panels.clear
 207                 page.side_panels.add new PlayerStatusPanel(game, player)
 208                 page.flow_panels.add new PlayerReviewsPanel(game, player)
 209                 page.flow_panels.add new AchievementsListPanel(player)
 210                 page.flow_panels.add new EventListPanel(player, list_limit, list_from)
 211                 rsp.body = page.write_to_string
 212                 return rsp
 213         end
 214 end
 215
 216 # Display the list of achievements unlocked for this game.
 217 class ListAchievements
 218         super GameAction
 219
 220         redef fun answer(request, url) do
 221                 var rsp = prepare_response(request, url)
 222                 page.breadcrumbs.add_link(game.url / "achievements", "achievements")
 223                 page.flow_panels.add new AchievementsListPanel(game)
 224                 rsp.body = page.write_to_string
 225                 return rsp
 226         end
 227 end
 228
 229 # Player details page.
 230 class AchievementHome
 231         super GameAction
 232
 233         redef fun answer(request, url) do
 234                 var rsp = prepare_response(request, url)
 235                 var name = request.param("achievement")
 236                 if name == null then
 237                         var msg = "Bad request: should look like /:owner/:repo/achievements/:achievement."
 238                         return bad_request(msg)
 239                 end
 240                 var achievement = game.load_achievement(name)
 241                 if achievement == null then
 242                         return bad_request("Request Error: unknown achievement {name}.")
 243                 end
 244                 page.breadcrumbs.add_link(game.url / "achievements", "achievements")
 245                 page.breadcrumbs.add_link(achievement.url, achievement.name)
 246                 page.flow_panels.add new AchievementPanel(achievement)
 247                 page.flow_panels.add new EventListPanel(achievement, list_limit, list_from)
 248                 rsp.body = page.write_to_string
 249                 return rsp
 250         end
 251 end
 252
 253 if args.length != 3 then
 254         print "Error: missing argument"
 255         print ""
 256         print "Usage:"
 257         print "web <host> <port> <root_url>"
 258         exit 1
 259 end
 260
 261 var host = args[0]
 262 var port = args[1]
 263 var root = args[2]
 264
 265 var iface = "{host}:{port}"
 266 var vh = new VirtualHost(iface)
 267 vh.routes.add new Route("/styles/", new FileServer("www/styles"))
 268 vh.routes.add new Route("/games/:owner/:repo/players/:player", new PlayerHome(root))
 269 vh.routes.add new Route("/games/:owner/:repo/players", new ListPlayers(root))
 270 vh.routes.add new Route("/games/:owner/:repo/achievements/:achievement", new AchievementHome(root))
 271 vh.routes.add new Route("/games/:owner/:repo/achievements", new ListAchievements(root))
 272 vh.routes.add new Route("/games/:owner/:repo", new RepoHome(root))
 273 vh.routes.add new Route("/", new RpgHome(root))
 274
 275 var fac = new HttpFactory.and_libevent
 276 fac.config.virtual_hosts.add vh
 277
 278 print "Launching server on http://{iface}/"
 279 fac.run