src/model/model_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # The abstract concept of model and related common things
  18 module model_base
  19
  20 # The container class of a Nit object-oriented model.
  21 # A model knows modules, classes and properties and can retrieve them.
  22 class Model
  23 end
  24
  25 # A named and possibly documented entity in the model.
  26 # This class is useful to generalize presentation of entities to the human.
  27 abstract class MEntity
  28         # The short (unqualified) name of this model entity.
  29         #
  30         # The short-name is based from the identifiers used to declare or denote the entity.
  31         # It is usually globally ambiguous but is often enough in a precise local context.
  32         #
  33         # It is suitable to use the short-name in message to the user.
  34         # However, special care must be used in case of potential ambiguities or name conflict.
  35         fun name: String is abstract
  36
  37         # A fully-qualified name of this model entity.
  38         #
  39         # The full-name is based on the short name and is usually prefixed by the name of an outer entity.
  40         # Usually the quad (`::`) is used to separate the different names.
  41         #
  42         # The full-name is expected to be unique and unambiguous in lawful Nit models for the same kind of entity.
  43         #
  44         # It is often suitable to use it in message to the user.
  45         # However, some full-name could be long and verbose,
  46         #
  47         # See the specific implementation in subclasses for details.
  48         fun full_name: String is abstract
  49
  50         # A fully-qualified C-like identifier of this model entity.
  51         #
  52         # The C-name is a name that respects the rule of identifiers in the C language:
  53         # it is only made of alphanumeric characters and starts with a letter (or a underscore).
  54         #
  55         # The C-name can be seen as a mangled version of the `full_name`.
  56         # Therefore, it is expected to be unique and unambiguous in lawful Nit models for the same kind of entity.
  57         #
  58         # The C-name is used by tools that need some identifiers in generated files to designate the
  59         # entity.
  60         #
  61         # Is is not suitable to use it directly with the user (e.g. in message) and
  62         # indirect use should be restricted (e.g. to name a web-page)
  63         fun c_name: String is abstract
  64
  65         # A Model Entity has a direct link to its model
  66         fun model: Model is abstract
  67
  68         # The indication that the entity did not pass some semantic verifications.
  69         #
  70         # This simple flag is set by a given analysis to say that the entity is broken and unusable in
  71         # an execution.
  72         # When an entity status is set to broken, it is usually associated with a error message.
  73         #
  74         # If it is safe to do so, clients of the model SHOULD just skip broken entities in their processing.
  75         # Clients that do not care about the executability (e.g. metrics) MAY still process the entity or
  76         # perform specific checks to determinate the validity of the entity.
  77         #
  78         # Note that the broken status is not propagated to enclosing and enclosed entities.
  79         # e.g. a broken method does not make the whole module broken.
  80         var is_broken = false is writable
  81 end
  82
  83 # Something that represents a concern
  84 abstract class MConcern
  85         super MEntity
  86         # The concern that contains `self` or null if `self` is the root of the concern hierarchy
  87         fun parent_concern: nullable MConcern is abstract
  88 end
  89
  90 # A visibility (for modules, class and properties)
  91 # Valid visibility are:
  92 #
  93 #  * `intrude_visibility`
  94 #  * `public_visibility`
  95 #  * `protected_visibility`
  96 #  * `none_visibility`
  97 #  * `private_visiblity`
  98 #
  99 # Note this class is basically an enum.
 100 # FIXME: use a real enum once user-defined enums are available
 101 class MVisibility
 102         super Comparable
 103         redef type OTHER: MVisibility
 104
 105         redef var to_s: String
 106
 107         private var level: Int
 108
 109         # TODO: private init because enumeration.
 110
 111         # Is self give less visibility than other
 112         # none < private < protected < public < intrude
 113         redef fun <(other)
 114         do
 115                 return self.level < other.level
 116         end
 117 end
 118
 119 # A `Comparator` to sort mentities by their names.
 120 class MEntityNameSorter
 121         super Comparator
 122
 123         redef type COMPARED: MEntity
 124
 125         # Returns `a.name <=> b.name`.
 126         redef fun compare(a, b) do return a.name <=> b.name
 127 end
 128
 129 # The visibility level `intrude`
 130 fun intrude_visibility: MVisibility do return once new MVisibility("intrude", 5)
 131 # The visibility level `public`
 132 fun public_visibility: MVisibility do return once new MVisibility("public", 4)
 133 # The visibility level `protected`
 134 fun protected_visibility: MVisibility do return once new MVisibility("protected", 3)
 135 # The visibility level `private`
 136 fun private_visibility: MVisibility do return once new MVisibility("private", 2)
 137 # The visibility level `none` (no visibility)
 138 fun none_visibility: MVisibility do return once new MVisibility("none", 1)