lib/gamnit/gamnit_linux.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Support services for Gamnit on GNU/Linux
  16 module gamnit_linux
  17
  18 import sdl2::events
  19
  20 intrude import gamnit
  21 intrude import display_linux
  22
  23 redef class App
  24         private var sdl_event_buffer = new SDLEventBuffer.malloc
  25
  26         redef fun feed_events
  27         do
  28                 var display = display
  29                 if display == null then return
  30
  31                 loop
  32                         var avail = sdl_event_buffer.poll_event
  33                         if not avail then break
  34
  35                         # Convert to an SDL event with data
  36                         var sdl_event = sdl_event_buffer.to_event
  37                         if sdl_event isa SDLWindowEvent and sdl_event.is_resized then
  38                                 display.width = sdl_event.data1
  39                                 display.height = sdl_event.data2
  40                                 display.aspect_ratio = sdl_event.data1.to_f / sdl_event.data2.to_f
  41                                 on_resize display
  42                         end
  43
  44                         # Convert to `mnit::inputs` conforming objects
  45                         var gamnit_event = sdl_event.to_gamnit_event(sdl_event_buffer)
  46                         accept_event gamnit_event
  47                 end
  48         end
  49 end
  50
  51 redef class GamnitDisplay
  52         redef var aspect_ratio = super is lazy
  53 end
  54
  55 # ---
  56 # Redef services from `sdl2::events`
  57
  58 redef class SDLEvent
  59         private fun to_gamnit_event(buffer: SDLEventBuffer): GamnitInputEvent
  60         do return new GamnitOtherEvent(buffer, self)
  61 end
  62
  63 redef class SDLQuitEvent
  64         redef fun to_gamnit_event(buffer) do return new GamnitQuitEvent(buffer, self)
  65 end
  66
  67 redef class SDLMouseEvent
  68         redef fun to_gamnit_event(buffer) do return new GamnitPointerEvent(buffer, self)
  69 end
  70
  71 redef class SDLMouseWheelEvent
  72         redef fun to_gamnit_event(buffer) do return new GamnitMouseWheelEvent(buffer, self)
  73 end
  74
  75 redef class SDLKeyboardEvent
  76         redef fun to_gamnit_event(buffer) do return new GamnitKeyEvent(buffer, self)
  77 end
  78
  79 # ---
  80 # Implement `mnit::inputs` interfaces
  81
  82 # SDL2 event wrapper implementing the `mnit::input` API
  83 #
  84 # There is two views to the underlying native object: `buffer` and `native`.
  85 class GamnitInputEvent
  86         super InputEvent
  87
  88         # Native SDL 2 event buffer with the pseudo class hierarchy metadata
  89         var buffer: SDLEventBuffer
  90
  91         # Native SDL 2 event
  92         var native: NATIVE
  93
  94         # Type of the `native` underlying SDL 2 event
  95         type NATIVE: SDLEvent
  96 end
  97
  98 # Event on user requested quit
  99 class GamnitQuitEvent
 100         super GamnitInputEvent
 101         super QuitEvent
 102
 103         redef type NATIVE: SDLQuitEvent
 104 end
 105
 106 # Event on keyboard input
 107 class GamnitKeyEvent
 108         super GamnitInputEvent
 109         super KeyEvent
 110
 111         redef type NATIVE: SDLKeyboardEvent
 112
 113         redef fun is_down do return buffer.is_keydown
 114         redef fun is_up do return buffer.is_keyup
 115         redef fun is_arrow_up do return native.keysym.is_up
 116         redef fun is_arrow_left do return native.keysym.is_left
 117         redef fun is_arrow_down do return native.keysym.is_down
 118         redef fun is_arrow_right do return native.keysym.is_right
 119         redef fun to_c do return native.to_s.chars.first
 120         redef fun name do return native.to_s.to_lower
 121 end
 122
 123 # Event on pointer, mouse and finger input
 124 class GamnitPointerEvent
 125         super GamnitInputEvent
 126         super PointerEvent
 127
 128         redef type NATIVE: SDLMouseEvent
 129
 130         redef fun x do return native.x.to_f
 131         redef fun y do return native.y.to_f
 132         redef fun is_move do return buffer.is_mouse_motion
 133
 134         redef fun pressed
 135         do
 136                 var native = native
 137                 if native isa SDLMouseButtonEvent then
 138                         return native.pressed and native.button == 1
 139                 else if native isa SDLMouseMotionEvent then
 140                         return native.state & 1 == 1
 141                 else abort
 142         end
 143 end
 144
 145 # Event on mouse wheel input
 146 class GamnitMouseWheelEvent
 147         super GamnitInputEvent
 148
 149         redef type NATIVE: SDLMouseWheelEvent
 150
 151         # Horizontal scroll amount
 152         fun x: Float do return native.x.to_f
 153
 154         # Vertical scroll amount
 155         fun y: Float do return native.y.to_f
 156 end
 157
 158 # SDL2 event not handled by gamnit
 159 class GamnitOtherEvent
 160         super GamnitInputEvent
 161 end