lib/popcorn/pop_tests.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Popcorn testing services
  16 #
  17 # ## Blackbox testing
  18 #
  19 # Popcorn allows you to test your apps using nitunit blackbox testing.
  20 #
  21 # With blackbox testing you compare the output of your program with a result file.
  22 #
  23 # To get started with blackbox testing, create a nitunit test suite and imports
  24 # the `pop_tests` module.
  25 #
  26 # You then need to build the app that will be tested by nitunit as shown in the
  27 # `test_example_hello` method.
  28 # Calling `run_test` will automatically set the `host` and `port` used for testing.
  29 #
  30 # Redefine the `client_test` method to write your scenario.
  31 # Here we use `curl` to access some URI on the app.
  32 #
  33 # ~~~nitish
  34 # module test_example_hello is test_suite
  35 #
  36 # import pop_tests
  37 # import example_hello
  38 #
  39 # class TestExampleHello
  40 #       super TestPopcorn
  41 #
  42 #       fun test_example_hello do
  43 #               var app = new App
  44 #               app.use("/", new HelloHandler)
  45 #               run_test(app)
  46 #       end
  47 #
  48 #       redef fun client_test do
  49 #               system "curl -s {host}:{port}"
  50 #               system "curl -s {host}:{port}/"
  51 #               system "curl -s {host}:{port}///////////"
  52 #               system "curl -s {host}:{port}/not_found"
  53 #               system "curl -s {host}:{port}/not_found/not_found"
  54 #       end
  55 # end
  56 # ~~~
  57 #
  58 # The blackbox testing needs a reference result file against wich the test output
  59 # will be compared.
  60 # Create your expected result file in `test_example_hello.sav/test_example_hello.res`.
  61 #
  62 # Test your app by running nitunit:
  63 #
  64 # ~~~bash
  65 # nitunit ./example_hello.nit
  66 # ~~~
  67 #
  68 # See `examples/hello_world` for the complete example.
  69 module pop_tests
  70
  71 import test_suite
  72 import popcorn
  73 import pthreads
  74
  75 redef class Sys
  76
  77         # Use localhost for testing
  78         var test_host = "localhost"
  79
  80         # Return a new port for each instance
  81         fun test_port: Int do
  82                 srand
  83                 return 10000+20000.rand
  84         end
  85 end
  86
  87 # Thread running the App to test.
  88 class AppThread
  89         super Thread
  90
  91         # Host used by tested App.
  92         var host: String
  93
  94         # Port used by tested App.
  95         var port: Int
  96
  97         # App to test.
  98         var app: App
  99
 100         redef fun main
 101         do
 102                 # Hide testing concept to force nitcorn to actually run
 103                 "NIT_TESTING".setenv("false")
 104                 app.quiet = true
 105                 app.listen(host, port)
 106                 return null
 107         end
 108 end
 109
 110 # Thread running the test client.
 111 class ClientThread
 112         super Thread
 113
 114         # Test suite to execute.
 115         var test_suite: TestPopcorn
 116
 117         redef fun main do
 118                 test_suite.client_test
 119                 print ""
 120                 return null
 121         end
 122 end
 123
 124 # TestSuite for Popcorn blackbox testing.
 125 class TestPopcorn
 126         super TestSuite
 127
 128         # Host used to run App.
 129         var host: String = test_host
 130
 131         # Port used to run App.
 132         var port: Int = test_port
 133
 134         # Run the test suite on the App.
 135         fun run_test(app: App) do
 136                 var server = new AppThread(host, port, app)
 137                 server.start
 138                 0.1.sleep
 139
 140                 var client = new ClientThread(self)
 141                 client.start
 142                 client.join
 143                 0.1.sleep
 144
 145                 exit 0
 146         end
 147
 148         # Redefine this method to implement your test scenario.
 149         fun client_test do end
 150
 151         # Regex to catch and hide the port from the output to get consistent results
 152         var host_re: Regex = "localhost:\[0-9\]+".to_re
 153
 154         # Execute a System function.
 155         fun system(cmd: String, title: nullable String)
 156         do
 157                 title = title or else cmd
 158                 title = title.replace(host_re, "localhost:*****")
 159                 print "\n[Client] {title}"
 160                 sys.system cmd
 161         end
 162 end