src/compiler/separate_erasure_compiler.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Separate compilation of a Nit program with generic type erasure
  16 module separate_erasure_compiler
  17
  18 intrude import separate_compiler
  19
  20 # Add separate erased compiler specific options
  21 redef class ToolContext
  22         # --erasure
  23         var opt_erasure = new OptionBool("Erase generic types", "--erasure")
  24         # --rta
  25         var opt_rta = new OptionBool("Activate RTA (implicit with --global and --separate)", "--rta")
  26         # --no-check-erasure-cast
  27         var opt_no_check_erasure_cast = new OptionBool("Disable implicit casts on unsafe return with erasure-typing policy (dangerous)", "--no-check-erasure-cast")
  28
  29         redef init
  30         do
  31                 super
  32                 self.option_context.add_option(self.opt_erasure, self.opt_no_check_erasure_cast, opt_rta)
  33         end
  34
  35         redef fun process_options(args)
  36         do
  37                 super
  38
  39                 if opt_no_check_all.value then
  40                         opt_no_check_erasure_cast.value = true
  41                 end
  42
  43                 # Temporary disabled. TODO: implement tagging in the erasure compiler.
  44                 if opt_erasure.value then
  45                         opt_no_tag_primitives.value = true
  46                 end
  47         end
  48
  49         var erasure_compiler_phase = new ErasureCompilerPhase(self, null)
  50 end
  51
  52 class ErasureCompilerPhase
  53         super Phase
  54         redef fun process_mainmodule(mainmodule, given_mmodules) do
  55                 if not toolcontext.opt_erasure.value then return
  56
  57                 var modelbuilder = toolcontext.modelbuilder
  58                 var analysis = null
  59                 if toolcontext.opt_rta.value then
  60                         analysis = modelbuilder.do_rapid_type_analysis(mainmodule)
  61                 end
  62                 modelbuilder.run_separate_erasure_compiler(mainmodule, analysis)
  63         end
  64 end
  65
  66 redef class ModelBuilder
  67         fun run_separate_erasure_compiler(mainmodule: MModule, runtime_type_analysis: nullable RapidTypeAnalysis)
  68         do
  69                 var time0 = get_time
  70                 self.toolcontext.info("*** GENERATING C ***", 1)
  71
  72                 var compiler = new SeparateErasureCompiler(mainmodule, self, runtime_type_analysis)
  73                 compiler.do_compilation
  74                 compiler.display_stats
  75                 var time1 = get_time
  76                 self.toolcontext.info("*** END GENERATING C: {time1-time0} ***", 2)
  77                 write_and_make(compiler)
  78         end
  79 end
  80
  81 class SeparateErasureCompiler
  82         super SeparateCompiler
  83
  84         private var class_ids: Map[MClass, Int] is noinit
  85         private var class_colors: Map[MClass, Int] is noinit
  86         protected var vt_colors: Map[MVirtualTypeProp, Int] is noinit
  87
  88         init do
  89
  90                 # Class coloring
  91                 var poset = mainmodule.flatten_mclass_hierarchy
  92                 var mclasses = new HashSet[MClass].from(poset)
  93                 var colorer = new POSetColorer[MClass]
  94                 colorer.colorize(poset)
  95                 class_ids = colorer.ids
  96                 class_colors = colorer.colors
  97                 class_tables = self.build_class_typing_tables(mclasses)
  98
  99                 # lookup vt to build layout with
 100                 var vts = new HashMap[MClass, Set[MVirtualTypeProp]]
 101                 for mclass in mclasses do
 102                         vts[mclass] = new HashSet[MVirtualTypeProp]
 103                         for mprop in self.mainmodule.properties(mclass) do
 104                                 if mprop isa MVirtualTypeProp then
 105                                         vts[mclass].add(mprop)
 106                                 end
 107                         end
 108                 end
 109
 110                 # vt coloration
 111                 var vt_colorer = new POSetBucketsColorer[MClass, MVirtualTypeProp](poset, colorer.conflicts)
 112                 vt_colors = vt_colorer.colorize(vts)
 113                 vt_tables = build_vt_tables(mclasses)
 114         end
 115
 116         fun build_vt_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MPropDef]] do
 117                 var tables = new HashMap[MClass, Array[nullable MPropDef]]
 118                 for mclass in mclasses do
 119                         var table = new Array[nullable MPropDef]
 120                         # first, fill table from parents by reverse linearization order
 121                         var parents = new Array[MClass]
 122                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 123                                 parents = mclass.in_hierarchy(mainmodule).greaters.to_a
 124                                 self.mainmodule.linearize_mclasses(parents)
 125                         end
 126                         for parent in parents do
 127                                 if parent == mclass then continue
 128                                 for mproperty in self.mainmodule.properties(parent) do
 129                                         if not mproperty isa MVirtualTypeProp then continue
 130                                         var color = vt_colors[mproperty]
 131                                         if table.length <= color then
 132                                                 for i in [table.length .. color[ do
 133                                                         table[i] = null
 134                                                 end
 135                                         end
 136                                         for mpropdef in mproperty.mpropdefs do
 137                                                 if mpropdef.mclassdef.mclass == parent then
 138                                                         table[color] = mpropdef
 139                                                 end
 140                                         end
 141                                 end
 142                         end
 143
 144                         # then override with local properties
 145                         for mproperty in self.mainmodule.properties(mclass) do
 146                                 if not mproperty isa MVirtualTypeProp then continue
 147                                 var color = vt_colors[mproperty]
 148                                 if table.length <= color then
 149                                         for i in [table.length .. color[ do
 150                                                 table[i] = null
 151                                         end
 152                                 end
 153                                 for mpropdef in mproperty.mpropdefs do
 154                                         if mpropdef.mclassdef.mclass == mclass then
 155                                                 table[color] = mpropdef
 156                                         end
 157                                 end
 158                         end
 159                         tables[mclass] = table
 160                 end
 161                 return tables
 162         end
 163
 164         # Build class tables
 165         fun build_class_typing_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MClass]] do
 166                 var tables = new HashMap[MClass, Array[nullable MClass]]
 167                 for mclass in mclasses do
 168                         var table = new Array[nullable MClass]
 169                         var supers = new Array[MClass]
 170                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 171                                 supers = mclass.in_hierarchy(mainmodule).greaters.to_a
 172                         end
 173                         for sup in supers do
 174                                 var color = class_colors[sup]
 175                                 if table.length <= color then
 176                                         for i in [table.length .. color[ do
 177                                                 table[i] = null
 178                                         end
 179                                 end
 180                                 table[color] = sup
 181                         end
 182                         tables[mclass] = table
 183                 end
 184                 return tables
 185         end
 186
 187         redef fun compile_header_structs do
 188                 self.header.add_decl("typedef void(*nitmethod_t)(void); /* general C type representing a Nit method. */")
 189                 self.compile_header_attribute_structs
 190                 self.header.add_decl("struct class \{ int id; const char *name; int box_kind; int color; const struct vts_table *vts_table; const struct type_table *type_table; nitmethod_t vft[]; \}; /* general C type representing a Nit class. */")
 191                 self.header.add_decl("struct type_table \{ int size; int table[]; \}; /* colorized type table. */")
 192                 self.header.add_decl("struct vts_entry \{ short int is_nullable; const struct class *class; \}; /* link (nullable or not) between the vts and is bound. */")
 193                 self.header.add_decl("struct vts_table \{ int dummy; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 194                 self.header.add_decl("typedef struct instance \{ const struct class *class; nitattribute_t attrs[1]; \} val; /* general C type representing a Nit instance. */")
 195         end
 196
 197         redef fun compile_class_to_c(mclass: MClass)
 198         do
 199                 var mtype = mclass.intro.bound_mtype
 200                 var c_name = mclass.c_name
 201
 202                 var vft = self.method_tables[mclass]
 203                 var attrs = self.attr_tables[mclass]
 204                 var class_table = self.class_tables[mclass]
 205                 var v = self.new_visitor
 206
 207                 var rta = runtime_type_analysis
 208                 var is_dead = false # mclass.kind == abstract_kind or mclass.kind == interface_kind
 209                 if not is_dead and rta != null and not rta.live_classes.has(mclass) and not mtype.is_c_primitive and mclass.name != "NativeArray" then
 210                         is_dead = true
 211                 end
 212
 213                 v.add_decl("/* runtime class {c_name} */")
 214
 215                 self.provide_declaration("class_{c_name}", "extern const struct class class_{c_name};")
 216                 v.add_decl("extern const struct type_table type_table_{c_name};")
 217
 218                 # Build class vft
 219                 v.add_decl("const struct class class_{c_name} = \{")
 220                 v.add_decl("{class_ids[mclass]},")
 221                 v.add_decl("\"{mclass.name}\", /* class_name_string */")
 222                 v.add_decl("{self.box_kind_of(mclass)}, /* box_kind */")
 223                 v.add_decl("{class_colors[mclass]},")
 224                 if not is_dead then
 225                         if build_class_vts_table(mclass) then
 226                                 v.require_declaration("vts_table_{c_name}")
 227                                 v.add_decl("&vts_table_{c_name},")
 228                         else
 229                                 v.add_decl("NULL,")
 230                         end
 231                         v.add_decl("&type_table_{c_name},")
 232                         v.add_decl("\{")
 233                         for i in [0 .. vft.length[ do
 234                                 var mpropdef = vft[i]
 235                                 if mpropdef == null then
 236                                         v.add_decl("NULL, /* empty */")
 237                                 else
 238                                         assert mpropdef isa MMethodDef
 239                                         if rta != null and not rta.live_methoddefs.has(mpropdef) then
 240                                                 v.add_decl("NULL, /* DEAD {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 241                                                 continue
 242                                         end
 243                                         var rf = mpropdef.virtual_runtime_function
 244                                         v.require_declaration(rf.c_name)
 245                                         v.add_decl("(nitmethod_t){rf.c_name}, /* pointer to {mpropdef.full_name} */")
 246                                 end
 247                         end
 248                         v.add_decl("\}")
 249                 end
 250                 v.add_decl("\};")
 251
 252                 # Build class type table
 253
 254                 v.add_decl("const struct type_table type_table_{c_name} = \{")
 255                 v.add_decl("{class_table.length},")
 256                 v.add_decl("\{")
 257                 for msuper in class_table do
 258                         if msuper == null then
 259                                 v.add_decl("-1, /* empty */")
 260                         else
 261                                 v.add_decl("{self.class_ids[msuper]}, /* {msuper} */")
 262                         end
 263                 end
 264                 v.add_decl("\}")
 265                 v.add_decl("\};")
 266
 267                 if mtype.is_c_primitive or mtype.mclass.name == "Pointer" then
 268                         #Build instance struct
 269                         self.header.add_decl("struct instance_{c_name} \{")
 270                         self.header.add_decl("const struct class *class;")
 271                         self.header.add_decl("{mtype.ctype} value;")
 272                         self.header.add_decl("\};")
 273
 274                         #Build BOX
 275                         self.provide_declaration("BOX_{c_name}", "val* BOX_{c_name}({mtype.ctype_extern});")
 276                         v.add_decl("/* allocate {mtype} */")
 277                         v.add_decl("val* BOX_{mtype.c_name}({mtype.ctype} value) \{")
 278                         v.add("struct instance_{c_name}*res = nit_alloc(sizeof(struct instance_{c_name}));")
 279                         v.require_declaration("class_{c_name}")
 280                         v.add("res->class = &class_{c_name};")
 281                         v.add("res->value = value;")
 282                         v.add("return (val*)res;")
 283                         v.add("\}")
 284
 285                         if mtype.mclass.name != "Pointer" then return
 286
 287                         v = new_visitor
 288                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}();")
 289                         v.add_decl("/* allocate {mtype} */")
 290                         v.add_decl("{mtype.ctype} NEW_{c_name}() \{")
 291                         if is_dead then
 292                                 v.add_abort("{mclass} is DEAD")
 293                         else
 294                                 var res = v.new_named_var(mtype, "self")
 295                                 res.is_exact = true
 296                                 v.add("{res} = nit_alloc(sizeof(struct instance_{mtype.c_name}));")
 297                                 v.require_declaration("class_{c_name}")
 298                                 v.add("{res}->class = &class_{c_name};")
 299                                 v.add("((struct instance_{mtype.c_name}*){res})->value = NULL;")
 300                                 v.add("return {res};")
 301                         end
 302                         v.add("\}")
 303                         return
 304                 else if mclass.name == "NativeArray" then
 305                         #Build instance struct
 306                         self.header.add_decl("struct instance_{c_name} \{")
 307                         self.header.add_decl("const struct class *class;")
 308                         self.header.add_decl("int length;")
 309                         self.header.add_decl("val* values[];")
 310                         self.header.add_decl("\};")
 311
 312                         #Build NEW
 313                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(int length);")
 314                         v.add_decl("/* allocate {mtype} */")
 315                         v.add_decl("{mtype.ctype} NEW_{c_name}(int length) \{")
 316                         var res = v.get_name("self")
 317                         v.add_decl("struct instance_{c_name} *{res};")
 318                         var mtype_elt = mtype.arguments.first
 319                         v.add("{res} = nit_alloc(sizeof(struct instance_{c_name}) + length*sizeof({mtype_elt.ctype}));")
 320                         v.require_declaration("class_{c_name}")
 321                         v.add("{res}->class = &class_{c_name};")
 322                         v.add("{res}->length = length;")
 323                         v.add("return (val*){res};")
 324                         v.add("\}")
 325                         return
 326                 else if mtype.mclass.kind == extern_kind and mtype.mclass.name != "NativeString" then
 327                         var pointer_type = mainmodule.pointer_type
 328
 329                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}();")
 330                         v.add_decl("/* allocate {mtype} */")
 331                         v.add_decl("{mtype.ctype} NEW_{c_name}() \{")
 332                         if is_dead then
 333                                 v.add_abort("{mclass} is DEAD")
 334                         else
 335                                 var res = v.new_named_var(mtype, "self")
 336                                 res.is_exact = true
 337                                 v.add("{res} = nit_alloc(sizeof(struct instance_{pointer_type.c_name}));")
 338                                 #v.add("{res}->type = type;")
 339                                 v.require_declaration("class_{c_name}")
 340                                 v.add("{res}->class = &class_{c_name};")
 341                                 v.add("((struct instance_{pointer_type.c_name}*){res})->value = NULL;")
 342                                 v.add("return {res};")
 343                         end
 344                         v.add("\}")
 345                         return
 346                 end
 347
 348                 #Build NEW
 349                 self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(void);")
 350                 v.add_decl("/* allocate {mtype} */")
 351                 v.add_decl("{mtype.ctype} NEW_{c_name}(void) \{")
 352                 if is_dead then
 353                         v.add_abort("{mclass} is DEAD")
 354                 else
 355
 356                         var res = v.new_named_var(mtype, "self")
 357                         res.is_exact = true
 358                         v.add("{res} = nit_alloc(sizeof(struct instance) + {attrs.length}*sizeof(nitattribute_t));")
 359                         v.require_declaration("class_{c_name}")
 360                         v.add("{res}->class = &class_{c_name};")
 361                         self.generate_init_attr(v, res, mtype)
 362                         v.set_finalizer res
 363                         v.add("return {res};")
 364                 end
 365                 v.add("\}")
 366         end
 367
 368         private fun build_class_vts_table(mclass: MClass): Bool do
 369                 if self.vt_tables[mclass].is_empty then return false
 370
 371                 self.provide_declaration("vts_table_{mclass.c_name}", "extern const struct vts_table vts_table_{mclass.c_name};")
 372
 373                 var v = new_visitor
 374                 v.add_decl("const struct vts_table vts_table_{mclass.c_name} = \{")
 375                 v.add_decl("0, /* dummy */")
 376                 v.add_decl("\{")
 377
 378                 for vt in self.vt_tables[mclass] do
 379                         if vt == null then
 380                                 v.add_decl("\{-1, NULL\}, /* empty */")
 381                         else
 382                                 var is_null = 0
 383                                 var bound = retrieve_vt_bound(mclass.intro.bound_mtype, vt.as(MVirtualTypeDef).bound)
 384                                 while bound isa MNullableType do
 385                                         bound = retrieve_vt_bound(mclass.intro.bound_mtype, bound.mtype)
 386                                         is_null = 1
 387                                 end
 388                                 var vtclass = bound.as(MClassType).mclass
 389                                 v.require_declaration("class_{vtclass.c_name}")
 390                                 v.add_decl("\{{is_null}, &class_{vtclass.c_name}\}, /* {vt} */")
 391                         end
 392                 end
 393                 v.add_decl("\},")
 394                 v.add_decl("\};")
 395                 return true
 396         end
 397
 398         private fun retrieve_vt_bound(anchor: MClassType, mtype: nullable MType): MType do
 399                 if mtype == null then
 400                         print "NOT YET IMPLEMENTED: retrieve_vt_bound on null"
 401                         abort
 402                 end
 403                 if mtype isa MVirtualType then
 404                         return mtype.anchor_to(mainmodule, anchor)
 405                 else if mtype isa MParameterType then
 406                         return mtype.anchor_to(mainmodule, anchor)
 407                 else
 408                         return mtype
 409                 end
 410         end
 411
 412         redef fun compile_types
 413         do
 414                 compile_color_consts(vt_colors)
 415         end
 416
 417         redef fun new_visitor do return new SeparateErasureCompilerVisitor(self)
 418
 419         # Stats
 420
 421         private var class_tables: Map[MClass, Array[nullable MClass]] is noinit
 422         private var vt_tables: Map[MClass, Array[nullable MPropDef]] is noinit
 423
 424         redef fun display_sizes
 425         do
 426                 print "# size of subtyping tables"
 427                 print "\ttotal \tholes"
 428                 var total = 0
 429                 var holes = 0
 430                 for t, table in class_tables do
 431                         total += table.length
 432                         for e in table do if e == null then holes += 1
 433                 end
 434                 print "\t{total}\t{holes}"
 435
 436                 print "# size of resolution tables"
 437                 print "\ttotal \tholes"
 438                 total = 0
 439                 holes = 0
 440                 for t, table in vt_tables do
 441                         total += table.length
 442                         for e in table do if e == null then holes += 1
 443                 end
 444                 print "\t{total}\t{holes}"
 445
 446                 print "# size of methods tables"
 447                 print "\ttotal \tholes"
 448                 total = 0
 449                 holes = 0
 450                 for t, table in method_tables do
 451                         total += table.length
 452                         for e in table do if e == null then holes += 1
 453                 end
 454                 print "\t{total}\t{holes}"
 455
 456                 print "# size of attributes tables"
 457                 print "\ttotal \tholes"
 458                 total = 0
 459                 holes = 0
 460                 for t, table in attr_tables do
 461                         total += table.length
 462                         for e in table do if e == null then holes += 1
 463                 end
 464                 print "\t{total}\t{holes}"
 465         end
 466 end
 467
 468 class SeparateErasureCompilerVisitor
 469         super SeparateCompilerVisitor
 470
 471         redef fun compile_callsite(callsite, arguments)
 472         do
 473                 var res = super
 474                 if callsite.erasure_cast and not self.compiler.as(SeparateErasureCompiler).modelbuilder.toolcontext.opt_no_check_erasure_cast.value then
 475                         assert res != null
 476                         var mtype = callsite.msignature.return_mtype
 477                         assert mtype != null
 478                         self.add("/* Erasure cast for return {res} isa {mtype} */")
 479                         var cond = self.type_test(res, mtype, "erasure")
 480                         self.add("if (!{cond}) \{")
 481                         #var x = self.class_name_string(res)
 482                         #var y = self.class_name_string(arguments.first)
 483                         #self.add("PRINT_ERROR(\"Erasure cast: expected {mtype} (self is %s), got %s for {res}\\n\", {y}, {x});")
 484                         self.add_abort("Cast failed")
 485                         self.add("\}")
 486                 end
 487                 return res
 488         end
 489
 490         redef fun init_instance(mtype)
 491         do
 492                 self.require_declaration("NEW_{mtype.mclass.c_name}")
 493                 return self.new_expr("NEW_{mtype.mclass.c_name}()", mtype)
 494         end
 495
 496         redef fun type_test(value, mtype, tag)
 497         do
 498                 self.add("/* type test for {value.inspect} isa {mtype} */")
 499
 500                 var res = self.new_var(bool_type)
 501
 502                 var cltype = self.get_name("cltype")
 503                 self.add_decl("int {cltype};")
 504                 var idtype = self.get_name("idtype")
 505                 self.add_decl("int {idtype};")
 506
 507                 var maybe_null = self.maybe_null(value)
 508                 var accept_null = "0"
 509                 if mtype isa MNullableType then
 510                         mtype = mtype.mtype
 511                         accept_null = "1"
 512                 end
 513                 if mtype isa MParameterType then
 514                         # Here we get the bound of the the formal type (eh, erasure...)
 515                         mtype = mtype.resolve_for(self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.mmodule, false)
 516                         if mtype isa MNullableType then
 517                                 mtype = mtype.mtype
 518                                 accept_null = "1"
 519                         end
 520                 end
 521
 522                 if value.mcasttype.is_subtype(self.frame.mpropdef.mclassdef.mmodule, self.frame.mpropdef.mclassdef.bound_mtype, mtype) then
 523                         self.add("{res} = 1; /* easy {value.inspect} isa {mtype}*/")
 524                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 525                                 self.compiler.count_type_test_skipped[tag] += 1
 526                                 self.add("count_type_test_skipped_{tag}++;")
 527                         end
 528                         return res
 529                 end
 530
 531                 var class_ptr
 532                 if not value.mtype.is_c_primitive then
 533                         class_ptr = "{value}->class->"
 534                 else
 535                         var mclass = value.mtype.as(MClassType).mclass
 536                         self.require_declaration("class_{mclass.c_name}")
 537                         class_ptr = "class_{mclass.c_name}."
 538                 end
 539
 540                 if mtype isa MClassType then
 541                         self.require_declaration("class_{mtype.mclass.c_name}")
 542                         self.add("{cltype} = class_{mtype.mclass.c_name}.color;")
 543                         self.add("{idtype} = class_{mtype.mclass.c_name}.id;")
 544                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 545                                 self.compiler.count_type_test_resolved[tag] += 1
 546                                 self.add("count_type_test_resolved_{tag}++;")
 547                         end
 548                 else if mtype isa MVirtualType then
 549                         var recv = self.frame.arguments.first
 550                         var recv_ptr
 551                         if not recv.mtype.is_c_primitive then
 552                                 recv_ptr = "{recv}->class->"
 553                         else
 554                                 var mclass = recv.mtype.as(MClassType).mclass
 555                                 self.require_declaration("class_{mclass.c_name}")
 556                                 recv_ptr = "class_{mclass.c_name}."
 557                         end
 558                         var entry = self.get_name("entry")
 559                         self.add("struct vts_entry {entry};")
 560                         self.require_declaration(mtype.mproperty.const_color)
 561                         self.add("{entry} = {recv_ptr}vts_table->vts[{mtype.mproperty.const_color}];")
 562                         self.add("{cltype} = {entry}.class->color;")
 563                         self.add("{idtype} = {entry}.class->id;")
 564                         if maybe_null and accept_null == "0" then
 565                                 var is_nullable = self.get_name("is_nullable")
 566                                 self.add_decl("short int {is_nullable};")
 567                                 self.add("{is_nullable} = {entry}.is_nullable;")
 568                                 accept_null = is_nullable.to_s
 569                         end
 570                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 571                                 self.compiler.count_type_test_unresolved[tag] += 1
 572                                 self.add("count_type_test_unresolved_{tag}++;")
 573                         end
 574                 else
 575                         self.debug("type_test({value.inspect}, {mtype})")
 576                         abort
 577                 end
 578
 579                 # check color is in table
 580                 if maybe_null then
 581                         self.add("if({value} == NULL) \{")
 582                         self.add("{res} = {accept_null};")
 583                         self.add("\} else \{")
 584                 end
 585                 self.add("if({cltype} >= {class_ptr}type_table->size) \{")
 586                 self.add("{res} = 0;")
 587                 self.add("\} else \{")
 588                 self.add("{res} = {class_ptr}type_table->table[{cltype}] == {idtype};")
 589                 self.add("\}")
 590                 if maybe_null then
 591                         self.add("\}")
 592                 end
 593
 594                 return res
 595         end
 596
 597         redef fun unbox_extern(value, mtype)
 598         do
 599                 if mtype isa MClassType and mtype.mclass.kind == extern_kind and
 600                    mtype.mclass.name != "NativeString" then
 601                         var pointer_type = compiler.mainmodule.pointer_type
 602                         var res = self.new_var_extern(mtype)
 603                         self.add "{res} = ((struct instance_{pointer_type.c_name}*){value})->value; /* unboxing {value.mtype} */"
 604                         return res
 605                 else
 606                         return value
 607                 end
 608         end
 609
 610         redef fun box_extern(value, mtype)
 611         do
 612                 if mtype isa MClassType and mtype.mclass.kind == extern_kind and
 613                    mtype.mclass.name != "NativeString" then
 614                         var valtype = compiler.mainmodule.pointer_type
 615                         var res = self.new_var(mtype)
 616                         if compiler.runtime_type_analysis != null and not compiler.runtime_type_analysis.live_types.has(value.mtype.as(MClassType)) then
 617                                 self.add("/*no boxing of {value.mtype}: {value.mtype} is not live! */")
 618                                 self.add("PRINT_ERROR(\"Dead code executed!\\n\"); show_backtrace(1);")
 619                                 return res
 620                         end
 621                         self.require_declaration("BOX_{valtype.c_name}")
 622                         self.add("{res} = BOX_{valtype.c_name}({value}); /* boxing {value.mtype} */")
 623                         self.require_declaration("class_{mtype.c_name}")
 624                         self.add("{res}->class = &class_{mtype.c_name};")
 625                         return res
 626                 else
 627                         return value
 628                 end
 629         end
 630
 631         redef fun class_name_string(value)
 632         do
 633                 var res = self.get_name("var_class_name")
 634                 self.add_decl("const char* {res};")
 635                 if not value.mtype.is_c_primitive then
 636                         self.add "{res} = {value} == NULL ? \"null\" : {value}->class->name;"
 637                 else
 638                         self.require_declaration("class_{value.mtype.c_name}")
 639                         self.add "{res} = class_{value.mtype.c_name}.name;"
 640                 end
 641                 return res
 642         end
 643
 644         redef fun native_array_instance(elttype, length)
 645         do
 646                 var nclass = self.get_class("NativeArray")
 647                 var mtype = nclass.get_mtype([elttype])
 648                 var res = self.new_var(mtype)
 649                 res.is_exact = true
 650                 self.require_declaration("NEW_{nclass.c_name}")
 651                 self.add("{res} = NEW_{nclass.c_name}({length});")
 652                 return res
 653         end
 654
 655         redef fun calloc_array(ret_type, arguments)
 656         do
 657                 var ret = ret_type.as(MClassType)
 658                 self.require_declaration("NEW_{ret.mclass.c_name}")
 659                 self.ret(self.new_expr("NEW_{ret.mclass.c_name}({arguments[1]})", ret_type))
 660         end
 661 end